gschem/configure.ac.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT
   3 AC_CONFIG_SRCDIR([src/gschem.c])
   4 AC_PREREQ(2.54)
   5
   6 PACKAGE=geda-gschem
   7 DOTTED_VERSION=1.5.1
   8 DATE_VERSION=20081221
   9 echo Configuring $PACKAGE version $DOTTED_VERSION.$DATE_VERSION
  10
  11 # Initialize automake
  12 AM_INIT_AUTOMAKE($PACKAGE, $DOTTED_VERSION, no-define)
  13 AM_CONFIG_HEADER([config.h])
  14 AC_SUBST([CONFIG_DEPENDENCIES], ['$(top_srcdir)/configure.ac.in'])
  15
  16 # Call this to make autoconf and friends happy
  17 AC_GNU_SOURCE
  18
  19 #########################################################################
  20 # Command line flags start
  21 #
  22 # --disable-stroke : turn off stroke support
  23 AC_ARG_ENABLE(stroke,
  24     [  --disable-stroke       Disable stroke support (don't use LibStroke at all)], [ if test $enableval = "no"; then
  25          no_stroke=yes
  26         fi ])
  27
  28 # Change default location for rc files
  29 AC_ARG_WITH(rcdir, [  --with-rcdir=path       Change where the system-*rc files are installed], [opt_rcdir=$withval])
  30
  31 # Change default location for XDG files (.desktop and icons)
  32 AC_ARG_WITH(xdgdatadir, [  --with-xdgdatadir=path  Change where the .desktop file and theme icons are installed [[DATADIR]]], [opt_xdgdatadir=$withval])
  33
  34 # Allow the user to specify where there libstroke library lives
  35 AC_ARG_WITH(stroke, [  --with-stroke=DIR       Tell configure where to find libstroke], [opt_stroke=$withval])
  36
  37 #
  38 # Command line flags end
  39 #########################################################################
  40
  41 #########################################################################
  42 #
  43 # Misc win32 / mingw checks and variables start
  44 AC_CANONICAL_HOST
  45
  46 # Figure out if we are building on win32 and what environment.
  47 case $host_os in
  48   *mingw32* ) echo "Configuring for mingw"; MINGW=yes ;;
  49 esac
  50
  51 if ! test "$MINGW" = "no" -o "$MINGW"x = x; then
  52    MINGW="yes"
  53    MINGW_CFLAGS="-mms-bitfields -mwindows"
  54 else
  55    # Unix host
  56    MINGW="no"
  57    MINGW_CFLAGS=
  58 fi
  59
  60 #
  61 # Misc win32 / mingw checks and variables end
  62 #########################################################################
  63
  64 # Checks for programs.
  65 AC_PROG_CC
  66 AM_CONDITIONAL(CCISGCC, test "$GCC" = "yes")
  67 AC_PROG_CPP
  68 AC_PROG_MAKE_SET
  69 IT_PROG_INTLTOOL(0.35.0)
  70
  71 ############################################################################
  72 # Update desktop database utility start
  73 #
  74
  75 AC_ARG_ENABLE(update-desktop-database,
  76    AC_HELP_STRING([--disable-update-desktop-database],
  77                    [do not update desktop file database after installation]),,
  78                    enable_update_desktop_database=yes)
  79
  80 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOP_DATABASE,
  81                test x$enable_update_desktop_database = xyes)
  82
  83 if test x$enable_update_desktop_database = xyes ; then
  84   AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, [update-desktop-database], no)
  85   if test $UPDATE_DESKTOP_DATABASE = no; then
  86      AC_MSG_ERROR([Cannot find update-desktop-database, make sure it is installed and in your PATH, or configure with --disable-update-desktop-database])
  87   fi
  88 fi
  89
  90 #
  91 # Update desktop database utility end
  92 ############################################################################
  93
  94 ############################################################################
  95 # Check for guile start
  96
  97 # Check for pkg-config
  98 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  99 if test $PKG_CONFIG = no; then
 100    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed and in your PATH])
 101 fi
 102
 103 PKG_CHECK_MODULES(GUILE, guile-1.8, GUILE_PC="yes", no_GUILE_PC="yes")
 104
 105 if test "$GUILE_PC" = "yes"
 106 then
 107
 108    GUILE_VERSION=`$PKG_CONFIG guile-1.8 --modversion`
 109
 110 else
 111
 112    # Find about the installed guile
 113    GUILE_FLAGS
 114    GUILE_VERSION=`$GUILE_CONFIG info guileversion`
 115
 116 fi
 117
 118 # Check Guile version
 119 guile_need_major=1
 120 guile_need_minor=6
 121 guile_need_version="$guile_need_major[].$guile_need_minor.0"
 122
 123 AC_MSG_CHECKING([Guile version >= $guile_need_version])
 124
 125 guile_major=`echo "$GUILE_VERSION" | sed 's/\([[^.]][[^.]]*\).*/\1/'`
 126 guile_minor=`echo "$GUILE_VERSION" | sed 's/[[^.]][[^.]]*.\([[^.]][[^.]]*\).*/\1/'`
 127 AC_MSG_RESULT($GUILE_VERSION)
 128
 129 if test "$guile_need_major" -gt "$guile_major" \
 130    || (test "$guile_need_major" -eq "$guile_major" \
 131        && test "$guile_need_minor" -gt "$guile_minor"); then
 132   AC_MSG_ERROR([Guile version >= $guile_need_version is required.])
 133 fi
 134
 135 # Guile 1.6 compatability
 136
 137 CFLAGS_temp_save="$CFLAGS"
 138 CFLAGS="$CFLAGS $GUILE_CFLAGS"
 139 AC_CHECK_DECLS([scm_is_string, scm_is_integer, scm_to_int,
 140 scm_from_int,  scm_is_true,    scm_is_false,
 141 scm_from_locale_string, scm_to_locale_string,
 142 scm_from_locale_symbol],,,
 143 [#include <libguile.h>])
 144 CFLAGS="$CFLAGS_temp_save"
 145
 146 AH_VERBATIM(SCM_IS_STRING, [#if !HAVE_DECL_SCM_IS_STRING
 147 #  define scm_is_string(x) SCM_STRINGP(x)
 148 #endif])
 149 AH_VERBATIM(SCM_IS_INTEGER, [#if !HAVE_DECL_SCM_IS_INTEGER
 150 #  define scm_is_integer(x) SCM_INUMP(x)
 151 #endif])
 152 AH_VERBATIM(SCM_TO_INT, [#if !HAVE_DECL_SCM_TO_INT
 153 #  define scm_to_int(x)     SCM_INUM(x)
 154 #endif])
 155 AH_VERBATIM(SCM_FROM_INT, [#if !HAVE_DECL_SCM_FROM_INT
 156 #  define scm_from_int(x)   SCM_MAKINUM(x)
 157 #endif])
 158 AH_VERBATIM(SCM_IS_TRUE, [#if !HAVE_DECL_SCM_IS_TRUE
 159 #  define scm_is_true(x)    SCM_NFALSEP(x)
 160 #endif])
 161 AH_VERBATIM(SCM_IS_FALSE, [#if !HAVE_DECL_SCM_IS_FALSE
 162 #  define scm_is_false(x)   SCM_FALSEP(x)
 163 #endif])
 164 AH_VERBATIM(SCM_FROM_LOCALE_STRING, [#if !HAVE_DECL_SCM_FROM_LOCALE_STRING
 165 #  define scm_from_locale_string(x) scm_makfrom0str(x)
 166 #endif])
 167 AH_VERBATIM(SCM_TO_LOCALE_STRING, [#if !HAVE_DECL_SCM_TO_LOCALE_STRING
 168 #  define scm_to_locale_string(x)   strdup(SCM_STRING_CHARS(x))
 169 #endif])
 170 AH_VERBATIM(SCM_FROM_LOCALE_SYMBOL, [#if !HAVE_DECL_SCM_FROM_LOCALE_SYMBOL
 171 #  define scm_from_locale_symbol(x)   scm_string_to_symbol (scm_from_locale_string(x))
 172 #endif])
 173
 174 #
 175 # Check for guile end
 176 ############################################################################
 177
 178 ############################################################################
 179 # Check for mics things start
 180 #
 181 # Checking for rint in math library
 182 AC_CHECK_LIB(m, rint, AC_DEFINE(HAS_RINT, 1, [If your math library has rint in it, define this]), no_RINT="yes")
 183
 184 # Checking for dynamic lib
 185 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", DL_LIB="")
 186 #
 187 # Check for mics things start
 188 ############################################################################
 189
 190 ############################################################################
 191 # Check for X11 start
 192 #
 193
 194 if test "$MINGW" = "no"
 195 then
 196    AC_PATH_X
 197    AC_PATH_XTRA
 198
 199    X_EXTRA_LIBS="$X_EXTRA_LIBS"
 200    X_LDFLAGS="$X_LDFLAGS $X_LIBS $X_EXTRA_LIBS $X_PRE_LIBS -lX11 -lm"
 201
 202    _use_rpath=no
 203    AC_MSG_CHECKING([if hardcoding of the X11 runtime library path is desired])
 204    AC_ARG_ENABLE([rpath],
 205        [  --enable-rpath         Enable hardcoding the X11 runtime library path [default=disabled]],
 206        [
 207         if test "X$enable_rpath" = "Xno" ; then
 208            AC_MSG_RESULT([no])
 209            _use_rpath=no
 210         else
 211            AC_MSG_RESULT([yes])
 212            _use_rpath=yes
 213         fi
 214        ],
 215        [
 216            AC_MSG_RESULT([no])
 217            _use_rpath=no
 218        ])
 219
 220    if test "X$_use_rpath" = "Xyes" ; then
 221       # Try to figure out if we need -Rpath for finding X11 libs
 222       # at runtime.  Why autoconf doesn't already do this, I don't
 223       # know...
 224       xlib_path=""
 225       for p in $X_LDFLAGS ; do
 226             case $p in
 227             -L*)
 228                 xlib_path="$xlib_path $p"
 229                 ;;
 230                 esac
 231       done
 232
 233       _save_LIBS=$LIBS
 234       LIBS="$LIBS $X_LDFLAGS"
 235       rpath=""
 236       for fl in "-Wl,-rpath " "-Wl,--rpath " "-rpath " "--rpath " "-Wl,-R" "-R" "-R " ; do
 237           xlib_rpath=`echo $xlib_path | sed "s/-L/$fl/g"`
 238           LIBS="$_save_LIBS $X_LIBS $xlib_rpath"
 239           AC_MSG_CHECKING([if the compiler accepts ${fl}path for runtime libraries])
 240           AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 241           AC_MSG_RESULT([yes])
 242             rpath=$fl,
 243             AC_MSG_RESULT([no]))
 244             test -n "$rpath" && break
 245       done
 246       if test -n "$rpath"; then
 247          X_LDFLAGS="$X_LDFLAGS $xlib_rpath"
 248       fi
 249       LIBS=$_save_LIBS
 250    fi
 251
 252 fi
 253
 254 #
 255 # Check for X11 end
 256 ############################################################################
 257
 258 ############################################################################
 259 # Check for gtk+ start
 260 #
 261
 262 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, GTK="yes", no_GTK="yes")
 263
 264 # This next bit of code figures out what gtk we need to use.
 265 if test "$GTK" = "yes"
 266 then
 267    GTK_VERSION=`$PKG_CONFIG gtk+-2.0 --modversion`
 268
 269    # Search for glib
 270    PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.8.0, GLIB="yes", no_GLIB="yes")
 271    if test "$GLIB" != "yes"
 272    then
 273        AC_MSG_ERROR([Cannot find glib 2.8.0 or later, please install it and rerun ./configure.])
 274    fi
 275    GLIB_VERSION=`$PKG_CONFIG glib-2.0 --modversion`
 276
 277    # Search for gthread
 278    PKG_CHECK_MODULES(GTHREAD, gthread-2.0, GTHREAD="yes", no_GTHREAD="yes")
 279    if test "$GTHREAD" = "yes"
 280    then
 281        AC_DEFINE(HAVE_GTHREAD, 1, [If gthread support is installed, define this])
 282    fi
 283
 284 else
 285    GTK_VERSION=""
 286 fi
 287
 288 if test "$GTK_VERSION" = ""
 289 then
 290    AC_MSG_ERROR([Cannot find gtk+ 2.8.0 or later, please install it and rerun ./configure.])
 291 fi
 292
 293 #
 294 # Check for gtk+ end
 295 ############################################################################
 296
 297 ############################################################################
 298 # Check for cairo start
 299 #
 300
 301 AC_ARG_ENABLE(cairo,
 302    AC_HELP_STRING([--disable-cairo],
 303                   [Disable the use of cairo for rendering]), , enable_cairo=yes)
 304
 305 AM_CONDITIONAL(ENABLE_CAIRO, test "x$enable_cairo" = "xyes")
 306
 307 PKG_CHECK_MODULES(CAIRO, cairo >= 1.2.0, CAIRO="yes", no_CAIRO="yes")
 308
 309 if test "x$enable_cairo" != "xyes"
 310 then
 311    AC_DEFINE(ENABLE_CAIRO, 1, [If cairo rendering is enabled, define this])
 312
 313    if test "$CAIRO" = "yes"
 314    then
 315       CAIRO_VERSION=`$PKG_CONFIG cairo --modversion`
 316    else
 317       AC_MSG_ERROR([Cannot find cairo 1.2.0 or later, please install or configure with --disable-cairo])
 318    fi
 319 fi
 320
 321 #
 322 # Check for cairo end
 323 ############################################################################
 324
 325 ############################################################################
 326 # Check for libgeda start
 327 #
 328 PKG_CHECK_MODULES(LIBGEDA, libgeda >= $DATE_VERSION, LIBGEDA="yes",
 329                   no_LIBGEDA="yes")
 330
 331 if test "$LIBGEDA" = "yes"
 332 then
 333    LIBGEDA_VERSION=`$PKG_CONFIG libgeda --modversion`
 334 else
 335    AC_MSG_ERROR([libgeda detection error: $LIBGEDA_PKG_ERRORS])
 336 fi
 337
 338 #
 339 # Check for libgeda end
 340 ############################################################################
 341
 342 ############################################################################
 343 # Check for libstroke start
 344 #
 345
 346 # user specified --with-stroke
 347 if eval "test x$opt_stroke != x"; then
 348    LIBSTROKE_LIBS="-L$opt_stroke/lib"
 349    LIBSTROKE_CFLAGS="-I$opt_stroke/include"
 350 fi
 351
 352 # only check if the user has not disable strokes
 353 if test "$no_stroke" != "yes"; then
 354    save_cppflags="$CPPFLAGS"
 355    save_ldflags="$LDFLAGS"
 356    CPPFLAGS="$CPPFLAGS $LIBSTROKE_CFLAGS"
 357    LDFLAGS="$LDFLAGS $LIBSTROKE_LIBS"
 358    AC_CHECK_LIB(stroke, stroke_init, LIBSTROKE="yes", LIBSTROKE="no")
 359    CPPFLAGS="$save_cppflags"
 360    LDFLAGS="$save_ldflags"
 361 fi
 362
 363 if test "$LIBSTROKE" = "yes"; then
 364    AC_DEFINE(HAS_LIBSTROKE, 1, [Define if you have libstroke installed])
 365    if eval "test x$opt_stroke = x"; then
 366        LIBSTROKE_LIBS="-lstroke"
 367        LIBSTROKE_CFLAGS=""
 368    else
 369        LIBSTROKE_LIBS="$LIBSTROKE_LIBS -lstroke"
 370        # LIBSTROKE_CFLAGS set above
 371    fi
 372 fi
 373
 374 if test "$no_stroke" = "yes"; then
 375    echo "**                                **"
 376    echo "** Disabling libstroke by request **"
 377    echo "**                                **"
 378    LIBSTROKE_LIB=""
 379    LIBSTROKE_CFLAGS=""
 380    LIBSTROKE="no"
 381 fi
 382
 383 #
 384 # Check for libstroke end
 385 ############################################################################
 386
 387 ############################################################################
 388 # Check for doxygen start
 389 #
 390 # Doxygen is a utility for generating html and latex documentation
 391 # from c source code files.
 392
 393 # search for Doxygen
 394 AC_PATH_PROG(DOXYGEN, doxygen, no, ${PATH})
 395
 396 if test "$DOXYGEN" = "no"; then
 397    # doxygen is not available on the system
 398    echo "** Cannot find Doxygen! **"
 399    echo "**   Documentation creation disabled    **"
 400    DOXYGEN=echo
 401
 402    # prevent from weaving the nw files
 403    # but does not prevent from processing gschemdoc
 404    builddoc=false
 405 else
 406    # doxygen is available on the system.
 407    # now checking if the tools for Texinfo files processing
 408    # is installed.
 409    # The docs can be either processed to produce dvi, html or info
 410    # with texi2dvi, texi2html or makeinfo respectively
 411    # Note : these tests on makeinfo and texi2dvi are no more
 412    #        needed as automake makes them for us
 413
 414    # enable the creation of html and latex documents.
 415    builddoc=true
 416 fi
 417
 418 # depending on variable builddoc, weaving is performed or not
 419 # using conditionnal in docs/Makefile.in
 420 AM_CONDITIONAL(BUILDDOC, test x$builddoc = xtrue)
 421
 422 #
 423 # Check for doxygen end
 424 #########################################################################
 425
 426 #########################################################################
 427 # Check for groff start
 428 #
 429
 430 # search for groff
 431 AC_PATH_PROG(GROFF, groff, no, ${PATH})
 432 if test $GROFF = "no"; then
 433         echo "Cannot find groff, some documentation will not be created."
 434 fi
 435
 436 #
 437 # Check for groff end
 438 #########################################################################
 439
 440 #########################################################################
 441 # Checks for header files start
 442 #
 443 AC_HEADER_STDC
 444 AC_HEADER_SYS_WAIT
 445 AC_HEADER_DIRENT
 446 AC_CHECK_HEADERS(unistd.h string.h stdlib.h \
 447                  stdarg.h assert.h fcntl.h errno.h sys/param.h)
 448
 449 # Check for locale.h
 450
 451 # Set USE_NLS
 452 AM_NLS
 453 AC_CHECK_HEADER([locale.h],
 454                 [AC_DEFINE([HAVE_LOCALE_H], 1, [Define if you have locale.h])],
 455                 [
 456                   if test "$USE_NLS" = "yes"; then
 457                     AC_MSG_ERROR([Cannot find useful locale.h, and nls support is enabled. Try compiling with --disable-nls])
 458                   fi
 459                 ])
 460
 461 # Set package name for translations
 462 GETTEXT_PACKAGE=$PACKAGE
 463 AC_SUBST(GETTEXT_PACKAGE)
 464
 465 # Checks for typedefs, structures, and compiler characteristics.
 466 AC_C_CONST
 467
 468 # Checks for library functions.
 469 AC_TYPE_SIGNAL
 470 AC_CHECK_FUNCS(strstr getuid getgid)
 471
 472 AC_MSG_CHECKING([for optarg in unistd.h])
 473 AC_TRY_COMPILE(
 474 [#include <unistd.h>],
 475 [ char *string = optarg; int i = optind; ],
 476 optarg_found=yes,
 477 optarg_found=no)
 478 AC_MSG_RESULT($optarg_found)
 479
 480 if test $optarg_found = yes; then
 481     AC_DEFINE(OPTARG_IN_UNISTD, 1, [Define if you have optarg in unistd.h])
 482 fi
 483
 484 #
 485 # Checks for header files end
 486 #########################################################################
 487
 488 #########################################################################
 489 #
 490
 491 # ------------- dmalloc -------------------
 492 dnl dmalloc checks
 493 with_dmalloc="no"
 494 AC_MSG_CHECKING([if dmalloc debugging should be enabled])
 495 AC_ARG_ENABLE([dmalloc],
 496 [  --enable-dmalloc        Compile and link with dmalloc for malloc debugging [[default=no]]],
 497 [
 498 if test "X$enable_dmalloc" != "Xno" ; then
 499         AC_MSG_RESULT([yes])
 500         AC_CHECK_HEADER(dmalloc.h,,
 501                 AC_ERROR([You have requested dmalloc debugging but dmalloc.h could not be found]))
 502         AC_CHECK_LIB(dmalloc,main,,
 503                 AC_ERROR([You have requested dmalloc debugging but -ldmalloc could not be found]))
 504         DMALLOC_LIBS="-ldmalloc"
 505         with_dmalloc="yes"
 506 else
 507         AC_MSG_RESULT([no])
 508         DMALLOC_LIBS=""
 509 fi
 510 ],
 511 [
 512         AC_MSG_RESULT([no])
 513         DMALLOC_LIBS=""
 514 ])
 515
 516 # ------------- ElectricFence -------------------
 517 dnl ElectricFence checks
 518 with_efence="no"
 519 AC_MSG_CHECKING([if ElectricFence debugging should be enabled])
 520 AC_ARG_ENABLE([efence],
 521 [  --enable-efence         Link with ElectricFence for malloc debugging [[default=no]]],
 522 [
 523 if test "X$enable_efence" != "Xno" ; then
 524         AC_MSG_RESULT([yes])
 525         AC_CHECK_LIB(efence,main,,
 526                 AC_ERROR([You have requested ElectricFence debugging but -lefence could not be found]))
 527         with_efence="yes"
 528 else
 529         AC_MSG_RESULT([no])
 530 fi
 531 ],
 532 [
 533 AC_MSG_RESULT([no])
 534 ])
 535
 536 #
 537 #########################################################################
 538 #########################################################################
 539 # gEDA/gaf specific setup start
 540 #
 541
 542 DATADIR=gEDA
 543 GEDADATADIR=$datadir/$DATADIR
 544
 545 if eval "test x$opt_rcdir = x"; then
 546         # path was not specified with --with-rcdir
 547         AC_DEFINE_UNQUOTED(GEDARCDIR, "none", [gEDA/gaf's rc directory])
 548         GEDARCDIR=$GEDADATADIR
 549 else
 550         # path WAS specified with --with-rcdir
 551         AC_DEFINE_UNQUOTED(GEDARCDIR, "$opt_rcdir", [gEDA/gaf's rc directory])
 552         GEDARCDIR="$opt_rcdir"
 553 fi
 554
 555 if test x$opt_xdgdatadir = x; then
 556         # path was not specified with --with-xdgdatadir
 557         XDGDATADIR='${datadir}'
 558 else
 559         # path WAS specified with --with-xdgdatadir
 560         XDGDATADIR="$opt_xdgdatadir"
 561 fi
 562 AC_SUBST(XDGDATADIR)
 563
 564 # Expand the prefix variable
 565 # I don't like the way this is done, but it works (I hope).
 566 if eval "test x$prefix = xNONE"; then
 567  dprefix=$ac_default_prefix
 568 else
 569  dprefix=$prefix
 570 fi
 571
 572 gedatopdir=$dprefix/share/$DATADIR
 573 expandgedadatadir=`echo $gedatopdir`
 574
 575 gedadocdir=$dprefix/share/doc/geda-doc
 576 # --with-docdir : tells where to store documentation if not default
 577 AC_ARG_WITH(docdir,
 578     [  --with-docdir      Where to store documentation if not default.],
 579         gedadocdir=$withval)
 580 expandgedadocdir=`echo $gedadocdir`
 581 GEDADOCDIR=$expandgedadocdir
 582 AC_SUBST(GEDADOCDIR)
 583
 584 # this has to be expanded ( no ${prefix} ) --
 585 AC_DEFINE_UNQUOTED(GEDADATADIR, "$gedatopdir", [gEDA/gaf's data directory])
 586 AC_DEFINE_UNQUOTED(DATE_VERSION, "$DATE_VERSION", [Currently running date version of gEDA/gaf])
 587 AC_DEFINE_UNQUOTED(DOTTED_VERSION, "$DOTTED_VERSION", [Currently running dotted version of gEDA/gaf])
 588 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this program's package])
 589
 590 #
 591 # gEDA/gaf specify things which need to setup
 592 #########################################################################
 593
 594 # Initialized gettext
 595 AM_GNU_GETTEXT
 596 AM_GNU_GETTEXT_VERSION([%INSTALLED_GETTEXT_VERSION%])
 597
 598 #GETTEXT_PACKAGE=$PACKAGE
 599 #AC_SUBST(GETTEXT_PACKAGE)
 600 #AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"],
 601 #                   [The domain to use with gettext])
 602 #AM_GLIB_GNU_GETTEXT
 603
 604 # Finally create the final CFLAGS and LDFLAGS for use in the makefiles
 605 GSCHEM_CFLAGS="$MINGW_CFLAGS $LIBSTROKE_CFLAGS $LIBGEDA_CFLAGS $GTK_CFLAGS $GTHREAD_CFLAGS"
 606 GSCHEM_LDFLAGS="$LIBSTROKE_LIBS $LIBGEDA_LIBS $GTK_LIBS $X_LDFLAGS $DMALLOC_LIBS $GTHREAD_LIBS"
 607
 608 # Makefile.in variable substitution
 609 AC_SUBST(DATE_VERSION)
 610 AC_SUBST(DOTTED_VERSION)
 611 AC_SUBST(GSCHEM_CFLAGS)
 612 AC_SUBST(GSCHEM_LDFLAGS)
 613 AC_SUBST(GEDADATADIR)
 614 AC_SUBST(GEDARCDIR)
 615 AC_SUBST(GUILEINTERP)
 616 AC_SUBST(INDENT)
 617
 618 # Create all the necessary derived files
 619 AC_CONFIG_FILES([Makefile
 620                 m4/Makefile
 621                 po/Makefile.in
 622                 intl/Makefile
 623                 src/Makefile
 624                 include/Makefile
 625                 scheme/Makefile
 626                 bitmap/Makefile
 627                 scripts/Makefile
 628                 scripts/config.sh
 629                 examples/Makefile
 630                 docs/Makefile
 631                 lib/Makefile
 632                 tests/Makefile
 633                 data/Makefile
 634                 lib/system-gschemrc ])
 635
 636
 637 AC_OUTPUT
 638
 639 expandedGEDADATADIR=`eval "echo $GEDADATADIR"`
 640 expandedGEDARCDIR=`eval "echo $GEDARCDIR"`
 641 expandedXDGDATADIR=`eval "echo $XDGDATADIR"`
 642 expandedGEDADOCDIR=`eval "echo $GEDADOCDIR"`
 643
 644 if test "x$enable_cairo" = "xyes"
 645 then
 646   cairo_report=$CAIRO_VERSION
 647 else
 648   cairo_report="[[DISABLED]]"
 649 fi
 650
 651 AC_MSG_RESULT([
 652 ** Configuration summary for $PACKAGE $DOTTED_VERSION.$DATE_VERSION:
 653
 654    GTK+ library version:             $GTK_VERSION
 655    CAIRO library version:            $cairo_report
 656    GUILE library version:            $GUILE_VERSION
 657    libgeda library version:          $LIBGEDA_VERSION
 658    libstroke library:                $LIBSTROKE
 659    mingw build:                      $MINGW
 660    data directory:                   $expandedGEDADATADIR
 661    rc directory:                     $expandedGEDARCDIR
 662    xdg directory:                    $expandedXDGDATADIR
 663    documentation directory:          $expandedGEDADOCDIR
 664    dmalloc debugging:                $with_dmalloc
 665    ElectricFence debugging:          $with_efence
 666 ])