gschem/configure.ac.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT
   3 AC_CONFIG_SRCDIR([src/gschem.c])
   4 AC_PREREQ(2.54)
   5
   6 PACKAGE=geda-gschem
   7 DOTTED_VERSION=1.5.0
   8 DATE_VERSION=20080706
   9 echo Configuring $PACKAGE version $DOTTED_VERSION.$DATE_VERSION
  10
  11 # Initialize automake
  12 AM_INIT_AUTOMAKE($PACKAGE, $DOTTED_VERSION, no-define)
  13 AM_CONFIG_HEADER([config.h])
  14 AC_SUBST([CONFIG_DEPENDENCIES], ['$(top_srcdir)/configure.ac.in'])
  15
  16 # Call this to make autoconf and friends happy
  17 AC_GNU_SOURCE
  18
  19 #########################################################################
  20 # Command line flags start
  21 #
  22 # --disable-stroke : turn off stroke support
  23 AC_ARG_ENABLE(stroke,
  24     [  --disable-stroke       Disable stroke support (don't use LibStroke at all)], [ if test $enableval = "no"; then
  25          no_stroke=yes
  26         fi ])
  27
  28 # Change default location for rc files
  29 AC_ARG_WITH(rcdir, [  --with-rcdir=path       Change where the system-*rc files are installed], [opt_rcdir=$withval])
  30
  31 # Change default location for XDG files (.desktop and icons)
  32 AC_ARG_WITH(xdgdatadir, [  --with-xdgdatadir=path  Change where the .desktop file and theme icons are installed [[DATADIR]]], [opt_xdgdatadir=$withval])
  33
  34 # Allow the user to specify where there libstroke library lives
  35 AC_ARG_WITH(stroke, [  --with-stroke=DIR       Tell configure where to find libstroke], [opt_stroke=$withval])
  36
  37 #
  38 # Command line flags end
  39 #########################################################################
  40
  41 #########################################################################
  42 #
  43 # Misc win32 / mingw checks and variables start
  44 AC_CANONICAL_HOST
  45
  46 # Figure out if we are building on win32 and what environment.
  47 case $host_os in
  48   *mingw32* ) echo "Configuring for mingw"; MINGW=yes ;;
  49 esac
  50
  51 if ! test "$MINGW" = "no" -o "$MINGW"x = x; then
  52    MINGW="yes"
  53 else
  54    # Unix host
  55    MINGW="no"
  56 fi
  57
  58 #
  59 # Misc win32 / mingw checks and variables end
  60 #########################################################################
  61
  62 # Checks for programs.
  63 AC_PROG_CC
  64 AM_CONDITIONAL(CCISGCC, test "$GCC" = "yes")
  65 AC_PROG_CPP
  66 AC_PROG_MAKE_SET
  67 IT_PROG_INTLTOOL(0.35.0)
  68
  69 ############################################################################
  70 # Update desktop database utility start
  71 #
  72
  73 AC_ARG_ENABLE(update-desktop-database,
  74    AC_HELP_STRING([--disable-update-desktop-database],
  75                    [do not update desktop file database after installation]),,
  76                    enable_update_desktop_database=yes)
  77
  78 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOP_DATABASE,
  79                test x$enable_update_desktop_database = xyes)
  80
  81 if test x$enable_update_desktop_database = xyes ; then
  82   AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, [update-desktop-database], no)
  83   if test $UPDATE_DESKTOP_DATABASE = no; then
  84      AC_MSG_ERROR([Cannot find update-desktop-database, make sure it is installed and in your PATH, or configure with --disable-update-desktop-database])
  85   fi
  86 fi
  87
  88 #
  89 # Update desktop database utility end
  90 ############################################################################
  91
  92 ############################################################################
  93 # Check for guile start
  94
  95 # Check for pkg-config
  96 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  97 if test $PKG_CONFIG = no; then
  98    AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed and in your PATH])
  99 fi
 100
 101 PKG_CHECK_MODULES(GUILE, guile-2.0, GUILE_PC="yes", no_GUILE_PC="yes")
 102
 103 if test "$GUILE_PC" = "yes"
 104 then
 105    GUILE_VERSION=`$PKG_CONFIG guile-2.0 --modversion`
 106 else
 107    # Find about the installed guile
 108    GUILE_FLAGS
 109    GUILE_VERSION=`$GUILE_CONFIG info guileversion`
 110 fi
 111
 112 # Check Guile version
 113 guile_need_major=1
 114 guile_need_minor=6
 115 guile_need_version="$guile_need_major[].$guile_need_minor.0"
 116
 117 AC_MSG_CHECKING([Guile version >= $guile_need_version])
 118
 119 guile_major=`echo "$GUILE_VERSION" | sed 's/\([[^.]][[^.]]*\).*/\1/'`
 120 guile_minor=`echo "$GUILE_VERSION" | sed 's/[[^.]][[^.]]*.\([[^.]][[^.]]*\).*/\1/'`
 121 AC_MSG_RESULT($GUILE_VERSION)
 122
 123 if test "$guile_need_major" -gt "$guile_major" \
 124    || (test "$guile_need_major" -eq "$guile_major" \
 125        && test "$guile_need_minor" -gt "$guile_minor"); then
 126   AC_MSG_ERROR([Guile version >= $guile_need_version is required.])
 127 fi
 128
 129 # Guile 1.6 compatability
 130
 131 CFLAGS_temp_save="$CFLAGS"
 132 CFLAGS="$CFLAGS $GUILE_CFLAGS"
 133 AC_CHECK_DECLS([scm_is_string, scm_is_integer, scm_to_int,
 134 scm_from_int,  scm_is_true,    scm_is_false,
 135 scm_from_locale_string, scm_to_locale_string,
 136 scm_from_locale_symbol],,,
 137 [#include <libguile.h>])
 138 CFLAGS="$CFLAGS_temp_save"
 139
 140 AH_VERBATIM(SCM_IS_STRING, [#if !HAVE_DECL_SCM_IS_STRING
 141 #  define scm_is_string(x) SCM_STRINGP(x)
 142 #endif])
 143 AH_VERBATIM(SCM_IS_INTEGER, [#if !HAVE_DECL_SCM_IS_INTEGER
 144 #  define scm_is_integer(x) SCM_INUMP(x)
 145 #endif])
 146 AH_VERBATIM(SCM_TO_INT, [#if !HAVE_DECL_SCM_TO_INT
 147 #  define scm_to_int(x)     SCM_INUM(x)
 148 #endif])
 149 AH_VERBATIM(SCM_FROM_INT, [#if !HAVE_DECL_SCM_FROM_INT
 150 #  define scm_from_int(x)   SCM_MAKINUM(x)
 151 #endif])
 152 AH_VERBATIM(SCM_IS_TRUE, [#if !HAVE_DECL_SCM_IS_TRUE
 153 #  define scm_is_true(x)    SCM_NFALSEP(x)
 154 #endif])
 155 AH_VERBATIM(SCM_IS_FALSE, [#if !HAVE_DECL_SCM_IS_FALSE
 156 #  define scm_is_false(x)   SCM_FALSEP(x)
 157 #endif])
 158 AH_VERBATIM(SCM_FROM_LOCALE_STRING, [#if !HAVE_DECL_SCM_FROM_LOCALE_STRING
 159 #  define scm_from_locale_string(x) scm_makfrom0str(x)
 160 #endif])
 161 AH_VERBATIM(SCM_TO_LOCALE_STRING, [#if !HAVE_DECL_SCM_TO_LOCALE_STRING
 162 #  define scm_to_locale_string(x)   strdup(SCM_STRING_CHARS(x))
 163 #endif])
 164 AH_VERBATIM(SCM_FROM_LOCALE_SYMBOL, [#if !HAVE_DECL_SCM_FROM_LOCALE_SYMBOL
 165 #  define scm_from_locale_symbol(x)   scm_string_to_symbol (scm_from_locale_string(x))
 166 #endif])
 167
 168 #
 169 # Check for guile end
 170 ############################################################################
 171
 172 ############################################################################
 173 # Check for misc things start
 174 #
 175 # Checking for rint in math library
 176 AC_CHECK_LIB(m, rint, AC_DEFINE(HAS_RINT, 1, [If your math library has rint in it, define this]), no_RINT="yes")
 177
 178 # Checking for dynamic lib
 179 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", DL_LIB="")
 180 #
 181 # Check for misc things end
 182 ############################################################################
 183
 184 ############################################################################
 185 # Check for X11 start
 186 #
 187
 188 if test "$MINGW" = "no"
 189 then
 190    AC_PATH_X
 191    AC_PATH_XTRA
 192
 193    X_EXTRA_LIBS="$X_EXTRA_LIBS"
 194    X_LDFLAGS="$X_LDFLAGS $X_LIBS $X_EXTRA_LIBS $X_PRE_LIBS -lX11 -lm"
 195
 196    _use_rpath=no
 197    AC_MSG_CHECKING([if hardcoding of the X11 runtime library path is desired])
 198    AC_ARG_ENABLE([rpath],
 199        [  --enable-rpath         Enable hardcoding the X11 runtime library path [default=disabled]],
 200        [
 201         if test "X$enable_rpath" = "Xno" ; then
 202            AC_MSG_RESULT([no])
 203            _use_rpath=no
 204         else
 205            AC_MSG_RESULT([yes])
 206            _use_rpath=yes
 207         fi
 208        ],
 209        [
 210            AC_MSG_RESULT([no])
 211            _use_rpath=no
 212        ])
 213
 214    if test "X$_use_rpath" = "Xyes" ; then
 215       # Try to figure out if we need -Rpath for finding X11 libs
 216       # at runtime.  Why autoconf doesn't already do this, I don't
 217       # know...
 218       xlib_path=""
 219       for p in $X_LDFLAGS ; do
 220             case $p in
 221             -L*)
 222                 xlib_path="$xlib_path $p"
 223                 ;;
 224                 esac
 225       done
 226
 227       _save_LIBS=$LIBS
 228       LIBS="$LIBS $X_LDFLAGS"
 229       rpath=""
 230       for fl in "-Wl,-rpath " "-Wl,--rpath " "-rpath " "--rpath " "-Wl,-R" "-R" "-R " ; do
 231           xlib_rpath=`echo $xlib_path | sed "s/-L/$fl/g"`
 232           LIBS="$_save_LIBS $X_LIBS $xlib_rpath"
 233           AC_MSG_CHECKING([if the compiler accepts ${fl}path for runtime libraries])
 234           AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 235           AC_MSG_RESULT([yes])
 236             rpath=$fl,
 237             AC_MSG_RESULT([no]))
 238             test -n "$rpath" && break
 239       done
 240       if test -n "$rpath"; then
 241          X_LDFLAGS="$X_LDFLAGS $xlib_rpath"
 242       fi
 243       LIBS=$_save_LIBS
 244    fi
 245
 246 fi
 247
 248 #
 249 # Check for X11 end
 250 ############################################################################
 251
 252 ############################################################################
 253 # Check for gtk+ 2.4 start
 254 #
 255
 256 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, GTK="yes", no_GTK="yes")
 257
 258 # This next bit of code figures out what gtk we need to use.
 259 if test "$GTK" = "yes"
 260 then
 261    GTK_VERSION=`$PKG_CONFIG gtk+-2.0 --modversion`
 262
 263    # Search for glib
 264    PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.8.0, GLIB="yes", no_GLIB="yes")
 265    if test "$GLIB" != "yes"
 266    then
 267        AC_MSG_ERROR([Cannot find glib 2.8.0 or later, please install it and rerun ./configure.])
 268    fi
 269    GLIB_VERSION=`$PKG_CONFIG glib-2.0 --modversion`
 270
 271    # Search for gthread
 272    PKG_CHECK_MODULES(GTHREAD, gthread-2.0, GTHREAD="yes", no_GTHREAD="yes")
 273    if test "$GTHREAD" = "yes"
 274    then
 275        AC_DEFINE(HAVE_GTHREAD, 1, [If gthread support is installed, define this])
 276    fi
 277
 278 else
 279    GTK_VERSION=""
 280 fi
 281
 282 if test "$GTK_VERSION" = ""
 283 then
 284    AC_MSG_ERROR([Cannot find gtk+ 2.8.0 or later, please install it and rerun ./configure.])
 285 fi
 286
 287 save_CFLAGS=$CFLAGS
 288 save_LIBS=$LIBS
 289 CFLAGS="$GLIB_CFLAGS $CFLAGS"
 290 LIBS="$LIBS $GLIB_LIBS"
 291 AC_CHECK_FUNCS([g_regex_new])
 292 CFLAGS=$save_CFLAGS
 293 LIBS=$save_LIBS
 294
 295 #
 296 # Check for gtk+ 2.4 end
 297 ############################################################################
 298
 299 ############################################################################
 300 # Check for cairo start
 301 #
 302
 303 AC_ARG_ENABLE(cairo,
 304    AC_HELP_STRING([--disable-cairo],
 305                   [Disable the use of cairo for rendering]), , enable_cairo=yes)
 306
 307 AM_CONDITIONAL(ENABLE_CAIRO, test "x$enable_cairo" = "xyes")
 308
 309 PKG_CHECK_MODULES(CAIRO, cairo >= 1.2.0, CAIRO="yes", no_CAIRO="yes")
 310
 311 if test "x$enable_cairo" != "xyes"
 312 then
 313    AC_DEFINE(ENABLE_CAIRO, 1, [If cairo rendering is enabled, define this])
 314
 315    if test "$CAIRO" = "yes"
 316    then
 317       CAIRO_VERSION=`$PKG_CONFIG cairo --modversion`
 318    else
 319       AC_MSG_ERROR([Cannot find cairo 1.2.0 or later, please install or configure with --disable-cairo])
 320    fi
 321 fi
 322
 323 #
 324 # Check for cairo end
 325 ############################################################################
 326
 327 ############################################################################
 328 # Check for libglade start
 329 #
 330 PKG_CHECK_MODULES(LIBGLADE, libglade-2.0,
 331                   [LIBGLADE_VERSION=`$PKG_CONFIG libglade-2.0 --modversion`])
 332 #
 333 # Check for libglade end
 334 ############################################################################
 335
 336 ############################################################################
 337 # Check for libgeda start
 338 #
 339 PKG_CHECK_MODULES(LIBGEDA, libgeda >= $DATE_VERSION, LIBGEDA="yes",
 340                   no_LIBGEDA="yes")
 341
 342 if test "$LIBGEDA" = "yes"
 343 then
 344    LIBGEDA_VERSION=`$PKG_CONFIG libgeda --modversion`
 345 else
 346    AC_MSG_ERROR([libgeda detection error: $LIBGEDA_PKG_ERRORS])
 347 fi
 348
 349 #
 350 # Check for libgeda end
 351 ############################################################################
 352
 353 ############################################################################
 354 # Check for libstroke start
 355 #
 356
 357 # user specified --with-stroke
 358 if eval "test x$opt_stroke != x"; then
 359    LIBSTROKE_LIBS="-L$opt_stroke/lib"
 360    LIBSTROKE_CFLAGS="-I$opt_stroke/include"
 361 fi
 362
 363 # only check if the user has not disable strokes
 364 if test "$no_stroke" != "yes"; then
 365    save_cppflags="$CPPFLAGS"
 366    save_ldflags="$LDFLAGS"
 367    CPPFLAGS="$CPPFLAGS $LIBSTROKE_CFLAGS"
 368    LDFLAGS="$LDFLAGS $LIBSTROKE_LIBS"
 369    AC_CHECK_LIB(stroke, stroke_init, LIBSTROKE="yes", LIBSTROKE="no")
 370    CPPFLAGS="$save_cppflags"
 371    LDFLAGS="$save_ldflags"
 372 fi
 373
 374 if test "$LIBSTROKE" = "yes"; then
 375    AC_DEFINE(HAS_LIBSTROKE, 1, [Define if you have libstroke installed])
 376    if eval "test x$opt_stroke = x"; then
 377        LIBSTROKE_LIBS="-lstroke"
 378        LIBSTROKE_CFLAGS=""
 379    else
 380        LIBSTROKE_LIBS="$LIBSTROKE_LIBS -lstroke"
 381        # LIBSTROKE_CFLAGS set above
 382    fi
 383 fi
 384
 385 if test "$no_stroke" = "yes"; then
 386    echo "**                                **"
 387    echo "** Disabling libstroke by request **"
 388    echo "**                                **"
 389    LIBSTROKE_LIB=""
 390    LIBSTROKE_CFLAGS=""
 391    LIBSTROKE="no"
 392 fi
 393
 394 #
 395 # Check for libstroke end
 396 ############################################################################
 397
 398 ############################################################################
 399 # Check for doxygen start
 400 #
 401 # Doxygen is a utility for generating html and latex documentation
 402 # from c source code files.
 403
 404 # search for Doxygen
 405 AC_PATH_PROG(DOXYGEN, doxygen, no, ${PATH})
 406
 407 if test "$DOXYGEN" = "no"; then
 408    # doxygen is not available on the system
 409    echo "** Cannot find Doxygen! **"
 410    echo "**   Documentation creation disabled    **"
 411    DOXYGEN=echo
 412
 413    # prevent from weaving the nw files
 414    # but does not prevent from processing gschemdoc
 415    builddoc=false
 416 else
 417    # doxygen is available on the system.
 418    # now checking if the tools for Texinfo files processing
 419    # is installed.
 420    # The docs can be either processed to produce dvi, html or info
 421    # with texi2dvi, texi2html or makeinfo respectively
 422    # Note : these tests on makeinfo and texi2dvi are no more
 423    #        needed as automake makes them for us
 424
 425    # enable the creation of html and latex documents.
 426    builddoc=true
 427 fi
 428
 429 # depending on variable builddoc, weaving is performed or not
 430 # using conditionnal in docs/Makefile.in
 431 AM_CONDITIONAL(BUILDDOC, test x$builddoc = xtrue)
 432
 433 #
 434 # Check for doxygen end
 435 #########################################################################
 436
 437 #########################################################################
 438 # Check for groff start
 439 #
 440
 441 # search for groff
 442 AC_PATH_PROG(GROFF, groff, no, ${PATH})
 443 if test $GROFF = "no"; then
 444         echo "Cannot find groff, some documentation will not be created."
 445 fi
 446
 447 #
 448 # Check for groff end
 449 #########################################################################
 450
 451 #########################################################################
 452 # Checks for header files start
 453 #
 454 AC_HEADER_STDC
 455 AC_HEADER_SYS_WAIT
 456 AC_HEADER_DIRENT
 457 AC_CHECK_HEADERS(unistd.h string.h stdlib.h \
 458                  stdarg.h assert.h fcntl.h errno.h sys/param.h)
 459
 460 # Check for locale.h
 461
 462 # Set USE_NLS
 463 AM_NLS
 464 AC_CHECK_HEADER([locale.h],
 465                 [AC_DEFINE([HAVE_LOCALE_H], 1, [Define if you have locale.h])],
 466                 [
 467                   if test "$USE_NLS" = "yes"; then
 468                     AC_MSG_ERROR([Cannot find useful locale.h, and nls support is enabled. Try compiling with --disable-nls])
 469                   fi
 470                 ])
 471
 472 # Set package name for translations
 473 GETTEXT_PACKAGE=$PACKAGE
 474 AC_SUBST(GETTEXT_PACKAGE)
 475
 476 # Checks for typedefs, structures, and compiler characteristics.
 477 AC_C_CONST
 478
 479 # Checks for library functions.
 480 AC_TYPE_SIGNAL
 481 AC_CHECK_FUNCS(strstr getuid getgid)
 482
 483 AC_MSG_CHECKING([for optarg in unistd.h])
 484 AC_TRY_COMPILE(
 485 [#include <unistd.h>],
 486 [ char *string = optarg; int i = optind; ],
 487 optarg_found=yes,
 488 optarg_found=no)
 489 AC_MSG_RESULT($optarg_found)
 490
 491 if test $optarg_found = yes; then
 492     AC_DEFINE(OPTARG_IN_UNISTD, 1, [Define if you have optarg in unistd.h])
 493 fi
 494
 495 #
 496 # Checks for header files end
 497 #########################################################################
 498
 499 #########################################################################
 500 #
 501
 502 # ------------- dmalloc -------------------
 503 dnl dmalloc checks
 504 with_dmalloc="no"
 505 AC_MSG_CHECKING([if dmalloc debugging should be enabled])
 506 AC_ARG_ENABLE([dmalloc],
 507 [  --enable-dmalloc        Compile and link with dmalloc for malloc debugging [[default=no]]],
 508 [
 509 if test "X$enable_dmalloc" != "Xno" ; then
 510         AC_MSG_RESULT([yes])
 511         AC_CHECK_HEADER(dmalloc.h,,
 512                 AC_ERROR([You have requested dmalloc debugging but dmalloc.h could not be found]))
 513         AC_CHECK_LIB(dmalloc,main,,
 514                 AC_ERROR([You have requested dmalloc debugging but -ldmalloc could not be found]))
 515         DMALLOC_LIBS="-ldmalloc"
 516         with_dmalloc="yes"
 517 else
 518         AC_MSG_RESULT([no])
 519         DMALLOC_LIBS=""
 520 fi
 521 ],
 522 [
 523         AC_MSG_RESULT([no])
 524         DMALLOC_LIBS=""
 525 ])
 526
 527 # ------------- ElectricFence -------------------
 528 dnl ElectricFence checks
 529 with_efence="no"
 530 AC_MSG_CHECKING([if ElectricFence debugging should be enabled])
 531 AC_ARG_ENABLE([efence],
 532 [  --enable-efence         Link with ElectricFence for malloc debugging [[default=no]]],
 533 [
 534 if test "X$enable_efence" != "Xno" ; then
 535         AC_MSG_RESULT([yes])
 536         AC_CHECK_LIB(efence,main,,
 537                 AC_ERROR([You have requested ElectricFence debugging but -lefence could not be found]))
 538         with_efence="yes"
 539 else
 540         AC_MSG_RESULT([no])
 541 fi
 542 ],
 543 [
 544 AC_MSG_RESULT([no])
 545 ])
 546
 547 #
 548 #########################################################################
 549 #########################################################################
 550 # gEDA/gaf specific setup start
 551 #
 552
 553 DATADIR=gEDA
 554 GEDADATADIR=$datadir/$DATADIR
 555
 556 if eval "test x$opt_rcdir = x"; then
 557         # path was not specified with --with-rcdir
 558         AC_DEFINE_UNQUOTED(GEDARCDIR, "none", [gEDA/gaf's rc directory])
 559         GEDARCDIR=$GEDADATADIR
 560 else
 561         # path WAS specified with --with-rcdir
 562         AC_DEFINE_UNQUOTED(GEDARCDIR, "$opt_rcdir", [gEDA/gaf's rc directory])
 563         GEDARCDIR="$opt_rcdir"
 564 fi
 565
 566 if test x$opt_xdgdatadir = x; then
 567         # path was not specified with --with-xdgdatadir
 568         XDGDATADIR='${datadir}'
 569 else
 570         # path WAS specified with --with-xdgdatadir
 571         XDGDATADIR="$opt_xdgdatadir"
 572 fi
 573 AC_SUBST(XDGDATADIR)
 574
 575 # Expand the prefix variable
 576 # I don't like the way this is done, but it works (I hope).
 577 if eval "test x$prefix = xNONE"; then
 578  dprefix=$ac_default_prefix
 579 else
 580  dprefix=$prefix
 581 fi
 582
 583 gedatopdir=$dprefix/share/$DATADIR
 584 expandgedadatadir=`echo $gedatopdir`
 585
 586 gedadocdir=$dprefix/share/doc/geda-doc
 587 # --with-docdir : tells where to store documentation if not default
 588 AC_ARG_WITH(docdir,
 589     [  --with-docdir      Where to store documentation if not default.],
 590         gedadocdir=$withval)
 591 expandgedadocdir=`echo $gedadocdir`
 592 GEDADOCDIR=$expandgedadocdir
 593 AC_SUBST(GEDADOCDIR)
 594
 595 # this has to be expanded ( no ${prefix} ) --
 596 AC_DEFINE_UNQUOTED(GEDADATADIR, "$gedatopdir", [gEDA/gaf's data directory])
 597 AC_DEFINE_UNQUOTED(DATE_VERSION, "$DATE_VERSION", [Currently running date version of gEDA/gaf])
 598 AC_DEFINE_UNQUOTED(DOTTED_VERSION, "$DOTTED_VERSION", [Currently running dotted version of gEDA/gaf])
 599 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this program's package])
 600
 601 #
 602 # gEDA/gaf specify things which need to setup
 603 #########################################################################
 604
 605 # Initialized gettext
 606 AM_GNU_GETTEXT
 607 AM_GNU_GETTEXT_VERSION([%INSTALLED_GETTEXT_VERSION%])
 608
 609 #GETTEXT_PACKAGE=$PACKAGE
 610 #AC_SUBST(GETTEXT_PACKAGE)
 611 #AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"],
 612 #                   [The domain to use with gettext])
 613 #AM_GLIB_GNU_GETTEXT
 614
 615 # Finally create the final CFLAGS and LDFLAGS for use in the makefiles
 616 GSCHEM_CFLAGS="$LIBSTROKE_CFLAGS $LIBGEDA_CFLAGS $LIBGLADE_CFLAGS $GTK_CFLAGS $GTHREAD_CFLAGS"
 617 GSCHEM_LDFLAGS="$LIBSTROKE_LIBS $LIBGEDA_LIBS $LIBGLADE_LIBS $GTK_LIBS $X_LDFLAGS $DMALLOC_LIBS $GTHREAD_LIBS"
 618
 619 # Makefile.in variable substitution
 620 AC_SUBST(DATE_VERSION)
 621 AC_SUBST(DOTTED_VERSION)
 622 AC_SUBST(GSCHEM_CFLAGS)
 623 AC_SUBST(GSCHEM_LDFLAGS)
 624 AC_SUBST(GEDADATADIR)
 625 AC_SUBST(GEDARCDIR)
 626 AC_SUBST(GUILEINTERP)
 627 AC_SUBST(INDENT)
 628
 629 # Create all the necessary derived files
 630 AC_CONFIG_FILES([Makefile
 631                 m4/Makefile
 632                 po/Makefile.in
 633                 intl/Makefile
 634                 src/Makefile
 635                 include/Makefile
 636                 scheme/Makefile
 637                 bitmap/Makefile
 638                 scripts/Makefile
 639                 scripts/config.sh
 640                 examples/Makefile
 641                 docs/Makefile
 642                 lib/Makefile
 643                 tests/Makefile
 644                 data/Makefile
 645                 lib/system-gschemrc ])
 646
 647
 648 AC_OUTPUT
 649
 650 expandedGEDADATADIR=`eval "echo $GEDADATADIR"`
 651 expandedGEDARCDIR=`eval "echo $GEDARCDIR"`
 652 expandedXDGDATADIR=`eval "echo $XDGDATADIR"`
 653 expandedGEDADOCDIR=`eval "echo $GEDADOCDIR"`
 654
 655 if test "x$enable_cairo" = "xyes"
 656 then
 657   cairo_report=$CAIRO_VERSION
 658 else
 659   cairo_report="[[DISABLED]]"
 660 fi
 661
 662 AC_MSG_RESULT([
 663 ** Configuration summary for $PACKAGE $DOTTED_VERSION.$DATE_VERSION:
 664
 665    GTK+ library version:             $GTK_VERSION
 666    CAIRO library version:            $cairo_report
 667    GUILE library version:            $GUILE_VERSION
 668    libgeda library version:          $LIBGEDA_VERSION
 669    libglade library version:         $LIBGLADE_VERSION
 670    libstroke library:                $LIBSTROKE
 671    mingw build:                      $MINGW
 672    data directory:                   $expandedGEDADATADIR
 673    rc directory:                     $expandedGEDARCDIR
 674    xdg directory:                    $expandedXDGDATADIR
 675    documentation directory:          $expandedGEDADOCDIR
 676    dmalloc debugging:                $with_dmalloc
 677    ElectricFence debugging:          $with_efence
 678 ])