configure.ac

   1 dnl                                                      -*-Autoconf-*-
   2 dnl Process this file with autoconf to generate configure.
   3 dnl
   4 dnl The AX_* macros are defined in files in the top-level m4
   5 dnl directory.
   6
   7 #####################################################################
   8 # Set up configuration system
   9 #####################################################################
  10
  11 AC_INIT([gEDA/gaf], [1.9.0], [https://bugs.launchpad.net/geda], [geda-gaf])
  12 AC_PREREQ([2.60])
  13
  14 AC_CONFIG_SRCDIR([libgeda/src/libgeda.c])
  15 AC_CONFIG_AUX_DIR([build-tools])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADER([config.h])
  18
  19 AM_INIT_AUTOMAKE([parallel-tests color-tests])
  20 AM_SILENT_RULES
  21
  22 AC_GNU_SOURCE # FIXME for some reason this is needed?
  23
  24 #####################################################################
  25 # Do version number magic
  26 #####################################################################
  27
  28 AX_GIT_VERSION([20121203])
  29
  30 # This is used for keeping the ChangeLog files up-to-date
  31 AC_SUBST([CHANGELOG_BASE], [1.0-20070526])
  32
  33 #####################################################################
  34 # Windows/MinGW/Cygwin support
  35 #####################################################################
  36
  37 AX_WINDOWS_FLAGS
  38
  39 #####################################################################
  40 # Check for compiling & linking tools
  41 #####################################################################
  42
  43 AC_PROG_CC
  44 AC_PROG_CPP
  45 AM_PROG_AR
  46
  47 AC_LIBTOOL_WIN32_DLL
  48 AC_DISABLE_STATIC
  49 AC_PROG_LIBTOOL
  50
  51 AM_PROG_CC_C_O
  52 AX_GCC_FLAGS([-Wall])
  53
  54 AC_PROG_MKDIR_P
  55 AM_PROG_LEX
  56 AX_PROG_AWK
  57 AX_PROG_GROFF
  58 AC_PATH_PROGS([M4], [gm4 m4], [m4])
  59
  60 #####################################################################
  61 # Internationalisation
  62 #####################################################################
  63
  64 AM_NLS
  65 AM_GNU_GETTEXT
  66 AM_GNU_GETTEXT_VERSION([0.16])
  67 AX_DESKTOP_I18N
  68
  69 #####################################################################
  70 # Check for libraries that use pkg-config
  71 #####################################################################
  72
  73 PKG_PROG_PKG_CONFIG
  74
  75 AX_CHECK_GUILE([1.8.0])
  76
  77 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.20.0], ,
  78   AC_MSG_ERROR([GLib 2.20.0 or later is required.]))
  79
  80 PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= 2.16.0], ,
  81   AC_MSG_ERROR([GTK+ 2.16.0 or later is required.]))
  82
  83 PKG_CHECK_MODULES(GDK, [gdk-2.0 >= 2.16.0], ,
  84   AC_MSG_ERROR([GDK 2.16.0 or later is required.]))
  85
  86 PKG_CHECK_MODULES(GDK_PIXBUF, [gdk-pixbuf-2.0 >= 2.16.0], ,
  87   AC_MSG_ERROR([GDK_PIXBUF 2.16.0 or later is required.]))
  88
  89 AX_CHECK_CAIRO
  90
  91 PKG_CHECK_MODULES(PANGOCAIRO, [pangocairo >= 0.26], ,
  92   AC_MSG_ERROR([PANGOCAIRO 0.26 or later is required.]))
  93
  94 PKG_CHECK_MODULES(PANGO, [pango >= 1.23.0], ,
  95   AC_MSG_ERROR([PANGO 1.23.0 or later is required.]))
  96
  97 #####################################################################
  98 # Header files & particular functions
  99 #####################################################################
 100
 101 AC_HEADER_SYS_WAIT
 102
 103 # FIXME these checks are obsolete, because every plausible platform
 104 # provides what they check for.
 105 AC_HEADER_STDC
 106
 107 # FIXME these checks may be pointless for one of three reasons: every
 108 # even vaguely sane libc implementation provides them; we don't use
 109 # any of their functions in favour of GLib alternatives; or we don't
 110 # provide an alternative, so the build will fail anyway.
 111 AC_CHECK_HEADERS([stdlib.h string.h unistd.h])
 112
 113 # FIXME since we don't have a sensible alternative, if these headers
 114 # are missing we should fail. Also need to remove HAVE_ERRNO_H tests
 115 # in the C source code, since if we *don't* have it the build will
 116 # fail anyway.
 117 AC_CHECK_HEADERS([errno.h fcntl.h])
 118
 119 # FIXME On a system without locale.h, the user may have just disabled NLS
 120 # to be able to build.  But are there known systems with working NLS but
 121 # without a locale.h?  We do need to include locale.h on some systems
 122 # to be able to build gschem/src/gschem.c
 123 AC_CHECK_HEADERS([locale.h])
 124
 125 # Check for lrint in math library.
 126 AC_CHECK_LIB([m], [lrint],
 127              AC_DEFINE([HAVE_LRINT], 1,
 128                        [If your math library has lrint in it, define this]))
 129
 130 AC_CHECK_LIB([m], [atan2])
 131
 132 AC_CHECK_FUNCS([chown getlogin])
 133
 134 # Check if the getopt header is present
 135 AC_CHECK_HEADERS([getopt.h])
 136 # Check for getopt_long
 137 # On FreeBSD the 'gnugetopt' library is needed.
 138 AC_SEARCH_LIBS([getopt_long], [gnugetopt],
 139                AC_DEFINE([HAVE_GETOPT_LONG], 1,
 140                          [Define to 1 if you have the `getopt_long' function.]))
 141
 142 # Check for misc features of awk
 143 AX_AWK_FEATURES
 144
 145 #####################################################################
 146 # Optional things
 147 #####################################################################
 148
 149 # Assertions
 150 AX_OPTION_ASSERT
 151 # Viewing documentation
 152 AX_OPTION_URI_VIEWER
 153 # API documentation
 154 AX_OPTION_DOXYGEN
 155 # XDG desktop files
 156 AX_OPTION_XDG_DATA
 157 # KDE 3 desktop files
 158 AX_OPTION_KDE3_DATA
 159 # XDG database updates
 160 AX_OPTION_XDG_DB
 161 # libstroke support
 162 AX_OPTION_STROKE
 163 # gattrib
 164 AX_OPTION_GATTRIB
 165
 166 #####################################################################
 167 # Tool-specific setup
 168 #####################################################################
 169
 170 # Where should data files be installed/searched for?
 171 AX_DATA_DIRS
 172 # Where should PCB footprints be searched for?
 173 AX_PCB_DIRS
 174 # Set up libgeda with the correct ld version number
 175 AX_LIBGEDA([43:0:0])
 176 # Set up libgedacairo with the correct ld version number
 177 AX_LIBGEDACAIRO([1:0:0])
 178
 179 #####################################################################
 180 # Generate output
 181 #####################################################################
 182
 183 AC_CONFIG_FILES([Makefile
 184                  intl/Makefile
 185
 186                  libgeda/Makefile
 187                  libgeda/libgeda.pc
 188                  libgeda/po/domain.mak
 189                  libgeda/po/Makefile.in
 190                  libgeda/data/Makefile
 191                  libgeda/docs/Makefile
 192                  libgeda/docs/images/Makefile
 193                  libgeda/include/Makefile
 194                  libgeda/lib/Makefile
 195                  libgeda/scheme/Makefile
 196                  libgeda/src/Makefile
 197
 198                  libgedacairo/Makefile
 199                  libgedacairo/libgedacairo.pc
 200
 201                  gaf/Makefile
 202                  gaf/po/Makefile.in
 203
 204                  gschem/Makefile
 205                  gschem/po/Makefile.in
 206                  gschem/docs/Makefile
 207                  gschem/include/Makefile
 208                  gschem/scripts/Makefile
 209                  gschem/src/Makefile
 210                  gschem/examples/Makefile
 211                  gschem/lib/Makefile
 212                  gschem/data/Makefile
 213                  gschem/bitmap/Makefile
 214                  gschem/tests/Makefile
 215                  gschem/scheme/Makefile
 216
 217                  gattrib/Makefile
 218                  gattrib/po/Makefile.in
 219                  gattrib/design/Makefile
 220                  gattrib/docs/Makefile
 221                  gattrib/include/Makefile
 222                  gattrib/lib/Makefile
 223                  gattrib/lib/system-gattribrc
 224                  gattrib/src/Makefile
 225                  gattrib/data/Makefile
 226
 227                  gsymcheck/docs/Makefile
 228                  gsymcheck/include/Makefile
 229                  gsymcheck/lib/Makefile
 230                  gsymcheck/lib/system-gsymcheckrc
 231                  gsymcheck/po/Makefile.in
 232                  gsymcheck/src/Makefile
 233                  gsymcheck/tests/Makefile
 234                  gsymcheck/Makefile
 235
 236                  gnetlist/Makefile
 237                  gnetlist/po/Makefile.in
 238                  gnetlist/src/Makefile
 239                  gnetlist/include/Makefile
 240                  gnetlist/scheme/Makefile
 241                  gnetlist/examples/Makefile
 242                  gnetlist/tests/Makefile
 243                  gnetlist/tests/hierarchy/Makefile
 244                  gnetlist/tests/hierarchy2/Makefile
 245                  gnetlist/tests/drc2/Makefile
 246                  gnetlist/tests/common/Makefile
 247                  gnetlist/docs/Makefile
 248                  gnetlist/docs/vams/Makefile
 249                  gnetlist/examples/vams/Makefile
 250                  gnetlist/examples/vams/vhdl/Makefile
 251                  gnetlist/examples/vams/vhdl/basic-vhdl/Makefile
 252                  gnetlist/examples/vams/vhdl/new-vhdl/Makefile
 253                  gnetlist/examples/switcap/Makefile
 254                  gnetlist/lib/Makefile
 255                  gnetlist/utils/Makefile
 256                  gnetlist/scripts/Makefile
 257                  gnetlist/scripts/annotate.sh
 258                  gnetlist/scripts/bom_xref.sh
 259                  gnetlist/scripts/bompp.sh
 260                  gnetlist/lib/system-gnetlistrc
 261
 262                  utils/Makefile
 263                  utils/docs/Makefile
 264                  utils/examples/Makefile
 265                  utils/examples/gmk_sym/Makefile
 266                  utils/examples/gsch2pcb/Makefile
 267                  utils/examples/tragesym/Makefile
 268                  utils/gschlas/Makefile
 269                  utils/gxyrs/Makefile
 270                  utils/include/Makefile
 271                  utils/lib/Makefile
 272                  utils/lib/system-gschlasrc
 273                  utils/scripts/Makefile
 274                  utils/scripts/sw2asc
 275                  utils/src/Makefile
 276                  utils/tests/Makefile
 277                  utils/tests/gxyrs/Makefile
 278                  utils/tests/gxyrs/inputs/Makefile
 279                  utils/tests/gxyrs/outputs/Makefile
 280                  utils/tests/refdes_renum/Makefile
 281                  utils/tests/refdes_renum/inputs/Makefile
 282                  utils/tests/refdes_renum/outputs/Makefile
 283
 284                  symbols/Makefile
 285                  symbols/documentation/Makefile
 286
 287                  docs/Makefile
 288                  docs/scheme-api/Makefile
 289                  docs/toplevel/Makefile
 290                  docs/toplevel/gedadocs.html
 291                  docs/wiki/Makefile
 292
 293                  examples/Makefile
 294                  examples/RF_Amp/Makefile
 295                  examples/RF_Amp/model/Makefile
 296                  examples/RF_Amp/sym/Makefile
 297                  examples/TwoStageAmp/Makefile
 298                  examples/gTAG/Makefile
 299                  examples/lightning_detector/Makefile
 300 ])
 301 AC_OUTPUT