xorn/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2013-2020 Roland Lutz
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation,
  16 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 AC_PREREQ([2.69])
  19 LT_PREREQ([2.4.6])
  20
  21 AC_INIT([Xorn], [0.0], [bug-xorn@hedmen.org], [], [http://hedmen.org/xorn/])
  22 AC_CONFIG_SRCDIR([src/cpython/storage/module.c])
  23 AC_CONFIG_MACRO_DIR([m4])
  24
  25 AM_INIT_AUTOMAKE([-Wall -Werror silent-rules subdir-objects])
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27 LT_INIT([])
  28
  29 AX_PROG_CC_WARNING([cast_function_type], [cast-function-type])
  30
  31 AC_PROG_CXX
  32
  33 AM_PATH_PYTHON([2.7])
  34 PKG_CHECK_MODULES([PYTHON], [python-2.7 >= 2.7],, [
  35   PKG_CHECK_MODULES([PYTHON], [python2 >= 2.7])
  36 ])
  37 PKG_CHECK_MODULES([GUILE], [guile-2.2],, [
  38   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.10])
  39 ])
  40
  41 AM_GNU_GETTEXT([external])
  42 AM_GNU_GETTEXT_VERSION([0.19.8])
  43
  44 # use location passed by main configure script
  45 AC_MSG_CHECKING([where to look for gEDA shared data])
  46 AC_ARG_VAR([GEDADATADIR], [path to gEDA shared data])
  47 gedadatadir="$GEDADATADIR"
  48 AC_MSG_RESULT([$gedadatadir])
  49 AS_IF([test "x$gedadatadir" = "x"],
  50       [AC_MSG_ERROR([No gEDA shared data location given
  51
  52 ==> This sometimes happens when the configuration scripts aren't run in
  53     the correct order.  Re-running `configure' should solve the issue.
  54 ])])
  55 AC_SUBST([gedadatadir])
  56
  57 # use location passed by main configure script
  58 AC_MSG_CHECKING([where to look for gEDA rc files])
  59 AC_ARG_VAR([GEDARCDIR], [path to gEDA rc files])
  60 gedasysconfdir="$GEDARCDIR"
  61 AC_MSG_RESULT([$gedasysconfdir])
  62 AC_SUBST([gedasysconfdir])
  63
  64 AC_CONFIG_HEADERS([config.h])
  65 AC_CONFIG_FILES([
  66         Makefile
  67         po/Makefile.in
  68         src/storage/Makefile
  69         src/cpython/storage/Makefile
  70         src/cpython/guile/Makefile
  71         src/python/Makefile
  72         src/gaf/Makefile
  73         src/command/Makefile
  74         src/backend/Makefile
  75         tests/Makefile
  76         tests/netlist/Makefile
  77 ])
  78 AC_OUTPUT