configure.ac

   1 dnl                                                      -*-Autoconf-*-
   2 dnl Process this file with autoconf to generate configure.
   3 dnl
   4 dnl The AX_* macros are defined in files in the top-level m4
   5 dnl directory.
   6
   7 #####################################################################
   8 # Set up configuration system
   9 #####################################################################
  10
  11 AC_INIT([gEDA/gaf], [1.8.0], [https://bugs.launchpad.net/geda], [geda-gaf])
  12 AC_PREREQ([2.60])
  13
  14 AC_CONFIG_SRCDIR([libgeda/src/libgeda.c])
  15 AC_CONFIG_AUX_DIR([build-tools])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADER([config.h])
  18
  19 AM_INIT_AUTOMAKE
  20
  21 AC_GNU_SOURCE # FIXME for some reason this is needed?
  22
  23 #####################################################################
  24 # Do version number magic
  25 #####################################################################
  26
  27 AX_GIT_VERSION([20121118])
  28
  29 # This is used for keeping the ChangeLog files up-to-date
  30 AC_SUBST([CHANGELOG_BASE], [1.0-20070526])
  31
  32 #####################################################################
  33 # Windows/MinGW/Cygwin support
  34 #####################################################################
  35
  36 AX_WINDOWS_FLAGS
  37
  38 #####################################################################
  39 # Check for compiling & linking tools
  40 #####################################################################
  41
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44
  45 AC_LIBTOOL_WIN32_DLL
  46 AC_DISABLE_STATIC
  47 AC_PROG_LIBTOOL
  48
  49 AM_PROG_CC_C_O
  50 AX_GCC_FLAGS([-Wall])
  51
  52 AC_PROG_MKDIR_P
  53 AM_PROG_LEX
  54 AX_PROG_AWK
  55 AX_PROG_GROFF
  56 AC_PATH_PROGS([M4], [gm4 m4], [m4])
  57
  58 #####################################################################
  59 # Internationalisation
  60 #####################################################################
  61
  62 AM_NLS
  63 AM_GNU_GETTEXT
  64 AM_GNU_GETTEXT_VERSION([0.16])
  65 AX_DESKTOP_I18N
  66
  67 #####################################################################
  68 # Check for libraries that use pkg-config
  69 #####################################################################
  70
  71 PKG_PROG_PKG_CONFIG
  72
  73 AX_CHECK_GUILE([1.8.0])
  74
  75 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.20.0], ,
  76   AC_MSG_ERROR([GLib 2.20.0 or later is required.]))
  77
  78 PKG_CHECK_MODULES(GTK, [gtk+-2.0 >= 2.16.0], ,
  79   AC_MSG_ERROR([GTK+ 2.16.0 or later is required.]))
  80
  81 PKG_CHECK_MODULES(GDK_PIXBUF, [gdk-pixbuf-2.0 >= 2.16.0], ,
  82   AC_MSG_ERROR([GDK_PIXBUF 2.16.0 or later is required.]))
  83
  84 PKG_CHECK_MODULES(CAIRO, [cairo >= 1.10.0], ,
  85   AC_MSG_ERROR([CAIRO 1.10.0 or later is required.]))
  86
  87 PKG_CHECK_MODULES(PANGOCAIRO, [pangocairo >= 0.26], ,
  88   AC_MSG_ERROR([PANGOCAIRO 0.26 or later is required.]))
  89
  90 #####################################################################
  91 # Header files & particular functions
  92 #####################################################################
  93
  94 AC_HEADER_SYS_WAIT
  95
  96 # FIXME these checks are obsolete, because every plausible platform
  97 # provides what they check for.
  98 AC_HEADER_STDC
  99
 100 # FIXME these checks may be pointless for one of three reasons: every
 101 # even vaguely sane libc implementation provides them; we don't use
 102 # any of their functions in favour of GLib alternatives; or we don't
 103 # provide an alternative, so the build will fail anyway.
 104 AC_CHECK_HEADERS([stdlib.h string.h unistd.h])
 105
 106 # FIXME since we don't have a sensible alternative, if these headers
 107 # are missing we should fail. Also need to remove HAVE_ERRNO_H tests
 108 # in the C source code, since if we *don't* have it the build will
 109 # fail anyway.
 110 AC_CHECK_HEADERS([errno.h fcntl.h])
 111
 112 # FIXME On a system without locale.h, the user may have just disabled NLS
 113 # to be able to build.  But are there known systems with working NLS but
 114 # without a locale.h?  We do need to include locale.h on some systems
 115 # to be able to build gschem/src/gschem.c
 116 AC_CHECK_HEADERS([locale.h])
 117
 118 # Check for lrint in math library.
 119 AC_CHECK_LIB([m], [lrint],
 120              AC_DEFINE([HAVE_LRINT], 1,
 121                        [If your math library has lrint in it, define this]))
 122
 123 AC_CHECK_LIB([m], [atan2])
 124
 125 AC_CHECK_FUNCS([chown getlogin])
 126
 127 # Check if the getopt header is present
 128 AC_CHECK_HEADERS([getopt.h])
 129 # Check for getopt_long
 130 # On FreeBSD the 'gnugetopt' library is needed.
 131 AC_SEARCH_LIBS([getopt_long], [gnugetopt],
 132                AC_DEFINE([HAVE_GETOPT_LONG], 1,
 133                          [Define to 1 if you have the `getopt_long' function.]))
 134
 135 # Check for misc features of awk
 136 AX_AWK_FEATURES
 137
 138 #####################################################################
 139 # Optional things
 140 #####################################################################
 141
 142 # Assertions
 143 AX_OPTION_ASSERT
 144 # Viewing documentation
 145 AX_OPTION_URI_VIEWER
 146 # API documentation
 147 AX_OPTION_DOXYGEN
 148 # XDG desktop files
 149 AX_OPTION_XDG_DATA
 150 # KDE 3 desktop files
 151 AX_OPTION_KDE3_DATA
 152 # XDG database updates
 153 AX_OPTION_XDG_DB
 154 # libstroke support
 155 AX_OPTION_STROKE
 156 # gattrib
 157 AX_OPTION_GATTRIB
 158
 159 #####################################################################
 160 # Tool-specific setup
 161 #####################################################################
 162
 163 # Where should data files be installed/searched for?
 164 AX_DATA_DIRS
 165 # Where should PCB footprints be searched for?
 166 AX_PCB_DIRS
 167 # Set up libgeda with the correct ld version number
 168 AX_LIBGEDA([41:0:0])
 169
 170 #####################################################################
 171 # Generate output
 172 #####################################################################
 173
 174 AC_CONFIG_FILES([Makefile
 175                  intl/Makefile
 176
 177                  libgeda/Makefile
 178                  libgeda/libgeda.pc
 179                  libgeda/po/domain.mak
 180                  libgeda/po/Makefile.in
 181                  libgeda/shell/Makefile
 182                  libgeda/data/Makefile
 183                  libgeda/docs/Makefile
 184                  libgeda/docs/images/Makefile
 185                  libgeda/include/Makefile
 186                  libgeda/lib/Makefile
 187                  libgeda/scheme/Makefile
 188                  libgeda/share/Makefile
 189                  libgeda/src/Makefile
 190
 191                  gschem/Makefile
 192                  gschem/po/Makefile.in
 193                  gschem/docs/Makefile
 194                  gschem/include/Makefile
 195                  gschem/scripts/Makefile
 196                  gschem/src/Makefile
 197                  gschem/examples/Makefile
 198                  gschem/lib/Makefile
 199                  gschem/data/Makefile
 200                  gschem/bitmap/Makefile
 201                  gschem/tests/Makefile
 202                  gschem/scheme/Makefile
 203
 204                  gattrib/Makefile
 205                  gattrib/po/Makefile.in
 206                  gattrib/design/Makefile
 207                  gattrib/docs/Makefile
 208                  gattrib/include/Makefile
 209                  gattrib/lib/Makefile
 210                  gattrib/lib/system-gattribrc
 211                  gattrib/src/Makefile
 212                  gattrib/data/Makefile
 213
 214                  gsymcheck/docs/Makefile
 215                  gsymcheck/include/Makefile
 216                  gsymcheck/lib/Makefile
 217                  gsymcheck/lib/system-gsymcheckrc
 218                  gsymcheck/src/Makefile
 219                  gsymcheck/tests/Makefile
 220                  gsymcheck/Makefile
 221
 222                  gnetlist/Makefile
 223                  gnetlist/src/Makefile
 224                  gnetlist/include/Makefile
 225                  gnetlist/scheme/Makefile
 226                  gnetlist/examples/Makefile
 227                  gnetlist/tests/Makefile
 228                  gnetlist/tests/hierarchy/Makefile
 229                  gnetlist/tests/hierarchy2/Makefile
 230                  gnetlist/tests/drc2/Makefile
 231                  gnetlist/tests/common/Makefile
 232                  gnetlist/docs/Makefile
 233                  gnetlist/docs/vams/Makefile
 234                  gnetlist/examples/vams/Makefile
 235                  gnetlist/examples/vams/vhdl/Makefile
 236                  gnetlist/examples/vams/vhdl/basic-vhdl/Makefile
 237                  gnetlist/examples/vams/vhdl/new-vhdl/Makefile
 238                  gnetlist/examples/switcap/Makefile
 239                  gnetlist/lib/Makefile
 240                  gnetlist/utils/Makefile
 241                  gnetlist/scripts/Makefile
 242                  gnetlist/scripts/annotate.sh
 243                  gnetlist/scripts/bom_xref.sh
 244                  gnetlist/scripts/bompp.sh
 245                  gnetlist/lib/system-gnetlistrc
 246
 247                  utils/Makefile
 248                  utils/docs/Makefile
 249                  utils/examples/Makefile
 250                  utils/examples/gmk_sym/Makefile
 251                  utils/examples/gsch2pcb/Makefile
 252                  utils/examples/tragesym/Makefile
 253                  utils/gsch2pdf/Makefile
 254                  utils/gschlas/Makefile
 255                  utils/gxyrs/Makefile
 256                  utils/include/Makefile
 257                  utils/lib/Makefile
 258                  utils/lib/system-gschlasrc
 259                  utils/scripts/Makefile
 260                  utils/scripts/sw2asc
 261                  utils/src/Makefile
 262                  utils/tests/Makefile
 263                  utils/tests/gxyrs/Makefile
 264                  utils/tests/gxyrs/inputs/Makefile
 265                  utils/tests/gxyrs/outputs/Makefile
 266                  utils/tests/refdes_renum/Makefile
 267                  utils/tests/refdes_renum/inputs/Makefile
 268                  utils/tests/refdes_renum/outputs/Makefile
 269
 270                  symbols/Makefile
 271                  symbols/documentation/Makefile
 272
 273                  docs/Makefile
 274                  docs/scheme-api/Makefile
 275                  docs/toplevel/Makefile
 276                  docs/toplevel/gedadocs.html
 277                  docs/wiki/Makefile
 278
 279                  examples/Makefile
 280                  examples/RF_Amp/Makefile
 281                  examples/RF_Amp/model/Makefile
 282                  examples/RF_Amp/sym/Makefile
 283                  examples/TwoStageAmp/Makefile
 284                  examples/gTAG/Makefile
 285                  examples/lightning_detector/Makefile
 286 ])
 287 AC_OUTPUT