build/autoconf/pkg.m4

   1 dnl This Source Code Form is subject to the terms of the Mozilla Public
   2 dnl License, v. 2.0. If a copy of the MPL was not distributed with this
   3 dnl file, You can obtain one at http://mozilla.org/MPL/2.0/.
   4
   5 # PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
   6 # defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
   7 # also defines GSTUFF_PKG_ERRORS on error
   8 # PKG_CONFIG is set by Python configure, if it is empty here it could not
   9 # be found.
  10 AC_DEFUN([PKG_CHECK_MODULES],
  11 [succeeded=no
  12
  13   if test -z "$PKG_CONFIG"; then
  14      echo "*** The pkg-config script could not be found. Make sure it is"
  15      echo "*** in your path, or set the PKG_CONFIG environment variable"
  16      echo "*** to the full path to pkg-config."
  17      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  18   else
  19      PKG_CONFIG_MIN_VERSION=0.9.0
  20      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
  21         AC_MSG_CHECKING(for $2)
  22
  23         if test -n "$PKG_CONFIG_SYSROOT_DIR"; then
  24             export PKG_CONFIG_SYSROOT_DIR
  25         fi
  26         if test -n "$PKG_CONFIG_LIBDIR"; then
  27             export PKG_CONFIG_LIBDIR
  28         fi
  29
  30         if $PKG_CONFIG --exists "$2" ; then
  31             AC_MSG_RESULT(yes)
  32             succeeded=yes
  33
  34             AC_MSG_CHECKING($1_CFLAGS)
  35             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
  36             AC_MSG_RESULT($$1_CFLAGS)
  37
  38             AC_MSG_CHECKING($1_LIBS)
  39             ## Remove evil flags like -Wl,--export-dynamic
  40             $1_LIBS="`$PKG_CONFIG --libs \"$2\" |sed s/-Wl,--export-dynamic//g`"
  41             AC_MSG_RESULT($$1_LIBS)
  42         else
  43             $1_CFLAGS=""
  44             $1_LIBS=""
  45             ## If we have a custom action on failure, don't print errors, but
  46             ## do set a variable so people can do so.
  47             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
  48             ifelse([$4], ,echo $$1_PKG_ERRORS,)
  49         fi
  50
  51         AC_SUBST_LIST($1_CFLAGS)
  52         AC_SUBST_LIST($1_LIBS)
  53      else
  54         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
  55         echo "*** See http://www.freedesktop.org/software/pkgconfig"
  56      fi
  57   fi
  58
  59   if test $succeeded = yes; then
  60      ifelse([$3], , :, [$3])
  61   else
  62      if test "$COMPILE_ENVIRONMENT"; then
  63        ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
  64      fi
  65   fi
  66 ])
  67
  68