accessible/mac/mozRootAccessible.mm

   1 /* clang-format off */
   2 /* -*- Mode: Objective-C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
   3 /* clang-format on */
   4 /* This Source Code Form is subject to the terms of the Mozilla Public
   5  * License, v. 2.0. If a copy of the MPL was not distributed with this
   6  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   7
   8 #include "RootAccessibleWrap.h"
   9
  10 #import "mozRootAccessible.h"
  11
  12 #import "mozView.h"
  13
  14 // This must be included last:
  15 #include "nsObjCExceptions.h"
  16
  17 using namespace mozilla::a11y;
  18
  19 static id<mozAccessible, mozView> getNativeViewFromRootAccessible(
  20     LocalAccessible* aAccessible) {
  21   RootAccessibleWrap* root =
  22       static_cast<RootAccessibleWrap*>(aAccessible->AsRoot());
  23   id<mozAccessible, mozView> nativeView = nil;
  24   root->GetNativeWidget((void**)&nativeView);
  25   return nativeView;
  26 }
  27
  28 #pragma mark -
  29
  30 @implementation mozRootAccessible
  31
  32 - (id)initWithAccessible:(mozilla::a11y::Accessible*)aAcc {
  33   NS_OBJC_BEGIN_TRY_BLOCK_RETURN;
  34
  35   MOZ_ASSERT(!aAcc->IsRemote(), "mozRootAccessible is never a proxy");
  36
  37   mParallelView = getNativeViewFromRootAccessible(aAcc->AsLocal());
  38
  39   return [super initWithAccessible:aAcc];
  40
  41   NS_OBJC_END_TRY_BLOCK_RETURN(nil);
  42 }
  43
  44 - (NSNumber*)moxMain {
  45   return @([[self moxWindow] isMainWindow]);
  46 }
  47
  48 - (NSNumber*)moxMinimized {
  49   return @([[self moxWindow] isMiniaturized]);
  50 }
  51
  52 // return the AXParent that our parallell NSView tells us about.
  53 - (id)moxUnignoredParent {
  54   NS_OBJC_BEGIN_TRY_BLOCK_RETURN;
  55
  56   // If there is no represented view (eg. headless), this will return nil.
  57   return [[self representedView]
  58       accessibilityAttributeValue:NSAccessibilityParentAttribute];
  59
  60   NS_OBJC_END_TRY_BLOCK_RETURN(nil);
  61 }
  62
  63 - (BOOL)hasRepresentedView {
  64   return YES;
  65 }
  66
  67 // this will return our parallell NSView. see mozDocAccessible.h
  68 - (id)representedView {
  69   NS_OBJC_BEGIN_TRY_BLOCK_RETURN;
  70
  71   MOZ_ASSERT(mParallelView,
  72              "root accessible does not have a native parallel view.");
  73
  74   return mParallelView;
  75
  76   NS_OBJC_END_TRY_BLOCK_RETURN(nil);
  77 }
  78
  79 - (BOOL)isRoot {
  80   return YES;
  81 }
  82
  83 @end