dom/webtransport/shared/PWebTransport.ipdl

   1 /* This Source Code Form is subject to the terms of the Mozilla Public
   2  * License, v. 2.0. If a copy of the MPL was not distributed with this file,
   3  * You can obtain one at http://mozilla.org/MPL/2.0/. */
   4
   5 include PBackgroundSharedTypes;
   6
   7 [RefCounted] using class mozilla::ipc::DataPipeReceiver from "mozilla/ipc/DataPipe.h";
   8 [RefCounted] using class mozilla::ipc::DataPipeSender from "mozilla/ipc/DataPipe.h";
   9 using mozilla::TimeStamp from "mozilla/TimeStamp.h";
  10
  11 namespace mozilla {
  12 namespace dom {
  13
  14 struct UnidirectionalStream {
  15   uint64_t streamId;
  16   nullable DataPipeSender outStream;
  17 };
  18
  19 union UnidirectionalStreamResponse {
  20   nsresult;
  21   UnidirectionalStream;
  22 };
  23
  24 struct BidirectionalStream {
  25   uint64_t streamId;
  26   nullable DataPipeReceiver inStream;
  27   nullable DataPipeSender outStream;
  28 };
  29
  30 union BidirectionalStreamResponse {
  31   nsresult;
  32   BidirectionalStream;
  33 };
  34
  35 struct ResetError {
  36   nsresult error;
  37 };
  38
  39 struct StopSendingError {
  40   nsresult error;
  41 };
  42
  43 union StreamResetOrStopSendingError {
  44   ResetError;
  45   StopSendingError;
  46 };
  47
  48 async protocol PWebTransport
  49 {
  50  parent:
  51   /**
  52    * TODO: documentation
  53    */
  54   async Close(uint32_t code, nsCString reason);
  55   async CreateUnidirectionalStream(int64_t? sendOrder)
  56       returns(UnidirectionalStreamResponse response);
  57   async CreateBidirectionalStream(int64_t? sendOrder)
  58       returns(BidirectionalStreamResponse response);
  59
  60   /**
  61   * IPC for sending webtransport datagrams
  62   * @param expirationTime time at which the datagram expires
  63   * @param data represents the datagram to be transferred
  64   */
  65   async OutgoingDatagram(uint8_t[] data, TimeStamp expirationTime)
  66     returns(nsresult response);
  67
  68   /**
  69   * Get the maximum supported datagram size from necko stack
  70   */
  71   async GetMaxDatagramSize()
  72     returns(uint64_t maxDatagramSize);
  73
  74  child:
  75
  76   async IncomingUnidirectionalStream(uint64_t streamId, nullable DataPipeReceiver receive);
  77   async IncomingBidirectionalStream(uint64_t streamId, nullable DataPipeReceiver receive, nullable DataPipeSender send);
  78
  79   /**
  80   * IPC for receiving webtransport datagrams
  81   * @param receivedTime is the time at which the parent received the datagram
  82   * @param data is the datagram received
  83   */
  84   async IncomingDatagram(uint8_t[] data, TimeStamp receivedTime);
  85
  86   async RemoteClosed(bool cleanly, uint32_t code, nsCString reason);
  87
  88   async OnStreamResetOrStopSending(uint64_t streamId,
  89                                    StreamResetOrStopSendingError error);
  90
  91   async CloseAll()
  92       returns(nsresult rv);
  93 };
  94
  95 } // namespace dom
  96 } // namespace mozilla