xpcom/base/nsMacPreferencesReader.mm

   1 /* This Source Code Form is subject to the terms of the Mozilla Public
   2  * License, v. 2.0. If a copy of the MPL was not distributed with this
   3  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   4
   5 #include "MacStringHelpers.h"
   6 #include "nsMacPreferencesReader.h"
   7 #include "nsString.h"
   8
   9 #include "js/JSON.h"
  10 #include "js/RootingAPI.h"
  11 #include "js/Value.h"
  12 #include "mozilla/JSONStringWriteFuncs.h"
  13
  14 NS_IMPL_ISUPPORTS(nsMacPreferencesReader, nsIMacPreferencesReader)
  15
  16 using namespace mozilla;
  17
  18 static void EvaluateDict(JSONWriter* aWriter, NSDictionary<NSString*, id>* aDict);
  19
  20 static void EvaluateArray(JSONWriter* aWriter, NSArray* aArray) {
  21   for (id elem in aArray) {
  22     if ([elem isKindOfClass:[NSString class]]) {
  23       aWriter->StringElement(MakeStringSpan([elem UTF8String]));
  24     } else if ([elem isKindOfClass:[NSNumber class]]) {
  25       aWriter->IntElement([elem longLongValue]);
  26     } else if ([elem isKindOfClass:[NSArray class]]) {
  27       aWriter->StartArrayElement();
  28       EvaluateArray(aWriter, elem);
  29       aWriter->EndArray();
  30     } else if ([elem isKindOfClass:[NSDictionary class]]) {
  31       aWriter->StartObjectElement();
  32       EvaluateDict(aWriter, elem);
  33       aWriter->EndObject();
  34     }
  35   }
  36 }
  37
  38 static void EvaluateDict(JSONWriter* aWriter, NSDictionary<NSString*, id>* aDict) {
  39   for (NSString* key in aDict) {
  40     id value = aDict[key];
  41     if ([value isKindOfClass:[NSString class]]) {
  42       aWriter->StringProperty(MakeStringSpan([key UTF8String]), MakeStringSpan([value UTF8String]));
  43     } else if ([value isKindOfClass:[NSNumber class]]) {
  44       aWriter->IntProperty(MakeStringSpan([key UTF8String]), [value longLongValue]);
  45     } else if ([value isKindOfClass:[NSArray class]]) {
  46       aWriter->StartArrayProperty(MakeStringSpan([key UTF8String]));
  47       EvaluateArray(aWriter, value);
  48       aWriter->EndArray();
  49     } else if ([value isKindOfClass:[NSDictionary class]]) {
  50       aWriter->StartObjectProperty(MakeStringSpan([key UTF8String]));
  51       EvaluateDict(aWriter, value);
  52       aWriter->EndObject();
  53     }
  54   }
  55 }
  56
  57 NS_IMETHODIMP
  58 nsMacPreferencesReader::PoliciesEnabled(bool* aPoliciesEnabled) {
  59   NSString* policiesEnabledStr = [NSString stringWithUTF8String:ENTERPRISE_POLICIES_ENABLED_KEY];
  60   *aPoliciesEnabled = [[NSUserDefaults standardUserDefaults] boolForKey:policiesEnabledStr] == YES;
  61   return NS_OK;
  62 }
  63
  64 NS_IMETHODIMP
  65 nsMacPreferencesReader::ReadPreferences(JSContext* aCx, JS::MutableHandle<JS::Value> aResult) {
  66   JSONStringWriteFunc<nsAutoCString> jsonStr;
  67   JSONWriter w(jsonStr);
  68   w.Start();
  69   EvaluateDict(&w, [[NSUserDefaults standardUserDefaults] dictionaryRepresentation]);
  70   w.End();
  71
  72   NS_ConvertUTF8toUTF16 jsonStr16(jsonStr.StringCRef());
  73
  74   JS::RootedValue val(aCx);
  75   MOZ_ALWAYS_TRUE(JS_ParseJSON(aCx, jsonStr16.get(), jsonStr16.Length(), &val));
  76
  77   aResult.set(val);
  78   return NS_OK;
  79 }