build.gradle

   1 def tryInt = { string ->
   2     if (string == null) {
   3         return string
   4     }
   5     if (string.isInteger()) {
   6         return string as Integer
   7     }
   8     return string
   9 }
  10
  11 allprojects {
  12     // Expose the per-object-directory configuration to all projects.
  13     ext {
  14         mozconfig = gradle.mozconfig
  15         topsrcdir = gradle.mozconfig.topsrcdir
  16         topobjdir = gradle.mozconfig.topobjdir
  17
  18         buildToolsVersion = mozconfig.substs.ANDROID_BUILD_TOOLS_VERSION
  19         compileSdkVersion = tryInt(mozconfig.substs.ANDROID_TARGET_SDK)
  20         targetSdkVersion = tryInt(mozconfig.substs.ANDROID_TARGET_SDK)
  21         minSdkVersion = tryInt(mozconfig.substs.MOZ_ANDROID_MIN_SDK_VERSION)
  22         manifestPlaceholders = [
  23             ANDROID_PACKAGE_NAME: mozconfig.substs.ANDROID_PACKAGE_NAME,
  24             ANDROID_TARGET_SDK: mozconfig.substs.ANDROID_TARGET_SDK,
  25             MOZ_ANDROID_MIN_SDK_VERSION: mozconfig.substs.MOZ_ANDROID_MIN_SDK_VERSION,
  26         ]
  27     }
  28
  29     repositories {
  30         gradle.mozconfig.substs.GRADLE_MAVEN_REPOSITORIES.each { repository ->
  31             maven {
  32                 url repository
  33             }
  34         }
  35     }
  36
  37     task downloadDependencies() {
  38         description 'Download all dependencies to the Gradle cache'
  39         doLast {
  40             configurations.each { configuration ->
  41                 if (configuration.canBeResolved) {
  42                     configuration.allDependencies.each { dependency ->
  43                         try {
  44                             configuration.files(dependency)
  45                         } catch(e) {
  46                             println("Could not resolve ${configuration.name} -> ${dependency.name}")
  47                             println(" > ${e.message}")
  48                             if (e.cause) {
  49                                 println(" >> ${e.cause}")
  50                                 if (e.cause.cause) {
  51                                     println(" >> ${e.cause.cause}")
  52                                 }
  53                             }
  54                             println("")
  55                         }
  56                     }
  57                 }
  58             }
  59         }
  60     }
  61 }
  62
  63 buildDir "${topobjdir}/gradle/build"
  64
  65 buildscript {
  66     repositories {
  67         gradle.mozconfig.substs.GRADLE_MAVEN_REPOSITORIES.each { repository ->
  68             maven {
  69                 url repository
  70             }
  71         }
  72     }
  73
  74     ext.kotlin_version = '1.3.41'
  75
  76     dependencies {
  77         classpath 'org.mozilla.apilint:apilint:0.3.1'
  78         classpath 'com.android.tools.build:gradle:3.4.2'
  79         classpath 'com.getkeepsafe.dexcount:dexcount-gradle-plugin:0.8.2'
  80         classpath 'org.apache.commons:commons-exec:1.3'
  81         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
  82     }
  83 }
  84
  85 // A stream that processes bytes line by line, prepending a tag before sending
  86 // each line to Gradle's logging.
  87 class TaggedLogOutputStream extends org.apache.commons.exec.LogOutputStream {
  88     String tag
  89     Logger logger
  90
  91     TaggedLogOutputStream(tag, logger) {
  92         this.tag = tag
  93         this.logger = logger
  94     }
  95
  96     void processLine(String line, int level) {
  97         logger.lifecycle("${this.tag} ${line}")
  98     }
  99 }
 100
 101 ext.geckoBinariesOnlyIf = { task ->
 102     // Never when Gradle was invoked within `mach build`.
 103     if ('1' == System.env.GRADLE_INVOKED_WITHIN_MACH_BUILD) {
 104         rootProject.logger.lifecycle("Skipping task ${task.path} because: within `mach build`")
 105         return false
 106     }
 107
 108     // Never for official builds.
 109     if (mozconfig.substs.MOZILLA_OFFICIAL) {
 110         rootProject.logger.lifecycle("Skipping task ${task.path} because: MOZILLA_OFFICIAL")
 111         return false
 112     }
 113
 114     // Multi-l10n builds set `AB_CD=multi`, which isn't a valid locale.  To
 115     // avoid failures, if Gradle is invoked with AB_CD=multi, we don't invoke
 116     // Make at all.
 117     if ('multi' == System.env.AB_CD) {
 118         rootProject.logger.lifecycle("Skipping task ${task.path} because: AB_CD=multi")
 119         return false
 120     }
 121
 122     // Single-locale l10n repacks set `IS_LANGUAGE_REPACK=1` and handle resource
 123     // and code generation themselves.
 124     if ('1' == System.env.IS_LANGUAGE_REPACK) {
 125         rootProject.logger.lifecycle("Skipping task ${task.path} because: IS_LANGUAGE_REPACK")
 126         return false
 127     }
 128
 129     rootProject.logger.lifecycle("Executing task ${task.path}")
 130     return true
 131 }
 132
 133 class MachExec extends Exec {
 134     def MachExec() {
 135         // Bug 1543982: When invoking `mach build` recursively, the outer `mach
 136         // build` itself modifies the environment, causing configure to run
 137         // again.  This tries to restore the environment that the outer `mach
 138         // build` was invoked in.  See the comment in
 139         // $topsrcdir/settings.gradle.
 140         project.ext.mozconfig.mozconfig.env.unmodified.each { k, v -> environment.remove(k) }
 141         environment project.ext.mozconfig.orig_mozconfig.env.unmodified
 142     }
 143 }
 144
 145 task machBuildFaster(type: MachExec) {
 146     onlyIf rootProject.ext.geckoBinariesOnlyIf
 147
 148     workingDir "${topsrcdir}"
 149
 150     commandLine mozconfig.substs.PYTHON3
 151     args "${topsrcdir}/mach"
 152     args 'build'
 153     args 'faster'
 154
 155     // Add `-v` if we're running under `--info` (or `--debug`).
 156     if (project.logger.isEnabled(LogLevel.INFO)) {
 157         args '-v'
 158     }
 159
 160     // `path` is like `:machBuildFaster`.
 161     standardOutput = new TaggedLogOutputStream("${path}>", logger)
 162     errorOutput = standardOutput
 163 }
 164
 165 task machStagePackage(type: MachExec) {
 166     onlyIf rootProject.ext.geckoBinariesOnlyIf
 167
 168     dependsOn rootProject.machBuildFaster
 169
 170     workingDir "${topobjdir}"
 171
 172     // We'd prefer this to be a `mach` invocation, but `mach build
 173     // mobile/android/installer/stage-package` doesn't work as expected.
 174     commandLine mozconfig.substs.GMAKE
 175     args '-C'
 176     args "${topobjdir}/mobile/android/installer"
 177     args 'stage-package'
 178
 179     outputs.file "${topobjdir}/dist/geckoview/assets/omni.ja"
 180
 181     outputs.file "${topobjdir}/dist/geckoview/assets/${mozconfig.substs.ANDROID_CPU_ARCH}/libxul.so"
 182     outputs.file "${topobjdir}/dist/geckoview/lib/${mozconfig.substs.ANDROID_CPU_ARCH}/libmozglue.so"
 183
 184     // Force running `stage-package`.
 185     outputs.upToDateWhen { false }
 186
 187     // `path` is like `:machStagePackage`.
 188     standardOutput = new TaggedLogOutputStream("${path}>", logger)
 189     errorOutput = standardOutput
 190 }
 191
 192 afterEvaluate {
 193     subprojects { project ->
 194         tasks.withType(JavaCompile) {
 195             // Add compiler args for all code except third-party code.
 196             options.compilerArgs += [
 197                 // Turn on all warnings, except...
 198                 "-Xlint:all",
 199                 // Deprecation, because we do use deprecated API for compatibility.
 200                 "-Xlint:-deprecation",
 201                 // Serial, because we don't use Java serialization.
 202                 "-Xlint:-serial",
 203                 // Classfile, because javac has a bug with MethodParameters attributes
 204                 // with Java 7. https://bugs.openjdk.java.net/browse/JDK-8190452
 205                 "-Xlint:-classfile",
 206                 // Turn all remaining warnings into errors,
 207                 // unless marked by @SuppressWarnings.
 208                 "-Werror"]
 209         }
 210     }
 211 }
 212
 213 apply plugin: 'idea'
 214
 215 idea {
 216     project {
 217         languageLevel = '1.8'
 218     }
 219
 220     module {
 221         // Object directories take a huge amount of time for IntelliJ to index.
 222         // Exclude them.  Convention is that object directories start with obj.
 223         // IntelliJ is clever and will not exclude the parts of the object
 224         // directory that are referenced, if there are any.  In practice,
 225         // indexing the entirety of the tree is taking too long, so exclude all
 226         // but mobile/.
 227         def topsrcdirURI = file(topsrcdir).toURI()
 228         excludeDirs += files(file(topsrcdir)
 229             .listFiles({it.isDirectory()} as FileFilter)
 230             .collect({topsrcdirURI.relativize(it.toURI()).toString()}) // Relative paths.
 231             .findAll({!it.equals('mobile/')}))
 232
 233         // If topobjdir is below topsrcdir, hide only some portions of that tree.
 234         def topobjdirURI = file(topobjdir).toURI()
 235         if (!topsrcdirURI.relativize(topobjdirURI).isAbsolute()) {
 236             excludeDirs -= file(topobjdir)
 237             excludeDirs += files(file(topobjdir).listFiles())
 238             excludeDirs -= file("${topobjdir}/gradle")
 239         }
 240     }
 241 }