widget/cocoa/VibrancyManager.mm

   1 /* -*- Mode: C++; tab-width: 8; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
   2 /* vim: set ts=8 sts=2 et sw=2 tw=80: */
   3 /* This Source Code Form is subject to the terms of the Mozilla Public
   4  * License, v. 2.0. If a copy of the MPL was not distributed with this file,
   5  * You can obtain one at http://mozilla.org/MPL/2.0/. */
   6
   7 #include "VibrancyManager.h"
   8 #include "ViewRegion.h"
   9 #include "nsRegion.h"
  10 #include "ViewRegion.h"
  11
  12 #import <objc/message.h>
  13
  14 #include "nsChildView.h"
  15 #include "mozilla/StaticPrefs_widget.h"
  16
  17 using namespace mozilla;
  18
  19 @interface MOZVibrantView : NSVisualEffectView {
  20   VibrancyType mType;
  21 }
  22 - (instancetype)initWithFrame:(NSRect)aRect
  23                  vibrancyType:(VibrancyType)aVibrancyType;
  24 @end
  25
  26 static NSVisualEffectState VisualEffectStateForVibrancyType(
  27     VibrancyType aType) {
  28   switch (aType) {
  29     case VibrancyType::Titlebar:
  30     case VibrancyType::Sidebar:
  31       break;
  32   }
  33   return NSVisualEffectStateFollowsWindowActiveState;
  34 }
  35
  36 static NSVisualEffectMaterial VisualEffectMaterialForVibrancyType(
  37     VibrancyType aType) {
  38   switch (aType) {
  39     case VibrancyType::Sidebar:
  40       return NSVisualEffectMaterialSidebar;
  41     case VibrancyType::Titlebar:
  42       return NSVisualEffectMaterialTitlebar;
  43   }
  44 }
  45
  46 static NSVisualEffectBlendingMode VisualEffectBlendingModeForVibrancyType(
  47     VibrancyType aType) {
  48   switch (aType) {
  49     case VibrancyType::Sidebar:
  50       return StaticPrefs::widget_macos_sidebar_blend_mode_behind_window()
  51                  ? NSVisualEffectBlendingModeBehindWindow
  52                  : NSVisualEffectBlendingModeWithinWindow;
  53     case VibrancyType::Titlebar:
  54       return StaticPrefs::widget_macos_titlebar_blend_mode_behind_window()
  55                  ? NSVisualEffectBlendingModeBehindWindow
  56                  : NSVisualEffectBlendingModeWithinWindow;
  57   }
  58 }
  59
  60 @implementation MOZVibrantView
  61 - (instancetype)initWithFrame:(NSRect)aRect vibrancyType:(VibrancyType)aType {
  62   self = [super initWithFrame:aRect];
  63   mType = aType;
  64
  65   self.appearance = nil;
  66   self.state = VisualEffectStateForVibrancyType(mType);
  67   self.material = VisualEffectMaterialForVibrancyType(mType);
  68   self.blendingMode = VisualEffectBlendingModeForVibrancyType(mType);
  69   self.emphasized = NO;
  70   return self;
  71 }
  72
  73 - (NSView*)hitTest:(NSPoint)aPoint {
  74   // This view must be transparent to mouse events.
  75   return nil;
  76 }
  77 @end
  78
  79 VibrancyManager::VibrancyManager(const nsChildView& aCoordinateConverter,
  80                                  NSView* aContainerView)
  81     : mCoordinateConverter(aCoordinateConverter),
  82       mContainerView(aContainerView) {}
  83
  84 VibrancyManager::~VibrancyManager() = default;
  85
  86 bool VibrancyManager::UpdateVibrantRegion(
  87     VibrancyType aType, const LayoutDeviceIntRegion& aRegion) {
  88   auto& slot = mVibrantRegions[aType];
  89   if (aRegion.IsEmpty()) {
  90     bool hadRegion = !!slot;
  91     slot = nullptr;
  92     return hadRegion;
  93   }
  94   if (!slot) {
  95     slot = MakeUnique<ViewRegion>();
  96   }
  97   return slot->UpdateRegion(aRegion, mCoordinateConverter, mContainerView, ^() {
  98     return [[MOZVibrantView alloc] initWithFrame:NSZeroRect vibrancyType:aType];
  99   });
 100 }