ipc/glue/ExtensionKitUtils.mm

   1 /* -*- Mode: c++; c-basic-offset: 2; tab-width: 4; indent-tabs-mode: nil; -*-
   2  * vim: set sw=2 ts=4 expandtab:
   3  * This Source Code Form is subject to the terms of the Mozilla Public
   4  * License, v. 2.0. If a copy of the MPL was not distributed with this
   5  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   6
   7 #include "ExtensionKitUtils.h"
   8 #include "LaunchError.h"
   9
  10 #import <BrowserEngineKit/BrowserEngineKit.h>
  11
  12 namespace mozilla::ipc {
  13
  14 void BEProcessCapabilityGrantDeleter::operator()(void* aGrant) const {
  15   auto grant = static_cast<id<BEProcessCapabilityGrant>>(aGrant);
  16   [grant invalidate];
  17   [grant release];
  18 }
  19
  20 void ExtensionKitProcess::StartProcess(
  21     Kind aKind,
  22     const std::function<void(Result<ExtensionKitProcess, LaunchError>&&)>&
  23         aCompletion) {
  24   auto callCompletion = [=](auto* aProcess, NSError* aError) {
  25     if (aProcess) {
  26       [aProcess retain];
  27       aCompletion(ExtensionKitProcess(aKind, aProcess));
  28     } else {
  29       NSLog(@"Error launching process, description '%@', reason '%@'",
  30             [aError localizedDescription], [aError localizedFailureReason]);
  31       aCompletion(Err(LaunchError("ExtensionKitProcess::StartProcess")));
  32     }
  33   };
  34
  35   switch (aKind) {
  36     case Kind::WebContent: {
  37       [BEWebContentProcess
  38           webContentProcessWithInterruptionHandler:^{
  39           }
  40           completion:^(BEWebContentProcess* process, NSError* error) {
  41             callCompletion(process, error);
  42           }];
  43       return;
  44     }
  45     case Kind::Networking: {
  46       [BENetworkingProcess
  47           networkProcessWithInterruptionHandler:^{
  48           }
  49           completion:^(BENetworkingProcess* process, NSError* error) {
  50             callCompletion(process, error);
  51           }];
  52       return;
  53     }
  54     case Kind::Rendering: {
  55       [BERenderingProcess
  56           renderingProcessWithInterruptionHandler:^{
  57           }
  58           completion:^(BERenderingProcess* process, NSError* error) {
  59             callCompletion(process, error);
  60           }];
  61       return;
  62     }
  63   }
  64 }
  65
  66 template <typename F>
  67 static void SwitchObject(ExtensionKitProcess::Kind aKind, void* aProcessObject,
  68                          F&& aMatcher) {
  69   switch (aKind) {
  70     case ExtensionKitProcess::Kind::WebContent:
  71       aMatcher(static_cast<BEWebContentProcess*>(aProcessObject));
  72       break;
  73     case ExtensionKitProcess::Kind::Networking:
  74       aMatcher(static_cast<BENetworkingProcess*>(aProcessObject));
  75       break;
  76     case ExtensionKitProcess::Kind::Rendering:
  77       aMatcher(static_cast<BERenderingProcess*>(aProcessObject));
  78       break;
  79   }
  80 }
  81
  82 DarwinObjectPtr<xpc_connection_t> ExtensionKitProcess::MakeLibXPCConnection() {
  83   NSError* error = nullptr;
  84   DarwinObjectPtr<xpc_connection_t> xpcConnection;
  85   SwitchObject(mKind, mProcessObject, [&](auto* aProcessObject) {
  86     xpcConnection = [aProcessObject makeLibXPCConnectionError:&error];
  87   });
  88   return xpcConnection;
  89 }
  90
  91 void ExtensionKitProcess::Invalidate() {
  92   SwitchObject(mKind, mProcessObject,
  93                [&](auto* aProcessObject) { [aProcessObject invalidate]; });
  94 }
  95
  96 UniqueBEProcessCapabilityGrant
  97 ExtensionKitProcess::GrantForegroundCapability() {
  98   NSError* error = nullptr;
  99   BEProcessCapability* cap = [BEProcessCapability foreground];
 100   id<BEProcessCapabilityGrant> grant = nil;
 101   SwitchObject(mKind, mProcessObject, [&](auto* aProcessObject) {
 102     grant = [aProcessObject grantCapability:cap error:&error];
 103   });
 104   return UniqueBEProcessCapabilityGrant(grant ? [grant retain] : nil);
 105 }
 106
 107 ExtensionKitProcess::ExtensionKitProcess(const ExtensionKitProcess& aOther)
 108     : mKind(aOther.mKind), mProcessObject(aOther.mProcessObject) {
 109   SwitchObject(mKind, mProcessObject,
 110                [&](auto* aProcessObject) { [aProcessObject retain]; });
 111 }
 112
 113 ExtensionKitProcess& ExtensionKitProcess::operator=(
 114     const ExtensionKitProcess& aOther) {
 115   Kind oldKind = std::exchange(mKind, aOther.mKind);
 116   void* oldProcessObject = std::exchange(mProcessObject, aOther.mProcessObject);
 117   SwitchObject(mKind, mProcessObject,
 118                [&](auto* aProcessObject) { [aProcessObject retain]; });
 119   SwitchObject(oldKind, oldProcessObject,
 120                [&](auto* aProcessObject) { [aProcessObject release]; });
 121   return *this;
 122 }
 123
 124 ExtensionKitProcess::~ExtensionKitProcess() {
 125   SwitchObject(mKind, mProcessObject,
 126                [&](auto* aProcessObject) { [aProcessObject release]; });
 127 }
 128
 129 }  // namespace mozilla::ipc