widget/cocoa/nsColorPicker.mm

   1 /* -*- Mode: C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
   2 /* This Source Code Form is subject to the terms of the Mozilla Public
   3  * License, v. 2.0. If a copy of the MPL was not distributed with this
   4  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   5
   6 #import <Cocoa/Cocoa.h>
   7
   8 #include "nsColorPicker.h"
   9 #include "nsCocoaUtils.h"
  10 #include "nsThreadUtils.h"
  11
  12 using namespace mozilla;
  13
  14 static unsigned int HexStrToInt(NSString* str) {
  15   unsigned int result = 0;
  16
  17   for (unsigned int i = 0; i < [str length]; ++i) {
  18     char c = [str characterAtIndex:i];
  19     result *= 16;
  20     if (c >= '0' && c <= '9') {
  21       result += c - '0';
  22     } else if (c >= 'A' && c <= 'F') {
  23       result += 10 + (c - 'A');
  24     } else {
  25       result += 10 + (c - 'a');
  26     }
  27   }
  28
  29   return result;
  30 }
  31
  32 @interface NSColorPanelWrapper : NSObject <NSWindowDelegate> {
  33   NSColorPanel* mColorPanel;
  34   nsColorPicker* mColorPicker;
  35 }
  36 - (id)initWithPicker:(nsColorPicker*)aPicker;
  37 - (void)open:(NSColor*)aInitialColor title:(NSString*)aTitle;
  38 - (void)colorChanged:(NSColorPanel*)aPanel;
  39 - (void)windowWillClose:(NSNotification*)aNotification;
  40 - (void)close;
  41 @end
  42
  43 @implementation NSColorPanelWrapper
  44 - (id)initWithPicker:(nsColorPicker*)aPicker {
  45   mColorPicker = aPicker;
  46   mColorPanel = [NSColorPanel sharedColorPanel];
  47
  48   self = [super init];
  49   return self;
  50 }
  51
  52 - (void)open:(NSColor*)aInitialColor title:(NSString*)aTitle {
  53   [mColorPanel setTarget:self];
  54   [mColorPanel setAction:@selector(colorChanged:)];
  55   [mColorPanel setDelegate:self];
  56   [mColorPanel setTitle:aTitle];
  57   [mColorPanel setColor:aInitialColor];
  58   [mColorPanel setFrameOrigin:[NSEvent mouseLocation]];
  59   [mColorPanel makeKeyAndOrderFront:nil];
  60 }
  61
  62 - (void)colorChanged:(NSColorPanel*)aPanel {
  63   if (!mColorPicker) {
  64     return;
  65   }
  66   mColorPicker->Update([mColorPanel color]);
  67 }
  68
  69 - (void)windowWillClose:(NSNotification*)aNotification {
  70   if (!mColorPicker) {
  71     return;
  72   }
  73   mColorPicker->Done();
  74 }
  75
  76 - (void)close {
  77   [mColorPanel setTarget:nil];
  78   [mColorPanel setAction:nil];
  79   [mColorPanel setDelegate:nil];
  80
  81   mColorPanel = nil;
  82   mColorPicker = nullptr;
  83 }
  84 @end
  85
  86 NS_IMPL_ISUPPORTS(nsColorPicker, nsIColorPicker)
  87
  88 nsColorPicker::~nsColorPicker() {
  89   if (mColorPanelWrapper) {
  90     [mColorPanelWrapper close];
  91     [mColorPanelWrapper release];
  92     mColorPanelWrapper = nullptr;
  93   }
  94 }
  95
  96 // TODO(bug 1805397): Implement default colors
  97 NS_IMETHODIMP
  98 nsColorPicker::Init(mozIDOMWindowProxy* aParent, const nsAString& aTitle,
  99                     const nsAString& aInitialColor, const nsTArray<nsString>& aDefaultColors) {
 100   MOZ_ASSERT(NS_IsMainThread(), "Color pickers can only be opened from main thread currently");
 101   mTitle = aTitle;
 102   mColor = aInitialColor;
 103   mColorPanelWrapper = [[NSColorPanelWrapper alloc] initWithPicker:this];
 104   return NS_OK;
 105 }
 106
 107 /* static */ NSColor* nsColorPicker::GetNSColorFromHexString(const nsAString& aColor) {
 108   NSString* str = nsCocoaUtils::ToNSString(aColor);
 109
 110   double red = HexStrToInt([str substringWithRange:NSMakeRange(1, 2)]) / 255.0;
 111   double green = HexStrToInt([str substringWithRange:NSMakeRange(3, 2)]) / 255.0;
 112   double blue = HexStrToInt([str substringWithRange:NSMakeRange(5, 2)]) / 255.0;
 113
 114   return [NSColor colorWithDeviceRed:red green:green blue:blue alpha:1.0];
 115 }
 116
 117 /* static */ void nsColorPicker::GetHexStringFromNSColor(NSColor* aColor, nsAString& aResult) {
 118   CGFloat redFloat, greenFloat, blueFloat;
 119
 120   NSColor* color = aColor;
 121   @try {
 122     [color getRed:&redFloat green:&greenFloat blue:&blueFloat alpha:nil];
 123   } @catch (NSException* e) {
 124     color = [color colorUsingColorSpace:[NSColorSpace genericRGBColorSpace]];
 125     [color getRed:&redFloat green:&greenFloat blue:&blueFloat alpha:nil];
 126   }
 127
 128   nsCocoaUtils::GetStringForNSString(
 129       [NSString stringWithFormat:@"#%02x%02x%02x", (int)(redFloat * 255), (int)(greenFloat * 255),
 130                                  (int)(blueFloat * 255)],
 131       aResult);
 132 }
 133
 134 NS_IMETHODIMP
 135 nsColorPicker::Open(nsIColorPickerShownCallback* aCallback) {
 136   MOZ_ASSERT(aCallback);
 137   mCallback = aCallback;
 138
 139   [mColorPanelWrapper open:GetNSColorFromHexString(mColor) title:nsCocoaUtils::ToNSString(mTitle)];
 140
 141   NS_ADDREF_THIS();
 142
 143   return NS_OK;
 144 }
 145
 146 void nsColorPicker::Update(NSColor* aColor) {
 147   GetHexStringFromNSColor(aColor, mColor);
 148   mCallback->Update(mColor);
 149 }
 150
 151 void nsColorPicker::Done() {
 152   [mColorPanelWrapper close];
 153   [mColorPanelWrapper release];
 154   mColorPanelWrapper = nullptr;
 155   mCallback->Done(u""_ns);
 156   mCallback = nullptr;
 157   NS_RELEASE_THIS();
 158 }