build.gradle

   1 def tryInt = { string ->
   2     if (string == null) {
   3         return string
   4     }
   5     if (string.isInteger()) {
   6         return string as Integer
   7     }
   8     return string
   9 }
  10
  11 allprojects {
  12     // Expose the per-object-directory configuration to all projects.
  13     ext {
  14         mozconfig = gradle.mozconfig
  15         topsrcdir = gradle.mozconfig.topsrcdir
  16         topobjdir = gradle.mozconfig.topobjdir
  17
  18         compileSdkVersion = 28
  19         targetSdkVersion = tryInt(mozconfig.substs.ANDROID_TARGET_SDK)
  20         minSdkVersion = tryInt(mozconfig.substs.MOZ_ANDROID_MIN_SDK_VERSION)
  21         manifestPlaceholders = [
  22             ANDROID_PACKAGE_NAME: mozconfig.substs.ANDROID_PACKAGE_NAME,
  23             ANDROID_TARGET_SDK: mozconfig.substs.ANDROID_TARGET_SDK,
  24             MOZ_ANDROID_MIN_SDK_VERSION: mozconfig.substs.MOZ_ANDROID_MIN_SDK_VERSION,
  25             MOZ_ANDROID_SHARED_ID: "${mozconfig.substs.ANDROID_PACKAGE_NAME}.sharedID",
  26         ]
  27     }
  28
  29     repositories {
  30         gradle.mozconfig.substs.GRADLE_MAVEN_REPOSITORIES.each { repository ->
  31             maven {
  32                 url repository
  33             }
  34         }
  35     }
  36
  37     task downloadDependencies() {
  38         description 'Download all dependencies to the Gradle cache'
  39         doLast {
  40             configurations.each { configuration ->
  41                 if (configuration.canBeResolved) {
  42                     configuration.allDependencies.each { dependency ->
  43                         try {
  44                             configuration.files(dependency)
  45                         } catch(e) {
  46                             println("Could not resolve ${configuration.name} -> ${dependency.name}")
  47                             println(" > ${e.message}")
  48                             if (e.cause) {
  49                                 println(" >> ${e.cause}")
  50                                 if (e.cause.cause) {
  51                                     println(" >> ${e.cause.cause}")
  52                                 }
  53                             }
  54                             println("")
  55                         }
  56                     }
  57                 }
  58             }
  59         }
  60     }
  61 }
  62
  63 buildDir "${topobjdir}/gradle/build"
  64
  65 buildscript {
  66     repositories {
  67         gradle.mozconfig.substs.GRADLE_MAVEN_REPOSITORIES.each { repository ->
  68             maven {
  69                 url repository
  70             }
  71         }
  72     }
  73
  74     ext.kotlin_version = '1.3.41'
  75     ext.support_library_version = '28.0.0'
  76     ext.jacoco_version = '0.8.1'
  77     ext.lifecycle_library_version = '1.1.1'
  78
  79     if (gradle.mozconfig.substs.MOZ_ANDROID_GOOGLE_PLAY_SERVICES) {
  80         ext.google_play_services_version = '15.0.1'
  81         ext.google_play_services_cast_version = '16.0.0'
  82         ext.google_play_services_fido_version = '17.0.0'
  83     }
  84
  85     dependencies {
  86         classpath 'org.mozilla.apilint:apilint:0.2.6'
  87         classpath 'com.android.tools.build:gradle:3.4.2'
  88         classpath 'com.getkeepsafe.dexcount:dexcount-gradle-plugin:0.8.2'
  89         classpath 'org.apache.commons:commons-exec:1.3'
  90         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
  91     }
  92 }
  93
  94 // A stream that processes bytes line by line, prepending a tag before sending
  95 // each line to Gradle's logging.
  96 class TaggedLogOutputStream extends org.apache.commons.exec.LogOutputStream {
  97     String tag
  98     Logger logger
  99
 100     TaggedLogOutputStream(tag, logger) {
 101         this.tag = tag
 102         this.logger = logger
 103     }
 104
 105     void processLine(String line, int level) {
 106         logger.lifecycle("${this.tag} ${line}")
 107     }
 108 }
 109
 110 ext.geckoBinariesOnlyIf = { task ->
 111     // Never when Gradle was invoked within `mach build`.
 112     if ('1' == System.env.GRADLE_INVOKED_WITHIN_MACH_BUILD) {
 113         rootProject.logger.lifecycle("Skipping task ${task.path} because: within `mach build`")
 114         return false
 115     }
 116
 117     // Never for official builds.
 118     if (mozconfig.substs.MOZILLA_OFFICIAL) {
 119         rootProject.logger.lifecycle("Skipping task ${task.path} because: MOZILLA_OFFICIAL")
 120         return false
 121     }
 122
 123     // Multi-l10n builds set `AB_CD=multi`, which isn't a valid locale.  This
 124     // causes the
 125     //
 126     // |mach build| > |mach gradle| >
 127     // |mach build mobile/android/base/generated_android_code_and_resources| >
 128     // AndroidManifest.xml > strings.xml > multi/brand.dtd
 129     //
 130     // dependency chain to fail, since multi isn't a real locale.  To avoid
 131     // this, if Gradle is invoked with AB_CD=multi, we don't invoke Make at all.
 132     if ('multi' == System.env.AB_CD) {
 133         rootProject.logger.lifecycle("Skipping task ${task.path} because: AB_CD=multi")
 134         return false
 135     }
 136
 137     // Single-locale l10n repacks set `IS_LANGUAGE_REPACK=1` and handle resource
 138     // and code generation themselves.
 139     if ('1' == System.env.IS_LANGUAGE_REPACK) {
 140         rootProject.logger.lifecycle("Skipping task ${task.path} because: IS_LANGUAGE_REPACK")
 141         return false
 142     }
 143
 144     rootProject.logger.lifecycle("Executing task ${task.path}")
 145     return true
 146 }
 147
 148 class MachExec extends Exec {
 149     def MachExec() {
 150         // Bug 1543982: When invoking `mach build` recursively, the outer `mach
 151         // build` itself modifies the environment, causing configure to run
 152         // again.  This tries to restore the environment that the outer `mach
 153         // build` was invoked in.  See the comment in
 154         // $topsrcdir/settings.gradle.
 155         project.ext.mozconfig.mozconfig.env.unmodified.each { k, v -> environment.remove(k) }
 156         environment project.ext.mozconfig.orig_mozconfig.env.unmodified
 157     }
 158 }
 159
 160 // Why |mach build mobile/android/base/...| and |mach build faster|?  |mach
 161 // build faster| generates dependentlibs.list, which in turn depends on compiled
 162 // code.  That causes a circular dependency between Java compilation/JNI wrapper
 163 // generation/native code compilation.  So we have the special target for
 164 // Android-specific generated code, and the |mach build faster| target for all
 165 // the stuff that goes into the omnijar.
 166 task machBuildFaster(type: MachExec) {
 167     onlyIf rootProject.ext.geckoBinariesOnlyIf
 168
 169     workingDir "${topsrcdir}"
 170
 171     commandLine mozconfig.substs.PYTHON
 172     args "${topsrcdir}/mach"
 173     args 'build'
 174     args 'faster'
 175
 176     // Add `-v` if we're running under `--info` (or `--debug`).
 177     if (project.logger.isEnabled(LogLevel.INFO)) {
 178         args '-v'
 179     }
 180
 181     // `path` is like `:machBuildFaster`.
 182     standardOutput = new TaggedLogOutputStream("${path}>", logger)
 183     errorOutput = standardOutput
 184 }
 185
 186 def createMachStagePackageTask(name) {
 187     return task(name, type: MachExec) {
 188         onlyIf rootProject.ext.geckoBinariesOnlyIf
 189
 190         dependsOn rootProject.machBuildFaster
 191
 192         workingDir "${topobjdir}"
 193
 194         // We'd prefer this to be a `mach` invocation, but `mach build
 195         // mobile/android/installer/stage-package` doesn't work as expected.
 196         commandLine mozconfig.substs.GMAKE
 197         args '-C'
 198         args "${topobjdir}/mobile/android/installer"
 199         args 'stage-package'
 200
 201         outputs.file "${topobjdir}/dist/fennec/assets/${mozconfig.substs.ANDROID_CPU_ARCH}/libxul.so"
 202         outputs.file "${topobjdir}/dist/fennec/lib/${mozconfig.substs.ANDROID_CPU_ARCH}/libmozglue.so"
 203
 204         // Force running `stage-package`.
 205         outputs.upToDateWhen { false }
 206
 207         // `path` is like `:machStagePackage`.
 208         standardOutput = new TaggedLogOutputStream("${path}>", logger)
 209         errorOutput = standardOutput
 210     }
 211 }
 212
 213 createMachStagePackageTask("machStagePackageForFennec").with {
 214     outputs.file "${topobjdir}/dist/fennec/assets/omni.ja"
 215 }
 216
 217 createMachStagePackageTask("machStagePackageForGeckoview").with {
 218     args 'MOZ_GECKOVIEW_JAR=1'
 219     outputs.file "${topobjdir}/dist/geckoview/assets/omni.ja"
 220     // Avoid races between stage-package invocations.
 221     mustRunAfter tasks["machStagePackageForFennec"]
 222 }
 223
 224 afterEvaluate {
 225     subprojects { project ->
 226         tasks.withType(JavaCompile) {
 227             // Add compiler args for all code except third-party code.
 228             options.compilerArgs += [
 229                 // Turn on all warnings, except...
 230                 "-Xlint:all",
 231                 // Deprecation, because we do use deprecated API for compatibility.
 232                 "-Xlint:-deprecation",
 233                 // Serial, because we don't use Java serialization.
 234                 "-Xlint:-serial",
 235                 // Classfile, because javac has a bug with MethodParameters attributes
 236                 // with Java 7. https://bugs.openjdk.java.net/browse/JDK-8190452
 237                 "-Xlint:-classfile",
 238                 // Turn all remaining warnings into errors,
 239                 // unless marked by @SuppressWarnings.
 240                 "-Werror"]
 241         }
 242     }
 243 }
 244
 245 apply plugin: 'idea'
 246
 247 idea {
 248     project {
 249         languageLevel = '1.8'
 250     }
 251
 252     module {
 253         // Object directories take a huge amount of time for IntelliJ to index.
 254         // Exclude them.  Convention is that object directories start with obj.
 255         // IntelliJ is clever and will not exclude the parts of the object
 256         // directory that are referenced, if there are any.  In practice,
 257         // indexing the entirety of the tree is taking too long, so exclude all
 258         // but mobile/.
 259         def topsrcdirURI = file(topsrcdir).toURI()
 260         excludeDirs += files(file(topsrcdir)
 261             .listFiles({it.isDirectory()} as FileFilter)
 262             .collect({topsrcdirURI.relativize(it.toURI()).toString()}) // Relative paths.
 263             .findAll({!it.equals('mobile/')}))
 264
 265         // If topobjdir is below topsrcdir, hide only some portions of that tree.
 266         def topobjdirURI = file(topobjdir).toURI()
 267         if (!topsrcdirURI.relativize(topobjdirURI).isAbsolute()) {
 268             excludeDirs -= file(topobjdir)
 269             excludeDirs += files(file(topobjdir).listFiles())
 270             excludeDirs -= file("${topobjdir}/gradle")
 271         }
 272     }
 273 }