widget/cocoa/OSXNotificationCenter.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /* This Source Code Form is subject to the terms of the Mozilla Public
   3  * License, v. 2.0. If a copy of the MPL was not distributed with this
   4  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   5
   6 #include "OSXNotificationCenter.h"
   7 #import <AppKit/AppKit.h>
   8 #include "imgIRequest.h"
   9 #include "imgIContainer.h"
  10 #include "nsNetUtil.h"
  11 #include "imgLoader.h"
  12 #import "nsCocoaUtils.h"
  13 #include "nsObjCExceptions.h"
  14 #include "nsString.h"
  15 #include "nsCOMPtr.h"
  16 #include "nsIObserver.h"
  17 #include "imgRequestProxy.h"
  18
  19 using namespace mozilla;
  20
  21 #if !defined(MAC_OS_X_VERSION_10_8) || (MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_8)
  22 @protocol NSUserNotificationCenterDelegate
  23 @end
  24 static NSString * const NSUserNotificationDefaultSoundName = @"DefaultSoundName";
  25 enum {
  26   NSUserNotificationActivationTypeNone = 0,
  27   NSUserNotificationActivationTypeContentsClicked = 1,
  28   NSUserNotificationActivationTypeActionButtonClicked = 2
  29 };
  30 typedef NSInteger NSUserNotificationActivationType;
  31 #endif
  32
  33 @protocol FakeNSUserNotification <NSObject>
  34 @property (copy) NSString* title;
  35 @property (copy) NSString* subtitle;
  36 @property (copy) NSString* informativeText;
  37 @property (copy) NSString* actionButtonTitle;
  38 @property (copy) NSDictionary* userInfo;
  39 @property (copy) NSDate* deliveryDate;
  40 @property (copy) NSTimeZone* deliveryTimeZone;
  41 @property (copy) NSDateComponents* deliveryRepeatInterval;
  42 @property (readonly) NSDate* actualDeliveryDate;
  43 @property (readonly, getter=isPresented) BOOL presented;
  44 @property (readonly, getter=isRemote) BOOL remote;
  45 @property (copy) NSString* soundName;
  46 @property BOOL hasActionButton;
  47 @property (readonly) NSUserNotificationActivationType activationType;
  48 @property (copy) NSString *otherButtonTitle;
  49 @property (copy) NSImage *contentImage;
  50 @end
  51
  52 @protocol FakeNSUserNotificationCenter <NSObject>
  53 + (id<FakeNSUserNotificationCenter>)defaultUserNotificationCenter;
  54 @property (assign) id <NSUserNotificationCenterDelegate> delegate;
  55 @property (copy) NSArray *scheduledNotifications;
  56 - (void)scheduleNotification:(id<FakeNSUserNotification>)notification;
  57 - (void)removeScheduledNotification:(id<FakeNSUserNotification>)notification;
  58 @property (readonly) NSArray *deliveredNotifications;
  59 - (void)deliverNotification:(id<FakeNSUserNotification>)notification;
  60 - (void)removeDeliveredNotification:(id<FakeNSUserNotification>)notification;
  61 - (void)removeAllDeliveredNotifications;
  62 - (void)_removeAllDisplayedNotifications;
  63 - (void)_removeDisplayedNotification:(id<FakeNSUserNotification>)notification;
  64 @end
  65
  66 @interface mozNotificationCenterDelegate : NSObject <NSUserNotificationCenterDelegate>
  67 {
  68   OSXNotificationCenter *mOSXNC;
  69 }
  70   - (id)initWithOSXNC:(OSXNotificationCenter*)osxnc;
  71 @end
  72
  73 @implementation mozNotificationCenterDelegate
  74
  75 - (id)initWithOSXNC:(OSXNotificationCenter*)osxnc
  76 {
  77   [super init];
  78   // We should *never* outlive this OSXNotificationCenter.
  79   mOSXNC = osxnc;
  80   return self;
  81 }
  82
  83 - (void)userNotificationCenter:(id<FakeNSUserNotificationCenter>)center
  84         didDeliverNotification:(id<FakeNSUserNotification>)notification
  85 {
  86
  87 }
  88
  89 - (void)userNotificationCenter:(id<FakeNSUserNotificationCenter>)center
  90        didActivateNotification:(id<FakeNSUserNotification>)notification
  91 {
  92   mOSXNC->OnClick([[notification userInfo] valueForKey:@"name"]);
  93 }
  94
  95 - (BOOL)userNotificationCenter:(id<FakeNSUserNotificationCenter>)center
  96      shouldPresentNotification:(id<FakeNSUserNotification>)notification
  97 {
  98   return YES;
  99 }
 100
 101 // This is an undocumented method that we need for parity with Safari.
 102 // Apple bug #15440664.
 103 - (void)userNotificationCenter:(id<FakeNSUserNotificationCenter>)center
 104   didRemoveDeliveredNotifications:(NSArray *)notifications
 105 {
 106   for (id<FakeNSUserNotification> notification in notifications) {
 107     NSString *name = [[notification userInfo] valueForKey:@"name"];
 108     mOSXNC->CloseAlertCocoaString(name);
 109   }
 110 }
 111
 112 @end
 113
 114 namespace mozilla {
 115
 116 class OSXNotificationInfo {
 117 private:
 118   ~OSXNotificationInfo();
 119
 120 public:
 121   NS_INLINE_DECL_REFCOUNTING(OSXNotificationInfo)
 122   OSXNotificationInfo(NSString *name, nsIObserver *observer,
 123                       const nsAString & alertCookie);
 124
 125   NSString *mName;
 126   nsCOMPtr<nsIObserver> mObserver;
 127   nsString mCookie;
 128   nsRefPtr<imgRequestProxy> mIconRequest;
 129   id<FakeNSUserNotification> mPendingNotifiction;
 130   nsCOMPtr<nsITimer> mIconTimeoutTimer;
 131 };
 132
 133 OSXNotificationInfo::OSXNotificationInfo(NSString *name, nsIObserver *observer,
 134                                          const nsAString & alertCookie)
 135 {
 136   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 137
 138   NS_ASSERTION(name, "Cannot create OSXNotificationInfo without a name!");
 139   mName = [name retain];
 140   mObserver = observer;
 141   mCookie = alertCookie;
 142   mPendingNotifiction = nil;
 143
 144   NS_OBJC_END_TRY_ABORT_BLOCK;
 145 }
 146
 147 OSXNotificationInfo::~OSXNotificationInfo()
 148 {
 149   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 150
 151   [mName release];
 152   [mPendingNotifiction release];
 153
 154   NS_OBJC_END_TRY_ABORT_BLOCK;
 155 }
 156
 157 static id<FakeNSUserNotificationCenter> GetNotificationCenter() {
 158   NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NIL;
 159
 160   Class c = NSClassFromString(@"NSUserNotificationCenter");
 161   return [c performSelector:@selector(defaultUserNotificationCenter)];
 162
 163   NS_OBJC_END_TRY_ABORT_BLOCK_NIL;
 164 }
 165
 166 OSXNotificationCenter::OSXNotificationCenter()
 167 {
 168   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 169
 170   mDelegate = [[mozNotificationCenterDelegate alloc] initWithOSXNC:this];
 171   GetNotificationCenter().delegate = mDelegate;
 172
 173   NS_OBJC_END_TRY_ABORT_BLOCK;
 174 }
 175
 176 OSXNotificationCenter::~OSXNotificationCenter()
 177 {
 178   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 179
 180   [GetNotificationCenter() removeAllDeliveredNotifications];
 181   [mDelegate release];
 182
 183   NS_OBJC_END_TRY_ABORT_BLOCK;
 184 }
 185
 186 NS_IMPL_ISUPPORTS(OSXNotificationCenter, nsIAlertsService, imgINotificationObserver, nsITimerCallback)
 187
 188 nsresult OSXNotificationCenter::Init()
 189 {
 190   NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT;
 191
 192   return (!!NSClassFromString(@"NSUserNotification")) ? NS_OK : NS_ERROR_FAILURE;
 193
 194   NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT;
 195 }
 196
 197 NS_IMETHODIMP
 198 OSXNotificationCenter::ShowAlertNotification(const nsAString & aImageUrl, const nsAString & aAlertTitle,
 199                                              const nsAString & aAlertText, bool aAlertTextClickable,
 200                                              const nsAString & aAlertCookie,
 201                                              nsIObserver * aAlertListener,
 202                                              const nsAString & aAlertName,
 203                                              const nsAString & aBidi,
 204                                              const nsAString & aLang,
 205                                              const nsAString & aData,
 206                                              nsIPrincipal * aPrincipal)
 207 {
 208   NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT;
 209
 210   Class unClass = NSClassFromString(@"NSUserNotification");
 211   id<FakeNSUserNotification> notification = [[unClass alloc] init];
 212   notification.title = [NSString stringWithCharacters:(const unichar *)aAlertTitle.BeginReading()
 213                                                length:aAlertTitle.Length()];
 214   notification.informativeText = [NSString stringWithCharacters:(const unichar *)aAlertText.BeginReading()
 215                                                          length:aAlertText.Length()];
 216   notification.soundName = NSUserNotificationDefaultSoundName;
 217   notification.hasActionButton = NO;
 218   NSString *alertName = [NSString stringWithCharacters:(const unichar *)aAlertName.BeginReading() length:aAlertName.Length()];
 219   if (!alertName) {
 220     return NS_ERROR_FAILURE;
 221   }
 222   notification.userInfo = [NSDictionary dictionaryWithObjects:[NSArray arrayWithObjects:alertName, nil]
 223                                                       forKeys:[NSArray arrayWithObjects:@"name", nil]];
 224
 225   OSXNotificationInfo *osxni = new OSXNotificationInfo(alertName, aAlertListener, aAlertCookie);
 226
 227   // Show the notification without waiting for an image if there is no icon URL or
 228   // notification icons are not supported on this version of OS X.
 229   if (aImageUrl.IsEmpty() || ![unClass instancesRespondToSelector:@selector(setContentImage:)]) {
 230     CloseAlertCocoaString(alertName);
 231     mActiveAlerts.AppendElement(osxni);
 232     [GetNotificationCenter() deliverNotification:notification];
 233     [notification release];
 234     if (aAlertListener) {
 235       aAlertListener->Observe(nullptr, "alertshow", PromiseFlatString(aAlertCookie).get());
 236     }
 237   } else {
 238     mPendingAlerts.AppendElement(osxni);
 239     osxni->mPendingNotifiction = notification;
 240     nsRefPtr<imgLoader> il = imgLoader::GetInstance();
 241     if (il) {
 242       nsCOMPtr<nsIURI> imageUri;
 243       NS_NewURI(getter_AddRefs(imageUri), aImageUrl);
 244       if (imageUri) {
 245         nsresult rv = il->LoadImage(imageUri, nullptr, nullptr, aPrincipal, nullptr,
 246                                     this, nullptr, nsIRequest::LOAD_NORMAL, nullptr,
 247                                     nullptr, EmptyString(),
 248                                     getter_AddRefs(osxni->mIconRequest));
 249         if (NS_SUCCEEDED(rv)) {
 250           // Set a timer for six seconds. If we don't have an icon by the time this
 251           // goes off then we go ahead without an icon.
 252           nsCOMPtr<nsITimer> timer = do_CreateInstance(NS_TIMER_CONTRACTID);
 253           osxni->mIconTimeoutTimer = timer;
 254           timer->InitWithCallback(this, 6000, nsITimer::TYPE_ONE_SHOT);
 255           return NS_OK;
 256         }
 257       }
 258     }
 259     ShowPendingNotification(osxni);
 260   }
 261
 262   return NS_OK;
 263
 264   NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT;
 265 }
 266
 267 NS_IMETHODIMP
 268 OSXNotificationCenter::CloseAlert(const nsAString& aAlertName,
 269                                   nsIPrincipal* aPrincipal)
 270 {
 271   NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT;
 272
 273   NSString *alertName = [NSString stringWithCharacters:(const unichar *)aAlertName.BeginReading() length:aAlertName.Length()];
 274   CloseAlertCocoaString(alertName);
 275   return NS_OK;
 276
 277   NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT;
 278 }
 279
 280 void
 281 OSXNotificationCenter::CloseAlertCocoaString(NSString *aAlertName)
 282 {
 283   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 284
 285   if (!aAlertName) {
 286     return; // Can't do anything without a name
 287   }
 288
 289   NSArray *notifications = [GetNotificationCenter() deliveredNotifications];
 290   for (id<FakeNSUserNotification> notification in notifications) {
 291     NSString *name = [[notification userInfo] valueForKey:@"name"];
 292     if ([name isEqualToString:aAlertName]) {
 293       [GetNotificationCenter() removeDeliveredNotification:notification];
 294       [GetNotificationCenter() _removeDisplayedNotification:notification];
 295       break;
 296     }
 297   }
 298
 299   for (unsigned int i = 0; i < mActiveAlerts.Length(); i++) {
 300     OSXNotificationInfo *osxni = mActiveAlerts[i];
 301     if ([aAlertName isEqualToString:osxni->mName]) {
 302       if (osxni->mObserver) {
 303         osxni->mObserver->Observe(nullptr, "alertfinished", osxni->mCookie.get());
 304       }
 305       mActiveAlerts.RemoveElementAt(i);
 306       break;
 307     }
 308   }
 309
 310   NS_OBJC_END_TRY_ABORT_BLOCK;
 311 }
 312
 313 void
 314 OSXNotificationCenter::OnClick(NSString *aAlertName)
 315 {
 316   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 317
 318   if (!aAlertName) {
 319     return; // Can't do anything without a name
 320   }
 321
 322   for (unsigned int i = 0; i < mActiveAlerts.Length(); i++) {
 323     OSXNotificationInfo *osxni = mActiveAlerts[i];
 324     if ([aAlertName isEqualToString:osxni->mName]) {
 325       if (osxni->mObserver) {
 326         osxni->mObserver->Observe(nullptr, "alertclickcallback", osxni->mCookie.get());
 327       }
 328       return;
 329     }
 330   }
 331
 332   NS_OBJC_END_TRY_ABORT_BLOCK;
 333 }
 334
 335 void
 336 OSXNotificationCenter::ShowPendingNotification(OSXNotificationInfo *osxni)
 337 {
 338   NS_OBJC_BEGIN_TRY_ABORT_BLOCK;
 339
 340   if (osxni->mIconTimeoutTimer) {
 341     osxni->mIconTimeoutTimer->Cancel();
 342     osxni->mIconTimeoutTimer = nullptr;
 343   }
 344
 345   if (osxni->mIconRequest) {
 346     osxni->mIconRequest->Cancel(NS_BINDING_ABORTED);
 347     osxni->mIconRequest = nullptr;
 348   }
 349
 350   CloseAlertCocoaString(osxni->mName);
 351
 352   for (unsigned int i = 0; i < mPendingAlerts.Length(); i++) {
 353     if (mPendingAlerts[i] == osxni) {
 354       mActiveAlerts.AppendElement(osxni);
 355       mPendingAlerts.RemoveElementAt(i);
 356       break;
 357     }
 358   }
 359
 360   [GetNotificationCenter() deliverNotification:osxni->mPendingNotifiction];
 361
 362   if (osxni->mObserver) {
 363     osxni->mObserver->Observe(nullptr, "alertshow", osxni->mCookie.get());
 364   }
 365
 366   [osxni->mPendingNotifiction release];
 367   osxni->mPendingNotifiction = nil;
 368
 369   NS_OBJC_END_TRY_ABORT_BLOCK;
 370 }
 371
 372 NS_IMETHODIMP
 373 OSXNotificationCenter::Notify(imgIRequest *aRequest, int32_t aType, const nsIntRect* aData)
 374 {
 375   NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT;
 376
 377   if (aType == imgINotificationObserver::LOAD_COMPLETE) {
 378     OSXNotificationInfo *osxni = nullptr;
 379     for (unsigned int i = 0; i < mPendingAlerts.Length(); i++) {
 380       if (aRequest == mPendingAlerts[i]->mIconRequest) {
 381         osxni = mPendingAlerts[i];
 382         break;
 383       }
 384     }
 385     if (!osxni || !osxni->mPendingNotifiction) {
 386       return NS_ERROR_FAILURE;
 387     }
 388     NSImage *cocoaImage = nil;
 389     uint32_t imgStatus = imgIRequest::STATUS_ERROR;
 390     nsresult rv = aRequest->GetImageStatus(&imgStatus);
 391     if (NS_SUCCEEDED(rv) && imgStatus != imgIRequest::STATUS_ERROR) {
 392       nsCOMPtr<imgIContainer> image;
 393       rv = aRequest->GetImage(getter_AddRefs(image));
 394       if (NS_SUCCEEDED(rv)) {
 395         nsCocoaUtils::CreateNSImageFromImageContainer(image, imgIContainer::FRAME_FIRST, &cocoaImage, 1.0f);
 396       }
 397     }
 398     (osxni->mPendingNotifiction).contentImage = cocoaImage;
 399     [cocoaImage release];
 400     ShowPendingNotification(osxni);
 401   }
 402   return NS_OK;
 403
 404   NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT;
 405 }
 406
 407 NS_IMETHODIMP
 408 OSXNotificationCenter::Notify(nsITimer *timer)
 409 {
 410   NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT;
 411
 412   if (!timer) {
 413     return NS_ERROR_FAILURE;
 414   }
 415
 416   for (unsigned int i = 0; i < mPendingAlerts.Length(); i++) {
 417     OSXNotificationInfo *osxni = mPendingAlerts[i];
 418     if (timer == osxni->mIconTimeoutTimer.get()) {
 419       osxni->mIconTimeoutTimer = nullptr;
 420       if (osxni->mPendingNotifiction) {
 421         ShowPendingNotification(osxni);
 422         break;
 423       }
 424     }
 425   }
 426   return NS_OK;
 427
 428   NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT;
 429 }
 430
 431 } // namespace mozilla