gfx/harfbuzz/src/hb-ot-shaper-khmer-machine.rl

   1 /*
   2  * Copyright © 2011,2012  Google, Inc.
   3  *
   4  *  This is part of HarfBuzz, a text shaping library.
   5  *
   6  * Permission is hereby granted, without written agreement and without
   7  * license or royalty fees, to use, copy, modify, and distribute this
   8  * software and its documentation for any purpose, provided that the
   9  * above copyright notice and the following two paragraphs appear in
  10  * all copies of this software.
  11  *
  12  * IN NO EVENT SHALL THE COPYRIGHT HOLDER BE LIABLE TO ANY PARTY FOR
  13  * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES
  14  * ARISING OUT OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN
  15  * IF THE COPYRIGHT HOLDER HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH
  16  * DAMAGE.
  17  *
  18  * THE COPYRIGHT HOLDER SPECIFICALLY DISCLAIMS ANY WARRANTIES, INCLUDING,
  19  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
  20  * FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
  21  * ON AN "AS IS" BASIS, AND THE COPYRIGHT HOLDER HAS NO OBLIGATION TO
  22  * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS.
  23  *
  24  * Google Author(s): Behdad Esfahbod
  25  */
  26
  27 #ifndef HB_OT_SHAPER_KHMER_MACHINE_HH
  28 #define HB_OT_SHAPER_KHMER_MACHINE_HH
  29
  30 #include "hb.hh"
  31
  32 #include "hb-ot-layout.hh"
  33 #include "hb-ot-shaper-indic.hh"
  34
  35 /* buffer var allocations */
  36 #define khmer_category() ot_shaper_var_u8_category() /* khmer_category_t */
  37
  38 using khmer_category_t = unsigned;
  39
  40 #define K_Cat(Cat) khmer_syllable_machine_ex_##Cat
  41
  42 enum khmer_syllable_type_t {
  43   khmer_consonant_syllable,
  44   khmer_broken_cluster,
  45   khmer_non_khmer_cluster,
  46 };
  47
  48 %%{
  49   machine khmer_syllable_machine;
  50   alphtype unsigned char;
  51   write exports;
  52   write data;
  53 }%%
  54
  55 %%{
  56
  57
  58 # We use category H for spec category Coeng
  59
  60 export C    = 1;
  61 export V    = 2;
  62 export H    = 4;
  63 export ZWNJ = 5;
  64 export ZWJ  = 6;
  65 export PLACEHOLDER = 10;
  66 export DOTTEDCIRCLE = 11;
  67 export Ra   = 15;
  68
  69 export VAbv = 20;
  70 export VBlw = 21;
  71 export VPre = 22;
  72 export VPst = 23;
  73
  74 export Robatic = 25;
  75 export Xgroup  = 26;
  76 export Ygroup  = 27;
  77
  78
  79 c = (C | Ra | V);
  80 cn = c.((ZWJ|ZWNJ)?.Robatic)?;
  81 joiner = (ZWJ | ZWNJ);
  82 xgroup = (joiner*.Xgroup)*;
  83 ygroup = Ygroup*;
  84
  85 # This grammar was experimentally extracted from what Uniscribe allows.
  86
  87 matra_group = VPre? xgroup VBlw? xgroup (joiner?.VAbv)? xgroup VPst?;
  88 syllable_tail = xgroup matra_group xgroup (H.c)? ygroup;
  89
  90
  91 broken_cluster =        Robatic? (H.cn)* (H | syllable_tail);
  92 consonant_syllable =    (cn|PLACEHOLDER|DOTTEDCIRCLE) broken_cluster;
  93 other =                 any;
  94
  95 main := |*
  96         consonant_syllable      => { found_syllable (khmer_consonant_syllable); };
  97         broken_cluster          => { found_syllable (khmer_broken_cluster); buffer->scratch_flags |= HB_BUFFER_SCRATCH_FLAG_HAS_BROKEN_SYLLABLE; };
  98         other                   => { found_syllable (khmer_non_khmer_cluster); };
  99 *|;
 100
 101
 102 }%%
 103
 104 #define found_syllable(syllable_type) \
 105   HB_STMT_START { \
 106     if (0) fprintf (stderr, "syllable %u..%u %s\n", ts, te, #syllable_type); \
 107     for (unsigned int i = ts; i < te; i++) \
 108       info[i].syllable() = (syllable_serial << 4) | syllable_type; \
 109     syllable_serial++; \
 110     if (syllable_serial == 16) syllable_serial = 1; \
 111   } HB_STMT_END
 112
 113 inline void
 114 find_syllables_khmer (hb_buffer_t *buffer)
 115 {
 116   unsigned int p, pe, eof, ts, te, act HB_UNUSED;
 117   int cs;
 118   hb_glyph_info_t *info = buffer->info;
 119   %%{
 120     write init;
 121     getkey info[p].khmer_category();
 122   }%%
 123
 124   p = 0;
 125   pe = eof = buffer->len;
 126
 127   unsigned int syllable_serial = 1;
 128   %%{
 129     write exec;
 130   }%%
 131 }
 132
 133 #undef found_syllable
 134
 135 #endif /* HB_OT_SHAPER_KHMER_MACHINE_HH */