settings.gradle

   1 // You might think topsrcdir is '.', but that's not true when the Gradle build
   2 // is launched from within IntelliJ.
   3 def topsrcdir = rootProject.projectDir.absolutePath
   4
   5 def commandLine = ["${topsrcdir}/mach", "environment", "--format", "json", "--verbose"]
   6 def proc = commandLine.execute(null, new File(topsrcdir))
   7 def standardOutput = new ByteArrayOutputStream()
   8 proc.consumeProcessOutput(standardOutput, standardOutput)
   9 proc.waitFor()
  10
  11 // Only show the output if something went wrong.
  12 if (proc.exitValue() != 0) {
  13     throw new GradleException("Process '${commandLine}' finished with non-zero exit value ${proc.exitValue()}:\n\n${standardOutput.toString()}")
  14 }
  15
  16 import groovy.json.JsonSlurper
  17 def slurper = new JsonSlurper()
  18 def json = slurper.parseText(standardOutput.toString())
  19
  20 if (json.substs.MOZ_BUILD_APP != 'mobile/android') {
  21     throw new GradleException("Building with Gradle is only supported for Fennec, i.e., MOZ_BUILD_APP == 'mobile/android'.")
  22 }
  23
  24 // Set the Android SDK location.  This is the *least specific* mechanism, which
  25 // is unfortunate: we'd prefer to use the *most specific* mechanism.  That is,
  26 // local.properties (first 'sdk.dir', then 'android.dir') and then the
  27 // environment variable ANDROID_HOME will override this.  That's unfortunate,
  28 // but it's hard to automatically arrange better.
  29 System.setProperty('android.home', json.substs.ANDROID_SDK_ROOT)
  30
  31 include ':app'
  32 include ':base'
  33 include ':omnijar'
  34 include ':thirdparty'
  35
  36 project(':app').projectDir = new File("${json.topsrcdir}/mobile/android/app")
  37 project(':base').projectDir = new File("${json.topsrcdir}/mobile/android/app/base")
  38 project(':omnijar').projectDir = new File("${json.topsrcdir}/mobile/android/app/omnijar")
  39 project(':thirdparty').projectDir = new File("${json.topsrcdir}/mobile/android/thirdparty")
  40
  41 // The Gradle instance is shared between settings.gradle and all the
  42 // other build.gradle files (see
  43 // http://forums.gradle.org/gradle/topics/define_extension_properties_from_settings_xml).
  44 // We use this ext property to pass the per-object-directory mozconfig
  45 // between scripts.  This lets us execute set-up code before we gradle
  46 // tries to configure the project even once, and as a side benefit
  47 // saves invoking |mach environment| multiple times.
  48 gradle.ext.mozconfig = json