configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.60])
   4 AC_INIT([Geany], [1.39],
   5                 [https://github.com/geany/geany/issues])
   6 AC_CONFIG_SRCDIR([src/geany.h])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE([1.11 -Wall parallel-tests subdir-objects])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 # Silence "AC_LINK_IFELSE before AC_USE_SYSTEM_EXTENSIONS" warnings
  13 # Note: Enables _GNU_SOURCE on Linux
  14 AC_USE_SYSTEM_EXTENSIONS
  15
  16 AM_GNU_GETTEXT_VERSION([0.19.8])
  17 AM_GNU_GETTEXT([external])
  18
  19 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  20
  21 GEANY_PREFIX
  22 GEANY_DOCDIR
  23
  24 GEANY_STATUS_ADD([Install Geany in], [${prefix}])
  25 if test -n "${build}" -a -n "${target}"; then
  26         GEANY_STATUS_ADD([Building Geany on], [${build}])
  27         GEANY_STATUS_ADD([Building Geany for], [${target}])
  28 fi
  29
  30 m4_ifdef([AM_PROG_AR],[AM_PROG_AR])
  31 LT_INIT([disable-static])
  32 AC_PROG_CC
  33 AM_PROG_CC_C_O
  34 AC_PROG_CXX
  35 GEANY_PROG_CXX
  36 AX_CXX_COMPILE_STDCXX_17
  37
  38 AC_PROG_INSTALL
  39 AC_PROG_LN_S
  40
  41 if test "$ac_cv_prog_cc_c99" = "no"; then
  42         AC_MSG_ERROR([Need a C99 compiler])
  43 fi
  44
  45 # autoscan start
  46
  47 # Checks for header files.
  48 AC_CHECK_HEADERS([fcntl.h glob.h stdlib.h sys/time.h errno.h limits.h])
  49
  50 # Checks for dependencies needed by ctags
  51 AC_CHECK_HEADERS([dirent.h fnmatch.h direct.h io.h sys/dir.h])
  52 AC_DEFINE([HAVE_STDBOOL_H], [1], [whether or not to use <stdbool.h>.])
  53 AC_CHECK_FUNC([regcomp],
  54                 [have_regcomp=yes],
  55                 [have_regcomp=no
  56                  dnl various stuff for ctags/gnu_regex/
  57                  AC_CHECK_HEADERS([langinfo.h locale.h libintl.h wctype.h wchar.h])
  58                  AC_CHECK_FUNCS([memcpy isblank wcrtomb mbrtowc wcscoll])
  59                  AC_FUNC_ALLOCA])
  60 AM_CONDITIONAL([USE_BUNDLED_REGEX], [test "xno" = "x$have_regcomp"])
  61 AC_CHECK_FUNC([fnmatch], [have_fnmatch=yes], [have_fnmatch=no])
  62 AM_CONDITIONAL([USE_BUNDLED_FNMATCH], [test "xno" = "x$have_fnmatch"])
  63
  64 # Checks for typedefs, structures, and compiler characteristics.
  65 AC_TYPE_OFF_T
  66 AC_TYPE_SIZE_T
  67 AC_STRUCT_TM
  68
  69 # Checks for library functions.
  70 AC_CHECK_FUNCS([realpath])
  71
  72 # Function checks for u-ctags
  73 AC_CHECK_FUNCS([strerror strstr asprintf])
  74 AC_CHECK_FUNCS([mkstemp tempnam], [break])
  75 AC_CHECK_FUNCS([strcasecmp stricmp], [break])
  76 AC_CHECK_FUNCS([strncasecmp strnicmp], [break])
  77 AC_CHECK_FUNCS([truncate ftruncate chsize], [break])
  78 # non-functions checks for u-ctags.  Not that we really need those as we don't
  79 # use u-ctags's main, but the corresponding macros have to be defined to
  80 # something, so simply perform the actual checks.
  81 AC_CHECK_DECLS([__environ],,,[[#include <unistd.h>]])
  82 AC_CHECK_DECLS([_NSGetEnviron],,,[[#include <crt_externs.h>]])
  83
  84 # autoscan end
  85
  86
  87 # check for VCS revision
  88 GEANY_CHECK_REVISION([dnl force debug mode for a VCS working copy
  89                                           CFLAGS="-g -DGEANY_DEBUG $CFLAGS"])
  90
  91 # GTK/GLib/GIO checks
  92 gtk_modules="gtk+-3.0 >= 3.0 glib-2.0 >= 2.32"
  93 gtk_modules_private="gio-2.0 >= 2.32 gmodule-no-export-2.0"
  94 PKG_CHECK_MODULES([GTK], [$gtk_modules $gtk_modules_private])
  95 AC_SUBST([DEPENDENCIES], [$gtk_modules])
  96 AS_VAR_APPEND([GTK_CFLAGS], [" -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32"])
  97 dnl Disable all GTK deprecations
  98 AS_VAR_APPEND([GTK_CFLAGS], [" -DGDK_DISABLE_DEPRECATION_WARNINGS"])
  99 AC_SUBST([GTK_CFLAGS])
 100 AC_SUBST([GTK_LIBS])
 101 GTK_VERSION=`$PKG_CONFIG --modversion gtk+-3.0`
 102 AC_SUBST([GTK_VERSION])
 103 GEANY_STATUS_ADD([Using GTK version], [${GTK_VERSION}])
 104 # GTHREAD checks
 105 gthread_modules="gthread-2.0"
 106 PKG_CHECK_MODULES([GTHREAD], [$gthread_modules])
 107 AC_SUBST([GTHREAD_CFLAGS])
 108 AC_SUBST([GTHREAD_LIBS])
 109
 110 # --disable-deprecated switch for GTK purification
 111 AC_ARG_ENABLE([deprecated],
 112                 [AS_HELP_STRING([--disable-deprecated], [Disable deprecated GTK functions.])],
 113                 [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"],
 114                 [])
 115
 116
 117 # Check for binary relocation support
 118 GEANY_CHECK_BINRELOC
 119 # CTags source compatibility (we actually use GRegex instead of POSIX regcomp)
 120 AC_DEFINE([HAVE_REGCOMP], [1], [Should always be 1, required for CTags.])
 121 # Plugins support
 122 GEANY_CHECK_PLUGINS
 123 # check for mingw specific settings
 124 GEANY_CHECK_MINGW
 125
 126 GEANY_CHECK_SOCKET
 127 GEANY_CHECK_VTE
 128 GEANY_CHECK_MAC_INTEGRATION
 129 GEANY_CHECK_THE_FORCE dnl hehe
 130
 131 AC_SUBST([GETTEXT_PACKAGE],[$PACKAGE])
 132 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$PACKAGE"], [Gettext package.])
 133
 134 # double eval since datarootdir is usually defined as ${prefix}/share
 135 AM_COND_IF([MINGW],
 136   [pkgdatadir='${prefix}/data'],
 137   [pkgdatadir='${datarootdir}/geany'])
 138 AM_COND_IF([MINGW],[LIBS="$LIBS -liconv"])
 139 AC_SUBST([GEANY_DATA_DIR], [$(eval echo $(eval echo $pkgdatadir))])
 140 AC_SUBST([pkgdatadir])
 141
 142 # The default Python command.  On Windows, use the `py` launcher by default
 143 AC_ARG_WITH([python-command],
 144                         [AS_HELP_STRING([--with-python-command],
 145                                                         [the default Python command [defaults to "py" on Windows and "python" otherwise]])],
 146                         [with_python_command=$withval],
 147                         [with_python_command=auto])
 148 AS_IF([test "x$with_python_command" = xauto],
 149           [AM_COND_IF([MINGW], [with_python_command=py], [with_python_command=python])])
 150 AC_SUBST([PYTHON_COMMAND], [$with_python_command])
 151
 152 # Documentation tools
 153 GEANY_CHECK_DOCUTILS
 154 GEANY_CHECK_DOXYGEN
 155 GEANY_CHECK_GTKDOC_HEADER
 156
 157 # libgeany
 158 GEANY_LIB_INIT
 159
 160 # Output
 161 AC_CONFIG_FILES([
 162                 Makefile
 163                 icons/Makefile
 164                 icons/16x16/Makefile
 165                 icons/24x24/Makefile
 166                 icons/32x32/Makefile
 167                 icons/48x48/Makefile
 168                 icons/scalable/Makefile
 169                 icons/tango/Makefile
 170                 icons/tango/16x16/Makefile
 171                 icons/tango/24x24/Makefile
 172                 icons/tango/32x32/Makefile
 173                 icons/tango/48x48/Makefile
 174                 icons/tango/scalable/Makefile
 175                 ctags/Makefile
 176                 scintilla/Makefile
 177                 src/Makefile
 178                 src/tagmanager/Makefile
 179                 plugins/Makefile
 180                 po/Makefile.in
 181                 data/Makefile
 182                 data/filedefs/filetypes.python
 183                 doc/Makefile
 184                 doc/geany.1
 185                 geany.pc
 186                 geany.nsi
 187                 tests/Makefile
 188                 tests/ctags/Makefile
 189 ])
 190 AC_OUTPUT
 191
 192 # Summary
 193 GEANY_STATUS_OUTPUT
 194 echo ""
 195 echo "Configuration is done OK."
 196 echo ""