m4/geany-docutils.m4

   1 dnl GEANY_CHECK_DOCUTILS
   2 dnl Check for the tools used to generate documentation
   3 dnl
   4 AC_DEFUN([GEANY_CHECK_DOCUTILS],
   5 [
   6         GEANY_CHECK_DOCUTILS_HTML
   7         GEANY_CHECK_DOCUTILS_PDF
   8 ])
   9 dnl
  10 dnl GEANY_CHECK_DOCUTILS_HTML
  11 dnl For HTML documentation generation
  12 dnl
  13 AC_DEFUN([GEANY_CHECK_DOCUTILS_HTML],
  14 [
  15         AC_REQUIRE([GEANY_CHECK_REVISION])
  16
  17         AS_IF([test -f "$srcdir/doc/geany.html"],
  18                 [have_prebuilt_html_docs=yes],
  19                 [have_prebuilt_html_docs=no])
  20
  21         dnl we require rst2html by default unless we don't build from Git
  22         dnl and already have the HTML manual built in-tree
  23         html_docs_default=yes
  24         AS_IF([test "$REVISION" = "-1" && test "x$have_prebuilt_html_docs" = xyes],
  25                 [html_docs_default=auto])
  26
  27         AC_ARG_ENABLE([html-docs],
  28                 [AS_HELP_STRING([--enable-html-docs],
  29                         [generate HTML documentation using rst2html [default=auto]])],
  30                 [geany_enable_html_docs="$enableval"],
  31                 [geany_enable_html_docs="$html_docs_default"])
  32         AC_ARG_VAR([RST2HTML], [Path to Docutils rst2html executable])
  33         AS_IF([test "x$geany_enable_html_docs" != "xno"],
  34         [
  35 dnl TODO: try rst2html.py first
  36                 AS_IF([test -z "$RST2HTML"], [RST2HTML="rst2html"])
  37                 AC_PATH_PROG([RST2HTML], [$RST2HTML], [no])
  38                 AS_IF([test "x$RST2HTML" != "xno"],
  39                         [geany_enable_html_docs="yes"],
  40                         [test "x$geany_enable_html_docs" = "xyes"],
  41                         [AC_MSG_ERROR([Documentation enabled but rst2html not found.
  42 You can explicitly disable building of the HTML manual with --disable-html-docs,
  43 but you then may not have a local copy of the HTML manual.])],
  44                         [geany_enable_html_docs="no"])
  45         ])
  46         AM_CONDITIONAL([WITH_RST2HTML], [test "x$geany_enable_html_docs" != "xno"])
  47         AM_CONDITIONAL([INSTALL_HTML_DOCS], [test "x$geany_enable_html_docs" != "xno" ||
  48                                              test "x$have_prebuilt_html_docs" = xyes])
  49         GEANY_STATUS_ADD([Build HTML documentation], [$geany_enable_html_docs])
  50 ])
  51 dnl
  52 dnl GEANY_CHECK_DOCUTILS_PDF
  53 dnl For PDF documentation generation
  54 dnl
  55 AC_DEFUN([GEANY_CHECK_DOCUTILS_PDF],
  56 [
  57         AC_ARG_ENABLE([pdf-docs],
  58                 [AS_HELP_STRING([--enable-pdf-docs],
  59                         [generate PDF documentation using rst2pdf [default=auto]])],
  60                 [geany_enable_pdf_docs="$enableval"],
  61                 [geany_enable_pdf_docs="auto"])
  62         AC_ARG_VAR([RST2PDF], [Path to Docutils rst2pdf executable])
  63         AS_IF([test "x$geany_enable_pdf_docs" != "xno"],
  64         [
  65                 AS_IF([test -z "$RST2PDF"], [RST2PDF="rst2pdf"])
  66                 AC_PATH_PROG([RST2PDF], [$RST2PDF], [no])
  67                 AS_IF([test "x$RST2PDF" != "xno"],
  68                         [geany_enable_pdf_docs="yes"],
  69                         [test "x$geany_enable_pdf_docs" = "xyes"],
  70                         [AC_MSG_ERROR([PDF documentation enabled but rst2pdf not found])],
  71                         [geany_enable_pdf_docs="no"])
  72         ])
  73         AM_CONDITIONAL([WITH_RST2PDF], [test "x$geany_enable_pdf_docs" != "xno"])
  74         GEANY_STATUS_ADD([Build PDF documentation], [$geany_enable_pdf_docs])
  75 ])