geany.nsi

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ; geany.nsi - this file is part of Geany, a fast and lightweight IDE
   3 ;
   4 ; Copyright 2007-2012 Enrico Tröger <enrico(dot)troeger(at)uvena(dot)de>
   5 ; Copyright 2007-2012 Nick Treleaven <nick(dot)treleaven(at)btinternet(dot)com>
   6 ;
   7 ; This program is free software; you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation; either version 2 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program; if not, write to the Free Software
  19 ; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  20 ;
  21 ;
  22 ; Installer script for Geany (Windows Installer)
  23 ; (Script originally generated by the HM NIS Edit Script Wizard)
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25
  26
  27 ; Do a Cyclic Redundancy Check to make sure the installer was not corrupted by the download
  28 CRCCheck force
  29 RequestExecutionLevel highest ; set execution level for Windows Vista
  30
  31 ;;;;;;;;;;;;;;;;;;;
  32 ; helper defines  ;
  33 ;;;;;;;;;;;;;;;;;;;
  34 !define PRODUCT_NAME "Geany"
  35 !define PRODUCT_VERSION "1.23"
  36 !define PRODUCT_VERSION_ID "1.23.0.0"
  37 !define PRODUCT_PUBLISHER "The Geany developer team"
  38 !define PRODUCT_WEB_SITE "http://www.geany.org/"
  39 !define PRODUCT_DIR_REGKEY "Software\Geany"
  40 !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  41 !define PRODUCT_EXE "$INSTDIR\bin\Geany.exe"
  42 !define PRODUCT_REGNAME "Geany.ProjectFile"
  43 !define PRODUCT_EXT ".geany"
  44 !define RESOURCEDIR "geany-${PRODUCT_VERSION}"
  45
  46 ;;;;;;;;;;;;;;;;;;;;;
  47 ; Version resource  ;
  48 ;;;;;;;;;;;;;;;;;;;;;
  49 VIProductVersion "${PRODUCT_VERSION_ID}"
  50 VIAddVersionKey "ProductName" "${PRODUCT_NAME}"
  51 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION}"
  52 VIAddVersionKey "ProductVersion" "${PRODUCT_VERSION}"
  53 VIAddVersionKey "LegalCopyright" "Copyright 2005-2012 by the Geany developer team"
  54 VIAddVersionKey "FileDescription" "${PRODUCT_NAME} Installer"
  55
  56 BrandingText "$(^NAME) installer (NSIS 2.46)"
  57 InstallDir "$PROGRAMFILES\Geany"
  58 Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  59 SetCompressor /SOLID lzma
  60 ShowInstDetails hide
  61 ShowUnInstDetails hide
  62 XPStyle on
  63 !ifdef INCLUDE_GTK
  64 OutFile "geany-${PRODUCT_VERSION}_setup.exe"
  65 !else
  66 OutFile "geany-${PRODUCT_VERSION}_nogtk_setup.exe"
  67 !endif
  68
  69 Var Answer
  70 Var UserName
  71 Var StartmenuFolder
  72 Var UNINSTDIR
  73
  74 ;;;;;;;;;;;;;;;;
  75 ; MUI Settings ;
  76 ;;;;;;;;;;;;;;;;
  77 !include "MUI2.nsh"
  78
  79 !define MUI_ABORTWARNING
  80 !define MUI_ICON "icons\geany.ico"
  81 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall-full.ico"
  82
  83 ; Welcome page
  84 !insertmacro MUI_PAGE_WELCOME
  85 ; License page
  86 ;!define MUI_LICENSEPAGE_RADIOBUTTONS
  87 !insertmacro MUI_PAGE_LICENSE "${RESOURCEDIR}\Copying.txt"
  88 ; Components page
  89 !insertmacro MUI_PAGE_COMPONENTS
  90 ; Directory page
  91 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE OnDirLeave
  92 !insertmacro MUI_PAGE_DIRECTORY
  93 ; Start menu page
  94 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "Geany"
  95 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
  96 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
  97 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
  98 !insertmacro MUI_PAGE_STARTMENU ${PRODUCT_NAME} "$StartmenuFolder"
  99 ; Instfiles page
 100 !insertmacro MUI_PAGE_INSTFILES
 101 ; Finish page
 102 !define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\News.txt"
 103 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Show Release Notes"
 104 !define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
 105 !define MUI_FINISHPAGE_RUN "$INSTDIR\bin\Geany.exe"
 106 !define MUI_FINISHPAGE_RUN_NOTCHECKED
 107 !insertmacro MUI_PAGE_FINISH
 108
 109 !insertmacro MUI_UNPAGE_INSTFILES ; Uninstaller page
 110 !insertmacro MUI_LANGUAGE "English" ; Language file
 111
 112 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
 113 ; Sections and InstTypes  ;
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 InstType "Full"
 116 InstType "Minimal"
 117
 118 Section "!Program Files" SEC01
 119         SectionIn RO 1 2
 120         SetOverwrite ifnewer
 121
 122         SetOutPath "$INSTDIR"
 123         File "${RESOURCEDIR}\*.txt"
 124
 125         SetOutPath "$INSTDIR\bin"
 126         File "${RESOURCEDIR}\bin\Geany.exe"
 127
 128         SetOutPath "$INSTDIR\data"
 129         File "${RESOURCEDIR}\data\GPL-2"
 130         File "${RESOURCEDIR}\data\file*"
 131         File "${RESOURCEDIR}\data\geany.glade"
 132         File "${RESOURCEDIR}\data\geany.gtkrc"
 133         File "${RESOURCEDIR}\data\snippets.conf"
 134         File "${RESOURCEDIR}\data\ui_toolbar.xml"
 135
 136         SetOutPath "$INSTDIR\data\templates"
 137         File /r "${RESOURCEDIR}\data\templates\*"
 138
 139         SetOutPath "$INSTDIR\data\colorschemes"
 140         File /r "${RESOURCEDIR}\data\colorschemes\*"
 141
 142         SetOutPath "$INSTDIR\share\icons"
 143         File /r "${RESOURCEDIR}\share\icons\*"
 144
 145         SetOutPath "$INSTDIR"
 146
 147         CreateShortCut "$INSTDIR\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 148         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 149         CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
 150         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 151         !insertmacro MUI_STARTMENU_WRITE_END
 152
 153         ; register the extension .geany
 154         ; write information about file type
 155         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}" "" "${PRODUCT_NAME} Project File"
 156         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\DefaultIcon" "" "${PRODUCT_EXE},0"
 157         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\Shell\open\command" "" '"${PRODUCT_EXE}" "%1"'
 158         ; write information about file extensions
 159         WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}" "" "${PRODUCT_REGNAME}"
 160         ; refresh shell
 161         System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) (0x08000000, 0, 0, 0)'
 162 SectionEnd
 163
 164 Section "Plugins" SEC02
 165         SectionIn 1
 166         SetOverwrite ifnewer
 167         SetOutPath "$INSTDIR\lib"
 168         File "${RESOURCEDIR}\lib\*.dll"
 169 SectionEnd
 170
 171 Section "Language Files" SEC03
 172         SectionIn 1
 173         SetOutPath "$INSTDIR\share\locale"
 174         File /r "${RESOURCEDIR}\share\locale\*"
 175 !ifdef INCLUDE_GTK
 176         SetOutPath "$INSTDIR\share"
 177         File /r "gtk\share\*"
 178 !endif
 179 SectionEnd
 180
 181 Section "Documentation" SEC04
 182         SectionIn 1
 183         SetOverwrite ifnewer
 184         SetOutPath "$INSTDIR"
 185         File /r "${RESOURCEDIR}\doc"
 186         WriteIniStr "$INSTDIR\Documentation.url" "InternetShortcut" "URL" "$INSTDIR\doc\Manual.html"
 187         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 188         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Documentation.lnk" "$INSTDIR\Documentation.url"
 189         !insertmacro MUI_STARTMENU_WRITE_END
 190 SectionEnd
 191
 192 Section "Autocompletion Tags" SEC05
 193         SectionIn 1
 194         SetOutPath "$INSTDIR\data"
 195         SetOverwrite ifnewer
 196         File "${RESOURCEDIR}\data\php.tags"
 197         File "${RESOURCEDIR}\data\pascal.tags"
 198         File "${RESOURCEDIR}\data\python.tags"
 199         File "${RESOURCEDIR}\data\html_entities.tags"
 200         File "${RESOURCEDIR}\data\c99.tags"
 201 SectionEnd
 202
 203 ; Include GTK runtime library but only if desired from command line
 204 !ifdef INCLUDE_GTK
 205 Section "GTK 2.16 Runtime Environment" SEC06
 206         SectionIn 1
 207         SetOverwrite ifnewer
 208         SetOutPath "$INSTDIR\bin"
 209         File /r "gtk\bin\*"
 210         SetOutPath "$INSTDIR\etc"
 211         File /r "gtk\etc\*"
 212         SetOutPath "$INSTDIR\lib"
 213         File /r "gtk\lib\*"
 214 SectionEnd
 215 !endif
 216
 217 Section "Context Menus" SEC07
 218         SectionIn 1
 219         WriteRegStr HKCR "*\shell\OpenWithGeany" "" "Open with Geany"
 220         WriteRegStr HKCR "*\shell\OpenWithGeany\command" "" '"$INSTDIR\bin\geany.exe" "%1"'
 221 SectionEnd
 222
 223 Section "Desktop Shortcuts" SEC08
 224         SectionIn 1
 225         CreateShortCut "$DESKTOP\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 226         CreateShortCut "$QUICKLAUNCH\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 227 SectionEnd
 228
 229 Section -AdditionalIcons
 230         SetOutPath $INSTDIR
 231         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 232         WriteIniStr "$INSTDIR\Website.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
 233         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Website.lnk" "$INSTDIR\Website.url"
 234         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Uninstall.lnk" "$INSTDIR\uninst.exe"
 235         !insertmacro MUI_STARTMENU_WRITE_END
 236 SectionEnd
 237
 238 Section -Post
 239         WriteUninstaller "$INSTDIR\uninst.exe"
 240         WriteRegStr SHCTX "${PRODUCT_DIR_REGKEY}" Path "$INSTDIR"
 241         WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
 242         ${if} $Answer == "yes" ; if user is admin
 243                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
 244                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
 245                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bin\Geany.exe"
 246                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
 247                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
 248                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLUpdateInfo" "${PRODUCT_WEB_SITE}"
 249                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
 250                 WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoModify" 0x00000001
 251                 WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoRepair" 0x00000001
 252         ${endif}
 253 SectionEnd
 254
 255 Section Uninstall
 256         Delete "$INSTDIR\Website.url"
 257         Delete "$INSTDIR\Documentation.url"
 258         Delete "$INSTDIR\uninst.exe"
 259         Delete "$INSTDIR\News.txt"
 260         Delete "$INSTDIR\ReadMe.txt"
 261         Delete "$INSTDIR\Thanks.txt"
 262         Delete "$INSTDIR\ToDo.txt"
 263         Delete "$INSTDIR\Authors.txt"
 264         Delete "$INSTDIR\ChangeLog.txt"
 265         Delete "$INSTDIR\Copying.txt"
 266         Delete "$INSTDIR\Geany.lnk"
 267
 268         ; delete start menu entry
 269         ReadRegStr $0 SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu"
 270         RMDir /r "$0"
 271
 272         Delete "$QUICKLAUNCH\Geany.lnk"
 273         Delete "$DESKTOP\Geany.lnk"
 274
 275         RMDir /r "$INSTDIR\bin"
 276         RMDir /r "$INSTDIR\doc"
 277         RMDir /r "$INSTDIR\data"
 278         RMDir /r "$INSTDIR\etc"
 279         RMDir /r "$INSTDIR\lib"
 280         RMDir /r "$INSTDIR\share"
 281         RMDir "$INSTDIR"
 282
 283         ; remove .geany file extension
 284         ReadRegStr $R0 SHCTX "Software\Classes\${PRODUCT_EXT}" ""
 285         ${if} $R0 == "${PRODUCT_REGNAME}"
 286                 DeleteRegKey SHCTX "${PRODUCT_EXT}"
 287                 DeleteRegKey HKCR "${PRODUCT_EXT}"
 288                 DeleteRegKey SHCTX "${PRODUCT_REGNAME}"
 289                 DeleteRegKey HKCR "${PRODUCT_REGNAME}"
 290         ${endif}
 291
 292         DeleteRegKey HKCR "*\shell\OpenWithGeany"
 293
 294         DeleteRegKey SHCTX "${PRODUCT_UNINST_KEY}"
 295         DeleteRegKey HKCU "${PRODUCT_UNINST_KEY}"
 296         DeleteRegKey SHCTX "${PRODUCT_DIR_REGKEY}"
 297         DeleteRegKey HKCU "${PRODUCT_DIR_REGKEY}"
 298
 299         SetAutoClose true
 300 SectionEnd
 301
 302 ;;;;;;;;;;;;;;;;;;;;;;;;;
 303 ; Section descriptions  ;
 304 ;;;;;;;;;;;;;;;;;;;;;;;;;
 305 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 306 !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} "Required program files. You cannot skip these files."
 307 !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} "Available plugins like 'Version Diff', 'Class Builder' and 'Insert Special Characters'."
 308 !insertmacro MUI_DESCRIPTION_TEXT ${SEC03} "Various translations of Geany's interface."
 309 !insertmacro MUI_DESCRIPTION_TEXT ${SEC04} "Manual in Text and HTML format."
 310 !insertmacro MUI_DESCRIPTION_TEXT ${SEC05} "Symbol lists necessary for auto completion of symbols."
 311 !ifdef INCLUDE_GTK
 312 !insertmacro MUI_DESCRIPTION_TEXT ${SEC06} "You need these files to run Geany. If you have already installed a GTK Runtime Environment (2.16 or higher), you can skip it."
 313 !endif
 314 !insertmacro MUI_DESCRIPTION_TEXT ${SEC07} "Add context menu item 'Open With Geany'"
 315 !insertmacro MUI_DESCRIPTION_TEXT ${SEC08} "Create shortcuts for Geany on the desktop and in the Quicklaunch Bar"
 316 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 317
 318 ;;;;;;;;;;;;;;;;;;;;;
 319 ; helper functions  ;
 320 ;;;;;;;;;;;;;;;;;;;;;
 321
 322 ; (from http://jabref.svn.sourceforge.net/viewvc/jabref/trunk/jabref/src/windows/nsis/setup.nsi)
 323 !macro IsUserAdmin Result UName
 324         ClearErrors
 325         UserInfo::GetName
 326         IfErrors Win9x
 327         Pop $0
 328         StrCpy ${UName} $0
 329         UserInfo::GetAccountType
 330         Pop $1
 331         ${if} $1 == "Admin"
 332                 StrCpy ${Result} "yes"
 333         ${else}
 334                 StrCpy ${Result} "no"
 335         ${endif}
 336         Goto done
 337
 338 Win9x:
 339         StrCpy ${Result} "yes"
 340 done:
 341 !macroend
 342
 343 Function .onInit
 344         StrCpy "$StartmenuFolder" "Geany"
 345
 346         ; (from http://jabref.svn.sourceforge.net/viewvc/jabref/trunk/jabref/src/windows/nsis/setup.nsi)
 347         ; If the user does *not* have administrator privileges, abort
 348         StrCpy $Answer ""
 349         StrCpy $UserName ""
 350         !insertmacro IsUserAdmin $Answer $UserName ; macro from LyXUtils.nsh
 351         ${if} $Answer == "yes"
 352                 SetShellVarContext all ; set that e.g. shortcuts will be created for all users
 353         ${else}
 354                 SetShellVarContext current
 355                 ; TODO is this really what we want? $PROGRAMFILES is not much better because
 356                 ; probably the unprivileged user can't write it anyways
 357                 StrCpy $INSTDIR "$PROFILE\$(^Name)"
 358         ${endif}
 359
 360         ; prevent running multiple instances of the installer
 361         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "geany_installer") i .r1 ?e'
 362         Pop $R0
 363         StrCmp $R0 0 +3
 364         MessageBox MB_OK|MB_ICONEXCLAMATION "The installer is already running." /SD IDOK
 365         Abort
 366         ; warn about a new install over an existing installation
 367         ReadRegStr $R0 SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString"
 368         StrCmp $R0 "" finish
 369
 370         MessageBox MB_YESNO|MB_ICONEXCLAMATION \
 371         "Geany has already been installed. $\nDo you want to remove the previous version before installing $(^Name) ?" \
 372                 /SD IDYES IDYES remove IDNO finish
 373
 374 remove:
 375         ; run the uninstaller
 376         ClearErrors
 377         ; we read the installation path of the old installation from the Registry
 378         ReadRegStr $UNINSTDIR SHCTX "${PRODUCT_DIR_REGKEY}" "Path"
 379         IfSilent dosilent nonsilent
 380 dosilent:
 381         ExecWait '$R0 /S _?=$UNINSTDIR' ;Do not copy the uninstaller to a temp file
 382         Goto finish
 383 nonsilent:
 384         ExecWait '$R0 _?=$UNINSTDIR' ;Do not copy the uninstaller to a temp file
 385 finish:
 386 FunctionEnd
 387
 388 Function un.onUninstSuccess
 389         HideWindow
 390         MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer." \
 391                 /SD IDOK
 392 FunctionEnd
 393
 394 Function un.onInit
 395         ; If the user does *not* have administrator privileges, abort
 396         StrCpy $Answer ""
 397         !insertmacro IsUserAdmin $Answer $UserName
 398         ${if} $Answer == "yes"
 399                 SetShellVarContext all
 400         ${else}
 401                 ; check if the Geany has been installed with admin permisions
 402                 ReadRegStr $0 HKLM "${PRODUCT_UNINST_KEY}" "Publisher"
 403                 ${if} $0 != ""
 404                         MessageBox MB_OK|MB_ICONSTOP "You need administrator privileges to uninstall Geany!" \
 405                                 /SD IDOK
 406                         Abort
 407                 ${endif}
 408                 SetShellVarContext current
 409         ${endif}
 410
 411         MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" \
 412                 /SD IDYES IDYES +2
 413         Abort
 414 FunctionEnd
 415
 416 Function OnDirLeave
 417         ClearErrors
 418         SetOutPath "$INSTDIR" ; what about IfError creating $INSTDIR?
 419         GetTempFileName $1 "$INSTDIR" ; creates tmp file (or fails)
 420         FileOpen $0 "$1" "w" ; error to open?
 421         FileWriteByte $0 "0"
 422         IfErrors notPossible possible
 423
 424 notPossible:
 425         RMDir "$INSTDIR" ; removes folder if empty
 426         MessageBox MB_OK "The given directory is not writeable. Please choose another one!" /SD IDOK
 427         Abort
 428 possible:
 429         FileClose $0
 430         Delete "$1"
 431 FunctionEnd