plugins/meson.build

   1 plugin_inc = [include_directories('..', '../src', '../src/tagmanager')]
   2 plugin_inc += iscintilla
   3
   4 plugins = [
   5         'Demoplugin',
   6         'Demoproxy',
   7         'Classbuilder',
   8         'HTMLChars',
   9         'Export',
  10         'SaveActions',
  11         'FileBrowser',
  12         'SplitWindow'
  13 ]
  14
  15 plugin_suffix = []
  16 if (host_machine.system() == 'darwin')
  17         plugin_suffix = 'so'  # use "so" instead of "dylib" so Geany finds plugins correctly
  18 endif
  19
  20 foreach plugin : plugins
  21         id = plugin.to_lower()
  22         skip_install = id.startswith('demo')
  23         shared_module(id,
  24                 id + '.c',
  25                 name_prefix: '', # "lib" seems to be the default prefix
  26                 name_suffix: plugin_suffix,
  27                 link_with: libgeany,
  28                 include_directories: plugin_inc,
  29                 c_args: [def_cflags, '-DG_LOG_DOMAIN="'+plugin+'"'],
  30                 dependencies: [deps, dep_libgeany],
  31                 install_dir: join_paths(prefix, get_option('libdir'), 'geany'),
  32                 install: not skip_install
  33         )
  34 endforeach