configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.60])
   4 AC_INIT([Geany], [1.29],
   5                 [https://sourceforge.net/tracker/?group_id=153444&atid=787791])
   6 AC_CONFIG_SRCDIR([src/geany.h])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE([1.11 -Wall parallel-tests subdir-objects])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  13
  14 GEANY_PREFIX
  15 GEANY_DOCDIR
  16
  17 GEANY_STATUS_ADD([Install Geany in], [${prefix}])
  18 if test -n "${build}" -a -n "${target}"; then
  19         GEANY_STATUS_ADD([Building Geany on], [${build}])
  20         GEANY_STATUS_ADD([Building Geany for], [${target}])
  21 fi
  22
  23 # why do we use this?
  24 AC_USE_SYSTEM_EXTENSIONS
  25
  26 m4_ifdef([AM_PROG_AR],[AM_PROG_AR])
  27 LT_INIT([disable-static])
  28 AC_PROG_CC
  29 AC_PROG_CC_C99
  30 AM_PROG_CC_C_O
  31
  32 AC_PROG_CXX
  33 # check for C++ compiler explicitly and fail if none is found, do this check
  34 # after AC_PROG_CXX has set the CXX environment variable
  35 if ! which $CXX >/dev/null 2>&1; then
  36         AC_MSG_ERROR([No C++ compiler found. Please install a C++ compiler.])
  37 fi
  38
  39 AC_PROG_INSTALL
  40 AC_PROG_LN_S
  41
  42 # autoscan start
  43
  44 # Checks for header files.
  45 AC_CHECK_HEADERS([fcntl.h fnmatch.h glob.h stdlib.h sys/time.h])
  46
  47 # Checks for typedefs, structures, and compiler characteristics.
  48 AC_TYPE_OFF_T
  49 AC_TYPE_SIZE_T
  50 AC_STRUCT_TM
  51
  52 # Checks for library functions.
  53 AC_CHECK_FUNCS([ftruncate fgetpos fnmatch mkstemp strerror strstr])
  54
  55 # autoscan end
  56
  57
  58 # check for VCS revision
  59 GEANY_CHECK_REVISION([dnl force debug mode for a VCS working copy
  60                                           CFLAGS="-g -DGEANY_DEBUG $CFLAGS"])
  61
  62
  63 AC_ARG_ENABLE([gtk3],
  64                 [AS_HELP_STRING([--enable-gtk3],
  65                                                 [compile with GTK3 support (experimental) [default=no]])],
  66                 [enable_gtk3=$enableval],
  67                 [enable_gtk3=no])
  68
  69 AS_IF([test "x$enable_gtk3" = xyes],
  70           [gtk_package=gtk+-3.0
  71            gtk_min_version=3.0],
  72           [gtk_package=gtk+-2.0
  73            gtk_min_version=2.24])
  74 AM_CONDITIONAL([GTK3], [test "x$gtk_package" = "xgtk+-3.0"])
  75
  76 # GTK/GLib/GIO checks
  77 gtk_modules="$gtk_package >= $gtk_min_version glib-2.0 >= 2.32"
  78 gtk_modules_private="gio-2.0 >= 2.32 gmodule-no-export-2.0"
  79 PKG_CHECK_MODULES([GTK], [$gtk_modules $gtk_modules_private])
  80 AC_SUBST([DEPENDENCIES], [$gtk_modules])
  81 AS_VAR_APPEND([GTK_CFLAGS], [" -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32"])
  82 dnl Disable all GTK deprecations on 3.x so long as we want to keep 2.x support and only require 3.0.
  83 dnl No need on 2.x as we target the latest version.
  84 AM_COND_IF([GTK3], [AS_VAR_APPEND([GTK_CFLAGS], [" -DGDK_DISABLE_DEPRECATION_WARNINGS"])])
  85 AC_SUBST([GTK_CFLAGS])
  86 AC_SUBST([GTK_LIBS])
  87 GTK_VERSION=`$PKG_CONFIG --modversion $gtk_package`
  88 AC_SUBST([GTK_VERSION])
  89 GEANY_STATUS_ADD([Using GTK version], [${GTK_VERSION}])
  90 # GTHREAD checks
  91 gthread_modules="gthread-2.0"
  92 PKG_CHECK_MODULES([GTHREAD], [$gthread_modules])
  93 AC_SUBST([GTHREAD_CFLAGS])
  94 AC_SUBST([GTHREAD_LIBS])
  95
  96 # --disable-deprecated switch for GTK purification
  97 AC_ARG_ENABLE([deprecated],
  98                 [AS_HELP_STRING([--disable-deprecated], [Disable deprecated GTK functions.])],
  99                 [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"],
 100                 [])
 101
 102
 103 # Check for binary relocation support
 104 GEANY_CHECK_BINRELOC
 105 # CTags source compatibility (we actually use GRegex instead of POSIX regcomp)
 106 AC_DEFINE([HAVE_REGCOMP], [1], [Should always be 1, required for CTags.])
 107 # Plugins support
 108 GEANY_CHECK_PLUGINS
 109 # check for mingw specific settings
 110 GEANY_CHECK_MINGW
 111
 112 GEANY_CHECK_SOCKET
 113 GEANY_CHECK_VTE
 114 GEANY_CHECK_MAC_INTEGRATION
 115 GEANY_CHECK_THE_FORCE dnl hehe
 116
 117 # i18n
 118 GEANY_I18N
 119
 120 # double eval since datarootdir is usually defined as ${prefix}/share
 121 AM_COND_IF([MINGW],
 122   [pkgdatadir='${prefix}/data'],
 123   [pkgdatadir='${datarootdir}/geany'])
 124 AC_SUBST([GEANY_DATA_DIR], [$(eval echo $(eval echo $pkgdatadir))])
 125 AC_SUBST([pkgdatadir])
 126
 127 # Documentation tools
 128 GEANY_CHECK_DOCUTILS
 129 GEANY_CHECK_DOXYGEN
 130 GEANY_CHECK_GTKDOC_HEADER
 131
 132 # libgeany
 133 GEANY_LIB_INIT
 134
 135 # Output
 136 AC_CONFIG_FILES([
 137                 Makefile
 138                 icons/Makefile
 139                 icons/16x16/Makefile
 140                 icons/24x24/Makefile
 141                 icons/32x32/Makefile
 142                 icons/48x48/Makefile
 143                 icons/scalable/Makefile
 144                 icons/tango/Makefile
 145                 icons/tango/16x16/Makefile
 146                 icons/tango/24x24/Makefile
 147                 icons/tango/32x32/Makefile
 148                 icons/tango/48x48/Makefile
 149                 icons/tango/scalable/Makefile
 150                 ctags/Makefile
 151                 scintilla/Makefile
 152                 scintilla/include/Makefile
 153                 src/Makefile
 154                 src/tagmanager/Makefile
 155                 plugins/Makefile
 156                 po/Makefile.in
 157                 data/Makefile
 158                 doc/Makefile
 159                 doc/geany.1
 160                 geany.spec
 161                 geany.pc
 162                 geany.nsi
 163                 doc/Doxyfile
 164                 tests/Makefile
 165                 tests/ctags/Makefile
 166 ])
 167 AC_OUTPUT
 168
 169 # Summary
 170 GEANY_STATUS_OUTPUT
 171 echo ""
 172 echo "Configuration is done OK."
 173 echo ""