configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3
   4 AC_INIT(configure.ac)
   5 AM_INIT_AUTOMAKE(geany, 0.20)
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   9
  10 AM_CONFIG_HEADER(config.h)
  11
  12 AC_GNU_SOURCE
  13 AC_AIX
  14 AC_MINIX
  15
  16 AC_PROG_CC
  17
  18 AC_PROG_CXX
  19 # check for C++ compiler explicitly and fail if none is found, do this check
  20 # after AC_PROG_CXX has set the CXX environment variable
  21 which $CXX >/dev/null 2>&1
  22 if test "x$?" != "x0"; then
  23         AC_MSG_ERROR([No C++ compiler found. Please install a C++ compiler.])
  24 fi
  25
  26 AC_PROG_INSTALL
  27 AC_PROG_LN_S
  28 AC_PROG_INTLTOOL
  29
  30 # for plugins
  31 AC_DISABLE_STATIC
  32 AM_PROG_LIBTOOL
  33 LIBTOOL="$LIBTOOL --silent"
  34
  35 # autoscan start
  36
  37 # Checks for header files.
  38 AC_CHECK_HEADERS([fcntl.h fnmatch.h glob.h regex.h stdlib.h sys/time.h])
  39
  40 # Checks for typedefs, structures, and compiler characteristics.
  41 AC_TYPE_OFF_T
  42 AC_TYPE_SIZE_T
  43 AC_STRUCT_TM
  44
  45 # Checks for library functions.
  46 AC_CHECK_FUNCS([gethostname ftruncate fgetpos mkstemp strerror strstr])
  47
  48 # autoscan end
  49
  50
  51 # get svn revision (try GIT first, then check for SVN)
  52 REVISION="r0"
  53 GIT=`which git 2>/dev/null`
  54 if test -d ".git" -a "x${GIT}" != "x" -a -x "${GIT}"
  55 then
  56         # check for git-svn repo first - find-rev (v1.5.4.1) doesn't always fail with git-only repo
  57         git svn info &>/dev/null
  58         if test "x$?" == "x0"; then
  59                 REVISION=r`git svn find-rev origin/trunk 2>/dev/null ||
  60                                 git svn find-rev trunk 2>/dev/null || git svn find-rev HEAD 2>/dev/null ||
  61                                 git svn find-rev master 2>/dev/null || echo 0`
  62         fi
  63 fi
  64 if test "x${REVISION}" = "xr0"
  65 then
  66         SVN=`which svn 2>/dev/null`
  67         if test -d ".svn" -a "x${SVN}" != "x" -a -x "${SVN}"
  68         then
  69                 REVISION=r`$SVN info|grep 'Last Changed Rev'|cut -d' ' -f4`
  70         fi
  71 fi
  72 if test "x${REVISION}" != "xr0"
  73 then
  74         # force debug mode for a SVN working copy
  75         CFLAGS="-g -DGEANY_DEBUG $CFLAGS"
  76 else
  77         REVISION="-1"
  78 fi
  79 AC_DEFINE_UNQUOTED([REVISION], "$REVISION", [subversion revision number])
  80
  81
  82 dnl Check for binary relocation support
  83 dnl taken from Inkscape (Hongli Lai <h.lai@chello.nl>)
  84
  85 AC_ARG_ENABLE(binreloc,
  86        [  --enable-binreloc       compile with binary relocation support],
  87        enable_binreloc=$enableval,enable_binreloc=no)
  88
  89 AC_MSG_CHECKING(whether binary relocation support should be enabled)
  90 if test "$enable_binreloc" = "yes"; then
  91        AC_MSG_RESULT(yes)
  92        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
  93        if test -e /proc/self/maps; then
  94                AC_MSG_RESULT(yes)
  95        else
  96                AC_MSG_RESULT(no)
  97                AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)
  98                enable_binreloc="no"
  99        fi
 100
 101 elif test "$enable_binreloc" = "auto"; then
 102        AC_MSG_RESULT(yes when available)
 103        AC_MSG_CHECKING(for linker mappings at /proc/self/maps)
 104        if test -e /proc/self/maps; then
 105                AC_MSG_RESULT(yes)
 106                enable_binreloc=yes
 107
 108                AC_MSG_CHECKING(whether everything is installed to the same prefix)
 109                if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \
 110                        "$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \
 111                        "$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'
 112                then
 113                        AC_MSG_RESULT(yes)
 114                else
 115                        AC_MSG_RESULT(no)
 116                        AC_MSG_NOTICE(Binary relocation support will be disabled.)
 117                        enable_binreloc=no
 118                fi
 119
 120        else
 121                AC_MSG_RESULT(no)
 122                enable_binreloc=no
 123        fi
 124
 125 elif test "$enable_binreloc" = "no"; then
 126        AC_MSG_RESULT(no)
 127 else
 128        AC_MSG_RESULT(no (unknown value "$enable_binreloc"))
 129        enable_binreloc=no
 130 fi
 131 if test "$enable_binreloc" = "yes"; then
 132    AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])
 133 fi
 134
 135
 136 # GTK checks
 137 gtk_modules="gtk+-2.0 >= 2.8.0"
 138 PKG_CHECK_MODULES(GTK, [$gtk_modules])
 139 AC_SUBST(GTK_CFLAGS)
 140 AC_SUBST(GTK_LIBS)
 141 # GIO checks
 142 gio_modules="gio-2.0 >= 2.16"
 143 PKG_CHECK_MODULES(GIO, [$gio_modules], have_gio=1, have_gio=0)
 144 AC_SUBST(GIO_CFLAGS)
 145 AC_SUBST(GIO_LIBS)
 146 if test $have_gio = 1 ; then
 147     AC_DEFINE(HAVE_GIO, 1, [Whether GIO is available])
 148 fi
 149
 150 # --disable-deprecated switch for GTK2 purification
 151 AC_ARG_ENABLE(deprecated, [  --disable-deprecated    Disable deprecated GTK functions. ],
 152                           [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
 153
 154 # Plugins support
 155 AC_ARG_ENABLE(plugins, [AC_HELP_STRING([--disable-plugins], [compile without plugin support  [default=no]])], , enable_plugins=yes)
 156
 157 if test "x$enable_plugins" = "xyes" ; then
 158         AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled.])
 159         AM_CONDITIONAL(PLUGINS, true)
 160 else
 161         AM_CONDITIONAL(PLUGINS, false)
 162 fi
 163
 164 # Use included GNU regex library
 165 AC_ARG_ENABLE(gnu-regex, [AC_HELP_STRING([--enable-gnu-regex], [compile with included GNU regex library  [default=no]])], , enable_gnu_regex=no)
 166
 167 # auto-enable included regex if necessary
 168 AC_CHECK_FUNCS([regcomp], [], [enable_gnu_regex="yes"])
 169
 170 if test "x$enable_gnu_regex" = "xyes" ; then
 171         AC_DEFINE(USE_INCLUDED_REGEX, 1, [Define if included GNU regex code should be used.])
 172         AC_DEFINE(HAVE_REGCOMP, 1, [Define if you have the 'regcomp' function.])
 173         AM_CONDITIONAL(USE_INCLUDED_REGEX, true)
 174 else
 175         AM_CONDITIONAL(USE_INCLUDED_REGEX, false)
 176 fi
 177
 178 case "${host}" in
 179     *mingw*)
 180         AC_CHECK_LIB(iberty, fnmatch, [], [
 181                 AC_MSG_ERROR([fnmatch does not present in libiberty. You need to update it, read http://www.geany.org/Support/CrossCompile for details.])
 182                 ])
 183         AC_DEFINE_UNQUOTED([WIN32], 1, [we are cross compiling for WIN32])
 184         want_vte="no"
 185         want_socket="yes"
 186         AC_DEFINE(HAVE_SOCKET, 1, [Define if you want to detect a running instance])
 187         AC_EXEEXT
 188         AM_CONDITIONAL(MINGW, true)
 189         ;;
 190     *)
 191         AM_CONDITIONAL(MINGW, false)
 192         ;;
 193 esac
 194
 195 dnl skip check if already decided
 196 if test "x$want_socket" = "x"; then
 197     # socket support
 198     AC_ARG_ENABLE(socket, AC_HELP_STRING([--enable-socket],[enable if you want to detect a running instance [[default=yes]]]),
 199      [want_socket="$enableval"], [want_socket="yes"])
 200
 201     if test "x$want_socket" = "xyes"; then
 202         AC_DEFINE(HAVE_SOCKET, 1, [Define if you want to detect a running instance])
 203         # this should bring in libsocket on Solaris:
 204         AC_SEARCH_LIBS([connect],[socket],[],[],[])
 205     fi
 206 fi
 207
 208 dnl skip check if already decided
 209 if test "x$want_vte" = "x"; then
 210     # VTE support
 211     AC_ARG_ENABLE(vte, AC_HELP_STRING([--enable-vte],
 212      [enable if you want virtual terminal support [[default=yes]]]),
 213      [want_vte="$enableval"], [want_vte="yes"])
 214     if test "x$want_vte" = "xyes"; then
 215         AC_DEFINE(HAVE_VTE, 1, [Define if you want VTE support])
 216     fi
 217     AC_ARG_WITH(vte-module-path, AC_HELP_STRING([--with-vte-module-path=PATH],
 218      [Path to a loadable libvte [[default=None]]]), [AC_DEFINE_UNQUOTED([VTE_MODULE_PATH],
 219      ["$withval"], [Path to a loadable libvte])])
 220 fi
 221
 222 GTK_VERSION=`$PKG_CONFIG --modversion gtk+-2.0`
 223
 224
 225 # GTK 2.10 printing support
 226 $PKG_CONFIG --exists 'gtk+-2.0 >= 2.10.0'
 227 if test "x$?" = "x0" ; then
 228         enable_printing="yes"
 229 else
 230         enable_printing="no (GTK >= 2.10 necessary)"
 231 fi
 232
 233
 234 # just for a laugh (it has absolutely no effect)
 235 AC_ARG_ENABLE(the-force, AC_HELP_STRING([--enable-the-force],
 236      [enable if you are Luke Skywalker and the force is with you [[default=no]]]), [be_luke="$enableval"], [be_luke="no"])
 237 AC_MSG_CHECKING([whether the force is with you])
 238 if test "x$be_luke" = "xyes"; then
 239         AC_MSG_RESULT([yes])
 240 else
 241         AC_MSG_RESULT([no])
 242 fi
 243
 244 # i18n
 245 GETTEXT_PACKAGE=geany
 246 AC_SUBST(GETTEXT_PACKAGE)
 247 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
 248
 249 if test -n "${LINGUAS}"
 250 then
 251         ALL_LINGUAS="${LINGUAS}"
 252 else
 253         if test -z "$conf_dir" ; then
 254                 conf_dir="."
 255         fi
 256         ALL_LINGUAS=`cd "$conf_dir/po" 2>/dev/null && ls *.po 2>/dev/null | $AWK 'BEGIN { FS="."; ORS=" " } { print $1 }'`
 257 fi
 258
 259 AM_GLIB_GNU_GETTEXT
 260 # workaround for intltool bug (http://bugzilla.gnome.org/show_bug.cgi?id=490845)
 261 if test "x$MSGFMT" = "xno"; then
 262         AC_MSG_ERROR([msgfmt not found. Please install the gettext package.])
 263 fi
 264
 265
 266 # Set ${datadir}
 267 if test "x${datadir}" = 'x${prefix}/share' -o "x${datarootdir}" = 'x${prefix}/share'; then
 268         if test "x${prefix}" = "xNONE"; then
 269                 prefix=${ac_default_prefix}
 270         fi
 271 fi
 272
 273 # Set ${docdir} if it is empty
 274 if test -z "${docdir}"; then
 275         docdir='${datadir}/doc/${PACKAGE}'
 276         AC_SUBST(docdir)
 277 fi
 278
 279 GEANY_DATA_DIR=`eval echo ${datarootdir}/geany`
 280 AC_SUBST(GEANY_DATA_DIR)
 281
 282 # intltool hack to define install_sh on Debian/Ubuntu systems
 283 if test "x$install_sh" = "x"; then
 284         install_sh="`pwd`/install-sh"
 285         AC_SUBST(install_sh)
 286 fi
 287
 288 AC_OUTPUT([
 289 Makefile
 290 icons/Makefile
 291 icons/16x16/Makefile
 292 icons/48x48/Makefile
 293 icons/scalable/Makefile
 294 tagmanager/Makefile
 295 tagmanager/include/Makefile
 296 scintilla/Makefile
 297 scintilla/include/Makefile
 298 src/Makefile
 299 plugins/Makefile
 300 po/Makefile.in
 301 doc/Makefile
 302 doc/geany.1
 303 geany.spec
 304 geany.pc
 305 doc/Doxyfile
 306 ])
 307
 308 echo "----------------------------------------"
 309 echo "Install Geany in                   : ${prefix}"
 310 if test "x${build}" != "x" -a "x${target}" != "x"
 311 then
 312         echo "Building Geany on                  : ${build}"
 313         echo "Building Geany for                 : ${target}"
 314 fi
 315 echo "Using GTK version                  : ${GTK_VERSION}"
 316 echo "Build with GTK printing support    : ${enable_printing}"
 317 echo "Build with plugin support          : ${enable_plugins}"
 318 echo "Use virtual terminal support       : ${want_vte}"
 319 echo "Use (UNIX domain) socket support   : ${want_socket}"
 320 if test "x$enable_gnu_regex" = "xyes" ; then
 321         echo "GNU regex library                  : built-in"
 322 else
 323         echo "GNU regex library                  : system"
 324 fi
 325
 326 if test "${REVISION}" != "-1"
 327 then
 328         echo "Compiling Subversion revision      : ${REVISION}"
 329 fi
 330 echo ""
 331 echo "Configuration is done OK."
 332 echo ""