geany.nsi

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ; geany.nsi - this file is part of Geany, a fast and lightweight IDE
   3 ;
   4 ; Copyright 2007-2012 Enrico Tröger <enrico(dot)troeger(at)uvena(dot)de>
   5 ; Copyright 2007-2012 Nick Treleaven <nick(dot)treleaven(at)btinternet(dot)com>
   6 ;
   7 ; This program is free software; you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation; either version 2 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program; if not, write to the Free Software
  19 ; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  20 ;
  21 ;
  22 ; Installer script for Geany (Windows Installer)
  23 ; (Script originally generated by the HM NIS Edit Script Wizard)
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25
  26
  27 ; Do a Cyclic Redundancy Check to make sure the installer was not corrupted by the download
  28 CRCCheck force
  29 RequestExecutionLevel highest ; set execution level for Windows Vista
  30
  31 ;;;;;;;;;;;;;;;;;;;
  32 ; helper defines  ;
  33 ;;;;;;;;;;;;;;;;;;;
  34 !define PRODUCT_NAME "Geany"
  35 !define PRODUCT_VERSION "1.25"
  36 !define PRODUCT_VERSION_ID "1.25.0.0"
  37 !define PRODUCT_PUBLISHER "The Geany developer team"
  38 !define PRODUCT_WEB_SITE "http://www.geany.org/"
  39 !define PRODUCT_DIR_REGKEY "Software\Geany"
  40 !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  41 !define PRODUCT_EXE "$INSTDIR\bin\Geany.exe"
  42 !define PRODUCT_REGNAME "Geany.ProjectFile"
  43 !define PRODUCT_EXT ".geany"
  44 !define RESOURCEDIR "geany-${PRODUCT_VERSION}"
  45
  46 ;;;;;;;;;;;;;;;;;;;;;
  47 ; Version resource  ;
  48 ;;;;;;;;;;;;;;;;;;;;;
  49 VIProductVersion "${PRODUCT_VERSION_ID}"
  50 VIAddVersionKey "ProductName" "${PRODUCT_NAME}"
  51 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION}"
  52 VIAddVersionKey "ProductVersion" "${PRODUCT_VERSION}"
  53 VIAddVersionKey "LegalCopyright" "Copyright 2005-2014 by the Geany developer team"
  54 VIAddVersionKey "FileDescription" "${PRODUCT_NAME} Installer"
  55
  56 BrandingText "$(^NAME) installer (NSIS 2.46)"
  57 InstallDir "$PROGRAMFILES\Geany"
  58 Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  59 SetCompressor /SOLID lzma
  60 ShowInstDetails hide
  61 ShowUnInstDetails hide
  62 XPStyle on
  63 !ifdef INCLUDE_GTK
  64 OutFile "geany-${PRODUCT_VERSION}_setup.exe"
  65 !else
  66 OutFile "geany-${PRODUCT_VERSION}_nogtk_setup.exe"
  67 !endif
  68
  69 Var Answer
  70 Var UserName
  71 Var StartmenuFolder
  72 Var UNINSTDIR
  73
  74 ;;;;;;;;;;;;;;;;
  75 ; MUI Settings ;
  76 ;;;;;;;;;;;;;;;;
  77 !include "MUI2.nsh"
  78
  79 !define MUI_ABORTWARNING
  80 !define MUI_ICON "icons\geany.ico"
  81 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall-full.ico"
  82
  83 ; Welcome page
  84 !insertmacro MUI_PAGE_WELCOME
  85 ; License page
  86 ;!define MUI_LICENSEPAGE_RADIOBUTTONS
  87 !insertmacro MUI_PAGE_LICENSE "${RESOURCEDIR}\Copying.txt"
  88 ; Components page
  89 !insertmacro MUI_PAGE_COMPONENTS
  90 ; Directory page
  91 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE OnDirLeave
  92 !insertmacro MUI_PAGE_DIRECTORY
  93 ; Start menu page
  94 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "Geany"
  95 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
  96 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
  97 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
  98 !insertmacro MUI_PAGE_STARTMENU ${PRODUCT_NAME} "$StartmenuFolder"
  99 ; Instfiles page
 100 !insertmacro MUI_PAGE_INSTFILES
 101 ; Finish page
 102 !define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\News.txt"
 103 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Show Release Notes"
 104 !define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
 105 !define MUI_FINISHPAGE_RUN "$INSTDIR\bin\Geany.exe"
 106 !define MUI_FINISHPAGE_RUN_NOTCHECKED
 107 !insertmacro MUI_PAGE_FINISH
 108
 109 !insertmacro MUI_UNPAGE_INSTFILES ; Uninstaller page
 110 !insertmacro MUI_LANGUAGE "English" ; Language file
 111
 112 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
 113 ; Sections and InstTypes  ;
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 InstType "Full"
 116 InstType "Minimal"
 117
 118 Section "!Program Files" SEC01
 119         SectionIn RO 1 2
 120         SetOverwrite ifnewer
 121
 122         SetOutPath "$INSTDIR"
 123         File "${RESOURCEDIR}\*.txt"
 124
 125         SetOutPath "$INSTDIR\bin"
 126         File "${RESOURCEDIR}\bin\Geany.exe"
 127
 128         SetOutPath "$INSTDIR\data"
 129         File "${RESOURCEDIR}\data\GPL-2"
 130         File "${RESOURCEDIR}\data\file*"
 131         File "${RESOURCEDIR}\data\geany.glade"
 132         File "${RESOURCEDIR}\data\geany.gtkrc"
 133         File "${RESOURCEDIR}\data\snippets.conf"
 134         File "${RESOURCEDIR}\data\ui_toolbar.xml"
 135
 136         SetOutPath "$INSTDIR\data\templates"
 137         File /r "${RESOURCEDIR}\data\templates\*"
 138
 139         SetOutPath "$INSTDIR\data\colorschemes"
 140         File /r "${RESOURCEDIR}\data\colorschemes\*"
 141         # Geany color schemes project, don't bail out if they are missing
 142         File /nonfatal /r "..\geany-themes\colorschemes\*.conf"
 143
 144         SetOutPath "$INSTDIR\share\icons"
 145         File /r "${RESOURCEDIR}\share\icons\*"
 146
 147         SetOutPath "$INSTDIR"
 148
 149         CreateShortCut "$INSTDIR\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 150         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 151         CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
 152         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 153         !insertmacro MUI_STARTMENU_WRITE_END
 154
 155         ; register the extension .geany
 156         ; write information about file type
 157         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}" "" "${PRODUCT_NAME} Project File"
 158         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\DefaultIcon" "" "${PRODUCT_EXE},0"
 159         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\Shell\open\command" "" '"${PRODUCT_EXE}" "%1"'
 160         ; write information about file extensions
 161         WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}" "" "${PRODUCT_REGNAME}"
 162         ; refresh shell
 163         System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) (0x08000000, 0, 0, 0)'
 164 SectionEnd
 165
 166 Section "Plugins" SEC02
 167         SectionIn 1
 168         SetOverwrite ifnewer
 169         SetOutPath "$INSTDIR\lib"
 170         File "${RESOURCEDIR}\lib\*.dll"
 171 SectionEnd
 172
 173 Section "Language Files" SEC03
 174         SectionIn 1
 175         SetOutPath "$INSTDIR\share\locale"
 176         File /r "${RESOURCEDIR}\share\locale\*"
 177 !ifdef INCLUDE_GTK
 178         SetOutPath "$INSTDIR\share"
 179         File /r "gtk\share\*"
 180 !endif
 181 SectionEnd
 182
 183 Section "Documentation" SEC04
 184         SectionIn 1
 185         SetOverwrite ifnewer
 186         SetOutPath "$INSTDIR"
 187         File /r "${RESOURCEDIR}\doc"
 188         WriteIniStr "$INSTDIR\Documentation.url" "InternetShortcut" "URL" "$INSTDIR\doc\Manual.html"
 189         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 190         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Documentation.lnk" "$INSTDIR\Documentation.url"
 191         !insertmacro MUI_STARTMENU_WRITE_END
 192 SectionEnd
 193
 194 Section "Autocompletion Tags" SEC05
 195         SectionIn 1
 196         SetOutPath "$INSTDIR\data"
 197         SetOverwrite ifnewer
 198         File "${RESOURCEDIR}\data\php.tags"
 199         File "${RESOURCEDIR}\data\pascal.tags"
 200         File "${RESOURCEDIR}\data\python.tags"
 201         File "${RESOURCEDIR}\data\html_entities.tags"
 202         File "${RESOURCEDIR}\data\c99.tags"
 203 SectionEnd
 204
 205 ; Include GTK runtime library but only if desired from command line
 206 !ifdef INCLUDE_GTK
 207 Section "GTK 2.16 Runtime Environment" SEC06
 208         SectionIn 1
 209         SetOverwrite ifnewer
 210         SetOutPath "$INSTDIR\bin"
 211         File /r "gtk\bin\*"
 212         SetOutPath "$INSTDIR\etc"
 213         File /r "gtk\etc\*"
 214         SetOutPath "$INSTDIR\lib"
 215         File /r "gtk\lib\*"
 216 SectionEnd
 217 !endif
 218
 219 Section "Context Menus" SEC07
 220         SectionIn 1
 221         WriteRegStr HKCR "*\shell\OpenWithGeany" "" "Open with Geany"
 222         WriteRegStr HKCR "*\shell\OpenWithGeany" "Icon" "$INSTDIR\bin\geany.exe"
 223         WriteRegStr HKCR "*\shell\OpenWithGeany\command" "" '"$INSTDIR\bin\geany.exe" "%1"'
 224 SectionEnd
 225
 226 Section "Desktop Shortcuts" SEC08
 227         SectionIn 1
 228         CreateShortCut "$DESKTOP\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 229         CreateShortCut "$QUICKLAUNCH\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 230 SectionEnd
 231
 232 ; Development files
 233 Section "Development files" SEC09
 234         SetOverwrite ifnewer
 235         SetOutPath "$INSTDIR\include"
 236         File /r "${RESOURCEDIR}\include\*"
 237
 238         SetOutPath "$INSTDIR\lib\pkgconfig"
 239         File "${RESOURCEDIR}\lib\pkgconfig\geany.pc"
 240 SectionEnd
 241
 242 Section -AdditionalIcons
 243         SetOutPath $INSTDIR
 244         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 245         WriteIniStr "$INSTDIR\Website.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
 246         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Website.lnk" "$INSTDIR\Website.url"
 247         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Uninstall.lnk" "$INSTDIR\uninst.exe"
 248         !insertmacro MUI_STARTMENU_WRITE_END
 249 SectionEnd
 250
 251 Section -Post
 252         WriteUninstaller "$INSTDIR\uninst.exe"
 253         WriteRegStr SHCTX "${PRODUCT_DIR_REGKEY}" Path "$INSTDIR"
 254         WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
 255         ${if} $Answer == "yes" ; if user is admin
 256                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
 257                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
 258                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bin\Geany.exe"
 259                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
 260                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
 261                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLUpdateInfo" "${PRODUCT_WEB_SITE}"
 262                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
 263                 WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoModify" 0x00000001
 264                 WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoRepair" 0x00000001
 265         ${endif}
 266 SectionEnd
 267
 268 Section Uninstall
 269         Delete "$INSTDIR\Website.url"
 270         Delete "$INSTDIR\Documentation.url"
 271         Delete "$INSTDIR\uninst.exe"
 272         Delete "$INSTDIR\News.txt"
 273         Delete "$INSTDIR\ReadMe.txt"
 274         Delete "$INSTDIR\Thanks.txt"
 275         Delete "$INSTDIR\ToDo.txt"
 276         Delete "$INSTDIR\Authors.txt"
 277         Delete "$INSTDIR\ChangeLog.txt"
 278         Delete "$INSTDIR\Copying.txt"
 279         Delete "$INSTDIR\Geany.lnk"
 280
 281         ; delete start menu entry
 282         ReadRegStr $0 SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu"
 283         RMDir /r "$0"
 284
 285         Delete "$QUICKLAUNCH\Geany.lnk"
 286         Delete "$DESKTOP\Geany.lnk"
 287
 288         RMDir /r "$INSTDIR\bin"
 289         RMDir /r "$INSTDIR\doc"
 290         RMDir /r "$INSTDIR\data"
 291         RMDir /r "$INSTDIR\etc"
 292         RMDir /r "$INSTDIR\include"
 293         RMDir /r "$INSTDIR\lib"
 294         RMDir /r "$INSTDIR\share"
 295         RMDir "$INSTDIR"
 296
 297         ; remove .geany file extension
 298         ReadRegStr $R0 SHCTX "Software\Classes\${PRODUCT_EXT}" ""
 299         ${if} $R0 == "${PRODUCT_REGNAME}"
 300                 DeleteRegKey SHCTX "${PRODUCT_EXT}"
 301                 DeleteRegKey HKCR "${PRODUCT_EXT}"
 302                 DeleteRegKey SHCTX "${PRODUCT_REGNAME}"
 303                 DeleteRegKey HKCR "${PRODUCT_REGNAME}"
 304         ${endif}
 305
 306         DeleteRegKey HKCR "*\shell\OpenWithGeany"
 307
 308         DeleteRegKey SHCTX "${PRODUCT_UNINST_KEY}"
 309         DeleteRegKey HKCU "${PRODUCT_UNINST_KEY}"
 310         DeleteRegKey SHCTX "${PRODUCT_DIR_REGKEY}"
 311         DeleteRegKey HKCU "${PRODUCT_DIR_REGKEY}"
 312
 313         SetAutoClose true
 314 SectionEnd
 315
 316 ;;;;;;;;;;;;;;;;;;;;;;;;;
 317 ; Section descriptions  ;
 318 ;;;;;;;;;;;;;;;;;;;;;;;;;
 319 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 320 !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} "Required program files. You cannot skip these files."
 321 !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} "Available plugins like 'Version Diff', 'Class Builder' and 'Insert Special Characters'."
 322 !insertmacro MUI_DESCRIPTION_TEXT ${SEC03} "Various translations of Geany's interface."
 323 !insertmacro MUI_DESCRIPTION_TEXT ${SEC04} "Manual in Text and HTML format."
 324 !insertmacro MUI_DESCRIPTION_TEXT ${SEC05} "Symbol lists necessary for auto completion of symbols."
 325 !ifdef INCLUDE_GTK
 326 !insertmacro MUI_DESCRIPTION_TEXT ${SEC06} "You need these files to run Geany. If you have already installed a GTK Runtime Environment (2.16 or higher), you can skip it."
 327 !endif
 328 !insertmacro MUI_DESCRIPTION_TEXT ${SEC07} "Add context menu item 'Open With Geany'"
 329 !insertmacro MUI_DESCRIPTION_TEXT ${SEC08} "Create shortcuts for Geany on the desktop and in the Quicklaunch Bar"
 330 !insertmacro MUI_DESCRIPTION_TEXT ${SEC09} "You need these files only if you want to develop own plugins for Geany. If unsure, you can skip it."
 331 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 332
 333 ;;;;;;;;;;;;;;;;;;;;;
 334 ; helper functions  ;
 335 ;;;;;;;;;;;;;;;;;;;;;
 336
 337 ; (from http://jabref.svn.sourceforge.net/viewvc/jabref/trunk/jabref/src/windows/nsis/setup.nsi)
 338 !macro IsUserAdmin Result UName
 339         ClearErrors
 340         UserInfo::GetName
 341         IfErrors Win9x
 342         Pop $0
 343         StrCpy ${UName} $0
 344         UserInfo::GetAccountType
 345         Pop $1
 346         ${if} $1 == "Admin"
 347                 StrCpy ${Result} "yes"
 348         ${else}
 349                 StrCpy ${Result} "no"
 350         ${endif}
 351         Goto done
 352
 353 Win9x:
 354         StrCpy ${Result} "yes"
 355 done:
 356 !macroend
 357
 358 Function .onInit
 359         StrCpy "$StartmenuFolder" "Geany"
 360
 361         ; (from http://jabref.svn.sourceforge.net/viewvc/jabref/trunk/jabref/src/windows/nsis/setup.nsi)
 362         ; If the user does *not* have administrator privileges, abort
 363         StrCpy $Answer ""
 364         StrCpy $UserName ""
 365         !insertmacro IsUserAdmin $Answer $UserName ; macro from LyXUtils.nsh
 366         ${if} $Answer == "yes"
 367                 SetShellVarContext all ; set that e.g. shortcuts will be created for all users
 368         ${else}
 369                 SetShellVarContext current
 370                 ; TODO is this really what we want? $PROGRAMFILES is not much better because
 371                 ; probably the unprivileged user can't write it anyways
 372                 StrCpy $INSTDIR "$PROFILE\$(^Name)"
 373         ${endif}
 374
 375         ; prevent running multiple instances of the installer
 376         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "geany_installer") i .r1 ?e'
 377         Pop $R0
 378         StrCmp $R0 0 +3
 379         MessageBox MB_OK|MB_ICONEXCLAMATION "The installer is already running." /SD IDOK
 380         Abort
 381         ; warn about a new install over an existing installation
 382         ReadRegStr $R0 SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString"
 383         StrCmp $R0 "" finish
 384
 385         MessageBox MB_YESNO|MB_ICONEXCLAMATION \
 386         "Geany has already been installed. $\nDo you want to remove the previous version before installing $(^Name) ?" \
 387                 /SD IDYES IDYES remove IDNO finish
 388
 389 remove:
 390         ; run the uninstaller
 391         ClearErrors
 392         ; we read the installation path of the old installation from the Registry
 393         ReadRegStr $UNINSTDIR SHCTX "${PRODUCT_DIR_REGKEY}" "Path"
 394         IfSilent dosilent nonsilent
 395 dosilent:
 396         ExecWait '$R0 /S _?=$UNINSTDIR' ;Do not copy the uninstaller to a temp file
 397         Goto finish
 398 nonsilent:
 399         ExecWait '$R0 _?=$UNINSTDIR' ;Do not copy the uninstaller to a temp file
 400 finish:
 401 FunctionEnd
 402
 403 Function un.onUninstSuccess
 404         HideWindow
 405         MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer." \
 406                 /SD IDOK
 407 FunctionEnd
 408
 409 Function un.onInit
 410         ; If the user does *not* have administrator privileges, abort
 411         StrCpy $Answer ""
 412         !insertmacro IsUserAdmin $Answer $UserName
 413         ${if} $Answer == "yes"
 414                 SetShellVarContext all
 415         ${else}
 416                 ; check if the Geany has been installed with admin permisions
 417                 ReadRegStr $0 HKLM "${PRODUCT_UNINST_KEY}" "Publisher"
 418                 ${if} $0 != ""
 419                         MessageBox MB_OK|MB_ICONSTOP "You need administrator privileges to uninstall Geany!" \
 420                                 /SD IDOK
 421                         Abort
 422                 ${endif}
 423                 SetShellVarContext current
 424         ${endif}
 425
 426         MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" \
 427                 /SD IDYES IDYES +2
 428         Abort
 429 FunctionEnd
 430
 431 Function OnDirLeave
 432         ClearErrors
 433         SetOutPath "$INSTDIR" ; what about IfError creating $INSTDIR?
 434         GetTempFileName $1 "$INSTDIR" ; creates tmp file (or fails)
 435         FileOpen $0 "$1" "w" ; error to open?
 436         FileWriteByte $0 "0"
 437         IfErrors notPossible possible
 438
 439 notPossible:
 440         RMDir "$INSTDIR" ; removes folder if empty
 441         MessageBox MB_OK "The given directory is not writeable. Please choose another one!" /SD IDOK
 442         Abort
 443 possible:
 444         FileClose $0
 445         Delete "$1"
 446 FunctionEnd