gajim.nsi

   1 !include "MUI2.nsh"
   2
   3 Name "Gajim"
   4 OutFile "Gajim.exe"
   5 SetCompressor /final /solid lzma
   6
   7 !define myAppName "Gajim"
   8
   9 InstallDir "$PROGRAMFILES\Gajim"
  10 InstallDirRegKey HKCU "Software\Gajim" ""
  11 RequestExecutionLevel admin
  12
  13 Var StartMenuFolder
  14
  15 !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
  16 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
  17 !define MUI_HEADERIMAGE
  18 !define MUI_HEADERIMAGE_BITMAP "data\pixmaps\nsis_header.bmp"
  19 !define MUI_WELCOMEFINISHPAGE_BITMAP "data\pixmaps\nsis_wizard.bmp"
  20 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "data\pixmaps\nsis_wizard.bmp"
  21 ;!define MUI_COMPONENTSPAGE_CHECKBITMAP "${NSISDIR}\Contrib\Graphics\Checks\colorful.bmp"
  22 !define MUI_COMPONENTSPAGE_SMALLDESC
  23 !define MUI_ABORTWARNING
  24
  25 !insertmacro MUI_PAGE_WELCOME
  26 !insertmacro MUI_PAGE_LICENSE "COPYING"
  27 !insertmacro MUI_PAGE_COMPONENTS
  28 !insertmacro MUI_PAGE_DIRECTORY
  29 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
  30 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\Gajim"
  31 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
  32 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
  33 !insertmacro MUI_PAGE_INSTFILES
  34 !define MUI_FINISHPAGE_RUN "$INSTDIR\bin\Gajim.exe"
  35 !insertmacro MUI_PAGE_FINISH
  36
  37 !insertmacro MUI_UNPAGE_WELCOME
  38 !insertmacro MUI_UNPAGE_CONFIRM
  39 !insertmacro MUI_UNPAGE_INSTFILES
  40 !insertmacro MUI_UNPAGE_FINISH
  41
  42 !insertmacro MUI_LANGUAGE "English"
  43 !insertmacro MUI_LANGUAGE "French"
  44 !insertmacro MUI_LANGUAGE "German"
  45 !insertmacro MUI_LANGUAGE "Italian"
  46 !insertmacro MUI_LANGUAGE "Russian"
  47 !insertmacro MUI_RESERVEFILE_LANGDLL
  48
  49 ; English
  50 LangString NAME_Emoticons ${LANG_ENGLISH} "Emoticons"
  51 LangString NAME_Iconsets ${LANG_ENGLISH} "Iconsets"
  52 LangString NAME_Languages ${LANG_ENGLISH} "Languages"
  53 LangString NAME_SecLanguagesOther ${LANG_ENGLISH} "Other"
  54 LangString NAME_Themes ${LANG_ENGLISH} "Themes"
  55 LangString NAME_SecDesktopIcon ${LANG_ENGLISH} "Create icon on desktop"
  56 LangString NAME_SecAutostart ${LANG_ENGLISH} "Start Gajim when Windows starts"
  57 LangString DESC_SecGajim ${LANG_ENGLISH} "Installs the main Gajim files."
  58 LangString DESC_SecGtk ${LANG_ENGLISH} "Installs Gtk+ 2 (necessary to run Gajim)."
  59 LangString DESC_SecDesktopIcon ${LANG_ENGLISH} "If set, a shortcut for Gajim will be created on the desktop."
  60 LangString DESC_SecAutostart ${LANG_ENGLISH} "If set, Gajim will be automatically started when Windows starts."
  61 LangString STR_Installed ${LANG_ENGLISH} "Apparently, Gajim is already installed."
  62 LangString STR_Uninstall ${LANG_ENGLISH} "Launch Uninstaller"
  63 LangString STR_Cancel ${LANG_ENGLISH} "Cancel"
  64 LangString STR_Running ${LANG_ENGLISH} "It appears that Gajim is currently running.$\n\
  65                 Please quit Gajim and restart the uninstaller."
  66
  67 ; French
  68 LangString NAME_Emoticons ${LANG_FRENCH} "Emoticônes"
  69 LangString NAME_Iconsets ${LANG_FRENCH} "Bibliothèque d'icônes"
  70 LangString NAME_Languages ${LANG_FRENCH} "Langues"
  71 LangString NAME_SecLanguagesOther ${LANG_FRENCH} "Autre"
  72 LangString NAME_Themes ${LANG_FRENCH} "Thèmes"
  73 LangString NAME_SecDesktopIcon ${LANG_FRENCH} "Créer une icône sur le bureau"
  74 LangString NAME_SecAutostart ${LANG_FRENCH} "Lancer Gajim au démarrage de Windows"
  75 LangString DESC_SecGajim ${LANG_FRENCH} "Installer les fichiers principaux de Gajim."
  76 LangString DESC_SecGtk ${LANG_FRENCH} "Installer Gtk+ 2 (nécessaire à Gajim)."
  77 LangString DESC_SecDesktopIcon ${LANG_FRENCH} "Si selectionné, un raccourci pour Gajim sera créé sur le bureau."
  78 LangString DESC_SecAutostart ${LANG_FRENCH} "Si activé, Gajim sera automatiquement lancé au démarrage de Windows."
  79 LangString STR_Installed ${LANG_FRENCH} "Gajim est apparement déja installé."
  80 LangString STR_Uninstall ${LANG_FRENCH} "Lancer la Désinstallation"
  81 LangString STR_Cancel ${LANG_FRENCH} "Annuler"
  82 LangString STR_Running ${LANG_FRENCH} "Gajim est apparament lancé.$\n\
  83                 Fermez-le et redémarrez le désinstallateur."
  84
  85 ; German
  86 LangString NAME_Emoticons ${LANG_GERMAN} "Emoticons"
  87 LangString NAME_Iconsets ${LANG_GERMAN} "Symbolsets"
  88 LangString NAME_Languages ${LANG_GERMAN} "Sprachen"
  89 LangString NAME_SecLanguagesOther ${LANG_GERMAN} "Sonstige"
  90 LangString NAME_Themes ${LANG_GERMAN} "Designs"
  91 LangString NAME_SecDesktopIcon ${LANG_GERMAN} "Desktop-Icon erstellen"
  92 LangString NAME_SecAutostart ${LANG_GERMAN} "Gajim mit Windows starten"
  93 LangString DESC_SecGajim ${LANG_GERMAN} "Installiert die Hauptdateien von Gajim."
  94 LangString DESC_SecGtk ${LANG_GERMAN} "Installert Gtk+ 2 (notwendig um Gajim zu benutzen)."
  95 LangString DESC_SecDesktopIcon ${LANG_GERMAN} "Wenn dies aktiviert wird, wird ein Icon für Gajim auf dem Desktop erstellt."
  96 LangString DESC_SecAutostart ${LANG_GERMAN} "Gajim wird automatisch gestartet, sowie Windows startet, wenn dies aktivier wird."
  97 LangString STR_Installed ${LANG_GERMAN} "Gajim scheint bereits installiert zu sein."
  98 LangString STR_Uninstall ${LANG_GERMAN} "Deinstallations-Programm starten"
  99 LangString STR_Cancel ${LANG_GERMAN} "Abbrechen"
 100 LangString STR_Running ${LANG_GERMAN} "Es scheint, dass Gajim bereits läuft.$\n\
 101                 Bitte beenden Sie es und starten Sie den Installer erneut.."
 102
 103 ; Italian
 104 LangString NAME_Emoticons ${LANG_ITALIAN} "Emoticons"
 105 LangString NAME_Iconsets ${LANG_ITALIAN} "Set di icone"
 106 LangString NAME_Languages ${LANG_ITALIAN} "Lingue"
 107 LangString NAME_SecLanguagesOther ${LANG_ITALIAN} "Altre"
 108 LangString NAME_Themes ${LANG_ITALIAN} "Temi"
 109 LangString NAME_SecDesktopIcon ${LANG_ITALIAN} "Crea un'icona sul desktop"
 110 LangString NAME_SecAutostart ${LANG_ITALIAN} "Lancia Gajim quando parte Windows"
 111 LangString DESC_SecGajim ${LANG_ITALIAN} "Installa i file principali di Gajim."
 112 LangString DESC_SecGtk ${LANG_ITALIAN} "Installa Gtk+ 2 (necessario per eseguire Gajim)."
 113 LangString DESC_SecDesktopIcon ${LANG_ITALIAN} "Se selezionato, un'icona verrà creata sul desktop."
 114 LangString DESC_SecAutostart ${LANG_ITALIAN} "Se selezionato, Gajim sarà eseguito all'avvio di Windows."
 115 LangString STR_Installed ${LANG_ITALIAN} "Gajim is apparently already installed."
 116 LangString STR_Uninstall ${LANG_ITALIAN} "Launch Uninstall"
 117 LangString STR_Cancel ${LANG_ITALIAN} "Cancel"
 118 LangString STR_Running ${LANG_ITALIAN} "It appears that Gajim is currently running.$\n\
 119                 Close it and restart uninstaller."
 120
 121 ; Russian
 122 LangString NAME_Emoticons ${LANG_RUSSIAN} "Ñìàéëèêè"
 123 LangString NAME_Iconsets ${LANG_RUSSIAN} "Òåìû èêîíîê"
 124 LangString NAME_Languages ${LANG_RUSSIAN} "ßçûêè"
 125 LangString NAME_SecLanguagesOther ${LANG_RUSSIAN} "Äðóãîå"
 126 LangString NAME_Themes ${LANG_RUSSIAN} "Òåìû"
 127 LangString NAME_SecDesktopIcon ${LANG_RUSSIAN} "Ñîçäàòü ÿðëûê íà ðàáî÷åì ñòîëå"
 128 LangString NAME_SecAutostart ${LANG_RUSSIAN} "Çàïóñêàòü Gajim ïðè çàãðóçêå Windows"
 129 LangString DESC_SecGajim ${LANG_RUSSIAN} "Óñòàíîâêà îñíîâíûõ ôàéëîâ Gajim."
 130 LangString DESC_SecGtk ${LANG_RUSSIAN} "Óñòàíîâêà Gtk+ 2 (íåîáõîäèìî äëÿ ðàáîòû Gajim)."
 131 LangString DESC_SecDesktopIcon ${LANG_RUSSIAN} "Åñëè îòìå÷åíî, íà ðàáî÷åì ñòîëå áóäåò ñîçäàí ÿðëûê Gajim."
 132 LangString DESC_SecAutostart ${LANG_RUSSIAN} "Åñëè îòìå÷åíî, Gajim áóäåò àâòîìàòè÷åñêè çàïóñêàòüñÿ ïðè çàãðóçêå Windows."
 133 LangString STR_Installed ${LANG_RUSSIAN} "Gajim is apparently already installed."
 134 LangString STR_Uninstall ${LANG_RUSSIAN} "Launch Uninstall"
 135 LangString STR_Cancel ${LANG_RUSSIAN} "Cancel"
 136 LangString STR_Running ${LANG_RUSSIAN} "It appears that Gajim is currently running.$\n\
 137                 Close it and restart uninstaller."
 138
 139 Section "Gajim" SecGajim
 140         SectionIn RO
 141
 142         SetOutPath "$INSTDIR"
 143         File "AUTHORS"
 144         File "COPYING"
 145         File "THANKS"
 146         File "THANKS.artists"
 147
 148         SetOutPath "$INSTDIR\bin"
 149         File "bin\cairo._cairo.pyd"
 150         File "bin\_ctypes.pyd"
 151         File "bin\gobject._gobject.pyd"
 152         File "bin\gtk._gtk.pyd"
 153         File "bin\_hashlib.pyd"
 154         File "bin\_socket.pyd"
 155         File "bin\_sqlite3.pyd"
 156         File "bin\_ssl.pyd"
 157         File "bin\_win32sysloader.pyd"
 158         File "bin\Crypto.Cipher.AES.pyd"
 159         File "bin\atk.pyd"
 160         File "bin\bz2.pyd"
 161         File "bin\OpenSSL.crypto.pyd"
 162         File "bin\gajim.exe"
 163         File "bin\gtk.glade.pyd"
 164         File "bin\history_manager.exe"
 165         File "bin\libeay32.dll"
 166         File "bin\libglade-2.0-0.dll"
 167         File "bin\library.zip"
 168         File "bin\libxml2.dll"
 169         File "bin\msvcr71.dll"
 170         File "bin\pangocairo.pyd"
 171         File "bin\pango.pyd"
 172         File "bin\pyexpat.pyd"
 173         File "bin\python25.dll"
 174         File "bin\pywintypes25.dll"
 175         File "bin\OpenSSL.rand.pyd"
 176         File "bin\select.pyd"
 177         File "bin\Crypto.Hash.SHA256.pyd"
 178         File "bin\sqlite3.dll"
 179         File "bin\ssleay32.dll"
 180         File "bin\OpenSSL.SSL.pyd"
 181         File "bin\unicodedata.pyd"
 182         File "bin\w9xpopen.exe"
 183         File "bin\win32api.pyd"
 184         File "bin\win32file.pyd"
 185         File "bin\winsound.pyd"
 186         File "bin\zlib1.dll"
 187
 188         WriteRegStr HKCU "Software\Gajim" "" $INSTDIR
 189         WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Gajim" "DisplayName" "Gajim"
 190         WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Gajim" "UninstallString" "$INSTDIR\Uninstall.exe"
 191         WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Gajim" "DisplayIcon" "$INSTDIR\bin\Gajim.exe"
 192         WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Gajim" "DisplayVersion" "0.12.1"
 193         WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Gajim" "URLInfoAbout" "http://www.gajim.org/"
 194         WriteUninstaller "$INSTDIR\Uninstall.exe"
 195
 196         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 197                 SetShellVarContext current
 198                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 199                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Gajim.lnk" "$INSTDIR\bin\Gajim.exe"
 200                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Change Theme.lnk" "$INSTDIR\bin\gtk\bin\gtkthemeselector.exe"
 201                 SetShellVarContext all
 202                 CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 203                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Gajim.lnk" "$INSTDIR\bin\Gajim.exe"
 204                 CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Change Theme.lnk" "$INSTDIR\bin\gtk\bin\gtkthemeselector.exe"
 205         !insertmacro MUI_STARTMENU_WRITE_END
 206
 207         SetOutPath "$INSTDIR\data"
 208         File /r "data\glade"
 209         File /r "data\moods"
 210         File /r "data\activities"
 211         File /r "data\other"
 212         File /r "data\pixmaps"
 213         File /r "data\sounds"
 214 SectionEnd
 215
 216 Section "Gtk+ 2" SecGtk
 217         SectionIn RO
 218         SetOutPath "$INSTDIR\bin\gtk"
 219         File /r "bin\gtk\bin"
 220         File /r "bin\gtk\etc"
 221         SetOutPath "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines"
 222         File "bin\gtk\lib\gtk-2.0\2.10.0\engines\libclearlooks.dll"
 223         File "bin\gtk\lib\gtk-2.0\2.10.0\engines\libpixmap.dll"
 224         File "bin\gtk\lib\gtk-2.0\2.10.0\engines\libsvg.dll"
 225         SetOutPath "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0"
 226         SetOutPath "$INSTDIR\bin\gtk\lib"
 227         File "bin\gtk\lib\charset.alias"
 228         SetOutPath "$INSTDIR\bin\gtk\share"
 229         File /r "bin\gtk\share\gtkthemeselector"
 230         File /r "bin\gtk\share\xml"
 231 SectionEnd
 232
 233 SectionGroup $(NAME_Emoticons)
 234
 235 Section "animated" SecEmoticonsAnimated
 236         SetOutPath "$INSTDIR\data\emoticons"
 237         File /r "data\emoticons\animated"
 238 SectionEnd
 239
 240 Section "static" SecEmoticonsStatic
 241         SectionIn RO
 242         SetOutPath "$INSTDIR\data\emoticons"
 243         File /r "data\emoticons\static"
 244 SectioNEnd
 245
 246 Section "static-big" SecEmoticonsStaticBig
 247         SetOutPath "$INSTDIR\data\emoticons"
 248         File /r "data\emoticons\static-big"
 249 SectionEnd
 250
 251 SectionGroupEnd
 252
 253 SectionGroup $(NAME_Iconsets)
 254
 255 Section "crystal" SecIconsetsCrystal
 256         SetOutPath "$INSTDIR\data\iconsets"
 257         File /r "data\iconsets\crystal"
 258 SectionEnd
 259
 260 Section "dcraven" SecIconsetsDcraven
 261         SectionIn RO
 262         SetOutPath "$INSTDIR\data\iconsets"
 263         File /r "data\iconsets\dcraven"
 264 SectionEnd
 265
 266 Section "gnome" SecIconsetsGnome
 267         SetOutPath "$INSTDIR\data\iconsets"
 268         File /r "data\iconsets\gnome"
 269 SectionEnd
 270
 271 Section "goojim" SecIconsetsGoojim
 272         SetOutPath "$INSTDIR\data\iconsets"
 273         File /r "data\iconsets\goojim"
 274 SectionEnd
 275
 276 Section "gossip" SecIconsetsGossip
 277         SetOutPath "$INSTDIR\data\iconsets"
 278         File /r "data\iconsets\gossip"
 279 SectionEnd
 280
 281 Section "gota" SecIconsetsGota
 282         SetOutPath "$INSTDIR\data\iconsets"
 283         File /r "data\iconsets\gota"
 284 SectionEnd
 285
 286 Section "jabberbulb" SecIconsetsJabberbulb
 287         SetOutPath "$INSTDIR\data\iconsets"
 288         File /r "data\iconsets\jabberbulb"
 289 SectionEnd
 290
 291 Section "nuvola" SecIconsetsNuvola
 292         SetOutPath "$INSTDIR\data\iconsets"
 293         File /r "data\iconsets\nuvola"
 294 SectionEnd
 295
 296 Section "simplebulb" SecIconsetsSimplebulb
 297         SetOutPath "$INSTDIR\data\iconsets"
 298         File /r "data\iconsets\simplebulb"
 299 SectionEnd
 300
 301 Section "stellar" SecIconsetsStellar
 302         SetOutPath "$INSTDIR\data\iconsets"
 303         File /r "data\iconsets\stellar"
 304 SectionEnd
 305
 306 Section "sun" SecIconsetsSun
 307         SetOutPath "$INSTDIR\data\iconsets"
 308         File /r "data\iconsets\sun"
 309 SectionEnd
 310
 311 Section "transports" SecIconsetsTransports
 312         SetOutPath "$INSTDIR\data\iconsets"
 313         File /r "data\iconsets\transports"
 314         SectionIn Ro
 315 SectionEnd
 316
 317 SectionGroupEnd
 318
 319 SectionGroup $(NAME_Languages)
 320
 321 Section "English (UK)" SecLanguagesEnglishUK
 322         SetOutPath "$INSTDIR\po"
 323         File /r "po\en_GB"
 324         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 325         File /r "bin\gtk\share\locale\en_GB"
 326 SectionEnd
 327
 328 Section "French" SecLanguagesFrench
 329         SetOutPath "$INSTDIR\po"
 330         File /r "po\fr"
 331         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 332         File /r "bin\gtk\share\locale\fr"
 333 SectionEnd
 334
 335 Section "German" SecLanguagesGerman
 336         SetOutPath "$INSTDIR\po"
 337         File /r "po\de"
 338         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 339         File /r "bin\gtk\share\locale\de"
 340 SectionEnd
 341
 342 Section "Italian" SecLanguagesItalian
 343         SetOutPath "$INSTDIR\po"
 344         File /r "po\it"
 345         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 346         File /r "bin\gtk\share\locale\it"
 347 SectionEnd
 348
 349 Section "Spanish" SecLanguagesSpanish
 350         SetOutPath "$INSTDIR\po"
 351         File /r "po\es"
 352         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 353         File /r "bin\gtk\share\locale\es"
 354 SectionEnd
 355
 356 Section "Russian" SecLanguagesRussian
 357         SetOutPath "$INSTDIR\po"
 358         File /r "po\ru"
 359         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 360         File /r "bin\gtk\share\locale\ru"
 361 SectionEnd
 362
 363 Section $(NAME_SecLanguagesOther) SecLanguagesOther
 364         SetOutPath "$INSTDIR\po"
 365         File /r "po\be"
 366         File /r "po\be@latin"
 367         File /r "po\bg"
 368         File /r "po\br"
 369         File /r "po\cs"
 370         File /r "po\da"
 371         File /r "po\el"
 372         File /r "po\eo"
 373         File /r "po\eu"
 374         File /r "po\gl"
 375         File /r "po\hr"
 376         File /r "po\lt"
 377         File /r "po\nb"
 378         File /r "po\nl"
 379         File /r "po\no"
 380         File /r "po\pl"
 381         File /r "po\pt"
 382         File /r "po\pt_BR"
 383         File /r "po\sk"
 384         File /r "po\sr"
 385         File /r "po\sr@Latn"
 386         File /r "po\sv"
 387         File /r "po\uk"
 388         File /r "po\zh_CN"
 389         SetOutPath "$INSTDIR\bin\gtk\share\locale"
 390         File /r "bin\gtk\share\locale\af"
 391         File /r "bin\gtk\share\locale\am"
 392         File /r "bin\gtk\share\locale\ang"
 393         File /r "bin\gtk\share\locale\ar"
 394         File /r "bin\gtk\share\locale\as"
 395         File /r "bin\gtk\share\locale\az"
 396         File /r "bin\gtk\share\locale\az_IR"
 397         File /r "bin\gtk\share\locale\be"
 398         File /r "bin\gtk\share\locale\be@latin"
 399         File /r "bin\gtk\share\locale\bg"
 400         File /r "bin\gtk\share\locale\bn"
 401         File /r "bin\gtk\share\locale\bn_IN"
 402         File /r "bin\gtk\share\locale\br"
 403         File /r "bin\gtk\share\locale\bs"
 404         File /r "bin\gtk\share\locale\ca"
 405         File /r "bin\gtk\share\locale\ca@valencia"
 406         File /r "bin\gtk\share\locale\cs"
 407         File /r "bin\gtk\share\locale\cy"
 408         File /r "bin\gtk\share\locale\da"
 409         File /r "bin\gtk\share\locale\dz"
 410         File /r "bin\gtk\share\locale\el"
 411         File /r "bin\gtk\share\locale\en_CA"
 412         File /r "bin\gtk\share\locale\eo"
 413         File /r "bin\gtk\share\locale\et"
 414         File /r "bin\gtk\share\locale\eu"
 415         File /r "bin\gtk\share\locale\fa"
 416         File /r "bin\gtk\share\locale\fi"
 417         File /r "bin\gtk\share\locale\ga"
 418         File /r "bin\gtk\share\locale\gl"
 419         File /r "bin\gtk\share\locale\gu"
 420         File /r "bin\gtk\share\locale\he"
 421         File /r "bin\gtk\share\locale\hi"
 422         File /r "bin\gtk\share\locale\hr"
 423         File /r "bin\gtk\share\locale\hu"
 424         File /r "bin\gtk\share\locale\hy"
 425         File /r "bin\gtk\share\locale\ia"
 426         File /r "bin\gtk\share\locale\id"
 427         File /r "bin\gtk\share\locale\io"
 428         File /r "bin\gtk\share\locale\is"
 429         File /r "bin\gtk\share\locale\ja"
 430         File /r "bin\gtk\share\locale\ka"
 431         File /r "bin\gtk\share\locale\kn"
 432         File /r "bin\gtk\share\locale\ko"
 433         File /r "bin\gtk\share\locale\ku"
 434         File /r "bin\gtk\share\locale\li"
 435         File /r "bin\gtk\share\locale\lt"
 436         File /r "bin\gtk\share\locale\lv"
 437         File /r "bin\gtk\share\locale\mai"
 438         File /r "bin\gtk\share\locale\mg"
 439         File /r "bin\gtk\share\locale\mi"
 440         File /r "bin\gtk\share\locale\mk"
 441         File /r "bin\gtk\share\locale\ml"
 442         File /r "bin\gtk\share\locale\mn"
 443         File /r "bin\gtk\share\locale\mr"
 444         File /r "bin\gtk\share\locale\ms"
 445         File /r "bin\gtk\share\locale\nb"
 446         File /r "bin\gtk\share\locale\ne"
 447         File /r "bin\gtk\share\locale\nl"
 448         File /r "bin\gtk\share\locale\nn"
 449         File /r "bin\gtk\share\locale\nso"
 450         File /r "bin\gtk\share\locale\oc"
 451         File /r "bin\gtk\share\locale\or"
 452         File /r "bin\gtk\share\locale\pa"
 453         File /r "bin\gtk\share\locale\pl"
 454         File /r "bin\gtk\share\locale\ps"
 455         File /r "bin\gtk\share\locale\pt"
 456         File /r "bin\gtk\share\locale\pt_BR"
 457         File /r "bin\gtk\share\locale\ro"
 458         File /r "bin\gtk\share\locale\rw"
 459         File /r "bin\gtk\share\locale\si"
 460         File /r "bin\gtk\share\locale\sk"
 461         File /r "bin\gtk\share\locale\sl"
 462         File /r "bin\gtk\share\locale\sq"
 463         File /r "bin\gtk\share\locale\sr"
 464         File /r "bin\gtk\share\locale\sr@ije"
 465         File /r "bin\gtk\share\locale\sr@latin"
 466         File /r "bin\gtk\share\locale\sv"
 467         File /r "bin\gtk\share\locale\ta"
 468         File /r "bin\gtk\share\locale\te"
 469         File /r "bin\gtk\share\locale\th"
 470         File /r "bin\gtk\share\locale\tk"
 471         File /r "bin\gtk\share\locale\tl"
 472         File /r "bin\gtk\share\locale\tr"
 473         File /r "bin\gtk\share\locale\tt"
 474         File /r "bin\gtk\share\locale\ug"
 475         File /r "bin\gtk\share\locale\uk"
 476         File /r "bin\gtk\share\locale\ur"
 477         File /r "bin\gtk\share\locale\uz"
 478         File /r "bin\gtk\share\locale\uz@cyrillic"
 479         File /r "bin\gtk\share\locale\vi"
 480         File /r "bin\gtk\share\locale\wa"
 481         File /r "bin\gtk\share\locale\xh"
 482         File /r "bin\gtk\share\locale\yi"
 483         File /r "bin\gtk\share\locale\zh_CN"
 484         File /r "bin\gtk\share\locale\zh_HK"
 485         File /r "bin\gtk\share\locale\zh_TW"
 486 SectionEnd
 487
 488 SectionGroupEnd
 489
 490 SectionGroup $(NAME_Themes)
 491
 492 Section "Clearlooks" SecThemesClearlooks
 493         SetOutPath "$INSTDIR\bin\gtk\share\themes"
 494         File /r "bin\gtk\share\themes\Clearlooks"
 495 SectionEnd
 496
 497 Section "Default GTK" SecThemesDefault
 498         SetOutPath "$INSTDIR\bin\gtk\share\themes"
 499         File /r "bin\gtk\share\themes\Default"
 500 SectionEnd
 501
 502 Section "Glossy" SecThemesGlossy
 503         SetOutPath "$INSTDIR\bin\gtk\share\themes"
 504         File /r "bin\gtk\share\themes\Glossy"
 505 SectionEnd
 506
 507 Section "Glossy-js" SecThemesGlossyJs
 508         SectionIn RO
 509         SetOutPath "$INSTDIR\bin\gtk\share\themes"
 510         File /r "bin\gtk\share\themes\Glossy-js"
 511 SectionEnd
 512
 513 Section "MS-Windows" SecThemesMSWindows
 514         SetOutPath "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines"
 515         File "bin\gtk\lib\gtk-2.0\2.10.0\engines\libwimp.dll"
 516         SetOutPath "$INSTDIR\bin\gtk\share\themes"
 517         File /r "bin\gtk\share\themes\MS-Windows"
 518 SectionEnd
 519
 520 SectionGroupEnd
 521
 522 Section $(NAME_SecDesktopIcon) SecDesktopIcon
 523         SetShellVarContext current
 524         SetOutPath "$INSTDIR\bin"
 525         CreateShortCut "$DESKTOP\Gajim.lnk" "$INSTDIR\bin\Gajim.exe"
 526 SectionEnd
 527
 528 Section $(NAME_SecAutostart) SecAutostart
 529         SetShellVarContext current
 530         SetOutPath "$INSTDIR\bin"
 531         CreateShortCut "$SMSTARTUP\Gajim.lnk" "$INSTDIR\bin\Gajim.exe"
 532 SectionEnd
 533
 534 Section "Uninstall"
 535         RMDir /r "$INSTDIR\bin\gtk\bin"
 536         RMDir /r "$INSTDIR\bin\gtk\etc"
 537         Delete "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines\libclearlooks.dll"
 538         Delete "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines\libpixmap.dll"
 539         Delete "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines\libsvg.dll"
 540         Delete "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines\libwimp.dll"
 541         RMDir "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0\engines"
 542         RMDir "$INSTDIR\bin\gtk\lib\gtk-2.0\2.10.0"
 543         RMDir "$INSTDIR\bin\gtk\lib\gtk-2.0"
 544         Delete "$INSTDIR\bin\gtk\lib\charset.alias"
 545         RMDir "$INSTDIR\bin\gtk\lib"
 546         RMDir /r "$INSTDIR\bin\gtk\share\locale\de"
 547         RMDir /r "$INSTDIR\bin\gtk\share\locale\en_GB"
 548         RMDir /r "$INSTDIR\bin\gtk\share\locale\es"
 549         RMDir /r "$INSTDIR\bin\gtk\share\locale\fr"
 550         RMDir /r "$INSTDIR\bin\gtk\share\locale\it"
 551         RMDir /r "$INSTDIR\bin\gtk\share\locale\ru"
 552         RMDir /r "$INSTDIR\bin\gtk\share\locale\af"
 553         RMDir /r "$INSTDIR\bin\gtk\share\locale\am"
 554         RMDir /r "$INSTDIR\bin\gtk\share\locale\ang"
 555         RMDir /r "$INSTDIR\bin\gtk\share\locale\ar"
 556         RMDir /r "$INSTDIR\bin\gtk\share\locale\as"
 557         RMDir /r "$INSTDIR\bin\gtk\share\locale\az"
 558         RMDir /r "$INSTDIR\bin\gtk\share\locale\az_IR"
 559         RMDir /r "$INSTDIR\bin\gtk\share\locale\be"
 560         RMDir /r "$INSTDIR\bin\gtk\share\locale\be@latin"
 561         RMDir /r "$INSTDIR\bin\gtk\share\locale\bg"
 562         RMDir /r "$INSTDIR\bin\gtk\share\locale\bn"
 563         RMDir /r "$INSTDIR\bin\gtk\share\locale\bn_IN"
 564         RMDir /r "$INSTDIR\bin\gtk\share\locale\br"
 565         RMDir /r "$INSTDIR\bin\gtk\share\locale\bs"
 566         RMDir /r "$INSTDIR\bin\gtk\share\locale\ca"
 567         RMDir /r "$INSTDIR\bin\gtk\share\locale\ca@valencia"
 568         RMDir /r "$INSTDIR\bin\gtk\share\locale\cs"
 569         RMDir /r "$INSTDIR\bin\gtk\share\locale\cy"
 570         RMDir /r "$INSTDIR\bin\gtk\share\locale\da"
 571         RMDir /r "$INSTDIR\bin\gtk\share\locale\dz"
 572         RMDir /r "$INSTDIR\bin\gtk\share\locale\el"
 573         RMDir /r "$INSTDIR\bin\gtk\share\locale\en_CA"
 574         RMDir /r "$INSTDIR\bin\gtk\share\locale\eo"
 575         RMDir /r "$INSTDIR\bin\gtk\share\locale\et"
 576         RMDir /r "$INSTDIR\bin\gtk\share\locale\eu"
 577         RMDir /r "$INSTDIR\bin\gtk\share\locale\fa"
 578         RMDir /r "$INSTDIR\bin\gtk\share\locale\fi"
 579         RMDir /r "$INSTDIR\bin\gtk\share\locale\ga"
 580         RMDir /r "$INSTDIR\bin\gtk\share\locale\gl"
 581         RMDir /r "$INSTDIR\bin\gtk\share\locale\gu"
 582         RMDir /r "$INSTDIR\bin\gtk\share\locale\he"
 583         RMDir /r "$INSTDIR\bin\gtk\share\locale\hi"
 584         RMDir /r "$INSTDIR\bin\gtk\share\locale\hr"
 585         RMDir /r "$INSTDIR\bin\gtk\share\locale\hu"
 586         RMDir /r "$INSTDIR\bin\gtk\share\locale\hy"
 587         RMDir /r "$INSTDIR\bin\gtk\share\locale\ia"
 588         RMDir /r "$INSTDIR\bin\gtk\share\locale\id"
 589         RMDir /r "$INSTDIR\bin\gtk\share\locale\io"
 590         RMDir /r "$INSTDIR\bin\gtk\share\locale\is"
 591         RMDir /r "$INSTDIR\bin\gtk\share\locale\ja"
 592         RMDir /r "$INSTDIR\bin\gtk\share\locale\ka"
 593         RMDir /r "$INSTDIR\bin\gtk\share\locale\kn"
 594         RMDir /r "$INSTDIR\bin\gtk\share\locale\ko"
 595         RMDir /r "$INSTDIR\bin\gtk\share\locale\ku"
 596         RMDir /r "$INSTDIR\bin\gtk\share\locale\li"
 597         RMDir /r "$INSTDIR\bin\gtk\share\locale\lt"
 598         RMDir /r "$INSTDIR\bin\gtk\share\locale\lv"
 599         RMDir /r "$INSTDIR\bin\gtk\share\locale\mai"
 600         RMDir /r "$INSTDIR\bin\gtk\share\locale\mg"
 601         RMDir /r "$INSTDIR\bin\gtk\share\locale\mi"
 602         RMDir /r "$INSTDIR\bin\gtk\share\locale\mk"
 603         RMDir /r "$INSTDIR\bin\gtk\share\locale\ml"
 604         RMDir /r "$INSTDIR\bin\gtk\share\locale\mn"
 605         RMDir /r "$INSTDIR\bin\gtk\share\locale\mr"
 606         RMDir /r "$INSTDIR\bin\gtk\share\locale\ms"
 607         RMDir /r "$INSTDIR\bin\gtk\share\locale\nb"
 608         RMDir /r "$INSTDIR\bin\gtk\share\locale\ne"
 609         RMDir /r "$INSTDIR\bin\gtk\share\locale\nl"
 610         RMDir /r "$INSTDIR\bin\gtk\share\locale\nn"
 611         RMDir /r "$INSTDIR\bin\gtk\share\locale\nso"
 612         RMDir /r "$INSTDIR\bin\gtk\share\locale\oc"
 613         RMDir /r "$INSTDIR\bin\gtk\share\locale\or"
 614         RMDir /r "$INSTDIR\bin\gtk\share\locale\pa"
 615         RMDir /r "$INSTDIR\bin\gtk\share\locale\pl"
 616         RMDir /r "$INSTDIR\bin\gtk\share\locale\ps"
 617         RMDir /r "$INSTDIR\bin\gtk\share\locale\pt"
 618         RMDir /r "$INSTDIR\bin\gtk\share\locale\pt_BR"
 619         RMDir /r "$INSTDIR\bin\gtk\share\locale\ro"
 620         RMDir /r "$INSTDIR\bin\gtk\share\locale\rw"
 621         RMDir /r "$INSTDIR\bin\gtk\share\locale\si"
 622         RMDir /r "$INSTDIR\bin\gtk\share\locale\sk"
 623         RMDir /r "$INSTDIR\bin\gtk\share\locale\sl"
 624         RMDir /r "$INSTDIR\bin\gtk\share\locale\sq"
 625         RMDir /r "$INSTDIR\bin\gtk\share\locale\sr"
 626         RMDir /r "$INSTDIR\bin\gtk\share\locale\sr@ije"
 627         RMDir /r "$INSTDIR\bin\gtk\share\locale\sr@latin"
 628         RMDir /r "$INSTDIR\bin\gtk\share\locale\sv"
 629         RMDir /r "$INSTDIR\bin\gtk\share\locale\ta"
 630         RMDir /r "$INSTDIR\bin\gtk\share\locale\te"
 631         RMDir /r "$INSTDIR\bin\gtk\share\locale\th"
 632         RMDir /r "$INSTDIR\bin\gtk\share\locale\tk"
 633         RMDir /r "$INSTDIR\bin\gtk\share\locale\tl"
 634         RMDir /r "$INSTDIR\bin\gtk\share\locale\tr"
 635         RMDir /r "$INSTDIR\bin\gtk\share\locale\tt"
 636         RMDir /r "$INSTDIR\bin\gtk\share\locale\ug"
 637         RMDir /r "$INSTDIR\bin\gtk\share\locale\uk"
 638         RMDir /r "$INSTDIR\bin\gtk\share\locale\ur"
 639         RMDir /r "$INSTDIR\bin\gtk\share\locale\uz"
 640         RMDir /r "$INSTDIR\bin\gtk\share\locale\uz@cyrillic"
 641         RMDir /r "$INSTDIR\bin\gtk\share\locale\vi"
 642         RMDir /r "$INSTDIR\bin\gtk\share\locale\wa"
 643         RMDir /r "$INSTDIR\bin\gtk\share\locale\xh"
 644         RMDir /r "$INSTDIR\bin\gtk\share\locale\yi"
 645         RMDir /r "$INSTDIR\bin\gtk\share\locale\zh_CN"
 646         RMDir /r "$INSTDIR\bin\gtk\share\locale\zh_HK"
 647         RMDir /r "$INSTDIR\bin\gtk\share\locale\zh_TW"
 648         RMDir "$INSTDIR\bin\gtk\share\locale"
 649         RMDir /r "$INSTDIR\bin\gtk\share\themes\Clearlooks"
 650         RMDir /r "$INSTDIR\bin\gtk\share\themes\Default"
 651         RMDir /r "$INSTDIR\bin\gtk\share\themes\Glossy"
 652         RMDir /r "$INSTDIR\bin\gtk\share\themes\Glossy-js"
 653         RMDir /r "$INSTDIR\bin\gtk\share\themes\MS-Windows"
 654         RMDir "$INSTDIR\bin\gtk\share\themes"
 655         RMDir /r "$INSTDIR\bin\gtk\share\gtkthemeselector"
 656         RMDir /r "$INSTDIR\bin\gtk\share\xml"
 657         RMDir "$INSTDIR\bin\gtk\share"
 658         RMDir "$INSTDIR\bin\gtk"
 659         Delete "$INSTDIR\bin\_ctypes.pyd"
 660         Delete "$INSTDIR\bin\_hashlib.pyd"
 661         Delete "$INSTDIR\bin\_socket.pyd"
 662         Delete "$INSTDIR\bin\_sqlite3.pyd"
 663         Delete "$INSTDIR\bin\_sqlite.pyd"
 664         Delete "$INSTDIR\bin\_ssl.pyd"
 665         Delete "$INSTDIR\bin\_win32sysloader.pyd"
 666         Delete "$INSTDIR\bin\atk.pyd"
 667         Delete "$INSTDIR\bin\bz2.pyd"
 668         Delete "$INSTDIR\bin\cairo._cairo.pyd"
 669         Delete "$INSTDIR\bin\Crypto.Cipher.AES.pyd"
 670         Delete "$INSTDIR\bin\Crypto.Hash.SHA256.pyd"
 671         Delete "$INSTDIR\bin\gajim.exe"
 672         Delete "$INSTDIR\bin\gobject._gobject.pyd"
 673         Delete "$INSTDIR\bin\gtk._gtk.pyd"
 674         Delete "$INSTDIR\bin\gtk.glade.pyd"
 675         Delete "$INSTDIR\bin\history_manager.exe"
 676         Delete "$INSTDIR\bin\libeay32.dll"
 677         Delete "$INSTDIR\bin\libglade-2.0-0.dll"
 678         Delete "$INSTDIR\bin\library.zip"
 679         Delete "$INSTDIR\bin\libxml2.dll"
 680         Delete "$INSTDIR\bin\msvcr71.dll"
 681         Delete "$INSTDIR\bin\OpenSSL.crypto.pyd"
 682         Delete "$INSTDIR\bin\OpenSSL.rand.pyd"
 683         Delete "$INSTDIR\bin\OpenSSL.SSL.pyd"
 684         Delete "$INSTDIR\bin\pangocairo.pyd"
 685         Delete "$INSTDIR\bin\pango.pyd"
 686         Delete "$INSTDIR\bin\pyexpat.pyd"
 687         Delete "$INSTDIR\bin\python25.dll"
 688         Delete "$INSTDIR\bin\pywintypes25.dll"
 689         Delete "$INSTDIR\bin\select.pyd"
 690         Delete "$INSTDIR\bin\sqlite3.dll"
 691         Delete "$INSTDIR\bin\ssleay32.dll"
 692         Delete "$INSTDIR\bin\unicodedata.pyd"
 693         Delete "$INSTDIR\bin\w9xpopen.exe"
 694         Delete "$INSTDIR\bin\win32api.pyd"
 695         Delete "$INSTDIR\bin\win32file.pyd"
 696         Delete "$INSTDIR\bin\winsound.pyd"
 697         Delete "$INSTDIR\bin\zlib1.dll"
 698         RMDir "$INSTDIR\bin"
 699         RMDir /r "$INSTDIR\data\glade"
 700         RMDir /r "$INSTDIR\data\moods"
 701         RMDir /r "$INSTDIR\data\activities"
 702         RMDir /r "$INSTDIR\data\other"
 703         RMDir /r "$INSTDIR\data\pixmaps"
 704         RMDir /r "$INSTDIR\data\sounds"
 705         RMDir /r "$INSTDIR\data\emoticons\animated"
 706         RMDir /r "$INSTDIR\data\emoticons\static"
 707         RMDir /r "$INSTDIR\data\emoticons\static-big"
 708         RMDir "$INSTDIR\data\emoticons"
 709         RMDir /r "$INSTDIR\data\iconsets\crystal"
 710         RMDir /r "$INSTDIR\data\iconsets\dcraven"
 711         RMDir /r "$INSTDIR\data\iconsets\gnome"
 712         RMDir /r "$INSTDIR\data\iconsets\goojim"
 713         RMDir /r "$INSTDIR\data\iconsets\gossip"
 714         RMDir /r "$INSTDIR\data\iconsets\gota"
 715         RMDir /r "$INSTDIR\data\iconsets\jabberbulb"
 716         RMDir /r "$INSTDIR\data\iconsets\nuvola"
 717         RMDir /r "$INSTDIR\data\iconsets\simplebulb"
 718         RMDir /r "$INSTDIR\data\iconsets\stellar"
 719         RMDir /r "$INSTDIR\data\iconsets\sun"
 720         RMDir /r "$INSTDIR\data\iconsets\transports"
 721         RMDir "$INSTDIR\data\iconsets"
 722         RMDir "$INSTDIR\data"
 723         RMDir /r "$INSTDIR\po\be"
 724         RMDir /r "$INSTDIR\po\be@latin"
 725         RMDir /r "$INSTDIR\po\bg"
 726         RMDir /r "$INSTDIR\po\br"
 727         RMDir /r "$INSTDIR\po\cs"
 728         RMDir /r "$INSTDIR\po\da"
 729         RMDir /r "$INSTDIR\po\de"
 730         RMDir /r "$INSTDIR\po\el"
 731         RMDir /r "$INSTDIR\po\en_GB"
 732         RMDir /r "$INSTDIR\po\eo"
 733         RMDir /r "$INSTDIR\po\es"
 734         RMDir /r "$INSTDIR\po\eu"
 735         RMDir /r "$INSTDIR\po\fr"
 736         RMDir /r "$INSTDIR\po\gl"
 737         RMDir /r "$INSTDIR\po\hr"
 738         RMDir /r "$INSTDIR\po\it"
 739         RMDir /r "$INSTDIR\po\lt"
 740         RMDir /r "$INSTDIR\po\nb"
 741         RMDir /r "$INSTDIR\po\nl"
 742         RMDir /r "$INSTDIR\po\no"
 743         RMDir /r "$INSTDIR\po\pl"
 744         RMDir /r "$INSTDIR\po\pt"
 745         RMDir /r "$INSTDIR\po\pt_BR"
 746         RMDir /r "$INSTDIR\po\ru"
 747         RMDir /r "$INSTDIR\po\sk"
 748         RMDir /r "$INSTDIR\po\sr"
 749         RMDir /r "$INSTDIR\po\sr@Latn"
 750         RMDir /r "$INSTDIR\po\sv"
 751         RMDir /r "$INSTDIR\po\uk"
 752         RMDir /r "$INSTDIR\po\zh_CN"
 753         RMDir "$INSTDIR\po"
 754         Delete "$INSTDIR\AUTHORS"
 755         Delete "$INSTDIR\COPYING"
 756         Delete "$INSTDIR\THANKS"
 757         Delete "$INSTDIR\THANKS.artists"
 758         Delete "$INSTDIR\Uninstall.exe"
 759         RMDir "$INSTDIR"
 760
 761         !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 762
 763         SetShellVarContext current
 764         Delete "$SMPROGRAMS\$StartMenuFolder\Gajim.lnk"
 765         Delete "$SMPROGRAMS\$StartMenuFolder\Change Theme.lnk"
 766         RMDir "$SMPROGRAMS\$StartMenuFolder"
 767         Delete "$DESKTOP\Gajim.lnk"
 768         Delete "$SMSTARTUP\Gajim.lnk"
 769         SetShellVarContext all
 770         Delete "$SMPROGRAMS\$StartMenuFolder\Gajim.lnk"
 771         Delete "$SMPROGRAMS\$StartMenuFolder\Change Theme.lnk"
 772         RMDir "$SMPROGRAMS\$StartMenuFolder"
 773
 774         DeleteRegKey /ifempty HKCU "Software\Gajim"
 775         DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Gajim"
 776 SectionEnd
 777
 778 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 779         !insertmacro MUI_DESCRIPTION_TEXT ${SecGajim} $(DESC_SecGajim)
 780         !insertmacro MUI_DESCRIPTION_TEXT ${SecGtk} $(DESC_SecGtk)
 781         !insertmacro MUI_DESCRIPTION_TEXT ${SecDesktopIcon} $(DESC_SecDesktopIcon)
 782         !insertmacro MUI_DESCRIPTION_TEXT ${SecAutostart} $(DESC_SecAutostart)
 783 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 784
 785 Function un.onInit
 786 ;       Check that Gajim is not running before uninstalling
 787         FindWindow $0 "gdkWindowToplevel" "Gajim"
 788         StrCmp $0 0 Remove
 789         MessageBox MB_ICONSTOP|MB_OK $(STR_Running)
 790         Quit
 791 Remove:
 792 FunctionEnd
 793
 794 Function .onInit
 795         BringToFront
 796 ;       Check if already running
 797 ;       If so don't open another but bring to front
 798         System::Call "kernel32::CreateMutexA(i 0, i 0, t '$(^Name)') i .r0 ?e"
 799         Pop $0
 800         StrCmp $0 0 launch
 801         StrLen $0 "$(^Name)"
 802         IntOp $0 $0 + 1
 803         FindWindow $1 '#32770' '' 0 $1
 804         IntCmp $1 0 +3
 805         System::Call "user32::ShowWindow(i r1,i 9) i."         ; If minimized then maximize
 806         System::Call "user32::SetForegroundWindow(i r1) i."    ; Bring to front
 807         Abort
 808
 809 launch:
 810 ;       Check to see if old install (inno setup) is already installed
 811         ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Gajim_is1" "UninstallString"
 812 ;       remove first and last " char
 813         StrLen $0 $R0
 814         IntOp $0 $0 - 2
 815         strcpy $1 $R0 $0 1
 816         IfFileExists $1 +1 NotInstalled
 817         messagebox::show MB_DEFBUTTON4|MB_TOPMOST "Gajim" \
 818                 "0,103" \
 819                 $(STR_Installed) \
 820                 $(STR_Uninstall) $(STR_Cancel)
 821                 Pop $R1
 822         StrCmp $R1 2 Quit +1
 823         ExecWait '$R0 _?=$INSTDIR' $R2
 824         StrCmp $R2 0 +1 Quit
 825
 826 NotInstalled:
 827 ;       Check to see if new installer (NSIS)already installed
 828         ReadRegStr $R3 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Gajim" "UninstallString"
 829         IfFileExists $R3 +1 ReallyNotInstalled
 830
 831         messagebox::show MB_DEFBUTTON4|MB_TOPMOST "Gajim" \
 832                 "0,103" \
 833                 $(STR_Installed) \
 834                 $(STR_Uninstall) $(STR_Cancel)
 835                 Pop $R4
 836         StrCmp $R4 2 Quit +1
 837         ExecWait '$R3 _?=$INSTDIR' $R5
 838         StrCmp $R5 0 ReallyNotInstalled Quit
 839 Quit:
 840         Quit
 841
 842 ReallyNotInstalled:
 843         !insertmacro MUI_LANGDLL_DISPLAY
 844 FunctionEnd