CMake/FOAMInternal.cmake

   1 # - Internal function for FreeFOAM
   2 #
   3 #  FOAM_OPTION(<var> <short> <description> <value>)
   4 #
   5 # Like OPTION(<var> <description> <value>), but also adds the variable <var>
   6 # with the short description <short> to the feature-summary table.
   7 #
   8 #  FOAM_INSTALLATION_PATH(<var> <path> <short> <description>)
   9 #
  10 # Like SET(<var> <path> CACHE PATH <description>), but also adds the variable
  11 # <var> with the short description <short> to the feature-summary table.
  12 # Further if the value of <var> is not an absolute path, it computes the
  13 # absolute path and assigns it to the <var> in the parent scope.
  14 #
  15 #  FOAM_CONDITIONAL_COMPONENT(<name> <enabled> <subdir> <reason>)
  16 #
  17 # Like ADD_SUBDIRECTORY(<subdir>) but if <enabled> evaulates to FALSE, <name>
  18 # is entered as being disabled because of <reason> into the feature-summary
  19 # table.
  20 #
  21 #  FOAM_PRINT_FEATURE_SUMMARY()
  22 #
  23 # Prints summaries of enabled/disabled features, installation paths and
  24 # disabled components.
  25 #
  26 #  FOAM_TARGET_LINK_LIBRARIES(<target> item1 [item2 [...]]
  27 #                             [[debug|optimized|general] <item>] ...)
  28 #
  29 # Like target_link_libraries() but explicitly sets the LINK_INTERFACE_LIBRARIES
  30 # property to exclude the third-party libraries.
  31 #
  32 #  FOAM_ADD_TUTORIAL_TESTS()
  33 #
  34 # Adds the individual cases of the tutorial in the current source directory as
  35 # tests. It runs the configured Allrun script in the directory with the --cases
  36 # option to obtain a list of cases, and adds each of them as a test. Each case
  37 # depends on its predecessor.
  38 #
  39
  40 #-------------------------------------------------------------------------------
  41 #               ______                _     ____          __  __
  42 #              |  ____|             _| |_  / __ \   /\   |  \/  |
  43 #              | |__ _ __ ___  ___ /     \| |  | | /  \  | \  / |
  44 #              |  __| '__/ _ \/ _ ( (| |) ) |  | |/ /\ \ | |\/| |
  45 #              | |  | | |  __/  __/\_   _/| |__| / ____ \| |  | |
  46 #              |_|  |_|  \___|\___|  |_|   \____/_/    \_\_|  |_|
  47 #
  48 #                   FreeFOAM: The Cross-Platform CFD Toolkit
  49 #
  50 # Copyright (C) 2008-2012 Michael Wild <themiwi@users.sf.net>
  51 #                         Gerber van der Graaf <gerber_graaf@users.sf.net>
  52 #-------------------------------------------------------------------------------
  53 # License
  54 #   This file is part of FreeFOAM.
  55 #
  56 #   FreeFOAM is free software: you can redistribute it and/or modify it
  57 #   under the terms of the GNU General Public License as published by the
  58 #   Free Software Foundation, either version 3 of the License, or (at your
  59 #   option) any later version.
  60 #
  61 #   FreeFOAM is distributed in the hope that it will be useful, but WITHOUT
  62 #   ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  63 #   FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  64 #   for more details.
  65 #
  66 #   You should have received a copy of the GNU General Public License
  67 #   along with FreeFOAM.  If not, see <http://www.gnu.org/licenses/>.
  68 #
  69 # Description
  70 #   Internal CMake functions for FreeFOAM
  71 #
  72 #-------------------------------------------------------------------------------
  73
  74 function(foam_option var short description value)
  75   _foam_set_feature_property("OPTION" ${var} "${short}")
  76   option(${var} "${description}" ${value})
  77 endfunction()
  78
  79 function(foam_installation_path var value short description)
  80   _foam_set_feature_property("PATH" ${var} "${short}")
  81   set(${var} ${value} CACHE PATH "${description}")
  82   mark_as_advanced(${var})
  83   set(${var}_ORIG ${${var}} PARENT_SCOPE)
  84   # make absolute path
  85   if(NOT IS_ABSOLUTE "${${var}}")
  86     set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}" PARENT_SCOPE)
  87   endif()
  88 endfunction()
  89
  90 macro(foam_conditional_component name enabled subdir description)
  91   if(${enabled})
  92     add_subdirectory(${subdir})
  93   else()
  94     _foam_set_feature_property("COMPONENT" ${name} "${description}")
  95   endif()
  96 endmacro()
  97
  98 function(_foam_set_feature_property type var short)
  99   set_property(GLOBAL APPEND PROPERTY FOAM_FEATURES ${var})
 100   set_property(GLOBAL PROPERTY FOAM_FEATURES_${var}_COMMENT "${short}")
 101   set_property(GLOBAL PROPERTY FOAM_FEATURES_${var}_TYPE "${type}")
 102 endfunction()
 103
 104 function(foam_print_feature_summary)
 105   set(OPTION_msg "Feature Summary:")
 106   set(PATH_msg "Installation Directories:")
 107   set(COMPONENT_msg "Disabled Components:")
 108   get_property(features GLOBAL PROPERTY FOAM_FEATURES)
 109   set(OPTION_len 0)
 110   set(OPTION_space)
 111   set(PATH_len 0)
 112   set(PATH_space)
 113   set(COMPONENT_len 0)
 114   set(COMPONENT_space)
 115   foreach(f ${features})
 116     get_property(desc GLOBAL PROPERTY FOAM_FEATURES_${f}_COMMENT)
 117     get_property(type GLOBAL PROPERTY FOAM_FEATURES_${f}_TYPE)
 118     if(NOT type STREQUAL "COMPONENT")
 119       string(LENGTH "${desc}" l)
 120     else()
 121       string(LENGTH "${f}" l)
 122     endif()
 123     if(l GREATER ${${type}_len})
 124       set(${type}_len ${l})
 125       set(${type}_space "${desc}")
 126     endif()
 127   endforeach()
 128   string(REGEX REPLACE "." " " OPTION_space "${OPTION_space}")
 129   string(REGEX REPLACE "." " " PATH_space "${PATH_space}")
 130   string(REGEX REPLACE "." " " COMPONENT_space "${COMPONENT_space}")
 131   foreach(f ${features})
 132     get_property(desc GLOBAL PROPERTY FOAM_FEATURES_${f}_COMMENT)
 133     get_property(type GLOBAL PROPERTY FOAM_FEATURES_${f}_TYPE)
 134     if(NOT type STREQUAL "COMPONENT")
 135       string(LENGTH "${desc}" l)
 136     else()
 137       string(LENGTH "${f}" l)
 138     endif()
 139     math(EXPR l "${${type}_len} - ${l}")
 140     string(SUBSTRING "${${type}_space}" 0 ${l} s)
 141     if(type STREQUAL "OPTION")
 142       if(${${f}})
 143         set(value ON)
 144       else()
 145         set(value OFF)
 146       endif()
 147     else()
 148       set(value "${${f}}")
 149     endif()
 150     if(NOT type STREQUAL "COMPONENT")
 151       set(${type}_msg "${${type}_msg}\n     ${desc}${s}  ${value}")
 152     else()
 153       set(${type}_msg "${${type}_msg}\n     ${f}${s}  ${desc}")
 154     endif()
 155   endforeach()
 156   message(STATUS "${OPTION_msg}\n")
 157   message(STATUS "${PATH_msg}\n")
 158   message(STATUS "${COMPONENT_msg}\n")
 159 endfunction()
 160
 161 function(foam_target_link_libraries target)
 162   set(libs "${ARGN}")
 163   target_link_libraries(${target} ${libs})
 164   get_property(tp_libs GLOBAL PROPERTY FOAM_THIRDPARTY_LIBRARIES)
 165   if(tp_libs)
 166     list(REMOVE_ITEM libs ${tp_libs})
 167     set_target_properties(${target} PROPERTIES
 168       LINK_INTERFACE_LIBRARIES "${libs}")
 169   endif()
 170 endfunction()
 171
 172 function(foam_add_tutorial_tests)
 173   if(NOT BUILD_TESTING)
 174     return()
 175   endif()
 176   set(allrun_script
 177     "${CMAKE_CURRENT_BINARY_DIR}/Allrun${FOAM_PY_SCRIPT_SUFFIX}")
 178   if(NOT EXISTS ${allrun_script})
 179     message(FATAL_ERROR
 180       "No Allrun script configured in ${CMAKE_CURRENT_SOURCE_DIR}")
 181     return()
 182   endif()
 183   execute_process(
 184     COMMAND "${PYTHON_EXECUTABLE}" "${allrun_script}" --cases
 185     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 186     RESULT_VARIABLE result
 187     OUTPUT_VARIABLE cases
 188     ERROR_VARIABLE errmsg
 189     OUTPUT_STRIP_TRAILING_WHITESPACE
 190     )
 191   if(result)
 192     message(SEND_ERROR "Error running Allrun --cases:\n${errmsg}")
 193     return()
 194   endif()
 195   string(REPLACE "\n" ";" cases "${cases}")
 196   set(last_c)
 197   if(NOT FOAM_ENABLE_FULL_TUTORIAL_TESTS)
 198     set(testarg --test)
 199   else()
 200     set(testarg)
 201   endif()
 202   foreach(c ${cases})
 203     add_test(NAME ${c} COMMAND ${PYTHON_EXECUTABLE} ${allrun_script}
 204       ${testarg} --verbose ${c})
 205     if(last_c)
 206       set_tests_properties(${c} PROPERTIES DEPENDS ${last_c})
 207     endif()
 208     set(last_c ${c})
 209   endforeach()
 210   foreach(c ${cases})
 211     add_test(NAME ${c}_clean COMMAND ${PYTHON_EXECUTABLE} ${allrun_script}
 212       --clean)
 213     set_tests_properties(${c}_clean PROPERTIES DEPENDS ${last_c})
 214   endforeach()
 215 endfunction()
 216
 217 # ------------------------- vim: set sw=2 sts=2 et: --------------- end-of-file