CMake/FOAMInternal.cmake

   1 # - Internal function for FreeFOAM
   2 #
   3 #  FOAM_OPTION(<var> <short> <description> <value>)
   4 #
   5 # Like OPTION(<var> <description> <value>), but also adds the variable <var>
   6 # with the short description <short> to the feature-summary table.
   7 #
   8 #  FOAM_INSTALLATION_PATH(<var> <path> <short> <description>)
   9 #
  10 # Like SET(<var> <path> CACHE PATH <description>), but also adds the variable
  11 # <var> with the short description <short> to the feature-summary table.
  12 # Further if the value of <var> is not an absolute path, it computes the
  13 # absolute path and assigns it to the <var> in the parent scope.
  14 #
  15 #  FOAM_CONDITIONAL_COMPONENT(<name> <enabled> <subdir> <reason>)
  16 #
  17 # Like ADD_SUBDIRECTORY(<subdir>) but if <enabled> evaulates to FALSE, <name>
  18 # is entered as being disabled because of <reason> into the feature-summary
  19 # table.
  20 #
  21 #  FOAM_PRINT_FEATURE_SUMMARY()
  22 #
  23 # Prints summaries of enabled/disabled features, installation paths and
  24 # disabled components.
  25 #
  26 #  FOAM_TARGET_LINK_LIBRARIES(<target> item1 [item2 [...]]
  27 #                             [[debug|optimized|general] <item>] ...)
  28 #
  29 # Like target_link_libraries() but explicitly sets the LINK_INTERFACE_LIBRARIES
  30 # property to exclude the third-party libraries.
  31 #
  32 #  FOAM_ADD_TUTORIAL_TESTS()
  33 #
  34 # Adds the individual cases of the tutorial in the current source directory as
  35 # tests. It runs the configured Allrun script in the directory with the --cases
  36 # option to obtain a list of cases, and adds each of them as a test. Each case
  37 # depends on its predecessor.
  38 #
  39
  40 #-------------------------------------------------------------------------------
  41 #               ______                _     ____          __  __
  42 #              |  ____|             _| |_  / __ \   /\   |  \/  |
  43 #              | |__ _ __ ___  ___ /     \| |  | | /  \  | \  / |
  44 #              |  __| '__/ _ \/ _ ( (| |) ) |  | |/ /\ \ | |\/| |
  45 #              | |  | | |  __/  __/\_   _/| |__| / ____ \| |  | |
  46 #              |_|  |_|  \___|\___|  |_|   \____/_/    \_\_|  |_|
  47 #
  48 #                   FreeFOAM: The Cross-Platform CFD Toolkit
  49 #
  50 # Copyright (C) 2008-2011 Michael Wild <themiwi@users.sf.net>
  51 #                         Gerber van der Graaf <gerber_graaf@users.sf.net>
  52 #-------------------------------------------------------------------------------
  53 # License
  54 #   This file is part of FreeFOAM.
  55 #
  56 #   FreeFOAM is free software; you can redistribute it and/or modify it
  57 #   under the terms of the GNU General Public License as published by the
  58 #   Free Software Foundation; either version 2 of the License, or (at your
  59 #   option) any later version.
  60 #
  61 #   FreeFOAM is distributed in the hope that it will be useful, but WITHOUT
  62 #   ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  63 #   FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  64 #   for more details.
  65 #
  66 #   You should have received a copy of the GNU General Public License
  67 #   along with FreeFOAM; if not, write to the Free Software Foundation,
  68 #   Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
  69 #
  70 # Description
  71 #   Internal CMake functions for FreeFOAM
  72 #
  73 #-------------------------------------------------------------------------------
  74
  75 function(foam_option var short description value)
  76   _foam_set_feature_property("OPTION" ${var} "${short}")
  77   option(${var} "${description}" ${value})
  78 endfunction()
  79
  80 function(foam_installation_path var value short description)
  81   _foam_set_feature_property("PATH" ${var} "${short}")
  82   set(${var} ${value} CACHE PATH "${description}")
  83   mark_as_advanced(${var})
  84   set(${var}_ORIG ${${var}} PARENT_SCOPE)
  85   # make absolute path
  86   if(NOT IS_ABSOLUTE "${${var}}")
  87     set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}" PARENT_SCOPE)
  88   endif()
  89 endfunction()
  90
  91 macro(foam_conditional_component name enabled subdir description)
  92   if(${enabled})
  93     add_subdirectory(${subdir})
  94   else()
  95     _foam_set_feature_property("COMPONENT" ${name} "${description}")
  96   endif()
  97 endmacro()
  98
  99 function(_foam_set_feature_property type var short)
 100   set_property(GLOBAL APPEND PROPERTY FOAM_FEATURES ${var})
 101   set_property(GLOBAL PROPERTY FOAM_FEATURES_${var}_COMMENT "${short}")
 102   set_property(GLOBAL PROPERTY FOAM_FEATURES_${var}_TYPE "${type}")
 103 endfunction()
 104
 105 function(foam_print_feature_summary)
 106   set(OPTION_msg "Feature Summary:")
 107   set(PATH_msg "Installation Directories:")
 108   set(COMPONENT_msg "Disabled Components:")
 109   get_property(features GLOBAL PROPERTY FOAM_FEATURES)
 110   set(OPTION_len 0)
 111   set(OPTION_space)
 112   set(PATH_len 0)
 113   set(PATH_space)
 114   set(COMPONENT_len 0)
 115   set(COMPONENT_space)
 116   foreach(f ${features})
 117     get_property(desc GLOBAL PROPERTY FOAM_FEATURES_${f}_COMMENT)
 118     get_property(type GLOBAL PROPERTY FOAM_FEATURES_${f}_TYPE)
 119     if(NOT type STREQUAL "COMPONENT")
 120       string(LENGTH "${desc}" l)
 121     else()
 122       string(LENGTH "${f}" l)
 123     endif()
 124     if(l GREATER ${${type}_len})
 125       set(${type}_len ${l})
 126       set(${type}_space "${desc}")
 127     endif()
 128   endforeach()
 129   string(REGEX REPLACE "." " " OPTION_space "${OPTION_space}")
 130   string(REGEX REPLACE "." " " PATH_space "${PATH_space}")
 131   string(REGEX REPLACE "." " " COMPONENT_space "${COMPONENT_space}")
 132   foreach(f ${features})
 133     get_property(desc GLOBAL PROPERTY FOAM_FEATURES_${f}_COMMENT)
 134     get_property(type GLOBAL PROPERTY FOAM_FEATURES_${f}_TYPE)
 135     if(NOT type STREQUAL "COMPONENT")
 136       string(LENGTH "${desc}" l)
 137     else()
 138       string(LENGTH "${f}" l)
 139     endif()
 140     math(EXPR l "${${type}_len} - ${l}")
 141     string(SUBSTRING "${${type}_space}" 0 ${l} s)
 142     if(type STREQUAL "OPTION")
 143       if(${${f}})
 144         set(value ON)
 145       else()
 146         set(value OFF)
 147       endif()
 148     else()
 149       set(value "${${f}}")
 150     endif()
 151     if(NOT type STREQUAL "COMPONENT")
 152       set(${type}_msg "${${type}_msg}\n     ${desc}${s}  ${value}")
 153     else()
 154       set(${type}_msg "${${type}_msg}\n     ${f}${s}  ${desc}")
 155     endif()
 156   endforeach()
 157   message(STATUS "${OPTION_msg}\n")
 158   message(STATUS "${PATH_msg}\n")
 159   message(STATUS "${COMPONENT_msg}\n")
 160 endfunction()
 161
 162 function(foam_target_link_libraries target)
 163   set(libs "${ARGN}")
 164   target_link_libraries(${target} ${libs})
 165   get_property(tp_libs GLOBAL PROPERTY FOAM_THIRDPARTY_LIBRARIES)
 166   if(tp_libs)
 167     list(REMOVE_ITEM libs ${tp_libs})
 168     set_target_properties(${target} PROPERTIES
 169       LINK_INTERFACE_LIBRARIES "${libs}")
 170   endif()
 171 endfunction()
 172
 173 function(foam_add_tutorial_tests)
 174   if(NOT BUILD_TESTING)
 175     return()
 176   endif()
 177   set(allrun_script
 178     "${CMAKE_CURRENT_BINARY_DIR}/Allrun${FOAM_PY_SCRIPT_SUFFIX}")
 179   if(NOT EXISTS ${allrun_script})
 180     message(FATAL_ERROR
 181       "No Allrun script configured in ${CMAKE_CURRENT_SOURCE_DIR}")
 182     return()
 183   endif()
 184   execute_process(
 185     COMMAND "${PYTHON_EXECUTABLE}" "${allrun_script}" --cases
 186     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 187     RESULT_VARIABLE result
 188     OUTPUT_VARIABLE cases
 189     ERROR_VARIABLE errmsg
 190     OUTPUT_STRIP_TRAILING_WHITESPACE
 191     )
 192   if(result)
 193     message(SEND_ERROR "Error running Allrun --cases:\n${errmsg}")
 194     return()
 195   endif()
 196   string(REPLACE "\n" ";" cases "${cases}")
 197   set(last_c)
 198   if(NOT FOAM_ENABLE_FULL_TUTORIAL_TESTS)
 199     set(testarg --test)
 200   else()
 201     set(testarg)
 202   endif()
 203   foreach(c ${cases})
 204     add_test(NAME ${c} COMMAND ${PYTHON_EXECUTABLE} ${allrun_script}
 205       ${testarg} --verbose ${c})
 206     if(last_c)
 207       set_tests_properties(${c} PROPERTIES DEPENDS ${last_c})
 208     endif()
 209     set(last_c ${c})
 210   endforeach()
 211   foreach(c ${cases})
 212     add_test(NAME ${c}_clean COMMAND ${PYTHON_EXECUTABLE} ${allrun_script}
 213       --clean)
 214     set_tests_properties(${c}_clean PROPERTIES DEPENDS ${last_c})
 215   endforeach()
 216 endfunction()
 217
 218 # ------------------------- vim: set sw=2 sts=2 et: --------------- end-of-file