m4/sound.m4

   1 AC_DEFUN([FC_CHECK_SOUND],[
   2  AC_ARG_ENABLE([sdl-mixer],
   3    AS_HELP_STRING([--enable-sdl-mixer], [use the SDL mixer [sdl2]]),
   4   [case "${enableval}" in
   5    sdl|sdl1.2) USE_SOUND_SDL=sdl ;;
   6    no)  USE_SOUND_SDL=no ;;
   7    yes|sdl2) USE_SOUND_SDL=sdl2 ;;
   8    *)   AC_MSG_ERROR([bad value ${enableval} for --enable-sdl-mixer]) ;;
   9    esac], [USE_SOUND_SDL=maybe])
  10
  11 if test "x$USE_SOUND_SDL" != "xno" && test "x$USE_SOUND_SDL" != "xsdl" ; then
  12   dnl Add SDL2-mixer support to client
  13   SDL2_VERSION=2.0.0
  14   AM_PATH_SDL2($SDL2_VERSION, SDL2=yes, SDL2=no)
  15   if test "x$SDL2" != "xno"; then
  16     PKG_CHECK_MODULES([SDL2MIXER], [SDL2_mixer],
  17 [
  18     SOUND_CFLAGS="$SOUND_CFLAGS $SDL2MIXER_CFLAGS"
  19     SOUND_LIBS="$SOUND_LIBS $SDL2MIXER_LIBS"
  20     AC_DEFINE([AUDIO_SDL], [1], [SDL Mixer support])
  21     AC_DEFINE([AUDIO_SDL2], [1], [SDL-2 Mixer in use])
  22     SDL_mixer=sdl2
  23     SOUND_SDL_OK=true
  24     if test x$sdl_headers_without_path != xyes ; then
  25       AC_CHECK_HEADER([SDL2/SDL_mixer.h], [], [
  26 AC_DEFINE([SDL2_PLAIN_INCLUDE], [1], [sdl2 headers must be included without path])
  27 sdl_headers_without_path=yes])
  28     fi
  29 ], [
  30     ac_save_CPPFLAGS="$CPPFLAGS"
  31     ac_save_CFLAGS="$CFLAGS"
  32     ac_save_LIBS="$LIBS"
  33     CPPFLAGS="$CPPFLAGS $SDL2_CFLAGS"
  34     CFLAGS="$CFLAGS $SDL2_CFLAGS"
  35     LIBS="$LIBS $SDL2_LIBS"
  36     AC_CHECK_HEADER([SDL_mixer.h], [SDL_mixer_h=1], [SDL_mixer_h=0])
  37     AC_CHECK_LIB([SDL2_mixer], [Mix_OpenAudio], [SDL_mixer=sdl2])
  38     CPPFLAGS="$ac_save_CPPFLAGS"
  39     CFLAGS="$ac_save_CFLAGS"
  40     LIBS="$ac_save_LIBS"
  41
  42     AC_MSG_CHECKING([building SDL2_mixer support])
  43     if test "x$SDL_mixer_h" = "x1"; then
  44       if test "x$SDL_mixer" = "xsdl2"; then
  45         SOUND_CFLAGS="$SOUND_CFLAGS $SDL2_CFLAGS"
  46         SOUND_LIBS="$SOUND_LIBS -lSDL2_mixer $SDL2_LIBS"
  47         AC_DEFINE([AUDIO_SDL], [1], [SDL Mixer support])
  48         AC_DEFINE([AUDIO_SDL2], [1], [SDL-2 Mixer in use])
  49         AC_MSG_RESULT([yes])
  50         SOUND_SDL_OK=true
  51       else
  52         AC_MSG_RESULT([no SDL2_mixer library found, install from http://www.libsdl.org/projects/SDL_mixer/index.html ])
  53       fi
  54     else
  55       AC_MSG_RESULT([no SDL2_mixer headers found, install from http://www.libsdl.org/projects/SDL_mixer/index.html])
  56     fi ])
  57   fi
  58 fi
  59
  60 if test "x$USE_SOUND_SDL" != "xsdl2" && test "x$USE_SOUND_SDL" != "xno" && test "x$SOUND_SDL_OK" != "xtrue" ; then
  61   dnl Add SDL-mixer support to client
  62   SDL_VERSION=1.0.0
  63   AM_PATH_SDL($SDL_VERSION, SDL=yes, SDL=no)
  64   if test "x$SDL" != "xno"; then
  65     PKG_CHECK_MODULES([SDLMIXER], [SDL_mixer],
  66 [
  67     SOUND_CFLAGS="$SOUND_CFLAGS $SDLMIXER_CFLAGS"
  68     SOUND_LIBS="$SOUND_LIBS $SDLMIXER_LIBS"
  69     AC_DEFINE([AUDIO_SDL], [1], [SDL_Mixer support])
  70     AC_DEFINE([AUDIO_SDL1_2], [1], [SDL-1.2 Mixer in use])
  71     SDL_mixer=sdl
  72     SOUND_SDL_OK=true
  73 ], [
  74     ac_save_CPPFLAGS="$CPPFLAGS"
  75     ac_save_CFLAGS="$CFLAGS"
  76     ac_save_LIBS="$LIBS"
  77     CPPFLAGS="$CPPFLAGS $SDL_CFLAGS"
  78     CFLAGS="$CFLAGS $SDL_CFLAGS"
  79     LIBS="$LIBS $SDL_LIBS"
  80     AC_CHECK_HEADER([SDL_mixer.h], [SDL_mixer_h=1], [SDL_mixer_h=0])
  81     AC_CHECK_LIB([SDL_mixer], [Mix_OpenAudio], [SDL_mixer=sdl])
  82     CPPFLAGS="$ac_save_CPPFLAGS"
  83     CFLAGS="$ac_save_CFLAGS"
  84     LIBS="$ac_save_LIBS"
  85
  86     AC_MSG_CHECKING([building SDL_mixer support])
  87     if test "x$SDL_mixer_h" = "x1"; then
  88       if test "x$SDL_mixer" = "xsdl"; then
  89         SOUND_CFLAGS="$SOUND_CFLAGS $SDL_CFLAGS"
  90         SOUND_LIBS="$SOUND_LIBS -lSDL_mixer $SDL_LIBS"
  91         AC_DEFINE([AUDIO_SDL], [1], [SDL_Mixer support])
  92         AC_DEFINE([AUDIO_SDL1_2], [1], [SDL-1.2 Mixer in use])
  93         AC_MSG_RESULT([yes])
  94         SOUND_SDL_OK=true
  95       else
  96         AC_MSG_RESULT([no SDL_mixer library found, install from http://www.libsdl.org/projects/SDL_mixer/index.html ])
  97       fi
  98     else
  99       AC_MSG_RESULT([no SDL_mixer headers found, install from http://www.libsdl.org/projects/SDL_mixer/index.html])
 100     fi ])
 101   fi
 102 fi
 103 if test "x$USE_SOUND_SDL" = "xsdl" || test "x$USE_SOUND_SDL" = "xsdl2" ;then
 104   if test "x$SOUND_SDL_OK" != "xtrue" ; then
 105      AC_MSG_ERROR([SDL mixer support requested, but cannot be compiled in])
 106   fi
 107 fi
 108 if test "x$USE_SOUND_SDL" = "xmaybe" && test "x$SOUND_SDL_OK" != "xtrue" ; then
 109   feature_sound=missing
 110 fi
 111 if test "x$SDL_mixer" = "x" ; then
 112   SDL_mixer=no
 113 fi
 114 ])