sys/tools/vnode_if.awk

   1 #!/usr/bin/awk -f
   2
   3 #-
   4 # Copyright (c) 1992, 1993
   5 #       The Regents of the University of California.  All rights reserved.
   6 #
   7 # Redistribution and use in source and binary forms, with or without
   8 # modification, are permitted provided that the following conditions
   9 # are met:
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 # 2. Redistributions in binary form must reproduce the above copyright
  13 #    notice, this list of conditions and the following disclaimer in the
  14 #    documentation and/or other materials provided with the distribution.
  15 # 4. Neither the name of the University nor the names of its contributors
  16 #    may be used to endorse or promote products derived from this software
  17 #    without specific prior written permission.
  18 #
  19 # THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  20 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  21 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  22 # ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  23 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  24 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  25 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  26 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  27 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  28 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  29 # SUCH DAMAGE.
  30
  31 #
  32 #       @(#)vnode_if.sh 8.1 (Berkeley) 6/10/93
  33 # $FreeBSD$
  34 #
  35 # Script to produce VFS front-end sugar.
  36 #
  37 # usage: vnode_if.awk <srcfile> [-c | -h | -p | -q]
  38 #       (where <srcfile> is currently /sys/kern/vnode_if.src)
  39 #       The source file must have a .src extension
  40 #
  41
  42 function usage()
  43 {
  44         print "usage: vnode_if.awk <srcfile> [-c|-h|-p|-q]";
  45         exit 1;
  46 }
  47
  48 function die(msg, what)
  49 {
  50         printf srcfile "(" fnr "): " > "/dev/stderr";
  51         printf msg "\n", what > "/dev/stderr";
  52         exit 1;
  53 }
  54
  55 function t_spc(type)
  56 {
  57         # Append a space if the type is not a pointer
  58         return (type ~ /\*$/) ? type : type " ";
  59 }
  60
  61 # These are just for convenience ...
  62 function printc(s) {print s > cfile;}
  63 function printh(s) {print s > hfile;}
  64 function printp(s) {print s > pfile;}
  65 function printq(s) {print s > qfile;}
  66
  67 function add_debug_code(name, arg, pos, ind)
  68 {
  69         if (arg == "vpp")
  70                 star = "*";
  71         else
  72                 star = "";
  73         if (lockdata[name, arg, pos] && (lockdata[name, arg, pos] != "-")) {
  74                 printc(ind"ASSERT_VI_UNLOCKED("star"a->a_"arg", \""uname"\");");
  75                 # Add assertions for locking
  76                 if (lockdata[name, arg, pos] == "L")
  77                         printc(ind"ASSERT_VOP_LOCKED(" star "a->a_"arg", \""uname"\");");
  78                 else if (lockdata[name, arg, pos] == "U")
  79                         printc(ind"ASSERT_VOP_UNLOCKED(" star "a->a_"arg", \""uname"\");");
  80                 else if (lockdata[name, arg, pos] == "E")
  81                         printc(ind"ASSERT_VOP_ELOCKED(" star "a->a_"arg", \""uname"\");");
  82                 else if (0) {
  83                         # XXX More checks!
  84                 }
  85         }
  86 }
  87
  88 function add_pre(name)
  89 {
  90         if (lockdata[name, "pre"]) {
  91                 printc("\t"lockdata[name, "pre"]"(a);");
  92         }
  93 }
  94
  95 function add_post(name)
  96 {
  97         if (lockdata[name, "post"]) {
  98                 printc("\t"lockdata[name, "post"]"(a, rc);");
  99         }
 100 }
 101
 102 function find_arg_with_type (type)
 103 {
 104         for (jj = 0; jj < numargs; jj++) {
 105                 if (types[jj] == type) {
 106                         return "VOPARG_OFFSETOF(struct " \
 107                             name "_args,a_" args[jj] ")";
 108                 }
 109         }
 110
 111         return "VDESC_NO_OFFSET";
 112 }
 113
 114 BEGIN{
 115
 116 # Process the command line
 117 for (i = 1; i < ARGC; i++) {
 118         arg = ARGV[i];
 119         if (arg !~ /^-[chpq]+$/ && arg !~ /\.src$/)
 120                 usage();
 121         if (arg ~ /^-.*c/)
 122                 cfile = "vnode_if.c";
 123         if (arg ~ /^-.*h/)
 124                 hfile = "vnode_if.h";
 125         if (arg ~ /^-.*p/)
 126                 pfile = "vnode_if_newproto.h";
 127         if (arg ~ /^-.*q/)
 128                 qfile = "vnode_if_typedef.h";
 129         if (arg ~ /\.src$/)
 130                 srcfile = arg;
 131 }
 132 ARGC = 1;
 133
 134 if (!cfile && !hfile && !pfile && !qfile)
 135         exit 0;
 136
 137 if (!srcfile)
 138         usage();
 139
 140 common_head = \
 141     "/*\n" \
 142     " * This file is produced automatically.\n" \
 143     " * Do not modify anything in here by hand.\n" \
 144     " *\n" \
 145     " * Created from $FreeBSD$\n" \
 146     " */\n" \
 147     "\n";
 148
 149 if (pfile) {
 150         printp(common_head)
 151         printp("struct vop_vector {")
 152         printp("\tstruct vop_vector\t*vop_default;")
 153         printp("\tvop_bypass_t\t*vop_bypass;")
 154 }
 155
 156 if (qfile) {
 157         printq(common_head)
 158 }
 159
 160 if (hfile) {
 161         printh(common_head "extern struct vnodeop_desc vop_default_desc;");
 162         printh("#include \"vnode_if_typedef.h\"")
 163         printh("#include \"vnode_if_newproto.h\"")
 164 }
 165
 166 if (cfile) {
 167         printc(common_head \
 168             "#include <sys/param.h>\n" \
 169             "#include <sys/event.h>\n" \
 170             "#include <sys/kernel.h>\n" \
 171             "#include <sys/mount.h>\n" \
 172             "#include <sys/sdt.h>\n" \
 173             "#include <sys/signalvar.h>\n" \
 174             "#include <sys/systm.h>\n" \
 175             "#include <sys/vnode.h>\n" \
 176             "\n" \
 177             "SDT_PROVIDER_DECLARE(vfs);\n" \
 178             "\n" \
 179             "struct vnodeop_desc vop_default_desc = {\n" \
 180             "   \"default\",\n" \
 181             "   0,\n" \
 182             "   (vop_bypass_t *)vop_panic,\n" \
 183             "   NULL,\n" \
 184             "   VDESC_NO_OFFSET,\n" \
 185             "   VDESC_NO_OFFSET,\n" \
 186             "   VDESC_NO_OFFSET,\n" \
 187             "   VDESC_NO_OFFSET,\n" \
 188             "};\n");
 189 }
 190
 191 while ((getline < srcfile) > 0) {
 192         fnr++;
 193         if (NF == 0)
 194                 continue;
 195         if ($1 ~ /^%%/) {
 196                 if (NF != 6 ||
 197                     $2 !~ /^[a-z_]+$/  ||  $3 !~ /^[a-z]+$/  ||
 198                     $4 !~ /^.$/  ||  $5 !~ /^.$/  ||  $6 !~ /^.$/) {
 199                         die("Invalid %s construction", "%%");
 200                         continue;
 201                 }
 202                 lockdata["vop_" $2, $3, "Entry"] = $4;
 203                 lockdata["vop_" $2, $3, "OK"]    = $5;
 204                 lockdata["vop_" $2, $3, "Error"] = $6;
 205                 continue;
 206         }
 207
 208         if ($1 ~ /^%!/) {
 209                 if (NF != 4 ||
 210                     ($3 != "pre" && $3 != "post")) {
 211                         die("Invalid %s construction", "%!");
 212                         continue;
 213                 }
 214                 lockdata["vop_" $2, $3] = $4;
 215                 continue;
 216         }
 217         if ($1 ~ /^#/)
 218                 continue;
 219
 220         # Get the function name.
 221         name = $1;
 222         uname = toupper(name);
 223
 224         # Get the function arguments.
 225         for (numargs = 0; ; ++numargs) {
 226                 if ((getline < srcfile) <= 0) {
 227                         die("Unable to read through the arguments for \"%s\"",
 228                             name);
 229                 }
 230                 fnr++;
 231                 if ($1 ~ /^\};/)
 232                         break;
 233
 234                 # Delete comments, if any.
 235                 gsub (/\/\*.*\*\//, "");
 236
 237                 # Condense whitespace and delete leading/trailing space.
 238                 gsub(/[[:space:]]+/, " ");
 239                 sub(/^ /, "");
 240                 sub(/ $/, "");
 241
 242                 # Pick off direction.
 243                 if ($1 != "INOUT" && $1 != "IN" && $1 != "OUT")
 244                         die("No IN/OUT direction for \"%s\".", $0);
 245                 dirs[numargs] = $1;
 246                 sub(/^[A-Z]* /, "");
 247
 248                 if ((reles[numargs] = $1) == "WILLRELE")
 249                         sub(/^[A-Z]* /, "");
 250                 else
 251                         reles[numargs] = "WONTRELE";
 252
 253                 # kill trailing ;
 254                 if (sub(/;$/, "") < 1)
 255                         die("Missing end-of-line ; in \"%s\".", $0);
 256
 257                 # pick off variable name
 258                 if ((argp = match($0, /[A-Za-z0-9_]+$/)) < 1)
 259                         die("Missing var name \"a_foo\" in \"%s\".", $0);
 260                 args[numargs] = substr($0, argp);
 261                 $0 = substr($0, 1, argp - 1);
 262
 263                 # what is left must be type
 264                 # remove trailing space (if any)
 265                 sub(/ $/, "");
 266                 types[numargs] = $0;
 267         }
 268         if (numargs > 4)
 269                 ctrargs = 4;
 270         else
 271                 ctrargs = numargs;
 272         ctrstr = ctrargs "(KTR_VOP, \"VOP\", \"" uname "\", (uintptr_t)a,\n\t    ";
 273         ctrstr = ctrstr "\"" args[0] ":0x%jX\", (uintptr_t)a->a_" args[0];
 274         for (i = 1; i < ctrargs; ++i)
 275                 ctrstr = ctrstr ", \"" args[i] ":0x%jX\", a->a_" args[i];
 276         ctrstr = ctrstr ");";
 277
 278         if (pfile) {
 279                 printp("\t"name"_t\t*"name";")
 280         }
 281         if (qfile) {
 282                 printq("struct "name"_args;")
 283                 printq("typedef int "name"_t(struct "name"_args *);\n")
 284         }
 285
 286         if (hfile) {
 287                 # Print out the vop_F_args structure.
 288                 printh("struct "name"_args {\n\tstruct vop_generic_args a_gen;");
 289                 for (i = 0; i < numargs; ++i)
 290                         printh("\t" t_spc(types[i]) "a_" args[i] ";");
 291                 printh("};");
 292                 printh("");
 293
 294                 # Print out extern declaration.
 295                 printh("extern struct vnodeop_desc " name "_desc;");
 296                 printh("");
 297
 298                 # Print out function prototypes.
 299                 printh("int " uname "_AP(struct " name "_args *);");
 300                 printh("int " uname "_APV(struct vop_vector *vop, struct " name "_args *);");
 301                 printh("");
 302                 printh("static __inline int " uname "(");
 303                 for (i = 0; i < numargs; ++i) {
 304                         printh("\t" t_spc(types[i]) args[i] \
 305                             (i < numargs - 1 ? "," : ")"));
 306                 }
 307                 printh("{");
 308                 printh("\tstruct " name "_args a;");
 309                 printh("");
 310                 printh("\ta.a_gen.a_desc = &" name "_desc;");
 311                 for (i = 0; i < numargs; ++i)
 312                         printh("\ta.a_" args[i] " = " args[i] ";");
 313                 printh("\treturn (" uname "_APV("args[0]"->v_op, &a));");
 314                 printh("}");
 315
 316                 printh("");
 317         }
 318
 319         if (cfile) {
 320                 # Print out the vop_F_vp_offsets structure.  This all depends
 321                 # on naming conventions and nothing else.
 322                 printc("static int " name "_vp_offsets[] = {");
 323                 # as a side effect, figure out the releflags
 324                 releflags = "";
 325                 vpnum = 0;
 326                 for (i = 0; i < numargs; i++) {
 327                         if (types[i] == "struct vnode *") {
 328                                 printc("\tVOPARG_OFFSETOF(struct " name \
 329                                     "_args,a_" args[i] "),");
 330                                 if (reles[i] == "WILLRELE") {
 331                                         releflags = releflags \
 332                                             "|VDESC_VP" vpnum "_WILLRELE";
 333                                 }
 334                                 vpnum++;
 335                         }
 336                 }
 337
 338                 sub(/^\|/, "", releflags);
 339                 printc("\tVDESC_NO_OFFSET");
 340                 printc("};");
 341
 342                 printc("\n");
 343                 printc("SDT_PROBE_DEFINE2(vfs, vop, " name ", entry, \"struct vnode *\", \"struct " name "_args *\");\n");
 344                 printc("SDT_PROBE_DEFINE3(vfs, vop, " name ", return, \"struct vnode *\", \"struct " name "_args *\", \"int\");\n");
 345
 346                 # Print out function.
 347                 printc("\nint\n" uname "_AP(struct " name "_args *a)");
 348                 printc("{");
 349                 printc("");
 350                 printc("\treturn(" uname "_APV(a->a_" args[0] "->v_op, a));");
 351                 printc("}");
 352                 printc("\nint\n" uname "_APV(struct vop_vector *vop, struct " name "_args *a)");
 353                 printc("{");
 354                 printc("\tint rc;");
 355                 printc("");
 356                 printc("\tVNASSERT(a->a_gen.a_desc == &" name "_desc, a->a_" args[0]",");
 357                 printc("\t    (\"Wrong a_desc in " name "(%p, %p)\", a->a_" args[0]", a));");
 358                 printc("\twhile(vop != NULL && \\");
 359                 printc("\t    vop->"name" == NULL && vop->vop_bypass == NULL)")
 360                 printc("\t\tvop = vop->vop_default;")
 361                 printc("\tVNASSERT(vop != NULL, a->a_" args[0]", (\"No "name"(%p, %p)\", a->a_" args[0]", a));")
 362                 printc("\tSDT_PROBE2(vfs, vop, " name ", entry, a->a_" args[0] ", a);\n");
 363                 for (i = 0; i < numargs; ++i)
 364                         add_debug_code(name, args[i], "Entry", "\t");
 365                 printc("\tKTR_START" ctrstr);
 366                 add_pre(name);
 367                 printc("\tVFS_PROLOGUE(a->a_" args[0]"->v_mount);")
 368                 printc("\tif (vop->"name" != NULL)")
 369                 printc("\t\trc = vop->"name"(a);")
 370                 printc("\telse")
 371                 printc("\t\trc = vop->vop_bypass(&a->a_gen);")
 372                 printc("\tVFS_EPILOGUE(a->a_" args[0]"->v_mount);")
 373                 printc("\tSDT_PROBE3(vfs, vop, " name ", return, a->a_" args[0] ", a, rc);\n");
 374                 printc("\tif (rc == 0) {");
 375                 for (i = 0; i < numargs; ++i)
 376                         add_debug_code(name, args[i], "OK", "\t\t");
 377                 printc("\t} else {");
 378                 for (i = 0; i < numargs; ++i)
 379                         add_debug_code(name, args[i], "Error", "\t\t");
 380                 printc("\t}");
 381                 add_post(name);
 382                 printc("\tKTR_STOP" ctrstr);
 383                 printc("\treturn (rc);");
 384                 printc("}\n");
 385
 386                 # Print out the vnodeop_desc structure.
 387                 printc("struct vnodeop_desc " name "_desc = {");
 388                 # printable name
 389                 printc("\t\"" name "\",");
 390                 # flags
 391                 vppwillrele = "";
 392                 for (i = 0; i < numargs; i++) {
 393                         if (types[i] == "struct vnode **" && \
 394                             reles[i] == "WILLRELE") {
 395                                 vppwillrele = "|VDESC_VPP_WILLRELE";
 396                         }
 397                 }
 398
 399                 if (!releflags)
 400                         releflags = "0";
 401                 printc("\t" releflags vppwillrele ",");
 402
 403                 # function to call
 404                 printc("\t(vop_bypass_t *)" uname "_AP,");
 405                 # vp offsets
 406                 printc("\t" name "_vp_offsets,");
 407                 # vpp (if any)
 408                 printc("\t" find_arg_with_type("struct vnode **") ",");
 409                 # cred (if any)
 410                 printc("\t" find_arg_with_type("struct ucred *") ",");
 411                 # thread (if any)
 412                 printc("\t" find_arg_with_type("struct thread *") ",");
 413                 # componentname
 414                 printc("\t" find_arg_with_type("struct componentname *") ",");
 415                 # transport layer information
 416                 printc("};\n");
 417         }
 418 }
 419
 420 if (pfile)
 421         printp("};")
 422
 423 if (hfile)
 424         close(hfile);
 425 if (cfile)
 426         close(cfile);
 427 if (pfile)
 428         close(pfile);
 429 close(srcfile);
 430
 431 exit 0;
 432
 433 }