sys/tools/fw_stub.awk

   1 #!/usr/bin/awk -f
   2
   3 #-
   4 # Copyright (c) 2006 Max Laier.
   5 # All rights reserved.
   6 #
   7 # Redistribution and use in source and binary forms, with or without
   8 # modification, are permitted provided that the following conditions
   9 # are met:
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 # 2. Redistributions in binary form must reproduce the above copyright
  13 #    notice, this list of conditions and the following disclaimer in the
  14 #    documentation and/or other materials provided with the distribution.
  15 #
  16 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS `AS IS'' AND
  17 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  18 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  19 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  20 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  22 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  23 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  24 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  25 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  26 # SUCH DAMAGE.
  27 #
  28 # $FreeBSD$
  29
  30 #
  31 # Script to generate module .c file from a list of firmware images
  32 #
  33
  34 function usage ()
  35 {
  36         print "usage: fw_stub <firmware:name>* [-l name] [-m modname] [-c outfile]";
  37         exit 1;
  38 }
  39
  40 #   These are just for convenience ...
  41 function printc(s)
  42 {
  43         if (opt_c)
  44                 print s > ctmpfilename;
  45         else
  46                 print s > "/dev/stdout";
  47 }
  48
  49 BEGIN {
  50
  51 #
  52 #   Process the command line.
  53 #
  54
  55 num_files = 0;
  56
  57 for (i = 1; i < ARGC; i++) {
  58         if (ARGV[i] ~ /^-/) {
  59                 #
  60                 #   awk doesn't have getopt(), so we have to do it ourselves.
  61                 #   This is a bit clumsy, but it works.
  62                 #
  63                 for (j = 2; j <= length(ARGV[i]); j++) {
  64                         o = substr(ARGV[i], j, 1);
  65                         if (o == "c") {
  66                                 if (length(ARGV[i]) > j) {
  67                                         opt_c = substr(ARGV[i], j + 1);
  68                                         break;
  69                                 }
  70                                 else {
  71                                         if (++i < ARGC)
  72                                                 opt_c = ARGV[i];
  73                                         else
  74                                                 usage();
  75                                 }
  76                         } else if (o == "m") {
  77                                 if (length(ARGV[i]) > j) {
  78                                         opt_m = substr(ARGV[i], j + 1);
  79                                         break;
  80                                 }
  81                                 else {
  82                                         if (++i < ARGC)
  83                                                 opt_m = ARGV[i];
  84                                         else
  85                                                 usage();
  86                                 }
  87                         } else if (o == "l") {
  88                                 if (length(ARGV[i]) > j) {
  89                                         opt_l = substr(ARGV[i], j + 1);
  90                                         break;
  91                                 }
  92                                 else {
  93                                         if (++i < ARGC)
  94                                                 opt_l = ARGV[i];
  95                                         else
  96                                                 usage();
  97                                 }
  98                         } else
  99                                 usage();
 100                 }
 101         } else {
 102                 split(ARGV[i], curr, ":");
 103                 filenames[num_files] = curr[1];
 104                 if (length(curr[2]) > 0)
 105                         shortnames[num_files] = curr[2];
 106                 else
 107                         shortnames[num_files] = curr[1];
 108                 if (length(curr[3]) > 0)
 109                         versions[num_files] = int(curr[3]);
 110                 else
 111                         versions[num_files] = 0;
 112                 num_files++;
 113         }
 114 }
 115
 116 if (!num_files || !opt_m)
 117         usage();
 118
 119 cfilename = opt_c;
 120 ctmpfilename = cfilename ".tmp";
 121 modname = opt_m;
 122 gsub(/[-\.]/, "_", modname);
 123
 124 printc("/*\
 125  * Automatically generated by:\
 126  * $FreeBSD$\
 127  */");
 128 printc("#include <sys/param.h>");
 129 printc("#include <sys/errno.h>");
 130 printc("#include <sys/kernel.h>");
 131 printc("#include <sys/module.h>");
 132 printc("#include <sys/linker.h>");
 133 printc("#include <sys/firmware.h>");
 134 printc("#include <sys/systm.h>\n");
 135
 136 if (opt_l) {
 137         printc("static long " opt_l "_license_ack = 0;");
 138 }
 139
 140 for (file_i = 0; file_i < num_files; file_i++) {
 141         symb = filenames[file_i];
 142         # '-', '.' and '/' are converted to '_' by ld/objcopy
 143         gsub(/-|\.|\//, "_", symb);
 144         printc("extern char _binary_" symb "_start[], _binary_" symb "_end[];");
 145 }
 146
 147 printc("\nstatic int\n"\
 148 modname "_fw_modevent(module_t mod, int type, void *unused)\
 149 {\
 150         const struct firmware *fp, *parent;\
 151         int error;\
 152         switch (type) {\
 153         case MOD_LOAD:\n");
 154
 155 if (opt_l) {
 156                 printc("\
 157                 TUNABLE_LONG_FETCH(\"legal." opt_l ".license_ack\", &" opt_l "_license_ack);\
 158                 if (!" opt_l "_license_ack) {\
 159                         printf(\"" opt_m ": You need to read the LICENSE file in /usr/share/doc/legal/" opt_l ".LICENSE.\\n\");\
 160                         printf(\"" opt_m ": If you agree with the license, set legal." opt_l ".license_ack=1 in /boot/loader.conf.\\n\");\
 161                         return(EPERM);\
 162                 }\n");
 163 }
 164
 165 for (file_i = 0; file_i < num_files; file_i++) {
 166         short = shortnames[file_i];
 167         symb = filenames[file_i];
 168         version = versions[file_i];
 169         # '-', '.' and '/' are converted to '_' by ld/objcopy
 170         gsub(/-|\.|\//, "_", symb);
 171
 172         reg = "\t\tfp = ";
 173         reg = reg "firmware_register(\"" short "\", _binary_" symb "_start , ";
 174         reg = reg "(size_t)(_binary_" symb "_end - _binary_" symb "_start), ";
 175         reg = reg version ", ";
 176
 177         if (file_i == 0)
 178                 reg = reg "NULL);";
 179         else
 180                 reg = reg "parent);";
 181
 182         printc(reg);
 183
 184         printc("\t\tif (fp == NULL)");
 185         printc("\t\t\tgoto fail_" file_i ";");
 186         if (file_i == 0)
 187                 printc("\t\tparent = fp;");
 188 }
 189
 190 printc("\t\treturn (0);");
 191
 192 for (file_i = num_files - 1; file_i > 0; file_i--) {
 193         printc("fail_" file_i ":")
 194         printc("\t\t(void)firmware_unregister(\"" shortnames[file_i - 1] "\");");
 195 }
 196
 197 printc("\tfail_0:");
 198 printc("\t\treturn (ENXIO);");
 199
 200 printc("\tcase MOD_UNLOAD:");
 201
 202 for (file_i = 1; file_i < num_files; file_i++) {
 203         printc("\t\terror = firmware_unregister(\"" shortnames[file_i] "\");");
 204         printc("\t\tif (error)");
 205         printc("\t\t\treturn (error);");
 206 }
 207
 208 printc("\t\terror = firmware_unregister(\"" shortnames[0] "\");");
 209
 210 printc("\t\treturn (error);\
 211         }\
 212         return (EINVAL);\
 213 }\
 214 \
 215 static moduledata_t " modname "_fw_mod = {\
 216         \"" modname "_fw\",\
 217         " modname "_fw_modevent,\
 218         0\
 219 };\
 220 DECLARE_MODULE(" modname "_fw, " modname "_fw_mod, SI_SUB_DRIVERS, SI_ORDER_FIRST);\
 221 MODULE_VERSION(" modname "_fw, 1);\
 222 MODULE_DEPEND(" modname "_fw, firmware, 1, 1, 1);\
 223 ");
 224
 225 if (opt_c)
 226         if ((rc = system("mv -f " ctmpfilename " " cfilename))) {
 227                 print "'mv -f " ctmpfilename " " cfilename "' failed: " rc \
 228                     > "/dev/stderr";
 229                 exit 1;
 230         }
 231
 232 exit 0;
 233
 234 }