CMakeLists.txt

   1 # 3.1 is OK for most parts. However:
   2 # 3.3 is needed in src/libFLAC
   3 # 3.5 is needed in src/libFLAC/ia32
   4 # 3.9 is needed in 'doc' because of doxygen_add_docs()
   5 cmake_minimum_required(VERSION 3.5)
   6
   7 if(NOT (CMAKE_BUILD_TYPE OR CMAKE_CONFIGURATION_TYPES OR DEFINED ENV{CFLAGS} OR DEFINED ENV{CXXFLAGS}))
   8     set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build, options are: None Debug Release RelWithDebInfo")
   9 endif()
  10
  11 project(FLAC VERSION 1.3.3) # HOMEPAGE_URL "https://www.xiph.org/flac/")
  12
  13 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  14
  15 option(BUILD_CXXLIBS "Build libFLAC++" ON)
  16 option(BUILD_PROGRAMS "Build and install programs" ON)
  17 option(BUILD_EXAMPLES "Build and install examples" ON)
  18 option(BUILD_DOCS "Build and install doxygen documents" ON)
  19 option(WITH_STACK_PROTECTOR "Enable GNU GCC stack smash protection" ON)
  20 option(INSTALL_MANPAGES "Install MAN pages" ON)
  21 option(INSTALL_PKGCONFIG_MODULES "Install PkgConfig modules" ON)
  22 option(INSTALL_CMAKE_CONFIG_MODULE "Install CMake package-config module" ON)
  23 option(WITH_OGG "ogg support (default: test for libogg)" ON)
  24
  25 if(WITH_OGG)
  26     find_package(OGG REQUIRED)
  27 endif()
  28
  29 find_package(Iconv)
  30 set(HAVE_ICONV ${Iconv_FOUND})
  31
  32 if(CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
  33     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations -Winline")
  34     set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -O3 -funroll-loops")
  35 endif()
  36 if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  37     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef")
  38 endif()
  39 if(CMAKE_C_COMPILER_ID MATCHES "GNU")
  40     set(CMAKE_EXE_LINKER_FLAGS -no-pie)
  41 endif()
  42
  43 include(CMakePackageConfigHelpers)
  44 include(CPack)
  45 include(CTest)
  46 include(CheckCCompilerFlag)
  47 include(CheckCXXCompilerFlag)
  48 include(CheckSymbolExists)
  49 include(CheckFunctionExists)
  50 include(CheckIncludeFile)
  51 include(CheckCSourceCompiles)
  52 include(CheckCXXSourceCompiles)
  53 include(GNUInstallDirs)
  54 include(UseSystemExtensions)
  55 include(TestBigEndian)
  56
  57 check_include_file("byteswap.h" HAVE_BYTESWAP_H)
  58 check_include_file("inttypes.h" HAVE_INTTYPES_H)
  59 check_include_file("stdint.h" HAVE_STDINT_H)
  60 check_include_file("x86intrin.h" FLAC__HAS_X86INTRIN)
  61
  62 check_function_exists(fseeko HAVE_FSEEKO)
  63
  64 check_c_source_compiles("int main() { return __builtin_bswap16 (0) ; }" HAVE_BSWAP16)
  65 check_c_source_compiles("int main() { return __builtin_bswap32 (0) ; }" HAVE_BSWAP32)
  66
  67 test_big_endian(CPU_IS_BIG_ENDIAN)
  68
  69 check_c_compiler_flag(-Werror HAVE_WERROR_FLAG)
  70 check_c_compiler_flag(-Wdeclaration-after-statement HAVE_DECL_AFTER_STMT_FLAG)
  71 check_c_compiler_flag(-mstackrealign HAVE_STACKREALIGN_FLAG)
  72 check_cxx_compiler_flag(-Weffc++ HAVE_WEFFCXX_FLAG)
  73
  74 if(WITH_STACK_PROTECTOR)
  75   if(NOT MSVC)
  76     check_c_compiler_flag("-fstack-protector-strong" HAVE_STACK_PROTECTOR_FLAG)
  77   endif()
  78 endif()
  79
  80 if(HAVE_WERROR_FLAG)
  81     option(ENABLE_WERROR "Enable -Werror in all Makefiles" OFF)
  82 endif()
  83
  84 add_compile_options(
  85     $<$<BOOL:${MSVC}>:/wd4267>
  86     $<$<BOOL:${MSVC}>:/wd4996>
  87     $<$<BOOL:${ENABLE_WERROR}>:-Werror>
  88     $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<BOOL:${HAVE_WEFFCXX_FLAG}>>:-Weffc++>
  89     $<$<AND:$<COMPILE_LANGUAGE:C>,$<BOOL:${HAVE_DECL_AFTER_STMT_FLAG}>>:-Wdeclaration-after-statement>)
  90
  91 if(HAVE_STACK_PROTECTOR_FLAG)
  92     add_compile_options(-fstack-protector-strong)
  93 endif()
  94
  95 if(CMAKE_SYSTEM_PROCESSOR STREQUAL "i686" AND HAVE_STACKREALIGN_FLAG)
  96     add_compile_options(-mstackrealign)
  97 endif()
  98
  99 include_directories("include")
 100
 101 include_directories("${CMAKE_CURRENT_BINARY_DIR}")
 102 add_definitions(-DHAVE_CONFIG_H)
 103
 104 if(MSVC)
 105     add_definitions(
 106         -D_CRT_SECURE_NO_WARNINGS
 107         -D_USE_MATH_DEFINES)
 108 endif()
 109 if(CMAKE_BUILD_TYPE STREQUAL Debug OR CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo)
 110     add_definitions(-DFLAC__OVERFLOW_DETECT)
 111 endif()
 112
 113 add_subdirectory("src")
 114 add_subdirectory("microbench")
 115 if(BUILD_DOCS)
 116     add_subdirectory("doc")
 117 endif()
 118 if(BUILD_EXAMPLES)
 119     add_subdirectory("examples")
 120 endif()
 121 if(BUILD_TESTING)
 122     add_subdirectory("test")
 123 endif()
 124
 125 configure_file(config.cmake.h.in config.h)
 126
 127 if(INSTALL_CMAKE_CONFIG_MODULE)
 128     install(
 129         EXPORT targets
 130         DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake"
 131         NAMESPACE FLAC::)
 132
 133     configure_package_config_file(
 134         flac-config.cmake.in flac-config.cmake
 135         INSTALL_DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake")
 136     write_basic_package_version_file(
 137         flac-config-version.cmake COMPATIBILITY AnyNewerVersion)
 138
 139     install(
 140         FILES
 141             "${CMAKE_CURRENT_BINARY_DIR}/flac-config.cmake"
 142             "${CMAKE_CURRENT_BINARY_DIR}/flac-config-version.cmake"
 143             "cmake/FindOGG.cmake"
 144         DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake")
 145 endif()
 146
 147 file(GLOB FLAC_HEADERS "include/FLAC/*.h")
 148 file(GLOB FLAC++_HEADERS "include/FLAC++/*.h")
 149 install(FILES ${FLAC_HEADERS} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/FLAC")
 150 install(FILES ${FLAC++_HEADERS} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/FLAC++")
 151 if(INSTALL_MANPAGES)
 152     install(FILES "man/flac.1" "man/metaflac.1" DESTINATION "${CMAKE_INSTALL_MANDIR}")
 153 endif()