arch/i386/kernel/head.S

   1 /*
   2  *  linux/arch/i386/kernel/head.S -- the 32-bit startup code.
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *
   6  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   7  *  and Martin Mares, November 1997.
   8  */
   9
  10 .text
  11 #include <linux/threads.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page.h>
  15 #include <asm/pgtable.h>
  16 #include <asm/desc.h>
  17 #include <asm/cache.h>
  18 #include <asm/thread_info.h>
  19 #include <asm/asm-offsets.h>
  20 #include <asm/setup.h>
  21
  22 /*
  23  * References to members of the new_cpu_data structure.
  24  */
  25
  26 #define X86             new_cpu_data+CPUINFO_x86
  27 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  28 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  29 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  30 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  31 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  32 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  33 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  34
  35 /*
  36  * This is how much memory *in addition to the memory covered up to
  37  * and including _end* we need mapped initially.  We need one bit for
  38  * each possible page, but only in low memory, which means
  39  * 2^32/4096/8 = 128K worst case (4G/4G split.)
  40  *
  41  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  42  * memory, which is currently unreclaimed.
  43  *
  44  * This should be a multiple of a page.
  45  */
  46 #define INIT_MAP_BEYOND_END     (128*1024)
  47
  48
  49 /*
  50  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  51  * %esi points to the real-mode code as a 32-bit pointer.
  52  * CS and DS must be 4 GB flat segments, but we don't depend on
  53  * any particular GDT layout, because we load our own as soon as we
  54  * can.
  55  */
  56 ENTRY(startup_32)
  57
  58 /*
  59  * Set segments to known values.
  60  */
  61         cld
  62         lgdt boot_gdt_descr - __PAGE_OFFSET
  63         movl $(__BOOT_DS),%eax
  64         movl %eax,%ds
  65         movl %eax,%es
  66         movl %eax,%fs
  67         movl %eax,%gs
  68
  69 /*
  70  * Clear BSS first so that there are no surprises...
  71  * No need to cld as DF is already clear from cld above...
  72  */
  73         xorl %eax,%eax
  74         movl $__bss_start - __PAGE_OFFSET,%edi
  75         movl $__bss_stop - __PAGE_OFFSET,%ecx
  76         subl %edi,%ecx
  77         shrl $2,%ecx
  78         rep ; stosl
  79 /*
  80  * Copy bootup parameters out of the way.
  81  * Note: %esi still has the pointer to the real-mode data.
  82  * With the kexec as boot loader, parameter segment might be loaded beyond
  83  * kernel image and might not even be addressable by early boot page tables.
  84  * (kexec on panic case). Hence copy out the parameters before initializing
  85  * page tables.
  86  */
  87         movl $(boot_params - __PAGE_OFFSET),%edi
  88         movl $(PARAM_SIZE/4),%ecx
  89         cld
  90         rep
  91         movsl
  92         movl boot_params - __PAGE_OFFSET + NEW_CL_POINTER,%esi
  93         andl %esi,%esi
  94         jnz 2f                  # New command line protocol
  95         cmpw $(OLD_CL_MAGIC),OLD_CL_MAGIC_ADDR
  96         jne 1f
  97         movzwl OLD_CL_OFFSET,%esi
  98         addl $(OLD_CL_BASE_ADDR),%esi
  99 2:
 100         movl $(saved_command_line - __PAGE_OFFSET),%edi
 101         movl $(COMMAND_LINE_SIZE/4),%ecx
 102         rep
 103         movsl
 104 1:
 105
 106 /*
 107  * Initialize page tables.  This creates a PDE and a set of page
 108  * tables, which are located immediately beyond _end.  The variable
 109  * init_pg_tables_end is set up to point to the first "safe" location.
 110  * Mappings are created both at virtual address 0 (identity mapping)
 111  * and PAGE_OFFSET for up to _end+sizeof(page tables)+INIT_MAP_BEYOND_END.
 112  *
 113  * Warning: don't use %esi or the stack in this code.  However, %esp
 114  * can be used as a GPR if you really need it...
 115  */
 116 page_pde_offset = (__PAGE_OFFSET >> 20);
 117
 118         movl $(pg0 - __PAGE_OFFSET), %edi
 119         movl $(swapper_pg_dir - __PAGE_OFFSET), %edx
 120         movl $0x007, %eax                       /* 0x007 = PRESENT+RW+USER */
 121 10:
 122         leal 0x007(%edi),%ecx                   /* Create PDE entry */
 123         movl %ecx,(%edx)                        /* Store identity PDE entry */
 124         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 125         addl $4,%edx
 126         movl $1024, %ecx
 127 11:
 128         stosl
 129         addl $0x1000,%eax
 130         loop 11b
 131         /* End condition: we must map up to and including INIT_MAP_BEYOND_END */
 132         /* bytes beyond the end of our own page tables; the +0x007 is the attribute bits */
 133         leal (INIT_MAP_BEYOND_END+0x007)(%edi),%ebp
 134         cmpl %ebp,%eax
 135         jb 10b
 136         movl %edi,(init_pg_tables_end - __PAGE_OFFSET)
 137
 138 #ifdef CONFIG_SMP
 139         xorl %ebx,%ebx                          /* This is the boot CPU (BSP) */
 140         jmp 3f
 141
 142 /*
 143  * Non-boot CPU entry point; entered from trampoline.S
 144  * We can't lgdt here, because lgdt itself uses a data segment, but
 145  * we know the trampoline has already loaded the boot_gdt_table GDT
 146  * for us.
 147  */
 148 ENTRY(startup_32_smp)
 149         cld
 150         movl $(__BOOT_DS),%eax
 151         movl %eax,%ds
 152         movl %eax,%es
 153         movl %eax,%fs
 154         movl %eax,%gs
 155
 156 /*
 157  *      New page tables may be in 4Mbyte page mode and may
 158  *      be using the global pages.
 159  *
 160  *      NOTE! If we are on a 486 we may have no cr4 at all!
 161  *      So we do not try to touch it unless we really have
 162  *      some bits in it to set.  This won't work if the BSP
 163  *      implements cr4 but this AP does not -- very unlikely
 164  *      but be warned!  The same applies to the pse feature
 165  *      if not equally supported. --macro
 166  *
 167  *      NOTE! We have to correct for the fact that we're
 168  *      not yet offset PAGE_OFFSET..
 169  */
 170 #define cr4_bits mmu_cr4_features-__PAGE_OFFSET
 171         movl cr4_bits,%edx
 172         andl %edx,%edx
 173         jz 6f
 174         movl %cr4,%eax          # Turn on paging options (PSE,PAE,..)
 175         orl %edx,%eax
 176         movl %eax,%cr4
 177
 178         btl $5, %eax            # check if PAE is enabled
 179         jnc 6f
 180
 181         /* Check if extended functions are implemented */
 182         movl $0x80000000, %eax
 183         cpuid
 184         cmpl $0x80000000, %eax
 185         jbe 6f
 186         mov $0x80000001, %eax
 187         cpuid
 188         /* Execute Disable bit supported? */
 189         btl $20, %edx
 190         jnc 6f
 191
 192         /* Setup EFER (Extended Feature Enable Register) */
 193         movl $0xc0000080, %ecx
 194         rdmsr
 195
 196         btsl $11, %eax
 197         /* Make changes effective */
 198         wrmsr
 199
 200 6:
 201         /* This is a secondary processor (AP) */
 202         xorl %ebx,%ebx
 203         incl %ebx
 204
 205 3:
 206 #endif /* CONFIG_SMP */
 207
 208 /*
 209  * Enable paging
 210  */
 211         movl $swapper_pg_dir-__PAGE_OFFSET,%eax
 212         movl %eax,%cr3          /* set the page table pointer.. */
 213         movl %cr0,%eax
 214         orl $0x80000000,%eax
 215         movl %eax,%cr0          /* ..and set paging (PG) bit */
 216         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 217 1:
 218         /* Set up the stack pointer */
 219         lss stack_start,%esp
 220
 221 /*
 222  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 223  * confuse the debugger if this code is traced.
 224  * XXX - best to initialize before switching to protected mode.
 225  */
 226         pushl $0
 227         popfl
 228
 229 #ifdef CONFIG_SMP
 230         andl %ebx,%ebx
 231         jz  1f                          /* Initial CPU cleans BSS */
 232         jmp checkCPUtype
 233 1:
 234 #endif /* CONFIG_SMP */
 235
 236 /*
 237  * start system 32-bit setup. We need to re-do some of the things done
 238  * in 16-bit mode for the "real" operations.
 239  */
 240         call setup_idt
 241
 242 checkCPUtype:
 243
 244         movl $-1,X86_CPUID              #  -1 for no CPUID initially
 245
 246 /* check if it is 486 or 386. */
 247 /*
 248  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 249  * apply at our cpl of 0 and the stack ought to be aligned already, and
 250  * we don't need to preserve eflags.
 251  */
 252
 253         movb $3,X86             # at least 386
 254         pushfl                  # push EFLAGS
 255         popl %eax               # get EFLAGS
 256         movl %eax,%ecx          # save original EFLAGS
 257         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 258         pushl %eax              # copy to EFLAGS
 259         popfl                   # set EFLAGS
 260         pushfl                  # get new EFLAGS
 261         popl %eax               # put it in eax
 262         xorl %ecx,%eax          # change in flags
 263         pushl %ecx              # restore original EFLAGS
 264         popfl
 265         testl $0x40000,%eax     # check if AC bit changed
 266         je is386
 267
 268         movb $4,X86             # at least 486
 269         testl $0x200000,%eax    # check if ID bit changed
 270         je is486
 271
 272         /* get vendor info */
 273         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 274         cpuid
 275         movl %eax,X86_CPUID             # save CPUID level
 276         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 277         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 278         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 279
 280         orl %eax,%eax                   # do we have processor info as well?
 281         je is486
 282
 283         movl $1,%eax            # Use the CPUID instruction to get CPU type
 284         cpuid
 285         movb %al,%cl            # save reg for future use
 286         andb $0x0f,%ah          # mask processor family
 287         movb %ah,X86
 288         andb $0xf0,%al          # mask model
 289         shrb $4,%al
 290         movb %al,X86_MODEL
 291         andb $0x0f,%cl          # mask mask revision
 292         movb %cl,X86_MASK
 293         movl %edx,X86_CAPABILITY
 294
 295 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 296         jmp 2f
 297
 298 is386:  movl $2,%ecx            # set MP
 299 2:      movl %cr0,%eax
 300         andl $0x80000011,%eax   # Save PG,PE,ET
 301         orl %ecx,%eax
 302         movl %eax,%cr0
 303
 304         call check_x87
 305         call setup_pda
 306         lgdt cpu_gdt_descr
 307         lidt idt_descr
 308         ljmp $(__KERNEL_CS),$1f
 309 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 310         movl %eax,%ss                   # after changing gdt.
 311
 312         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 313         movl %eax,%ds
 314         movl %eax,%es
 315
 316         xorl %eax,%eax                  # Clear FS and LDT
 317         movl %eax,%fs
 318         lldt %ax
 319
 320         movl $(__KERNEL_PDA),%eax
 321         mov  %eax,%gs
 322
 323         cld                     # gcc2 wants the direction flag cleared at all times
 324         pushl $0                # fake return address for unwinder
 325 #ifdef CONFIG_SMP
 326         movb ready, %cl
 327         movb $1, ready
 328         cmpb $0,%cl             # the first CPU calls start_kernel
 329         jne initialize_secondary # all other CPUs call initialize_secondary
 330 #endif /* CONFIG_SMP */
 331         jmp start_kernel
 332
 333 /*
 334  * We depend on ET to be correct. This checks for 287/387.
 335  */
 336 check_x87:
 337         movb $0,X86_HARD_MATH
 338         clts
 339         fninit
 340         fstsw %ax
 341         cmpb $0,%al
 342         je 1f
 343         movl %cr0,%eax          /* no coprocessor: have to set bits */
 344         xorl $4,%eax            /* set EM */
 345         movl %eax,%cr0
 346         ret
 347         ALIGN
 348 1:      movb $1,X86_HARD_MATH
 349         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 350         ret
 351
 352 /*
 353  * Point the GDT at this CPU's PDA.  On boot this will be
 354  * cpu_gdt_table and boot_pda; for secondary CPUs, these will be
 355  * that CPU's GDT and PDA.
 356  */
 357 setup_pda:
 358         /* get the PDA pointer */
 359         movl start_pda, %eax
 360
 361         /* slot the PDA address into the GDT */
 362         mov cpu_gdt_descr+2, %ecx
 363         mov %ax, (__KERNEL_PDA+0+2)(%ecx)               /* base & 0x0000ffff */
 364         shr $16, %eax
 365         mov %al, (__KERNEL_PDA+4+0)(%ecx)               /* base & 0x00ff0000 */
 366         mov %ah, (__KERNEL_PDA+4+3)(%ecx)               /* base & 0xff000000 */
 367         ret
 368
 369 /*
 370  *  setup_idt
 371  *
 372  *  sets up a idt with 256 entries pointing to
 373  *  ignore_int, interrupt gates. It doesn't actually load
 374  *  idt - that can be done only after paging has been enabled
 375  *  and the kernel moved to PAGE_OFFSET. Interrupts
 376  *  are enabled elsewhere, when we can be relatively
 377  *  sure everything is ok.
 378  *
 379  *  Warning: %esi is live across this function.
 380  */
 381 setup_idt:
 382         lea ignore_int,%edx
 383         movl $(__KERNEL_CS << 16),%eax
 384         movw %dx,%ax            /* selector = 0x0010 = cs */
 385         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 386
 387         lea idt_table,%edi
 388         mov $256,%ecx
 389 rp_sidt:
 390         movl %eax,(%edi)
 391         movl %edx,4(%edi)
 392         addl $8,%edi
 393         dec %ecx
 394         jne rp_sidt
 395
 396 .macro  set_early_handler handler,trapno
 397         lea \handler,%edx
 398         movl $(__KERNEL_CS << 16),%eax
 399         movw %dx,%ax
 400         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 401         lea idt_table,%edi
 402         movl %eax,8*\trapno(%edi)
 403         movl %edx,8*\trapno+4(%edi)
 404 .endm
 405
 406         set_early_handler handler=early_divide_err,trapno=0
 407         set_early_handler handler=early_illegal_opcode,trapno=6
 408         set_early_handler handler=early_protection_fault,trapno=13
 409         set_early_handler handler=early_page_fault,trapno=14
 410
 411         ret
 412
 413 early_divide_err:
 414         xor %edx,%edx
 415         pushl $0        /* fake errcode */
 416         jmp early_fault
 417
 418 early_illegal_opcode:
 419         movl $6,%edx
 420         pushl $0        /* fake errcode */
 421         jmp early_fault
 422
 423 early_protection_fault:
 424         movl $13,%edx
 425         jmp early_fault
 426
 427 early_page_fault:
 428         movl $14,%edx
 429         jmp early_fault
 430
 431 early_fault:
 432         cld
 433 #ifdef CONFIG_PRINTK
 434         movl $(__KERNEL_DS),%eax
 435         movl %eax,%ds
 436         movl %eax,%es
 437         cmpl $2,early_recursion_flag
 438         je hlt_loop
 439         incl early_recursion_flag
 440         movl %cr2,%eax
 441         pushl %eax
 442         pushl %edx              /* trapno */
 443         pushl $fault_msg
 444 #ifdef CONFIG_EARLY_PRINTK
 445         call early_printk
 446 #else
 447         call printk
 448 #endif
 449 #endif
 450 hlt_loop:
 451         hlt
 452         jmp hlt_loop
 453
 454 /* This is the default interrupt "handler" :-) */
 455         ALIGN
 456 ignore_int:
 457         cld
 458 #ifdef CONFIG_PRINTK
 459         pushl %eax
 460         pushl %ecx
 461         pushl %edx
 462         pushl %es
 463         pushl %ds
 464         movl $(__KERNEL_DS),%eax
 465         movl %eax,%ds
 466         movl %eax,%es
 467         cmpl $2,early_recursion_flag
 468         je hlt_loop
 469         incl early_recursion_flag
 470         pushl 16(%esp)
 471         pushl 24(%esp)
 472         pushl 32(%esp)
 473         pushl 40(%esp)
 474         pushl $int_msg
 475 #ifdef CONFIG_EARLY_PRINTK
 476         call early_printk
 477 #else
 478         call printk
 479 #endif
 480         addl $(5*4),%esp
 481         popl %ds
 482         popl %es
 483         popl %edx
 484         popl %ecx
 485         popl %eax
 486 #endif
 487         iret
 488
 489 /*
 490  * Real beginning of normal "text" segment
 491  */
 492 ENTRY(stext)
 493 ENTRY(_stext)
 494
 495 /*
 496  * BSS section
 497  */
 498 .section ".bss.page_aligned","w"
 499 ENTRY(swapper_pg_dir)
 500         .fill 1024,4,0
 501 ENTRY(empty_zero_page)
 502         .fill 4096,1,0
 503
 504 /*
 505  * This starts the data section.
 506  */
 507 .data
 508 ENTRY(start_pda)
 509         .long boot_pda
 510
 511 ENTRY(stack_start)
 512         .long init_thread_union+THREAD_SIZE
 513         .long __BOOT_DS
 514
 515 ready:  .byte 0
 516
 517 early_recursion_flag:
 518         .long 0
 519
 520 int_msg:
 521         .asciz "Unknown interrupt or fault at EIP %p %p %p\n"
 522
 523 fault_msg:
 524         .ascii "Int %d: CR2 %p  err %p  EIP %p  CS %p  flags %p\n"
 525         .asciz "Stack: %p %p %p %p %p %p %p %p\n"
 526
 527 /*
 528  * The IDT and GDT 'descriptors' are a strange 48-bit object
 529  * only used by the lidt and lgdt instructions. They are not
 530  * like usual segment descriptors - they consist of a 16-bit
 531  * segment size, and 32-bit linear address value:
 532  */
 533
 534 .globl boot_gdt_descr
 535 .globl idt_descr
 536
 537         ALIGN
 538 # early boot GDT descriptor (must use 1:1 address mapping)
 539         .word 0                         # 32 bit align gdt_desc.address
 540 boot_gdt_descr:
 541         .word __BOOT_DS+7
 542         .long boot_gdt_table - __PAGE_OFFSET
 543
 544         .word 0                         # 32-bit align idt_desc.address
 545 idt_descr:
 546         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 547         .long idt_table
 548
 549 # boot GDT descriptor (later on used by CPU#0):
 550         .word 0                         # 32 bit align gdt_desc.address
 551 ENTRY(cpu_gdt_descr)
 552         .word GDT_ENTRIES*8-1
 553         .long cpu_gdt_table
 554
 555 /*
 556  * The boot_gdt_table must mirror the equivalent in setup.S and is
 557  * used only for booting.
 558  */
 559         .align L1_CACHE_BYTES
 560 ENTRY(boot_gdt_table)
 561         .fill GDT_ENTRY_BOOT_CS,8,0
 562         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 563         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */
 564
 565 /*
 566  * The Global Descriptor Table contains 28 quadwords, per-CPU.
 567  */
 568         .align L1_CACHE_BYTES
 569 ENTRY(cpu_gdt_table)
 570         .quad 0x0000000000000000        /* NULL descriptor */
 571         .quad 0x0000000000000000        /* 0x0b reserved */
 572         .quad 0x0000000000000000        /* 0x13 reserved */
 573         .quad 0x0000000000000000        /* 0x1b reserved */
 574         .quad 0x0000000000000000        /* 0x20 unused */
 575         .quad 0x0000000000000000        /* 0x28 unused */
 576         .quad 0x0000000000000000        /* 0x33 TLS entry 1 */
 577         .quad 0x0000000000000000        /* 0x3b TLS entry 2 */
 578         .quad 0x0000000000000000        /* 0x43 TLS entry 3 */
 579         .quad 0x0000000000000000        /* 0x4b reserved */
 580         .quad 0x0000000000000000        /* 0x53 reserved */
 581         .quad 0x0000000000000000        /* 0x5b reserved */
 582
 583         .quad 0x00cf9a000000ffff        /* 0x60 kernel 4GB code at 0x00000000 */
 584         .quad 0x00cf92000000ffff        /* 0x68 kernel 4GB data at 0x00000000 */
 585         .quad 0x00cffa000000ffff        /* 0x73 user 4GB code at 0x00000000 */
 586         .quad 0x00cff2000000ffff        /* 0x7b user 4GB data at 0x00000000 */
 587
 588         .quad 0x0000000000000000        /* 0x80 TSS descriptor */
 589         .quad 0x0000000000000000        /* 0x88 LDT descriptor */
 590
 591         /*
 592          * Segments used for calling PnP BIOS have byte granularity.
 593          * They code segments and data segments have fixed 64k limits,
 594          * the transfer segment sizes are set at run time.
 595          */
 596         .quad 0x00409a000000ffff        /* 0x90 32-bit code */
 597         .quad 0x00009a000000ffff        /* 0x98 16-bit code */
 598         .quad 0x000092000000ffff        /* 0xa0 16-bit data */
 599         .quad 0x0000920000000000        /* 0xa8 16-bit data */
 600         .quad 0x0000920000000000        /* 0xb0 16-bit data */
 601
 602         /*
 603          * The APM segments have byte granularity and their bases
 604          * are set at run time.  All have 64k limits.
 605          */
 606         .quad 0x00409a000000ffff        /* 0xb8 APM CS    code */
 607         .quad 0x00009a000000ffff        /* 0xc0 APM CS 16 code (16 bit) */
 608         .quad 0x004092000000ffff        /* 0xc8 APM DS    data */
 609
 610         .quad 0x00c0920000000000        /* 0xd0 - ESPFIX SS */
 611         .quad 0x00cf92000000ffff        /* 0xd8 - PDA */
 612         .quad 0x0000000000000000        /* 0xe0 - unused */
 613         .quad 0x0000000000000000        /* 0xe8 - unused */
 614         .quad 0x0000000000000000        /* 0xf0 - unused */
 615         .quad 0x0000000000000000        /* 0xf8 - GDT entry 31: double-fault TSS */
 616