| blob | e2239361cac3bcce38ddd681b0a835f2392d86df |
1 /*
2 * File: arch/blackfin/mach-common/entry.S
3 * Based on:
4 * Author: Linus Torvalds
5 *
6 * Created: ?
7 * Description: contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all
9 * interrupts and faults that can result in a task-switch.
10 *
11 * Modified:
12 * Copyright 2004-2006 Analog Devices Inc.
13 *
14 * Bugs: Enter bugs at http://blackfin.uclinux.org/
15 *
16 * This program is free software; you can redistribute it and/or modify
17 * it under the terms of the GNU General Public License as published by
18 * the Free Software Foundation; either version 2 of the License, or
19 * (at your option) any later version.
20 *
21 * This program is distributed in the hope that it will be useful,
22 * but WITHOUT ANY WARRANTY; without even the implied warranty of
23 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
24 * GNU General Public License for more details.
25 *
26 * You should have received a copy of the GNU General Public License
27 * along with this program; if not, see the file COPYING, or write
28 * to the Free Software Foundation, Inc.,
29 * 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
30 */
32 /* NOTE: This code handles signal-recognition, which happens every time
33 * after a timer-interrupt and after each system call.
34 */
37 #include <linux/linkage.h>
38 #include <linux/unistd.h>
39 #include <asm/blackfin.h>
40 #include <asm/errno.h>
41 #include <asm/thread_info.h> /* TIF_NEED_RESCHED */
42 #include <asm/asm-offsets.h>
43 #include <asm/trace.h>
45 #include <asm/mach-common/context.S>
47 #if defined(CONFIG_BFIN_SCRATCH_REG_RETN)
48 # define EX_SCRATCH_REG RETN
49 #elif defined(CONFIG_BFIN_SCRATCH_REG_RETE)
50 # define EX_SCRATCH_REG RETE
51 #else
52 # define EX_SCRATCH_REG CYCLES
53 #endif
55 #ifdef CONFIG_EXCPT_IRQ_SYSC_L1
56 .section .l1.text
57 #else
58 .text
59 #endif
61 /* Slightly simplified and streamlined entry point for CPLB misses.
62 * This one does not lower the level to IRQ5, and thus can be used to
63 * patch up CPLB misses on the kernel stack.
64 */
65 ENTRY(_ex_dcplb)
66 #if ANOMALY_05000261
67 /*
68 * Work around an anomaly: if we see a new DCPLB fault, return
69 * without doing anything. Then, if we get the same fault again,
70 * handle it.
71 */
72 p5.l = _last_cplb_fault_retx;
73 p5.h = _last_cplb_fault_retx;
74 r7 = [p5];
75 r6 = retx;
76 [p5] = r6;
77 cc = r6 == r7;
78 if !cc jump _return_from_exception;
79 /* fall through */
80 #endif
81 ENDPROC(_ex_dcplb)
83 ENTRY(_ex_icplb)
84 (R7:6,P5:4) = [sp++];
85 ASTAT = [sp++];
86 SAVE_ALL_SYS
87 call __cplb_hdr;
88 DEBUG_START_HWTRACE(p5, r7)
89 RESTORE_ALL_SYS
90 SP = EX_SCRATCH_REG;
91 rtx;
92 ENDPROC(_ex_icplb)
94 ENTRY(_ex_syscall)
95 DEBUG_START_HWTRACE(p5, r7)
96 (R7:6,P5:4) = [sp++];
97 ASTAT = [sp++];
98 raise 15; /* invoked by TRAP #0, for sys call */
99 sp = EX_SCRATCH_REG;
100 rtx
101 ENDPROC(_ex_syscall)
103 ENTRY(_ex_soft_bp)
104 r7 = retx;
105 r7 += -2;
106 retx = r7;
107 jump.s _ex_trap_c;
108 ENDPROC(_ex_soft_bp)
110 ENTRY(_ex_single_step)
111 r7 = retx;
112 r6 = reti;
113 cc = r7 == r6;
114 if cc jump _return_from_exception
115 r7 = syscfg;
116 bitclr (r7, 0);
117 syscfg = R7;
119 p5.l = lo(IPEND);
120 p5.h = hi(IPEND);
121 r6 = [p5];
122 cc = bittst(r6, 5);
123 if !cc jump _ex_trap_c;
124 p4.l = lo(EVT5);
125 p4.h = hi(EVT5);
126 r6.h = _exception_to_level5;
127 r6.l = _exception_to_level5;
128 r7 = [p4];
129 cc = r6 == r7;
130 if !cc jump _ex_trap_c;
132 ENTRY(_return_from_exception)
133 DEBUG_START_HWTRACE(p5, r7)
134 #if ANOMALY_05000257
135 R7=LC0;
136 LC0=R7;
137 R7=LC1;
138 LC1=R7;
139 #endif
140 (R7:6,P5:4) = [sp++];
141 ASTAT = [sp++];
142 sp = EX_SCRATCH_REG;
143 rtx;
144 ENDPROC(_ex_soft_bp)
146 ENTRY(_handle_bad_cplb)
147 /* To get here, we just tried and failed to change a CPLB
148 * so, handle things in trap_c (C code), by lowering to
149 * IRQ5, just like we normally do. Since this is not a
150 * "normal" return path, we have a do alot of stuff to
151 * the stack to get ready so, we can fall through - we
152 * need to make a CPLB exception look like a normal exception
153 */
155 DEBUG_START_HWTRACE(p5, r7)
156 RESTORE_ALL_SYS
157 [--sp] = ASTAT;
158 [--sp] = (R7:6, P5:4);
160 ENTRY(_ex_replaceable)
161 nop;
163 ENTRY(_ex_trap_c)
164 /* Make sure we are not in a double fault */
165 p4.l = lo(IPEND);
166 p4.h = hi(IPEND);
167 r7 = [p4];
168 CC = BITTST (r7, 5);
169 if CC jump _double_fault;
171 /* Call C code (trap_c) to handle the exception, which most
172 * likely involves sending a signal to the current process.
173 * To avoid double faults, lower our priority to IRQ5 first.
174 */
175 P5.h = _exception_to_level5;
176 P5.l = _exception_to_level5;
177 p4.l = lo(EVT5);
178 p4.h = hi(EVT5);
179 [p4] = p5;
180 csync;
182 /* Disable all interrupts, but make sure level 5 is enabled so
183 * we can switch to that level. Save the old mask. */
184 cli r6;
185 p4.l = _excpt_saved_imask;
186 p4.h = _excpt_saved_imask;
187 [p4] = r6;
188 r6 = 0x3f;
189 sti r6;
191 /* Save the excause into a circular buffer, in case the instruction
192 * which caused this excecptions causes others.
193 */
194 P5.l = _in_ptr_excause;
195 P5.h = _in_ptr_excause;
196 R7 = [P5];
197 R7 += 4;
198 R6 = 0xF;
199 R7 = R7 & R6;
200 [P5] = R7;
201 R6.l = _excause_circ_buf;
202 R6.h = _excause_circ_buf;
203 R7 = R7 + R6;
204 p5 = R7;
205 R6 = SEQSTAT;
206 [P5] = R6;
208 DEBUG_START_HWTRACE(p5, r7)
209 (R7:6,P5:4) = [sp++];
210 ASTAT = [sp++];
211 SP = EX_SCRATCH_REG;
212 raise 5;
213 rtx;
214 ENDPROC(_ex_trap_c)
216 /* We just realized we got an exception, while we were processing a different
217 * exception. This is a unrecoverable event, so crash
218 */
219 ENTRY(_double_fault)
220 /* Turn caches & protection off, to ensure we don't get any more
221 * double exceptions
222 */
224 P4.L = LO(IMEM_CONTROL);
225 P4.H = HI(IMEM_CONTROL);
227 R5 = [P4]; /* Control Register*/
228 BITCLR(R5,ENICPLB_P);
229 SSYNC; /* SSYNC required before writing to IMEM_CONTROL. */
230 .align 8;
231 [P4] = R5;
232 SSYNC;
234 P4.L = LO(DMEM_CONTROL);
235 P4.H = HI(DMEM_CONTROL);
236 R5 = [P4];
237 BITCLR(R5,ENDCPLB_P);
238 SSYNC; /* SSYNC required before writing to DMEM_CONTROL. */
239 .align 8;
240 [P4] = R5;
241 SSYNC;
243 /* Fix up the stack */
244 (R7:6,P5:4) = [sp++];
245 ASTAT = [sp++];
246 SP = EX_SCRATCH_REG;
248 /* We should be out of the exception stack, and back down into
249 * kernel or user space stack
250 */
251 SAVE_ALL_SYS
253 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
254 SP += -12;
255 call _double_fault_c;
256 SP += 12;
257 .L_double_fault_panic:
258 JUMP .L_double_fault_panic
260 ENDPROC(_double_fault)
262 ENTRY(_exception_to_level5)
263 SAVE_ALL_SYS
265 /* Restore interrupt mask. We haven't pushed RETI, so this
266 * doesn't enable interrupts until we return from this handler. */
267 p4.l = _excpt_saved_imask;
268 p4.h = _excpt_saved_imask;
269 r6 = [p4];
270 sti r6;
272 /* Restore the hardware error vector. */
273 P5.h = _evt_ivhw;
274 P5.l = _evt_ivhw;
275 p4.l = lo(EVT5);
276 p4.h = hi(EVT5);
277 [p4] = p5;
278 csync;
280 p2.l = lo(IPEND);
281 p2.h = hi(IPEND);
282 csync;
283 r0 = [p2]; /* Read current IPEND */
284 [sp + PT_IPEND] = r0; /* Store IPEND */
286 /* Pop the excause from the circular buffer and push it on the stack
287 * (in the right place - if you change the location of SEQSTAT, you
288 * must change this offset.
289 */
290 .L_excep_to_5_again:
291 P5.l = _out_ptr_excause;
292 P5.h = _out_ptr_excause;
293 R7 = [P5];
294 R7 += 4;
295 R6 = 0xF;
296 R7 = R7 & R6;
297 [P5] = R7;
298 R6.l = _excause_circ_buf;
299 R6.h = _excause_circ_buf;
300 R7 = R7 + R6;
301 P5 = R7;
302 R1 = [P5];
303 [SP + 8] = r1;
305 r0 = sp; /* stack frame pt_regs pointer argument ==> r0 */
306 SP += -12;
307 call _trap_c;
308 SP += 12;
310 /* See if anything else is in the exception buffer
311 * if there is, process it
312 */
313 P5.l = _out_ptr_excause;
314 P5.h = _out_ptr_excause;
315 P4.l = _in_ptr_excause;
316 P4.h = _in_ptr_excause;
317 R6 = [P5];
318 R7 = [P4];
319 CC = R6 == R7;
320 if ! CC JUMP .L_excep_to_5_again
322 call _ret_from_exception;
323 RESTORE_ALL_SYS
324 rti;
325 ENDPROC(_exception_to_level5)
327 ENTRY(_trap) /* Exception: 4th entry into system event table(supervisor mode)*/
328 /* Since the kernel stack can be anywhere, it's not guaranteed to be
329 * covered by a CPLB. Switch to an exception stack; use RETN as a
330 * scratch register (for want of a better option).
331 */
332 EX_SCRATCH_REG = sp;
333 sp.l = _exception_stack_top;
334 sp.h = _exception_stack_top;
335 /* Try to deal with syscalls quickly. */
336 [--sp] = ASTAT;
337 [--sp] = (R7:6, P5:4);
338 DEBUG_STOP_HWTRACE(p5, r7)
339 r7 = SEQSTAT; /* reason code is in bit 5:0 */
340 r6.l = lo(SEQSTAT_EXCAUSE);
341 r6.h = hi(SEQSTAT_EXCAUSE);
342 r7 = r7 & r6;
343 p5.h = _ex_table;
344 p5.l = _ex_table;
345 p4 = r7;
346 p5 = p5 + (p4 << 2);
347 p4 = [p5];
348 jump (p4);
350 .Lbadsys:
351 r7 = -ENOSYS; /* signextending enough */
352 [sp + PT_R0] = r7; /* return value from system call */
353 jump .Lsyscall_really_exit;
354 ENDPROC(_trap)
356 ENTRY(_kernel_execve)
357 link SIZEOF_PTREGS;
358 p0 = sp;
359 r3 = SIZEOF_PTREGS / 4;
360 r4 = 0(x);
361 0:
362 [p0++] = r4;
363 r3 += -1;
364 cc = r3 == 0;
365 if !cc jump 0b (bp);
367 p0 = sp;
368 sp += -16;
369 [sp + 12] = p0;
370 call _do_execve;
371 SP += 16;
372 cc = r0 == 0;
373 if ! cc jump 1f;
374 /* Success. Copy our temporary pt_regs to the top of the kernel
375 * stack and do a normal exception return.
376 */
377 r1 = sp;
378 r0 = (-KERNEL_STACK_SIZE) (x);
379 r1 = r1 & r0;
380 p2 = r1;
381 p3 = [p2];
382 r0 = KERNEL_STACK_SIZE - 4 (z);
383 p1 = r0;
384 p1 = p1 + p2;
386 p0 = fp;
387 r4 = [p0--];
388 r3 = SIZEOF_PTREGS / 4;
389 0:
390 r4 = [p0--];
391 [p1--] = r4;
392 r3 += -1;
393 cc = r3 == 0;
394 if ! cc jump 0b (bp);
396 r0 = (KERNEL_STACK_SIZE - SIZEOF_PTREGS) (z);
397 p1 = r0;
398 p1 = p1 + p2;
399 sp = p1;
400 r0 = syscfg;
401 [SP + PT_SYSCFG] = r0;
402 [p3 + (TASK_THREAD + THREAD_KSP)] = sp;
404 RESTORE_CONTEXT;
405 rti;
406 1:
407 unlink;
408 rts;
409 ENDPROC(_kernel_execve)
411 ENTRY(_system_call)
412 /* Store IPEND */
413 p2.l = lo(IPEND);
414 p2.h = hi(IPEND);
415 csync;
416 r0 = [p2];
417 [sp + PT_IPEND] = r0;
419 /* Store RETS for now */
420 r0 = rets;
421 [sp + PT_RESERVED] = r0;
422 /* Set the stack for the current process */
423 r7 = sp;
424 r6.l = lo(ALIGN_PAGE_MASK);
425 r6.h = hi(ALIGN_PAGE_MASK);
426 r7 = r7 & r6; /* thread_info */
427 p2 = r7;
428 p2 = [p2];
430 [p2+(TASK_THREAD+THREAD_KSP)] = sp;
432 /* Check the System Call */
433 r7 = __NR_syscall;
434 /* System call number is passed in P0 */
435 r6 = p0;
436 cc = r6 < r7;
437 if ! cc jump .Lbadsys;
439 /* are we tracing syscalls?*/
440 r7 = sp;
441 r6.l = lo(ALIGN_PAGE_MASK);
442 r6.h = hi(ALIGN_PAGE_MASK);
443 r7 = r7 & r6;
444 p2 = r7;
445 r7 = [p2+TI_FLAGS];
446 CC = BITTST(r7,TIF_SYSCALL_TRACE);
447 if CC JUMP _sys_trace;
449 /* Execute the appropriate system call */
451 p4 = p0;
452 p5.l = _sys_call_table;
453 p5.h = _sys_call_table;
454 p5 = p5 + (p4 << 2);
455 r0 = [sp + PT_R0];
456 r1 = [sp + PT_R1];
457 r2 = [sp + PT_R2];
458 p5 = [p5];
460 [--sp] = r5;
461 [--sp] = r4;
462 [--sp] = r3;
463 SP += -12;
464 call (p5);
465 SP += 24;
466 [sp + PT_R0] = r0;
468 .Lresume_userspace:
469 r7 = sp;
470 r4.l = lo(ALIGN_PAGE_MASK);
471 r4.h = hi(ALIGN_PAGE_MASK);
472 r7 = r7 & r4; /* thread_info->flags */
473 p5 = r7;
474 .Lresume_userspace_1:
475 /* Disable interrupts. */
476 [--sp] = reti;
477 reti = [sp++];
479 r7 = [p5 + TI_FLAGS];
480 r4.l = lo(_TIF_WORK_MASK);
481 r4.h = hi(_TIF_WORK_MASK);
482 r7 = r7 & r4;
484 .Lsyscall_resched:
485 cc = BITTST(r7, TIF_NEED_RESCHED);
486 if !cc jump .Lsyscall_sigpending;
488 /* Reenable interrupts. */
489 [--sp] = reti;
490 r0 = [sp++];
492 SP += -12;
493 call _schedule;
494 SP += 12;
496 jump .Lresume_userspace_1;
498 .Lsyscall_sigpending:
499 cc = BITTST(r7, TIF_RESTORE_SIGMASK);
500 if cc jump .Lsyscall_do_signals;
501 cc = BITTST(r7, TIF_SIGPENDING);
502 if !cc jump .Lsyscall_really_exit;
503 .Lsyscall_do_signals:
504 /* Reenable interrupts. */
505 [--sp] = reti;
506 r0 = [sp++];
508 r0 = sp;
509 SP += -12;
510 call _do_signal;
511 SP += 12;
513 .Lsyscall_really_exit:
514 r5 = [sp + PT_RESERVED];
515 rets = r5;
516 rts;
517 ENDPROC(_system_call)
519 _sys_trace:
520 call _syscall_trace;
522 /* Execute the appropriate system call */
524 p4 = [SP + PT_P0];
525 p5.l = _sys_call_table;
526 p5.h = _sys_call_table;
527 p5 = p5 + (p4 << 2);
528 r0 = [sp + PT_R0];
529 r1 = [sp + PT_R1];
530 r2 = [sp + PT_R2];
531 r3 = [sp + PT_R3];
532 r4 = [sp + PT_R4];
533 r5 = [sp + PT_R5];
534 p5 = [p5];
536 [--sp] = r5;
537 [--sp] = r4;
538 [--sp] = r3;
539 SP += -12;
540 call (p5);
541 SP += 24;
542 [sp + PT_R0] = r0;
544 call _syscall_trace;
545 jump .Lresume_userspace;
546 ENDPROC(_sys_trace)
548 ENTRY(_resume)
549 /*
550 * Beware - when entering resume, prev (the current task) is
551 * in r0, next (the new task) is in r1.
552 */
553 p0 = r0;
554 p1 = r1;
555 [--sp] = rets;
556 [--sp] = fp;
557 [--sp] = (r7:4, p5:3);
559 /* save usp */
560 p2 = usp;
561 [p0+(TASK_THREAD+THREAD_USP)] = p2;
563 /* save current kernel stack pointer */
564 [p0+(TASK_THREAD+THREAD_KSP)] = sp;
566 /* save program counter */
567 r1.l = _new_old_task;
568 r1.h = _new_old_task;
569 [p0+(TASK_THREAD+THREAD_PC)] = r1;
571 /* restore the kernel stack pointer */
572 sp = [p1+(TASK_THREAD+THREAD_KSP)];
574 /* restore user stack pointer */
575 p0 = [p1+(TASK_THREAD+THREAD_USP)];
576 usp = p0;
578 /* restore pc */
579 p0 = [p1+(TASK_THREAD+THREAD_PC)];
580 jump (p0);
582 /*
583 * Following code actually lands up in a new (old) task.
584 */
586 _new_old_task:
587 (r7:4, p5:3) = [sp++];
588 fp = [sp++];
589 rets = [sp++];
591 /*
592 * When we come out of resume, r0 carries "old" task, becuase we are
593 * in "new" task.
594 */
595 rts;
596 ENDPROC(_resume)
598 ENTRY(_ret_from_exception)
599 p2.l = lo(IPEND);
600 p2.h = hi(IPEND);
602 csync;
603 r0 = [p2];
604 [sp + PT_IPEND] = r0;
606 1:
607 r1 = 0x37(Z);
608 r2 = ~r1;
609 r2.h = 0;
610 r0 = r2 & r0;
611 cc = r0 == 0;
612 if !cc jump 4f; /* if not return to user mode, get out */
614 /* Make sure any pending system call or deferred exception
615 * return in ILAT for this process to get executed, otherwise
616 * in case context switch happens, system call of
617 * first process (i.e in ILAT) will be carried
618 * forward to the switched process
619 */
621 p2.l = lo(ILAT);
622 p2.h = hi(ILAT);
623 r0 = [p2];
624 r1 = (EVT_IVG14 | EVT_IVG15) (z);
625 r0 = r0 & r1;
626 cc = r0 == 0;
627 if !cc jump 5f;
629 /* Set the stack for the current process */
630 r7 = sp;
631 r4.l = lo(ALIGN_PAGE_MASK);
632 r4.h = hi(ALIGN_PAGE_MASK);
633 r7 = r7 & r4; /* thread_info->flags */
634 p5 = r7;
635 r7 = [p5 + TI_FLAGS];
636 r4.l = lo(_TIF_WORK_MASK);
637 r4.h = hi(_TIF_WORK_MASK);
638 r7 = r7 & r4;
639 cc = r7 == 0;
640 if cc jump 4f;
642 p0.l = lo(EVT15);
643 p0.h = hi(EVT15);
644 p1.l = _schedule_and_signal;
645 p1.h = _schedule_and_signal;
646 [p0] = p1;
647 csync;
648 raise 15; /* raise evt14 to do signal or reschedule */
649 4:
650 r0 = syscfg;
651 bitclr(r0, 0);
652 syscfg = r0;
653 5:
654 rts;
655 ENDPROC(_ret_from_exception)
657 ENTRY(_return_from_int)
658 /* If someone else already raised IRQ 15, do nothing. */
659 csync;
660 p2.l = lo(ILAT);
661 p2.h = hi(ILAT);
662 r0 = [p2];
663 cc = bittst (r0, EVT_IVG15_P);
664 if cc jump 2f;
666 /* if not return to user mode, get out */
667 p2.l = lo(IPEND);
668 p2.h = hi(IPEND);
669 r0 = [p2];
670 r1 = 0x17(Z);
671 r2 = ~r1;
672 r2.h = 0;
673 r0 = r2 & r0;
674 r1 = 1;
675 r1 = r0 - r1;
676 r2 = r0 & r1;
677 cc = r2 == 0;
678 if !cc jump 2f;
680 /* Lower the interrupt level to 15. */
681 p0.l = lo(EVT15);
682 p0.h = hi(EVT15);
683 p1.l = _schedule_and_signal_from_int;
684 p1.h = _schedule_and_signal_from_int;
685 [p0] = p1;
686 csync;
687 #if ANOMALY_05000281
688 r0.l = lo(CONFIG_BOOT_LOAD);
689 r0.h = hi(CONFIG_BOOT_LOAD);
690 reti = r0;
691 #endif
692 r0 = 0x801f (z);
693 STI r0;
694 raise 15; /* raise evt15 to do signal or reschedule */
695 rti;
696 2:
697 rts;
698 ENDPROC(_return_from_int)
700 ENTRY(_lower_to_irq14)
701 #if ANOMALY_05000281
702 r0.l = lo(CONFIG_BOOT_LOAD);
703 r0.h = hi(CONFIG_BOOT_LOAD);
704 reti = r0;
705 #endif
706 r0 = 0x401f;
707 sti r0;
708 raise 14;
709 rti;
710 ENTRY(_evt14_softirq)
711 #ifdef CONFIG_DEBUG_HWERR
712 r0 = 0x3f;
713 sti r0;
714 #else
715 cli r0;
716 #endif
717 [--sp] = RETI;
718 SP += 4;
719 rts;
721 _schedule_and_signal_from_int:
722 /* To end up here, vector 15 was changed - so we have to change it
723 * back.
724 */
725 p0.l = lo(EVT15);
726 p0.h = hi(EVT15);
727 p1.l = _evt_system_call;
728 p1.h = _evt_system_call;
729 [p0] = p1;
730 csync;
732 /* Set orig_p0 to -1 to indicate this isn't the end of a syscall. */
733 r0 = -1 (x);
734 [sp + PT_ORIG_P0] = r0;
736 p1 = rets;
737 [sp + PT_RESERVED] = p1;
739 p0.l = _irq_flags;
740 p0.h = _irq_flags;
741 r0 = [p0];
742 sti r0;
744 r0 = sp;
745 sp += -12;
746 call _finish_atomic_sections;
747 sp += 12;
748 jump.s .Lresume_userspace;
750 _schedule_and_signal:
751 SAVE_CONTEXT_SYSCALL
752 /* To end up here, vector 15 was changed - so we have to change it
753 * back.
754 */
755 p0.l = lo(EVT15);
756 p0.h = hi(EVT15);
757 p1.l = _evt_system_call;
758 p1.h = _evt_system_call;
759 [p0] = p1;
760 csync;
761 p0.l = 1f;
762 p0.h = 1f;
763 [sp + PT_RESERVED] = P0;
764 call .Lresume_userspace;
765 1:
766 RESTORE_CONTEXT
767 rti;
768 ENDPROC(_lower_to_irq14)
770 /* Make sure when we start, that the circular buffer is initialized properly
771 * R0 and P0 are call clobbered, so we can use them here.
772 */
773 ENTRY(_init_exception_buff)
774 r0 = 0;
775 p0.h = _in_ptr_excause;
776 p0.l = _in_ptr_excause;
777 [p0] = r0;
778 p0.h = _out_ptr_excause;
779 p0.l = _out_ptr_excause;
780 [p0] = r0;
781 rts;
782 ENDPROC(_init_exception_buff)
784 /* We handle this 100% in exception space - to reduce overhead
785 * Only potiential problem is if the software buffer gets swapped out of the
786 * CPLB table - then double fault. - so we don't let this happen in other places
787 */
788 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
789 ENTRY(_ex_trace_buff_full)
790 [--sp] = P3;
791 [--sp] = P2;
792 [--sp] = LC0;
793 [--sp] = LT0;
794 [--sp] = LB0;
795 P5.L = _trace_buff_offset;
796 P5.H = _trace_buff_offset;
797 P3 = [P5]; /* trace_buff_offset */
798 P5.L = lo(TBUFSTAT);
799 P5.H = hi(TBUFSTAT);
800 R7 = [P5];
801 R7 <<= 1; /* double, since we need to read twice */
802 LC0 = R7;
803 R7 <<= 2; /* need to shift over again,
804 * to get the number of bytes */
805 P5.L = lo(TBUF);
806 P5.H = hi(TBUF);
807 R6 = ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*1024) - 1;
809 P2 = R7;
810 P3 = P3 + P2;
811 R7 = P3;
812 R7 = R7 & R6;
813 P3 = R7;
814 P2.L = _trace_buff_offset;
815 P2.H = _trace_buff_offset;
816 [P2] = P3;
818 P2.L = _software_trace_buff;
819 P2.H = _software_trace_buff;
821 LSETUP (.Lstart, .Lend) LC0;
822 .Lstart:
823 R7 = [P5]; /* read TBUF */
824 P4 = P3 + P2;
825 [P4] = R7;
826 P3 += -4;
827 R7 = P3;
828 R7 = R7 & R6;
829 .Lend:
830 P3 = R7;
832 LB0 = [sp++];
833 LT0 = [sp++];
834 LC0 = [sp++];
835 P2 = [sp++];
836 P3 = [sp++];
837 jump _return_from_exception;
839 #if CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN == 4
840 .data
841 #else
842 .section .l1.data.B
843 #endif
844 ENTRY(_trace_buff_offset)
845 .long 0;
846 ALIGN
847 ENTRY(_software_trace_buff)
848 .rept ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*256);
849 .long 0
850 .endr
851 #endif
853 /*
854 * Put these in the kernel data section - that should always be covered by
855 * a CPLB. This is needed to ensure we don't get double fault conditions
856 */
858 #ifdef CONFIG_SYSCALL_TAB_L1
859 .section .l1.data
860 #else
861 .data
862 #endif
863 ENTRY(_ex_table)
864 /* entry for each EXCAUSE[5:0]
865 * This table must be in sync with the table in ./kernel/traps.c
866 * EXCPT instruction can provide 4 bits of EXCAUSE, allowing 16 to be user defined
867 */
868 .long _ex_syscall /* 0x00 - User Defined - Linux Syscall */
869 .long _ex_soft_bp /* 0x01 - User Defined - Software breakpoint */
870 .long _ex_replaceable /* 0x02 - User Defined */
871 .long _ex_trap_c /* 0x03 - User Defined - userspace stack overflow */
872 .long _ex_replaceable /* 0x04 - User Defined */
873 .long _ex_replaceable /* 0x05 - User Defined */
874 .long _ex_replaceable /* 0x06 - User Defined */
875 .long _ex_replaceable /* 0x07 - User Defined */
876 .long _ex_replaceable /* 0x08 - User Defined */
877 .long _ex_replaceable /* 0x09 - User Defined */
878 .long _ex_replaceable /* 0x0A - User Defined */
879 .long _ex_replaceable /* 0x0B - User Defined */
880 .long _ex_replaceable /* 0x0C - User Defined */
881 .long _ex_replaceable /* 0x0D - User Defined */
882 .long _ex_replaceable /* 0x0E - User Defined */
883 .long _ex_replaceable /* 0x0F - User Defined */
884 .long _ex_single_step /* 0x10 - HW Single step */
885 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
886 .long _ex_trace_buff_full /* 0x11 - Trace Buffer Full */
887 #else
888 .long _ex_trap_c /* 0x11 - Trace Buffer Full */
889 #endif
890 .long _ex_trap_c /* 0x12 - Reserved */
891 .long _ex_trap_c /* 0x13 - Reserved */
892 .long _ex_trap_c /* 0x14 - Reserved */
893 .long _ex_trap_c /* 0x15 - Reserved */
894 .long _ex_trap_c /* 0x16 - Reserved */
895 .long _ex_trap_c /* 0x17 - Reserved */
896 .long _ex_trap_c /* 0x18 - Reserved */
897 .long _ex_trap_c /* 0x19 - Reserved */
898 .long _ex_trap_c /* 0x1A - Reserved */
899 .long _ex_trap_c /* 0x1B - Reserved */
900 .long _ex_trap_c /* 0x1C - Reserved */
901 .long _ex_trap_c /* 0x1D - Reserved */
902 .long _ex_trap_c /* 0x1E - Reserved */
903 .long _ex_trap_c /* 0x1F - Reserved */
904 .long _ex_trap_c /* 0x20 - Reserved */
905 .long _ex_trap_c /* 0x21 - Undefined Instruction */
906 .long _ex_trap_c /* 0x22 - Illegal Instruction Combination */
907 .long _ex_dcplb /* 0x23 - Data CPLB Protection Violation */
908 .long _ex_trap_c /* 0x24 - Data access misaligned */
909 .long _ex_trap_c /* 0x25 - Unrecoverable Event */
910 .long _ex_dcplb /* 0x26 - Data CPLB Miss */
911 .long _ex_trap_c /* 0x27 - Data CPLB Multiple Hits - Linux Trap Zero */
912 .long _ex_trap_c /* 0x28 - Emulation Watchpoint */
913 .long _ex_trap_c /* 0x29 - Instruction fetch access error (535 only) */
914 .long _ex_trap_c /* 0x2A - Instruction fetch misaligned */
915 .long _ex_icplb /* 0x2B - Instruction CPLB protection Violation */
916 .long _ex_icplb /* 0x2C - Instruction CPLB miss */
917 .long _ex_trap_c /* 0x2D - Instruction CPLB Multiple Hits */
918 .long _ex_trap_c /* 0x2E - Illegal use of Supervisor Resource */
919 .long _ex_trap_c /* 0x2E - Illegal use of Supervisor Resource */
920 .long _ex_trap_c /* 0x2F - Reserved */
921 .long _ex_trap_c /* 0x30 - Reserved */
922 .long _ex_trap_c /* 0x31 - Reserved */
923 .long _ex_trap_c /* 0x32 - Reserved */
924 .long _ex_trap_c /* 0x33 - Reserved */
925 .long _ex_trap_c /* 0x34 - Reserved */
926 .long _ex_trap_c /* 0x35 - Reserved */
927 .long _ex_trap_c /* 0x36 - Reserved */
928 .long _ex_trap_c /* 0x37 - Reserved */
929 .long _ex_trap_c /* 0x38 - Reserved */
930 .long _ex_trap_c /* 0x39 - Reserved */
931 .long _ex_trap_c /* 0x3A - Reserved */
932 .long _ex_trap_c /* 0x3B - Reserved */
933 .long _ex_trap_c /* 0x3C - Reserved */
934 .long _ex_trap_c /* 0x3D - Reserved */
935 .long _ex_trap_c /* 0x3E - Reserved */
936 .long _ex_trap_c /* 0x3F - Reserved */
937 END(_ex_table)
939 ENTRY(_sys_call_table)
940 .long _sys_restart_syscall /* 0 */
941 .long _sys_exit
942 .long _sys_fork
943 .long _sys_read
944 .long _sys_write
945 .long _sys_open /* 5 */
946 .long _sys_close
947 .long _sys_ni_syscall /* old waitpid */
948 .long _sys_creat
949 .long _sys_link
950 .long _sys_unlink /* 10 */
951 .long _sys_execve
952 .long _sys_chdir
953 .long _sys_time
954 .long _sys_mknod
955 .long _sys_chmod /* 15 */
956 .long _sys_chown /* chown16 */
957 .long _sys_ni_syscall /* old break syscall holder */
958 .long _sys_ni_syscall /* old stat */
959 .long _sys_lseek
960 .long _sys_getpid /* 20 */
961 .long _sys_mount
962 .long _sys_ni_syscall /* old umount */
963 .long _sys_setuid
964 .long _sys_getuid
965 .long _sys_stime /* 25 */
966 .long _sys_ptrace
967 .long _sys_alarm
968 .long _sys_ni_syscall /* old fstat */
969 .long _sys_pause
970 .long _sys_ni_syscall /* old utime */ /* 30 */
971 .long _sys_ni_syscall /* old stty syscall holder */
972 .long _sys_ni_syscall /* old gtty syscall holder */
973 .long _sys_access
974 .long _sys_nice
975 .long _sys_ni_syscall /* 35 */ /* old ftime syscall holder */
976 .long _sys_sync
977 .long _sys_kill
978 .long _sys_rename
979 .long _sys_mkdir
980 .long _sys_rmdir /* 40 */
981 .long _sys_dup
982 .long _sys_pipe
983 .long _sys_times
984 .long _sys_ni_syscall /* old prof syscall holder */
985 .long _sys_brk /* 45 */
986 .long _sys_setgid
987 .long _sys_getgid
988 .long _sys_ni_syscall /* old sys_signal */
989 .long _sys_geteuid /* geteuid16 */
990 .long _sys_getegid /* getegid16 */ /* 50 */
991 .long _sys_acct
992 .long _sys_umount /* recycled never used phys() */
993 .long _sys_ni_syscall /* old lock syscall holder */
994 .long _sys_ioctl
995 .long _sys_fcntl /* 55 */
996 .long _sys_ni_syscall /* old mpx syscall holder */
997 .long _sys_setpgid
998 .long _sys_ni_syscall /* old ulimit syscall holder */
999 .long _sys_ni_syscall /* old old uname */
1000 .long _sys_umask /* 60 */
1001 .long _sys_chroot
1002 .long _sys_ustat
1003 .long _sys_dup2
1004 .long _sys_getppid
1005 .long _sys_getpgrp /* 65 */
1006 .long _sys_setsid
1007 .long _sys_ni_syscall /* old sys_sigaction */
1008 .long _sys_sgetmask
1009 .long _sys_ssetmask
1010 .long _sys_setreuid /* setreuid16 */ /* 70 */
1011 .long _sys_setregid /* setregid16 */
1012 .long _sys_ni_syscall /* old sys_sigsuspend */
1013 .long _sys_ni_syscall /* old sys_sigpending */
1014 .long _sys_sethostname
1015 .long _sys_setrlimit /* 75 */
1016 .long _sys_ni_syscall /* old getrlimit */
1017 .long _sys_getrusage
1018 .long _sys_gettimeofday
1019 .long _sys_settimeofday
1020 .long _sys_getgroups /* getgroups16 */ /* 80 */
1021 .long _sys_setgroups /* setgroups16 */
1022 .long _sys_ni_syscall /* old_select */
1023 .long _sys_symlink
1024 .long _sys_ni_syscall /* old lstat */
1025 .long _sys_readlink /* 85 */
1026 .long _sys_uselib
1027 .long _sys_ni_syscall /* sys_swapon */
1028 .long _sys_reboot
1029 .long _sys_ni_syscall /* old_readdir */
1030 .long _sys_ni_syscall /* sys_mmap */ /* 90 */
1031 .long _sys_munmap
1032 .long _sys_truncate
1033 .long _sys_ftruncate
1034 .long _sys_fchmod
1035 .long _sys_fchown /* fchown16 */ /* 95 */
1036 .long _sys_getpriority
1037 .long _sys_setpriority
1038 .long _sys_ni_syscall /* old profil syscall holder */
1039 .long _sys_statfs
1040 .long _sys_fstatfs /* 100 */
1041 .long _sys_ni_syscall
1042 .long _sys_ni_syscall /* old sys_socketcall */
1043 .long _sys_syslog
1044 .long _sys_setitimer
1045 .long _sys_getitimer /* 105 */
1046 .long _sys_newstat
1047 .long _sys_newlstat
1048 .long _sys_newfstat
1049 .long _sys_ni_syscall /* old uname */
1050 .long _sys_ni_syscall /* iopl for i386 */ /* 110 */
1051 .long _sys_vhangup
1052 .long _sys_ni_syscall /* obsolete idle() syscall */
1053 .long _sys_ni_syscall /* vm86old for i386 */
1054 .long _sys_wait4
1055 .long _sys_ni_syscall /* 115 */ /* sys_swapoff */
1056 .long _sys_sysinfo
1057 .long _sys_ni_syscall /* old sys_ipc */
1058 .long _sys_fsync
1059 .long _sys_ni_syscall /* old sys_sigreturn */
1060 .long _sys_clone /* 120 */
1061 .long _sys_setdomainname
1062 .long _sys_newuname
1063 .long _sys_ni_syscall /* old sys_modify_ldt */
1064 .long _sys_adjtimex
1065 .long _sys_ni_syscall /* 125 */ /* sys_mprotect */
1066 .long _sys_ni_syscall /* old sys_sigprocmask */
1067 .long _sys_ni_syscall /* old "creat_module" */
1068 .long _sys_init_module
1069 .long _sys_delete_module
1070 .long _sys_ni_syscall /* 130: old "get_kernel_syms" */
1071 .long _sys_quotactl
1072 .long _sys_getpgid
1073 .long _sys_fchdir
1074 .long _sys_bdflush
1075 .long _sys_ni_syscall /* 135 */ /* sys_sysfs */
1076 .long _sys_personality
1077 .long _sys_ni_syscall /* for afs_syscall */
1078 .long _sys_setfsuid /* setfsuid16 */
1079 .long _sys_setfsgid /* setfsgid16 */
1080 .long _sys_llseek /* 140 */
1081 .long _sys_getdents
1082 .long _sys_ni_syscall /* sys_select */
1083 .long _sys_flock
1084 .long _sys_ni_syscall /* sys_msync */
1085 .long _sys_readv /* 145 */
1086 .long _sys_writev
1087 .long _sys_getsid
1088 .long _sys_fdatasync
1089 .long _sys_sysctl
1090 .long _sys_ni_syscall /* 150 */ /* sys_mlock */
1091 .long _sys_ni_syscall /* sys_munlock */
1092 .long _sys_ni_syscall /* sys_mlockall */
1093 .long _sys_ni_syscall /* sys_munlockall */
1094 .long _sys_sched_setparam
1095 .long _sys_sched_getparam /* 155 */
1096 .long _sys_sched_setscheduler
1097 .long _sys_sched_getscheduler
1098 .long _sys_sched_yield
1099 .long _sys_sched_get_priority_max
1100 .long _sys_sched_get_priority_min /* 160 */
1101 .long _sys_sched_rr_get_interval
1102 .long _sys_nanosleep
1103 .long _sys_mremap
1104 .long _sys_setresuid /* setresuid16 */
1105 .long _sys_getresuid /* getresuid16 */ /* 165 */
1106 .long _sys_ni_syscall /* for vm86 */
1107 .long _sys_ni_syscall /* old "query_module" */
1108 .long _sys_ni_syscall /* sys_poll */
1109 .long _sys_nfsservctl
1110 .long _sys_setresgid /* setresgid16 */ /* 170 */
1111 .long _sys_getresgid /* getresgid16 */
1112 .long _sys_prctl
1113 .long _sys_rt_sigreturn
1114 .long _sys_rt_sigaction
1115 .long _sys_rt_sigprocmask /* 175 */
1116 .long _sys_rt_sigpending
1117 .long _sys_rt_sigtimedwait
1118 .long _sys_rt_sigqueueinfo
1119 .long _sys_rt_sigsuspend
1120 .long _sys_pread64 /* 180 */
1121 .long _sys_pwrite64
1122 .long _sys_lchown /* lchown16 */
1123 .long _sys_getcwd
1124 .long _sys_capget
1125 .long _sys_capset /* 185 */
1126 .long _sys_sigaltstack
1127 .long _sys_sendfile
1128 .long _sys_ni_syscall /* streams1 */
1129 .long _sys_ni_syscall /* streams2 */
1130 .long _sys_vfork /* 190 */
1131 .long _sys_getrlimit
1132 .long _sys_mmap2
1133 .long _sys_truncate64
1134 .long _sys_ftruncate64
1135 .long _sys_stat64 /* 195 */
1136 .long _sys_lstat64
1137 .long _sys_fstat64
1138 .long _sys_chown
1139 .long _sys_getuid
1140 .long _sys_getgid /* 200 */
1141 .long _sys_geteuid
1142 .long _sys_getegid
1143 .long _sys_setreuid
1144 .long _sys_setregid
1145 .long _sys_getgroups /* 205 */
1146 .long _sys_setgroups
1147 .long _sys_fchown
1148 .long _sys_setresuid
1149 .long _sys_getresuid
1150 .long _sys_setresgid /* 210 */
1151 .long _sys_getresgid
1152 .long _sys_lchown
1153 .long _sys_setuid
1154 .long _sys_setgid
1155 .long _sys_setfsuid /* 215 */
1156 .long _sys_setfsgid
1157 .long _sys_pivot_root
1158 .long _sys_ni_syscall /* sys_mincore */
1159 .long _sys_ni_syscall /* sys_madvise */
1160 .long _sys_getdents64 /* 220 */
1161 .long _sys_fcntl64
1162 .long _sys_ni_syscall /* reserved for TUX */
1163 .long _sys_ni_syscall
1164 .long _sys_gettid
1165 .long _sys_readahead /* 225 */
1166 .long _sys_setxattr
1167 .long _sys_lsetxattr
1168 .long _sys_fsetxattr
1169 .long _sys_getxattr
1170 .long _sys_lgetxattr /* 230 */
1171 .long _sys_fgetxattr
1172 .long _sys_listxattr
1173 .long _sys_llistxattr
1174 .long _sys_flistxattr
1175 .long _sys_removexattr /* 235 */
1176 .long _sys_lremovexattr
1177 .long _sys_fremovexattr
1178 .long _sys_tkill
1179 .long _sys_sendfile64
1180 .long _sys_futex /* 240 */
1181 .long _sys_sched_setaffinity
1182 .long _sys_sched_getaffinity
1183 .long _sys_ni_syscall /* sys_set_thread_area */
1184 .long _sys_ni_syscall /* sys_get_thread_area */
1185 .long _sys_io_setup /* 245 */
1186 .long _sys_io_destroy
1187 .long _sys_io_getevents
1188 .long _sys_io_submit
1189 .long _sys_io_cancel
1190 .long _sys_ni_syscall /* 250 */ /* sys_alloc_hugepages */
1191 .long _sys_ni_syscall /* sys_freec_hugepages */
1192 .long _sys_exit_group
1193 .long _sys_lookup_dcookie
1194 .long _sys_bfin_spinlock
1195 .long _sys_epoll_create /* 255 */
1196 .long _sys_epoll_ctl
1197 .long _sys_epoll_wait
1198 .long _sys_ni_syscall /* remap_file_pages */
1199 .long _sys_set_tid_address
1200 .long _sys_timer_create /* 260 */
1201 .long _sys_timer_settime
1202 .long _sys_timer_gettime
1203 .long _sys_timer_getoverrun
1204 .long _sys_timer_delete
1205 .long _sys_clock_settime /* 265 */
1206 .long _sys_clock_gettime
1207 .long _sys_clock_getres
1208 .long _sys_clock_nanosleep
1209 .long _sys_statfs64
1210 .long _sys_fstatfs64 /* 270 */
1211 .long _sys_tgkill
1212 .long _sys_utimes
1213 .long _sys_fadvise64_64
1214 .long _sys_ni_syscall /* vserver */
1215 .long _sys_ni_syscall /* 275, mbind */
1216 .long _sys_ni_syscall /* get_mempolicy */
1217 .long _sys_ni_syscall /* set_mempolicy */
1218 .long _sys_mq_open
1219 .long _sys_mq_unlink
1220 .long _sys_mq_timedsend /* 280 */
1221 .long _sys_mq_timedreceive
1222 .long _sys_mq_notify
1223 .long _sys_mq_getsetattr
1224 .long _sys_ni_syscall /* kexec_load */
1225 .long _sys_waitid /* 285 */
1226 .long _sys_add_key
1227 .long _sys_request_key
1228 .long _sys_keyctl
1229 .long _sys_ioprio_set
1230 .long _sys_ioprio_get /* 290 */
1231 .long _sys_inotify_init
1232 .long _sys_inotify_add_watch
1233 .long _sys_inotify_rm_watch
1234 .long _sys_ni_syscall /* migrate_pages */
1235 .long _sys_openat /* 295 */
1236 .long _sys_mkdirat
1237 .long _sys_mknodat
1238 .long _sys_fchownat
1239 .long _sys_futimesat
1240 .long _sys_fstatat64 /* 300 */
1241 .long _sys_unlinkat
1242 .long _sys_renameat
1243 .long _sys_linkat
1244 .long _sys_symlinkat
1245 .long _sys_readlinkat /* 305 */
1246 .long _sys_fchmodat
1247 .long _sys_faccessat
1248 .long _sys_pselect6
1249 .long _sys_ppoll
1250 .long _sys_unshare /* 310 */
1251 .long _sys_sram_alloc
1252 .long _sys_sram_free
1253 .long _sys_dma_memcpy
1254 .long _sys_accept
1255 .long _sys_bind /* 315 */
1256 .long _sys_connect
1257 .long _sys_getpeername
1258 .long _sys_getsockname
1259 .long _sys_getsockopt
1260 .long _sys_listen /* 320 */
1261 .long _sys_recv
1262 .long _sys_recvfrom
1263 .long _sys_recvmsg
1264 .long _sys_send
1265 .long _sys_sendmsg /* 325 */
1266 .long _sys_sendto
1267 .long _sys_setsockopt
1268 .long _sys_shutdown
1269 .long _sys_socket
1270 .long _sys_socketpair /* 330 */
1271 .long _sys_semctl
1272 .long _sys_semget
1273 .long _sys_semop
1274 .long _sys_msgctl
1275 .long _sys_msgget /* 335 */
1276 .long _sys_msgrcv
1277 .long _sys_msgsnd
1278 .long _sys_shmat
1279 .long _sys_shmctl
1280 .long _sys_shmdt /* 340 */
1281 .long _sys_shmget
1282 .long _sys_splice
1283 .long _sys_sync_file_range
1284 .long _sys_tee
1285 .long _sys_vmsplice /* 345 */
1286 .long _sys_epoll_pwait
1287 .long _sys_utimensat
1288 .long _sys_signalfd
1289 .long _sys_timerfd
1290 .long _sys_eventfd /* 350 */
1291 .long _sys_pread64
1292 .long _sys_pwrite64
1293 .long _sys_fadvise64
1294 .long _sys_set_robust_list
1295 .long _sys_get_robust_list /* 355 */
1296 .long _sys_fallocate
1297 .rept NR_syscalls-(.-_sys_call_table)/4
1298 .long _sys_ni_syscall
1299 .endr
1300 _excpt_saved_imask:
1301 .long 0;
1303 _exception_stack:
1304 .rept 1024
1305 .long 0;
1306 .endr
1307 _exception_stack_top:
1309 #if ANOMALY_05000261
1310 /* Used by the assembly entry point to work around an anomaly. */
1311 _last_cplb_fault_retx:
1312 .long 0;
1313 #endif
1314 /*
1315 * Single instructions can have multiple faults, which need to be
1316 * handled by traps.c, in irq5. We store the exception cause to ensure
1317 * we don't miss a double fault condition
1318 */
1319 ENTRY(_in_ptr_excause)
1320 .long 0;
1321 ENTRY(_out_ptr_excause)
1322 .long 0;
1323 ALIGN
1324 ENTRY(_excause_circ_buf)
1325 .rept 4
1326 .long 0
1327 .endr