src/ferm

   1 #!/usr/bin/perl
   2
   3 #
   4 # ferm, a firewall setup program that makes firewall rules easy!
   5 #
   6 # Copyright (C) 2001-2008 Auke Kok, Max Kellermann
   7 #
   8 # Comments, questions, greetings and additions to this program
   9 # may be sent to <ferm@foo-projects.org>
  10 #
  11
  12 #
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2 of the License, or
  16 # (at your option) any later version.
  17 #
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  26 #
  27
  28 # $Id$
  29
  30 BEGIN {
  31     eval { require strict; import strict; };
  32     $has_strict = not $@;
  33     if ($@) {
  34         # we need no vars.pm if there is not even strict.pm
  35         $INC{'vars.pm'} = 1;
  36         *vars::import = sub {};
  37     } else {
  38         require IO::Handle;
  39     }
  40
  41     eval { require Getopt::Long; import Getopt::Long; };
  42     $has_getopt = not $@;
  43 }
  44
  45 use vars qw($has_strict $has_getopt);
  46
  47 use vars qw($DATE $VERSION);
  48
  49 # subversion keyword magic
  50 $DATE = '$Date$' =~ m,(\d{4})-(\d\d)-(\d\d), ? $1.$2.$3 : '';
  51
  52 $VERSION = '2.0';
  53 $VERSION .= '~svn' . $DATE;
  54
  55 ## interface variables
  56 # %option = command line and other options
  57 use vars qw(%option);
  58
  59 ## hooks
  60 use vars qw(@pre_hooks @post_hooks);
  61
  62 ## parser variables
  63 # $script: current script file
  64 # @stack = ferm's parser stack containing local variables
  65 # $auto_chain = index for the next auto-generated chain
  66 use vars qw($script @stack $auto_chain);
  67
  68 ## netfilter variables
  69 # %domains = state information about all domains ("ip" and "ip6")
  70 # - initialized: domain initialization is done
  71 # - tools: hash providing the paths of the domain's tools
  72 # - previous: save file of the previous ruleset, for rollback
  73 # - tables{$name}: ferm state information about tables
  74 #   - has_builtin: whether built-in chains have been determined in this table
  75 #   - chains{$chain}: ferm state information about the chains
  76 #     - builtin: whether this is a built-in chain
  77 use vars qw(%domains);
  78
  79 ## constants
  80 use vars qw(%deprecated_keywords);
  81
  82 # keywords from ferm 1.1 which are deprecated, and the new one; these
  83 # are automatically replaced, and a warning is printed
  84 %deprecated_keywords = ( goto => 'jump',
  85                        );
  86
  87 # these hashes provide the Netfilter module definitions
  88 use vars qw(%proto_defs %match_defs %target_defs);
  89
  90 #
  91 # This subsubsystem allows you to support (most) new netfilter modules
  92 # in ferm.  Add a call to one of the "add_XY_def()" functions below.
  93 #
  94 # Ok, now about the cryptic syntax: the function "add_XY_def()"
  95 # registers a new module.  There are three kinds of modules: protocol
  96 # module (e.g. TCP, ICMP), match modules (e.g. state, physdev) and
  97 # target modules (e.g. DNAT, MARK).
  98 #
  99 # The first parameter is always the module name which is passed to
 100 # iptables with "-p", "-m" or "-j" (depending on which kind of module
 101 # this is).
 102 #
 103 # After that, you add an encoded string for each option the module
 104 # supports.  This is where it becomes tricky.
 105 #
 106 # foo           defaults to an option with one argument (which may be a ferm
 107 #               array)
 108 #
 109 # foo*0         option without any arguments
 110 #
 111 # foo=s         one argument which must not be a ferm array ('s' stands for
 112 #               'scalar')
 113 #
 114 # u32=m         an array which renders into multiple iptables options in one
 115 #               rule
 116 #
 117 # ctstate=c     one argument, if it's an array, pass it to iptables as a
 118 #               single comma separated value; example:
 119 #                 ctstate (ESTABLISHED RELATED)  translates to:
 120 #                 --ctstate ESTABLISHED,RELATED
 121 #
 122 # foo=sac       three arguments: scalar, array, comma separated; you may
 123 #               concatenate more than one letter code after the '='
 124 #
 125 # foo&bar       one argument; call the perl function '&bar()' which parses
 126 #               the argument
 127 #
 128 # !foo          negation is allowed and the '!' is written before the keyword
 129 #
 130 # foo!          same as above, but '!' is after the keyword and before the
 131 #               parameters
 132 #
 133 # to:=to-destination    makes "to" an alias for "to-destination"; you have
 134 #                       to add a declaration for option "to-destination"
 135 #
 136
 137 # add a module definition
 138 sub add_def_x {
 139     my $defs = shift;
 140     my $domain_family = shift;
 141     my $params_default = shift;
 142     my $name = shift;
 143     die if exists $defs->{$domain_family}{$name};
 144     my $def = $defs->{$domain_family}{$name} = {};
 145     foreach (@_) {
 146         my $keyword = $_;
 147         my $k = {};
 148
 149         my $params = $params_default;
 150         $params = $1 if $keyword =~ s,\*(\d+)$,,;
 151         $params = $1 if $keyword =~ s,=([acs]+|m)$,,;
 152         if ($keyword =~ s,&(\S+)$,,) {
 153             $params = eval "\\&$1";
 154             die $@ if $@;
 155         }
 156         $k->{params} = $params if $params;
 157
 158         $k->{negation} = $k->{pre_negation} = 1 if $keyword =~ s,^!,,;
 159         $k->{negation} = 1 if $keyword =~ s,!$,,;
 160
 161         $k->{alias} = [$1, $def->{keywords}{$1} || die] if $keyword =~ s,:=(\S+)$,,;
 162
 163         $def->{keywords}{$keyword} = $k;
 164     }
 165
 166     return $def;
 167 }
 168
 169 # add a protocol module definition
 170 sub add_proto_def_x(@) {
 171     my $domain_family = shift;
 172     add_def_x(\%proto_defs, $domain_family, 1, @_);
 173 }
 174
 175 # add a match module definition
 176 sub add_match_def_x(@) {
 177     my $domain_family = shift;
 178     add_def_x(\%match_defs, $domain_family, 1, @_);
 179 }
 180
 181 # add a target module definition
 182 sub add_target_def_x(@) {
 183     my $domain_family = shift;
 184     add_def_x(\%target_defs, $domain_family, 's', @_);
 185 }
 186
 187 sub add_def {
 188     my $defs = shift;
 189     add_def_x($defs, 'ip', @_);
 190 }
 191
 192 # add a protocol module definition
 193 sub add_proto_def(@) {
 194     add_def(\%proto_defs, 1, @_);
 195 }
 196
 197 # add a match module definition
 198 sub add_match_def(@) {
 199     add_def(\%match_defs, 1, @_);
 200 }
 201
 202 # add a target module definition
 203 sub add_target_def(@) {
 204     add_def(\%target_defs, 's', @_);
 205 }
 206
 207 add_proto_def 'dccp', qw(dccp-types!=c dccp-option!);
 208 add_proto_def 'mh', qw(mh-type!);
 209 add_proto_def 'icmp', qw(icmp-type!);
 210 add_proto_def 'icmpv6', qw(icmpv6-type! icmp-type:=icmpv6-type);
 211 add_proto_def 'sctp', qw(chunk-types!=sc);
 212 add_proto_def 'tcp', qw(tcp-flags!=cc !syn*0 tcp-option! mss);
 213 add_proto_def 'udp', qw();
 214
 215 add_match_def '',
 216   # --source, --destination
 217   qw(source! saddr:=source destination! daddr:=destination),
 218   # --in-interface
 219   qw(in-interface! interface:=in-interface if:=in-interface),
 220   # --out-interface
 221   qw(out-interface! outerface:=out-interface of:=out-interface),
 222   # --fragment
 223   qw(!fragment*0);
 224 add_match_def 'account', qw(aaddr=s aname=s ashort*0);
 225 add_match_def 'addrtype', qw(src-type dst-type);
 226 add_match_def 'ah', qw(ahspi! ahlen! ahres*0);
 227 add_match_def 'comment', qw(comment=s);
 228 add_match_def 'condition', qw(condition!);
 229 add_match_def 'connbytes', qw(!connbytes connbytes-dir connbytes-mode);
 230 add_match_def 'connlimit', qw(!connlimit-above connlimit-mask);
 231 add_match_def 'connmark', qw(mark);
 232 add_match_def 'conntrack', qw(ctstate=c ctproto ctorigsrc! ctorigdst!),
 233   qw(ctreplsrc! ctrepldst! ctstatus ctexpire=s);
 234 add_match_def 'dscp', qw(dscp dscp-class);
 235 add_match_def 'ecn', qw(ecn-tcp-cwr*0 ecn-tcp-ece*0 ecn-ip-ect);
 236 add_match_def 'esp', qw(espspi!);
 237 add_match_def 'eui64';
 238 add_match_def 'fuzzy', qw(lower-limit=s upper-limit=s);
 239 add_match_def 'hbh', qw(hbh-len! hbh-opts=c);
 240 add_match_def 'helper', qw(helper);
 241 add_match_def 'hl', qw(hl-eq! hl-lt=s hl-gt=s);
 242 add_match_def 'hashlimit', qw(hashlimit=s hashlimit-burst=s hashlimit-mode=s hashlimit-name=s),
 243   qw(hashlimit-htable-size=s hashlimit-htable-max=s),
 244   qw(hashlimit-htable-expire=s hashlimit-htable-gcinterval=s);
 245 add_match_def 'iprange', qw(!src-range !dst-range);
 246 add_match_def 'ipv4options', qw(ssrr*0 lsrr*0 no-srr*0 !rr*0 !ts*0 !ra*0 !any-opt*0);
 247 add_match_def 'ipv6header', qw(header!=c soft*0);
 248 add_match_def 'length', qw(length!);
 249 add_match_def 'limit', qw(limit=s limit-burst=s);
 250 add_match_def 'mac', qw(mac-source!);
 251 add_match_def 'mark', qw(mark);
 252 add_match_def 'multiport', qw(source-ports!&multiport_params),
 253   qw(destination-ports!&multiport_params ports!&multiport_params);
 254 add_match_def 'nth', qw(every counter start packet);
 255 add_match_def 'owner', qw(uid-owner gid-owner pid-owner sid-owner cmd-owner);
 256 add_match_def 'physdev', qw(physdev-in! physdev-out!),
 257   qw(!physdev-is-in*0 !physdev-is-out*0 !physdev-is-bridged*0);
 258 add_match_def 'pkttype', qw(pkt-type),
 259 add_match_def 'policy',
 260   qw(dir pol strict*0 reqid spi proto mode tunnel-src tunnel-dst next*0);
 261 add_match_def 'psd', qw(psd-weight-threshold psd-delay-threshold),
 262   qw(psd-lo-ports-weight psd-hi-ports-weight);
 263 add_match_def 'quota', qw(quota=s);
 264 add_match_def 'random', qw(average);
 265 add_match_def 'realm', qw(realm!);
 266 add_match_def 'recent', qw(name=s !set*0 !rcheck*0 !update*0 !seconds !hitcount rttl*0 rsource*0 rdest*0);
 267 add_match_def 'rt', qw(rt-type! rt-segsleft! rt-len! rt-0-res*0 rt-0-addrs=c rt-0-not-strict*0);
 268 add_match_def 'set', qw(set=sc);
 269 add_match_def 'state', qw(state=c);
 270 add_match_def 'statistic', qw(mode=s probability=s every=s packet=s);
 271 add_match_def 'string', qw(algo=s from=s to=s string hex-string);
 272 add_match_def 'tcpmss', qw(!mss);
 273 add_match_def 'time', qw(timestart=s timestop=s days=c datestart=s datestop=s),
 274   qw(!monthday=c !weekdays=c utc*0 localtz*0);
 275 add_match_def 'tos', qw(!tos);
 276 add_match_def 'ttl', qw(ttl-eq ttl-lt=s ttl-gt=s);
 277 add_match_def 'u32', qw(!u32=m);
 278
 279 add_target_def 'BALANCE', qw(to-destination to:=to-destination);
 280 add_target_def 'CLASSIFY', qw(set-class);
 281 add_target_def 'CLUSTERIP', qw(new*0 hashmode clustermac total-nodes local-node hash-init);
 282 add_target_def 'CONNMARK', qw(set-mark save-mark*0 restore-mark*0 mask);
 283 add_target_def 'CONNSECMARK', qw(save*0 restore*0);
 284 add_target_def 'DNAT', qw(to-destination=m to:=to-destination random*0);
 285 add_target_def 'DSCP', qw(set-dscp set-dscp-class);
 286 add_target_def 'ECN', qw(ecn-tcp-remove*0);
 287 add_target_def 'HL', qw(hl-set hl-dec hl-inc);
 288 add_target_def 'IPV4OPTSSTRIP';
 289 add_target_def 'LOG', qw(log-level log-prefix),
 290   qw(log-tcp-sequence*0 log-tcp-options*0 log-ip-options*0 log-uid*0);
 291 add_target_def 'MARK', qw(set-mark set-xmark and-mark or-mark xor-mark);
 292 add_target_def 'MASQUERADE', qw(to-ports random*0);
 293 add_target_def 'MIRROR';
 294 add_target_def 'NETMAP', qw(to);
 295 add_target_def 'NFLOG', qw(nflog-group nflog-prefix nflog-range nflog-threshold);
 296 add_target_def 'NFQUEUE', qw(queue-num);
 297 add_target_def 'NOTRACK';
 298 add_target_def 'REDIRECT', qw(to-ports random*0);
 299 add_target_def 'REJECT', qw(reject-with);
 300 add_target_def 'ROUTE', qw(oif iif gw continue*0 tee*0);
 301 add_target_def 'SAME', qw(to nodst*0 random*0);
 302 add_target_def 'SECMARK', qw(selctx);
 303 add_target_def 'SET', qw(add-set=sc del-set=sc);
 304 add_target_def 'SNAT', qw(to-source=m to:=to-source random*0);
 305 add_target_def 'TARPIT';
 306 add_target_def 'TCPMSS', qw(set-mss clamp-mss-to-pmtu*0);
 307 add_target_def 'TOS', qw(set-tos and-tos or-tos xor-tos);
 308 add_target_def 'TRACE';
 309 add_target_def 'TTL', qw(ttl-set ttl-dec ttl-inc);
 310 add_target_def 'ULOG', qw(ulog-nlgroup ulog-prefix ulog-cprange ulog-qthreshold);
 311
 312 add_match_def_x 'arp', '',
 313   # ip
 314   qw(source-ip! destination-ip! saddr:=source-ip daddr:=destination-ip),
 315   # mac
 316   qw(source-mac! destination-mac!),
 317   # --in-interface
 318   qw(in-interface! interface:=in-interface if:=in-interface),
 319   # --out-interface
 320   qw(out-interface! outerface:=out-interface of:=out-interface),
 321   # misc
 322   qw(h-length=s opcode=s h-type=s proto-type=s),
 323   qw(mangle-ip-s=s mangle-ip-d=s mangle-mac-s=s mangle-mac-d=s mangle-target=s);
 324
 325 add_match_def_x 'eb', '',
 326   # protocol
 327   qw(protocol! proto:=protocol),
 328   # --in-interface
 329   qw(in-interface! interface:=in-interface if:=in-interface),
 330   # --out-interface
 331   qw(out-interface! outerface:=out-interface of:=out-interface),
 332   # logical interface
 333   qw(logical-in! logical-out!),
 334   # --source, --destination
 335   qw(source! saddr:=source destination! daddr:=destination),
 336   # 802.3
 337   qw(802_3-sap! 802_3-type!),
 338   # arp
 339   qw(arp-opcode! arp-htype!=ss arp-ptype!=ss),
 340   qw(arp-ip-src! arp-ip-dst! arp-mac-src! arp-mac-dst!),
 341   # ip
 342   qw(ip-source! ip-destination! ip-tos! ip-protocol! ip-sport! ip-dport!),
 343   # mark_m
 344   qw(mark!),
 345   # pkttype
 346   qw(pkttype-type!),
 347   # stp
 348   qw(stp-type! stp-flags! stp-root-prio! stp-root-addr! stp-root-cost!),
 349   qw(stp-sender-prio! stp-sender-addr! stp-port! stp-msg-age! stp-max-age!),
 350   qw(stp-hello-time! stp-forward-delay!),
 351   # vlan
 352   qw(vlan-id! vlan-prio! vlan-encap!),
 353   # log
 354   qw(log*0 log-level=s log-prefix=s log-ip*0 log-arp*0);
 355
 356 add_target_def_x 'eb', 'arpreply', qw(arpreply-mac arpreply-target);
 357 add_target_def_x 'eb', 'dnat', qw(to-destination dnat-target);
 358 add_target_def_x 'eb', 'mark', qw(set-mark mark-target);
 359 add_target_def_x 'eb', 'redirect', qw(redirect-target);
 360 add_target_def_x 'eb', 'snat', qw(to-source snat-target);
 361
 362 # import-ferm uses the above tables
 363 return 1 if $0 =~ /import-ferm$/;
 364
 365 use vars qw(%builtin_keywords);
 366
 367 sub get_builtin_keywords($) {
 368     my $domain_family = shift;
 369     return {} unless defined $domain_family;
 370
 371     return {%{$builtin_keywords{$domain_family}}}
 372       if exists $builtin_keywords{$domain_family};
 373
 374     return {} unless exists $match_defs{$domain_family};
 375     my $defs_kw = $match_defs{$domain_family}{''}{keywords};
 376     my %keywords = map { $_ => ['builtin', '', $defs_kw->{$_} ] } keys %$defs_kw;
 377
 378     $builtin_keywords{$domain_family} = \%keywords;
 379     return {%keywords};
 380 }
 381
 382 # parameter parser for ipt_multiport
 383 sub multiport_params {
 384     my $fw = shift;
 385
 386     # multiport only allows 15 ports at a time. For this
 387     # reason, we do a little magic here: split the ports
 388     # into portions of 15, and handle these portions as
 389     # array elements
 390
 391     my $proto = $fw->{protocol};
 392     error('To use multiport, you have to specify "proto tcp" or "proto udp" first')
 393       unless defined $proto and grep { /^(?:tcp|udp|udplite)$/ } to_array($proto);
 394
 395     my $value = getvalues(undef, undef,
 396                           allow_negation => 1,
 397                           allow_array_negation => 1);
 398     if (ref $value and ref $value eq 'ARRAY') {
 399         my @value = @$value;
 400         my @params;
 401
 402         while (@value) {
 403             push @params, join(',', splice(@value, 0, 15));
 404         }
 405
 406         return @params == 1
 407           ? $params[0]
 408             : \@params;
 409     } else {
 410         return join_value(',', $value);
 411     }
 412 }
 413
 414 # initialize stack: command line definitions
 415 unshift @stack, {};
 416
 417 # Get command line stuff
 418 if ($has_getopt) {
 419     my ($opt_noexec, $opt_flush, $opt_lines, $opt_interactive,
 420         $opt_verbose, $opt_debug,
 421         $opt_help,
 422         $opt_version, $opt_test, $opt_fast, $opt_shell,
 423         $opt_domain);
 424
 425     Getopt::Long::Configure('bundling', 'auto_help', 'no_ignore_case',
 426                             'no_auto_abbrev');
 427
 428     sub opt_def {
 429         my ($opt, $value) = @_;
 430         die 'Invalid --def specification'
 431           unless $value =~ /^\$?(\w+)=(.*)$/s;
 432         my ($name, $unparsed_value) = ($1, $2);
 433         my $tokens = tokenize_string($unparsed_value);
 434         my $value = getvalues(\&next_array_token, $tokens);
 435         die 'Extra tokens after --def'
 436           if @$tokens > 0;
 437         $stack[0]{vars}{$name} = $value;
 438     }
 439
 440     local $SIG{__WARN__} = sub { die $_[0]; };
 441     GetOptions('noexec|n' => \$opt_noexec,
 442                'flush|F' => \$opt_flush,
 443                'lines|l' => \$opt_lines,
 444                'interactive|i' => \$opt_interactive,
 445                'verbose|v' => \$opt_verbose,
 446                'debug|d' => \$opt_debug,
 447                'help|h' => \$opt_help,
 448                'version|V' => \$opt_version,
 449                test => \$opt_test,
 450                remote => \$opt_test,
 451                fast => \$opt_fast,
 452                shell => \$opt_shell,
 453                'domain=s' => \$opt_domain,
 454                'def=s' => \&opt_def,
 455               );
 456
 457     if (defined $opt_help) {
 458         require Pod::Usage;
 459         Pod::Usage::pod2usage(-exitstatus => 0);
 460     }
 461
 462     if (defined $opt_version) {
 463         printversion();
 464         exit 0;
 465     };
 466
 467     $option{'noexec'} = (defined $opt_noexec);
 468     $option{flush} = defined $opt_flush;
 469     $option{'lines'} = (defined $opt_lines);
 470     $option{interactive} = (defined $opt_interactive);
 471     $option{test} = (defined $opt_test);
 472
 473     if ($option{test}) {
 474         $option{noexec} = 1;
 475         $option{lines} = 1;
 476     }
 477
 478     delete $option{interactive} if $option{noexec};
 479
 480     mydie('ferm interactive mode not possible: /dev/stdin is not a tty')
 481       if $option{interactive} and not -t STDIN;
 482     mydie('ferm interactive mode not possible: /dev/stderr is not a tty')
 483       if $option{interactive} and not -t STDERR;
 484
 485     $option{fast} = 1 if defined $opt_fast;
 486
 487     if (defined $opt_shell) {
 488         $option{$_} = 1 foreach qw(shell fast lines);
 489     }
 490
 491     $option{domain} = $opt_domain if defined $opt_domain;
 492
 493     print STDERR "Warning: ignoring the obsolete --debug option\n"
 494       if defined $opt_debug;
 495     print STDERR "Warning: ignoring the obsolete --verbose option\n"
 496       if defined $opt_verbose;
 497 } else {
 498     # tiny getopt emulation for microperl
 499     my $filename;
 500     foreach (@ARGV) {
 501         if ($_ eq '--noexec' or $_ eq '-n') {
 502             $option{noexec} = 1;
 503         } elsif ($_ eq '--lines' or $_ eq '-l') {
 504             $option{lines} = 1;
 505         } elsif ($_ eq '--fast') {
 506             $option{fast} = 1;
 507         } elsif ($_ eq '--test') {
 508             $option{test} = 1;
 509             $option{noexec} = 1;
 510             $option{lines} = 1;
 511         } elsif ($_ eq '--shell') {
 512             $option{$_} = 1 foreach qw(shell fast lines);
 513         } elsif (/^-/) {
 514             printf STDERR "Usage: ferm [--noexec] [--lines] [--fast] [--shell] FILENAME\n";
 515             exit 1;
 516         } else {
 517             $filename = $_;
 518         }
 519     }
 520     undef @ARGV;
 521     push @ARGV, $filename;
 522 }
 523
 524 unless (@ARGV == 1) {
 525     require Pod::Usage;
 526     Pod::Usage::pod2usage(-exitstatus => 1);
 527 }
 528
 529 if ($has_strict) {
 530     open LINES, ">&STDOUT" if $option{lines};
 531     open STDOUT, ">&STDERR" if $option{shell};
 532 } else {
 533     # microperl can't redirect file handles
 534     *LINES = *STDOUT;
 535
 536     if ($option{fast} and not $option{noexec}) {
 537         print STDERR "Sorry, ferm on microperl does not allow --fast without --noexec\n";
 538         exit 1
 539     }
 540 }
 541
 542 unshift @stack, {};
 543 open_script($ARGV[0]);
 544
 545 # parse all input recursively
 546 enter(0);
 547 die unless @stack == 2;
 548
 549 # execute all generated rules
 550 my $status;
 551
 552 foreach my $cmd (@pre_hooks) {
 553     print LINES "$cmd\n" if $option{lines};
 554     system($cmd) unless $option{noexec};
 555 }
 556
 557 while (my ($domain, $domain_info) = each %domains) {
 558     next unless $domain_info->{enabled};
 559     my $s = $option{fast} &&
 560       defined $domain_info->{tools}{'tables-restore'}
 561       ? execute_fast($domain, $domain_info)
 562         : execute_slow($domain, $domain_info);
 563     $status = $s if defined $s;
 564 }
 565
 566 foreach my $cmd (@post_hooks) {
 567     print "$cmd\n" if $option{lines};
 568     system($cmd) unless $option{noexec};
 569 }
 570
 571 if (defined $status) {
 572     rollback();
 573     exit $status;
 574 }
 575
 576 # ask user, and rollback if there is no confirmation
 577
 578 confirm_rules() or rollback() if $option{interactive};
 579
 580 exit 0;
 581
 582 # end of program execution!
 583
 584
 585 # funcs
 586
 587 sub printversion {
 588     print "ferm $VERSION\n";
 589     print "Copyright (C) 2001-2008 Auke Kok, Max Kellermann\n";
 590     print "This program is free software released under GPLv2.\n";
 591     print "See the included COPYING file for license details.\n";
 592 }
 593
 594
 595 sub mydie {
 596     print STDERR @_;
 597     print STDERR "\n";
 598     exit 1;
 599 }
 600
 601
 602 sub error {
 603     # returns a nice formatted error message, showing the
 604     # location of the error.
 605     my $tabs = 0;
 606     my @lines;
 607     my $l = 0;
 608     my @words = map { @$_ } @{$script->{past_tokens}};
 609
 610     for my $w ( 0 .. $#words ) {
 611         if ($words[$w] eq "\x29")
 612             { $l++ ; $lines[$l] = "    " x ($tabs-- -1) ;};
 613         if ($words[$w] eq "\x28")
 614             { $l++ ; $lines[$l] = "    " x $tabs++ ;};
 615         if ($words[$w] eq "\x7d")
 616             { $l++ ; $lines[$l] = "    " x ($tabs-- -1) ;};
 617         if ($words[$w] eq "\x7b")
 618             { $l++ ; $lines[$l] = "    " x $tabs++ ;};
 619         if ( $l > $#lines ) { $lines[$l] = "" };
 620         $lines[$l] .= $words[$w] . " ";
 621         if ($words[$w] eq "\x28")
 622             { $l++ ; $lines[$l] = "    " x $tabs ;};
 623         if (($words[$w] eq "\x29") && ($words[$w+1] ne "\x7b"))
 624             { $l++ ; $lines[$l] = "    " x $tabs ;};
 625         if ($words[$w] eq "\x7b")
 626             { $l++ ; $lines[$l] = "    " x $tabs ;};
 627         if (($words[$w] eq "\x7d") && ($words[$w+1] ne "\x7d"))
 628             { $l++ ; $lines[$l] = "    " x $tabs ;};
 629         if (($words[$w] eq "\x3b") && ($words[$w+1] ne "\x7d"))
 630             { $l++ ; $lines[$l] = "    " x $tabs ;}
 631         if ($words[$w-1] eq "option")
 632             { $l++ ; $lines[$l] = "    " x $tabs ;}
 633     }
 634     my $start = $#lines - 4;
 635     if ($start < 0) { $start = 0 } ;
 636     print STDERR "Error in $script->{filename} line $script->{line}:\n";
 637     for $l ( $start .. $#lines)
 638         { print STDERR $lines[$l]; if ($l != $#lines ) {print STDERR "\n"} ; };
 639     print STDERR "<--\n";
 640     mydie(@_);
 641 }
 642
 643 # print a warning message about code from an input file
 644 sub warning {
 645     print STDERR "Warning in $script->{filename} line $script->{line}: "
 646       . (shift) . "\n";
 647 }
 648
 649 sub find_tool($) {
 650     my $name = shift;
 651     return $name if $option{test};
 652     for my $path ('/sbin', split ':', $ENV{PATH}) {
 653         my $ret = "$path/$name";
 654         return $ret if -x $ret;
 655     }
 656     die "$name not found in PATH\n";
 657 }
 658
 659 sub initialize_domain {
 660     my $domain = shift;
 661     my $domain_info = $domains{$domain} ||= {};
 662
 663     return if exists $domain_info->{initialized};
 664
 665     die "Invalid domain '$domain'\n" unless $domain =~ /^(?:ip6?|arp|eb)$/;
 666
 667     my @tools = qw(tables);
 668     push @tools, qw(tables-save tables-restore)
 669       if $domain =~ /^ip6?$/;
 670
 671     # determine the location of this domain's tools
 672     my %tools = map { $_ => find_tool($domain . $_) } @tools;
 673     $domain_info->{tools} = \%tools;
 674
 675     # make tables-save tell us about the state of this domain
 676     # (which tables and chains do exist?), also remember the old
 677     # save data which may be used later by the rollback function
 678     local *SAVE;
 679     if (!$option{test} &&
 680         exists $tools{'tables-save'} &&
 681         open(SAVE, "$tools{'tables-save'}|")) {
 682         my $save = '';
 683
 684         my $table_info;
 685         while (<SAVE>) {
 686             $save .= $_;
 687
 688             if (/^\*(\w+)/) {
 689                 my $table = $1;
 690                 $table_info = $domain_info->{tables}{$table} ||= {};
 691             } elsif (defined $table_info and /^:(\w+)\s+(\S+)/
 692                      and $2 ne '-') {
 693                 $table_info->{chains}{$1}{builtin} = 1;
 694                 $table_info->{has_builtin} = 1;
 695             }
 696         }
 697
 698         # for rollback
 699         $domain_info->{previous} = $save;
 700     }
 701
 702     $domain_info->{initialized} = 1;
 703 }
 704
 705 # split the an input string into words and delete comments
 706 sub tokenize_string($) {
 707     my $string = shift;
 708
 709     my @ret;
 710
 711     foreach my $word ($string =~ m/(".*?"|'.*?'|`.*?`|[!,=&\$\%\(\){};]|[-+\w\/\.:]+|@\w+|#)/g) {
 712         last if $word eq '#';
 713         push @ret, $word;
 714     }
 715
 716     return \@ret;
 717 }
 718
 719 # shift an array; helper function to be passed to &getvar / &getvalues
 720 sub next_array_token {
 721     my $array = shift;
 722     shift @$array;
 723 }
 724
 725 # read some more tokens from the input file into a buffer
 726 sub prepare_tokens() {
 727     my $tokens = $script->{tokens};
 728     while (@$tokens == 0) {
 729         my $handle = $script->{handle};
 730         my $line = <$handle>;
 731         return unless defined $line;
 732
 733         $script->{line} ++;
 734
 735         # the next parser stage eats this
 736         push @$tokens, @{tokenize_string($line)};
 737     }
 738
 739     return 1;
 740 }
 741
 742 # open a ferm sub script
 743 sub open_script($) {
 744     my $filename = shift;
 745
 746     for (my $s = $script; defined $s; $s = $s->{parent}) {
 747         mydie("Circular reference in $script->{filename} line $script->{line}: $filename")
 748           if $s->{filename} eq $filename;
 749     }
 750
 751     local *FILE;
 752     open FILE, "<$filename"
 753       or mydie("Failed to open $filename: $!");
 754     my $handle = *FILE;
 755
 756     $script = { filename => $filename,
 757                 handle => $handle,
 758                 line => 0,
 759                 past_tokens => [],
 760                 tokens => [],
 761                 parent => $script,
 762               };
 763
 764     return $script;
 765 }
 766
 767 # collect script filenames which are being included
 768 sub collect_filenames(@) {
 769     my @ret;
 770
 771     # determine the current script's parent directory for relative
 772     # file names
 773     die unless defined $script;
 774     my $parent_dir = $script->{filename} =~ m,^(.*/),
 775       ? $1 : './';
 776
 777     foreach my $pathname (@_) {
 778         # non-absolute file names are relative to the parent script's
 779         # file name
 780         $pathname = $parent_dir . $pathname
 781           unless $pathname =~ m,^/,;
 782
 783         if ($pathname =~ m,/$,) {
 784             # include all regular files in a directory
 785
 786             error("'$pathname' is not a directory")
 787               unless -d $pathname;
 788
 789             local *DIR;
 790             opendir DIR, $pathname
 791               or error("Failed to open directory '$pathname': $!");
 792             my @names = readdir DIR;
 793             closedir DIR;
 794
 795             # sort those names for a well-defined order
 796             foreach my $name (sort { $a cmp $b } @names) {
 797                 # don't include hidden and backup files
 798                 next if /^\.|~$/;
 799
 800                 my $filename = $pathname . $name;
 801                 push @ret, $filename
 802                   if -f $filename;
 803             }
 804         } elsif ($pathname =~ m,\|$,) {
 805             # run a program and use its output
 806             push @ret, $pathname;
 807         } elsif ($pathname =~ m,^\|,) {
 808             error('This kind of pipe is not allowed');
 809         } else {
 810             # include a regular file
 811
 812             error("'$pathname' is a directory; maybe use trailing '/' to include a directory?")
 813               if -d $pathname;
 814             error("'$pathname' is not a file")
 815               unless -f $pathname;
 816
 817             push @ret, $pathname;
 818         }
 819     }
 820
 821     return @ret;
 822 }
 823
 824 # peek a token from the queue, but don't remove it
 825 sub peek_token() {
 826     return unless prepare_tokens();
 827     return $script->{tokens}[0];
 828 }
 829
 830 # get a token from the queue
 831 sub next_token() {
 832     return unless prepare_tokens();
 833     my $token = shift @{$script->{tokens}};
 834
 835     # update $script->{past_tokens}
 836     my $past_tokens = $script->{past_tokens};
 837
 838     if (@$past_tokens > 0) {
 839         my $prev_token = $past_tokens->[-1][-1];
 840         $past_tokens->[-1] = @$past_tokens > 1 ? ['{'] : []
 841           if $prev_token eq ';';
 842         pop @$past_tokens
 843           if $prev_token eq '}';
 844     }
 845
 846     push @$past_tokens, [] if $token eq '{' or @$past_tokens == 0;
 847     push @{$past_tokens->[-1]}, $token;
 848
 849     # return
 850     return $token;
 851 }
 852
 853 sub expect_token($;$) {
 854     my $expect = shift;
 855     my $msg = shift;
 856     my $token = next_token();
 857     error($msg || "'$expect' expected")
 858       unless defined $token and $token eq $expect;
 859 }
 860
 861 # require that another token exists, and that it's not a "special"
 862 # token, e.g. ";" and "{"
 863 sub require_next_token {
 864     my $code = shift || \&next_token;
 865
 866     my $token = &$code(@_);
 867
 868     error('unexpected end of file')
 869       unless defined $token;
 870
 871     error("'$token' not allowed here")
 872       if $token =~ /^[;{}]$/;
 873
 874     return $token;
 875 }
 876
 877 # return the value of a variable
 878 sub variable_value($) {
 879     my $name = shift;
 880
 881     foreach (@stack) {
 882         return $_->{vars}{$name}
 883           if exists $_->{vars}{$name};
 884     }
 885
 886     return $stack[0]{auto}{$name}
 887       if exists $stack[0]{auto}{$name};
 888
 889     return;
 890 }
 891
 892 # determine the value of a variable, die if the value is an array
 893 sub string_variable_value($) {
 894     my $name = shift;
 895     my $value = variable_value($name);
 896
 897     error("variable '$name' must be a string, but it is an array")
 898       if ref $value;
 899
 900     return $value;
 901 }
 902
 903 # similar to the built-in "join" function, but also handle negated
 904 # values in a special way
 905 sub join_value($$) {
 906     my ($expr, $value) = @_;
 907
 908     unless (ref $value) {
 909         return $value;
 910     } elsif (ref $value eq 'ARRAY') {
 911         return join($expr, @$value);
 912     } elsif (ref $value eq 'negated') {
 913         # bless'negated' is a special marker for negated values
 914         $value = join_value($expr, $value->[0]);
 915         return bless [ $value ], 'negated';
 916     } else {
 917         die;
 918     }
 919 }
 920
 921 # returns the next parameter, which may either be a scalar or an array
 922 sub getvalues {
 923     my ($code, $param) = (shift, shift);
 924     my %options = @_;
 925
 926     my $token = require_next_token($code, $param);
 927
 928     if ($token eq '(') {
 929         # read an array until ")"
 930         my @wordlist;
 931
 932         for (;;) {
 933             $token = getvalues($code, $param,
 934                                parenthesis_allowed => 1,
 935                                comma_allowed => 1);
 936
 937             unless (ref $token) {
 938                 last if $token eq ')';
 939
 940                 if ($token eq ',') {
 941                     error('Comma is not allowed within arrays, please use only a space');
 942                     next;
 943                 }
 944
 945                 push @wordlist, $token;
 946             } elsif (ref $token eq 'ARRAY') {
 947                 push @wordlist, @$token;
 948             } else {
 949                 error('unknown toke type');
 950             }
 951         }
 952
 953         error('empty array not allowed here')
 954           unless @wordlist or not $options{non_empty};
 955
 956         return @wordlist == 1
 957           ? $wordlist[0]
 958             : \@wordlist;
 959     } elsif ($token =~ /^\`(.*)\`$/s) {
 960         # execute a shell command, insert output
 961         my $command = $1;
 962         my $output = `$command`;
 963         unless ($? == 0) {
 964             if ($? == -1) {
 965                 error("failed to execute: $!");
 966             } elsif ($? & 0x7f) {
 967                 error("child died with signal " . ($? & 0x7f));
 968             } elsif ($? >> 8) {
 969                 error("child exited with status " . ($? >> 8));
 970             }
 971         }
 972
 973         # remove comments
 974         $output =~ s/#.*//mg;
 975
 976         # tokenize
 977         my @tokens = grep { length } split /\s+/s, $output;
 978
 979         my @values;
 980         while (@tokens) {
 981             my $value = getvalues(\&next_array_token, \@tokens);
 982             push @values, to_array($value);
 983         }
 984
 985         # and recurse
 986         return @values == 1
 987           ? $values[0]
 988             : \@values;
 989     } elsif ($token =~ /^\'(.*)\'$/s) {
 990         # single quotes: a string
 991         return $1;
 992     } elsif ($token =~ /^\"(.*)\"$/s) {
 993         # double quotes: a string with escapes
 994         $token = $1;
 995         $token =~ s,\$(\w+),string_variable_value($1),eg;
 996         return $token;
 997     } elsif ($token eq '!') {
 998         error('negation is not allowed here')
 999           unless $options{allow_negation};
1000
1001         $token = getvalues($code, $param);
1002
1003         error('it is not possible to negate an array')
1004           if ref $token and not $options{allow_array_negation};
1005
1006         return bless [ $token ], 'negated';
1007     } elsif ($token eq ',') {
1008         return $token
1009           if $options{comma_allowed};
1010
1011         error('comma is not allowed here');
1012     } elsif ($token eq '=') {
1013         error('equals operator ("=") is not allowed here');
1014     } elsif ($token eq '$') {
1015         my $name = require_next_token($code, $param);
1016         error('variable name expected - if you want to concatenate strings, try using double quotes')
1017           unless $name =~ /^\w+$/;
1018
1019         my $value = variable_value($name);
1020
1021         error("no such variable: \$$name")
1022           unless defined $value;
1023
1024         return $value;
1025     } elsif ($token eq '&') {
1026         error("function calls are not allowed as keyword parameter");
1027     } elsif ($token eq ')' and not $options{parenthesis_allowed}) {
1028         error('Syntax error');
1029     } elsif ($token =~ /^@/) {
1030         if ($token eq '@resolve') {
1031             my @params = get_function_params();
1032             error('Usage: @resolve((hostname ...))')
1033               unless @params == 1;
1034             eval { require Net::DNS; };
1035             error('For the @resolve() function, you need the Perl library Net::DNS')
1036               if $@;
1037             my $type = 'A';
1038             my $resolver = new Net::DNS::Resolver;
1039             my @result;
1040             foreach my $hostname (to_array($params[0])) {
1041                 my $query = $resolver->search($hostname, $type);
1042                 error("DNS query for '$hostname' failed: " . $resolver->errorstring)
1043                   unless $query;
1044                 foreach my $rr ($query->answer) {
1045                     next unless $rr->type eq $type;
1046                     push @result, $rr->address;
1047                 }
1048             }
1049             return \@result;
1050         } else {
1051             error("unknown ferm built-in function");
1052         }
1053     } else {
1054         return $token;
1055     }
1056 }
1057
1058 # returns the next parameter, but only allow a scalar
1059 sub getvar {
1060     my $token = getvalues(@_);
1061
1062     error('array not allowed here')
1063       if ref $token and ref $token eq 'ARRAY';
1064
1065     return $token;
1066 }
1067
1068 sub get_function_params(%) {
1069     expect_token('(', 'function name must be followed by "()"');
1070
1071     my $token = peek_token();
1072     if ($token eq ')') {
1073         require_next_token;
1074         return;
1075     }
1076
1077     my @params;
1078
1079     while (1) {
1080         if (@params > 0) {
1081             $token = require_next_token();
1082             last
1083               if $token eq ')';
1084
1085             error('"," expected')
1086               unless $token eq ',';
1087         }
1088
1089         push @params, getvalues(undef, undef, @_);
1090     }
1091
1092     return @params;
1093 }
1094
1095 # collect all tokens in a flat array reference until the end of the
1096 # command is reached
1097 sub collect_tokens() {
1098     my @level;
1099     my @tokens;
1100
1101     while (1) {
1102         my $keyword = next_token();
1103         error('unexpected end of file within function/variable declaration')
1104           unless defined $keyword;
1105
1106         if ($keyword =~ /^[\{\(]$/) {
1107             push @level, $keyword;
1108         } elsif ($keyword =~ /^[\}\)]$/) {
1109             my $expected = $keyword;
1110             $expected =~ tr/\}\)/\{\(/;
1111             my $opener = pop @level;
1112             error("unmatched '$keyword'")
1113               unless defined $opener and $opener eq $expected;
1114         } elsif ($keyword eq ';' and @level == 0) {
1115             last;
1116         }
1117
1118         push @tokens, $keyword;
1119
1120         last
1121           if $keyword eq '}' and @level == 0;
1122     }
1123
1124     return \@tokens;
1125 }
1126
1127
1128 # returns the specified value as an array. dereference arrayrefs
1129 sub to_array($) {
1130     my $value = shift;
1131     die unless wantarray;
1132     die if @_;
1133     unless (ref $value) {
1134         return $value;
1135     } elsif (ref $value eq 'ARRAY') {
1136         return @$value;
1137     } else {
1138         die;
1139     }
1140 }
1141
1142 # evaluate the specified value as bool
1143 sub eval_bool($) {
1144     my $value = shift;
1145     die if wantarray;
1146     die if @_;
1147     unless (ref $value) {
1148         return $value;
1149     } elsif (ref $value eq 'ARRAY') {
1150         return @$value > 0;
1151     } else {
1152         die;
1153     }
1154 }
1155
1156 sub is_netfilter_core_target($) {
1157     my $target = shift;
1158     die unless defined $target and length $target;
1159
1160     return $target =~ /^(?:ACCEPT|DROP|RETURN|QUEUE)$/;
1161 }
1162
1163 sub is_netfilter_module_target($$) {
1164     my ($domain_family, $target) = @_;
1165     die unless defined $target and length $target;
1166
1167     return defined $domain_family &&
1168       exists $target_defs{$domain_family} &&
1169         $target_defs{$domain_family}{$target};
1170 }
1171
1172 sub is_netfilter_builtin_chain($$) {
1173     my ($table, $chain) = @_;
1174
1175     return grep { $_ eq $chain }
1176       qw(PREROUTING INPUT FORWARD OUTPUT POSTROUTING);
1177 }
1178
1179 sub netfilter_canonical_protocol($) {
1180     my $proto = shift;
1181     return 'icmpv6'
1182       if $proto eq 'ipv6-icmp';
1183     return 'mh'
1184       if $proto eq 'ipv6-mh';
1185     return $proto;
1186 }
1187
1188 sub netfilter_protocol_module($) {
1189     my $proto = shift;
1190     return unless defined $proto;
1191     return 'icmp6'
1192       if $proto eq 'icmpv6';
1193     return $proto;
1194 }
1195
1196 # escape the string in a way safe for the shell
1197 sub shell_escape($) {
1198     my $token = shift;
1199
1200     return $token if $token =~ /^[-_a-zA-Z0-9]+$/s;
1201
1202     if ($option{fast}) {
1203         # iptables-save/iptables-restore are quite buggy concerning
1204         # escaping and special characters... we're trying our best
1205         # here
1206
1207         $token =~ s,",',g;
1208         $token = '"' . $token . '"'
1209           if $token =~ /[\s\'\\;&]/s;
1210     } else {
1211         return $token
1212           if $token =~ /^\`.*\`$/;
1213         $token =~ s/'/\\'/g;
1214         $token = '\'' . $token . '\''
1215           if $token =~ /[\s\"\\;<>&|]/s;
1216     }
1217
1218     return $token;
1219 }
1220
1221 # append an option to the shell command line, using information from
1222 # the module definition (see %match_defs etc.)
1223 sub shell_append_option($$$) {
1224     my ($ref, $keyword, $value) = @_;
1225
1226     if (ref $value) {
1227         if (ref $value eq 'negated') {
1228             $value = $value->[0];
1229             $keyword .= ' !';
1230         } elsif (ref $value eq 'pre_negated') {
1231             $value = $value->[0];
1232             $$ref .= ' !';
1233         }
1234     }
1235
1236     unless (defined $value) {
1237         $$ref .= " --$keyword";
1238     } elsif (ref $value) {
1239         if (ref $value eq 'params') {
1240             $$ref .= " --$keyword ";
1241             $$ref .= join(' ', map { shell_escape($_) } @$value);
1242         } elsif (ref $value eq 'multi') {
1243             foreach (@$value) {
1244                 $$ref .= " --$keyword " . shell_escape($_);
1245             }
1246         } else {
1247             die;
1248         }
1249     } else {
1250         $$ref .= " --$keyword " . shell_escape($value);
1251     }
1252 }
1253
1254 # convert an internal rule structure into an iptables call
1255 sub tables($$$) {
1256     my ($table_info, $chain_info, $rule) = @_;
1257
1258     return if $option{flush};
1259
1260     # return if this is a declaration-only rule
1261     return
1262       unless $rule->{has_rule};
1263
1264     my $rr = '';
1265
1266     # general iptables options
1267
1268     shell_append_option(\$rr, 'protocol', $rule->{protocol})
1269       if exists $rule->{protocol};
1270
1271     while (my ($keyword, $value) = each %{$rule->{builtin}}) {
1272         shell_append_option(\$rr, $keyword, $value);
1273     }
1274
1275     #
1276     # match module options
1277     #
1278
1279     my %modules;
1280
1281     if (defined $rule->{protocol}) {
1282         my $proto = $rule->{protocol};
1283
1284         # special case: --dport and --sport for TCP/UDP
1285         if ($rule->{domain_family} eq 'ip' and
1286             (exists $rule->{dport} or exists $rule->{sport}) and
1287             $proto =~ /^(?:tcp|udp|udplite|dccp|sctp)$/) {
1288             unless (exists $modules{$proto}) {
1289                 $rr .= " -m $proto";
1290                 $modules{$proto} = 1;
1291             }
1292
1293             shell_append_option(\$rr, 'dport', $rule->{dport})
1294               if exists $rule->{dport};
1295             shell_append_option(\$rr, 'sport', $rule->{sport})
1296               if exists $rule->{sport};
1297         }
1298     }
1299
1300     # modules stored in %match_defs
1301
1302     foreach my $match (@{$rule->{match}}) {
1303         my $module_name = $match->{name};
1304         unless (exists $modules{$module_name}) {
1305             $rr .= " -m $module_name";
1306             $modules{$module_name} = 1;
1307         }
1308
1309         while (my ($keyword, $value) = each %{$match->{options}}) {
1310             shell_append_option(\$rr, $keyword, $value);
1311         }
1312     }
1313
1314     #
1315     # target options
1316     #
1317
1318     my $action = $rule->{action};
1319     if ($action->{type} eq 'jump') {
1320         $table_info->{chains}{$action->{chain}}{rules} ||= [];
1321         $rr .= " -j " . $action->{chain};
1322     } elsif ($action->{type} eq 'goto') {
1323         $table_info->{chains}{$action->{chain}}{rules} ||= [];
1324         $rr .= " -g " . $action->{chain};
1325     } elsif ($action->{type} eq 'target') {
1326         $rr .= " -j " . $action->{target};
1327
1328         # targets stored in %target_defs
1329
1330         while (my ($keyword, $value) = each %{$rule->{target_options}}) {
1331             shell_append_option(\$rr, $keyword, $value);
1332         }
1333     } elsif ($action->{type} ne 'nop') {
1334         die;
1335     }
1336
1337     # this line is done
1338     my $chain_rules = $chain_info->{rules} ||= [];
1339     push @$chain_rules, { rule => $rr,
1340                           script => $rule->{script},
1341                         };
1342 };
1343
1344 sub transform_rule($$) {
1345     my ($domain, $rule) = @_;
1346
1347     $rule->{protocol} = 'icmpv6'
1348       if $domain eq 'ip6' and $rule->{protocol} eq 'icmp';
1349 }
1350
1351 sub printrule($$$$) {
1352     my ($domain, $table, $chain, $rule) = @_;
1353
1354     transform_rule($domain, $rule);
1355
1356     my $domain_info = $domains{$domain};
1357     $domain_info->{enabled} = 1;
1358     my $table_info = $domain_info->{tables}{$table} ||= {};
1359     my $chain_info = $table_info->{chains}{$chain} ||= {};
1360
1361     # prints all rules in a hash
1362     tables($table_info, $chain_info, $rule);
1363 }
1364
1365
1366 sub check_unfold(\@$$) {
1367     my ($unfold, $parent, $key) = @_;
1368
1369     return unless ref $parent->{$key} and
1370       ref $parent->{$key} eq 'ARRAY';
1371
1372     push @$unfold, $parent, $key, $parent->{$key};
1373 }
1374
1375 sub mkrules2($$$$) {
1376     my ($domain, $table, $chain, $fw) = @_;
1377
1378     my @unfold;
1379
1380     foreach my $key (keys %{$fw->{builtin}}) {
1381         check_unfold(@unfold, $fw->{builtin}, $key);
1382     }
1383
1384     foreach my $match (@{$fw->{match}}) {
1385         while (my ($key, $value) = each %{$match->{options}}) {
1386             check_unfold(@unfold, $match->{options}, $key);
1387         }
1388     }
1389
1390     check_unfold(@unfold, $fw, 'protocol');
1391     check_unfold(@unfold, $fw, 'sport');
1392     check_unfold(@unfold, $fw, 'dport');
1393
1394     if (@unfold == 0) {
1395         printrule($domain, $table, $chain, $fw);
1396         return;
1397     }
1398
1399     sub dofr {
1400         my $fw = shift;
1401         my ($domain, $table, $chain) = (shift, shift, shift);
1402         my ($parent, $key, $values) = (shift, shift, shift);
1403
1404         foreach my $value (@$values) {
1405             $parent->{$key} = $value;
1406
1407             if (@_) {
1408                 dofr($fw, $domain, $table, $chain, @_);
1409             } else {
1410                 printrule($domain, $table, $chain, $fw);
1411             }
1412         }
1413     }
1414
1415     dofr($fw, $domain, $table, $chain, @unfold);
1416 }
1417
1418 # convert a bunch of internal rule structures in iptables calls,
1419 # unfold arrays during that
1420 sub mkrules($) {
1421     my $fw = shift;
1422
1423     foreach my $domain (to_array $fw->{domain}) {
1424         foreach my $table (to_array $fw->{table}) {
1425             foreach my $chain (to_array $fw->{chain}) {
1426                 mkrules2($domain, $table, $chain, $fw);
1427             }
1428         }
1429     }
1430 }
1431
1432 sub filter_domains($) {
1433     my $domains = shift;
1434     my $result = [];
1435
1436     foreach my $domain (to_array $domains) {
1437         next if exists $option{domain}
1438           and $domain ne $option{domain};
1439
1440         eval {
1441             initialize_domain($domain);
1442         };
1443         error($@) if $@;
1444
1445         push @$result, $domain;
1446     }
1447
1448     return @$result == 1 ? $result->[0] : $result;
1449 }
1450
1451 # parse a keyword from a module definition
1452 sub parse_keyword($$$$) {
1453     my ($current, $def, $keyword, $negated_ref) = @_;
1454
1455     my $params = $def->{params};
1456
1457     my $value;
1458
1459     my $negated;
1460     if ($$negated_ref && exists $def->{pre_negation}) {
1461         $negated = 1;
1462         undef $$negated_ref;
1463     }
1464
1465     unless (defined $params) {
1466         undef $value;
1467     } elsif (ref $params && ref $params eq 'CODE') {
1468         $value = &$params($current);
1469     } elsif ($params eq 'm') {
1470         $value = bless [ to_array getvalues() ], 'multi';
1471     } elsif ($params =~ /^[a-z]/) {
1472         if (exists $def->{negation} and not $negated) {
1473             my $token = peek_token();
1474             if ($token eq '!') {
1475                 require_next_token;
1476                 $negated = 1;
1477             }
1478         }
1479
1480         my @params;
1481         foreach my $p (split(//, $params)) {
1482             if ($p eq 's') {
1483                 push @params, getvar();
1484             } elsif ($p eq 'c') {
1485                 my @v = to_array getvalues(undef, undef,
1486                                            non_empty => 1);
1487                 push @params, join(',', @v);
1488             } else {
1489                 die;
1490             }
1491         }
1492
1493         $value = @params == 1
1494           ? $params[0]
1495             : bless \@params, 'params';
1496     } elsif ($params == 1) {
1497         if (exists $def->{negation} and not $negated) {
1498             my $token = peek_token();
1499             if ($token eq '!') {
1500                 require_next_token;
1501                 $negated = 1;
1502             }
1503         }
1504
1505         $value = getvalues();
1506
1507         warning("log-prefix is too long; truncating to 29 characters: '$1'")
1508           if $keyword eq 'log-prefix' && $value =~ s,^(.{29}).+$,$1,;
1509     } else {
1510         if (exists $def->{negation} and not $negated) {
1511             my $token = peek_token();
1512             if ($token eq '!') {
1513                 require_next_token;
1514                 $negated = 1;
1515             }
1516         }
1517
1518         $value = bless [ map {
1519             getvar()
1520         } (1..$params) ], 'params';
1521     }
1522
1523     $value = bless [ $value ], exists $def->{pre_negation} ? 'pre_negated' : 'negated'
1524       if $negated;
1525
1526     return $value;
1527 }
1528
1529 # parse options of a module
1530 sub parse_option($$$$$) {
1531     my ($def, $current, $store, $keyword, $negated_ref) = @_;
1532
1533     while (exists $def->{alias}) {
1534         ($keyword, $def) = @{$def->{alias}};
1535         die unless defined $def;
1536     }
1537
1538     $store->{$keyword}
1539       = parse_keyword($current, $def,
1540                       $keyword, $negated_ref);
1541     return 1;
1542 }
1543
1544 # parse options for a protocol module definition
1545 sub parse_protocol_options($$$$) {
1546     my ($current, $proto, $keyword, $negated_ref) = @_;
1547
1548     my $domain_family = $current->{'domain_family'};
1549     my $proto_defs = $proto_defs{$domain_family};
1550     return unless defined $proto_defs;
1551
1552     my $proto_def = $proto_defs->{$proto};
1553     return unless defined $proto_def and
1554       exists $proto_def->{keywords}{$keyword};
1555
1556     my $module_name = $proto eq 'icmpv6' ? 'icmp6' : $proto;
1557     my $module = { name => $module_name,
1558                    options => {},
1559                  };
1560     push @{$current->{match}}, $module;
1561
1562     return parse_option($proto_def->{keywords}{$keyword},
1563                         $current, $module->{options},
1564                         $keyword, $negated_ref);
1565 }
1566
1567 sub copy_on_write($$) {
1568     my ($rule, $key) = @_;
1569     return unless exists $rule->{cow}{$key};
1570     $rule->{$key} = {%{$rule->{$key}}};
1571     delete $rule->{cow}{$key};
1572 }
1573
1574 sub clone_match($) {
1575     my $match = shift;
1576     return { name => $match->{name},
1577              options => { %{$match->{options}} },
1578            };
1579 }
1580
1581 sub new_level(\%$) {
1582     my ($current, $prev) = @_;
1583
1584     %$current = ();
1585     if (defined $prev) {
1586         # copy data from previous level
1587         $current->{cow} = { keywords => 1, };
1588         $current->{keywords} = $prev->{keywords};
1589         $current->{builtin} = { %{$prev->{builtin}} };
1590         $current->{match} = [ map { clone_match($_) } @{$prev->{match}} ];
1591         $current->{action} = { %{$prev->{action}} };
1592         foreach my $key (qw(domain domain_family table chain protocol sport dport)) {
1593             $current->{$key} = $prev->{$key}
1594               if exists $prev->{$key};
1595         }
1596     } else {
1597         $current->{cow} = {};
1598         $current->{keywords} = {};
1599         $current->{builtin} = {};
1600         $current->{match} = [];
1601         $current->{action} = {};
1602     }
1603 }
1604
1605 sub merge_keywords(\%$$$) {
1606     my ($rule, $type, $module, $keywords) = @_;
1607     copy_on_write($rule, 'keywords');
1608     while (my ($name, $def) = each %$keywords) {
1609         $rule->{keywords}{$name} = [ $type, $module, $def ];
1610     }
1611 }
1612
1613 sub set_domain(\%$) {
1614     my ($rule, $domain) = @_;
1615
1616     my $filtered_domain = filter_domains($domain);
1617     my $domain_family;
1618     unless (ref $domain) {
1619         $domain_family = $domain eq 'ip6' ? 'ip' : $domain;
1620     } elsif (@$domain == 0) {
1621         $domain_family = 'none';
1622     } elsif (grep { not /^ip6?$/s } @$domain) {
1623         error('Cannot combine non-IP domains');
1624     } else {
1625         $domain_family = 'ip';
1626     }
1627
1628     $rule->{domain_family} = $domain_family;
1629     $rule->{keywords} = get_builtin_keywords($domain_family);
1630     delete $rule->{cow}{keywords};
1631
1632     $rule->{domain} = $stack[0]{auto}{DOMAIN} = $filtered_domain;
1633 }
1634
1635 sub set_module_target(\%$$) {
1636     my ($rule, $name, $defs) = @_;
1637
1638     if ($name eq 'TCPMSS') {
1639         my $protos = $rule->{protocol};
1640         error('No protocol specified before TCPMSS')
1641           unless defined $protos;
1642         foreach my $proto (to_array $protos) {
1643             error('TCPMSS not available for protocol "$proto"')
1644               unless $proto eq 'tcp';
1645         }
1646     }
1647
1648     $rule->{action} = {
1649         type => 'target',
1650         target => $name,
1651     };
1652
1653     merge_keywords(%$rule, 'target', $name, $defs->{keywords});
1654 }
1655
1656 # the main parser loop: read tokens, convert them into internal rule
1657 # structures
1658 sub enter($$) {
1659     my $lev = shift;  # current recursion depth
1660     my $prev = shift; # previous rule hash
1661
1662     # enter is the core of the firewall setup, it is a
1663     # simple parser program that recognizes keywords and
1664     # retreives parameters to set up the kernel routing
1665     # chains
1666
1667     my $base_level = $script->{base_level} || 0;
1668     die if $base_level > $lev;
1669
1670     my %current;
1671     new_level(%current, $prev);
1672
1673     # read keywords 1 by 1 and dump into parser
1674     while (defined (my $keyword = next_token())) {
1675         # check if the current rule should be negated
1676         my $negated = $keyword eq '!';
1677         if ($negated) {
1678             # negation. get the next word which contains the 'real'
1679             # rule
1680             $keyword = getvar();
1681
1682             error('unexpected end of file after negation')
1683               unless defined $keyword;
1684         }
1685
1686         # the core: parse all data
1687         for ($keyword)
1688         {
1689             # deprecated keyword?
1690             if (exists $deprecated_keywords{$keyword}) {
1691                 my $new_keyword = $deprecated_keywords{$keyword};
1692                 warning("'$keyword' is deprecated, please use '$new_keyword' instead");
1693                 $keyword = $new_keyword;
1694             }
1695
1696             # effectuation operator
1697             if ($keyword eq ';') {
1698                 if ($current{has_rule} and not $current{action}{type}) {
1699                     # something is wrong when a rule was specifiedd,
1700                     # but no action
1701                     error('No action defined; did you mean "NOP"?');
1702                 }
1703
1704                 error('No chain defined') unless exists $current{chain};
1705
1706                 $current{script} = { filename => $script->{filename},
1707                                      line => $script->{line},
1708                                    };
1709
1710                 mkrules(\%current);
1711
1712                 # and clean up variables set in this level
1713                 new_level(%current, $prev);
1714
1715                 next;
1716             }
1717
1718             # conditional expression
1719             if ($keyword eq '@if') {
1720                 unless (eval_bool(getvalues)) {
1721                     collect_tokens;
1722                     my $token = peek_token();
1723                     require_next_token() if $token and $token eq '@else';
1724                 }
1725
1726                 next;
1727             }
1728
1729             if ($keyword eq '@else') {
1730                 # hack: if this "else" has not been eaten by the "if"
1731                 # handler above, we believe it came from an if clause
1732                 # which evaluated "true" - remove the "else" part now.
1733                 collect_tokens;
1734                 next;
1735             }
1736
1737             # hooks for custom shell commands
1738             if ($keyword eq 'hook') {
1739                 error('"hook" must be the first token in a command')
1740                   if exists $current{domain};
1741
1742                 my $position = getvar();
1743                 my $hooks;
1744                 if ($position eq 'pre') {
1745                     $hooks = \@pre_hooks;
1746                 } elsif ($position eq 'post') {
1747                     $hooks = \@post_hooks;
1748                 } else {
1749                     error("Invalid hook position: '$position'");
1750                 }
1751
1752                 push @$hooks, getvar();
1753
1754                 expect_token(';');
1755                 next;
1756             }
1757
1758             # recursing operators
1759             if ($keyword eq '{') {
1760                 # push stack
1761                 my $old_stack_depth = @stack;
1762
1763                 unshift @stack, { auto => { %{$stack[0]{auto} || {}} } };
1764
1765                 # recurse
1766                 enter($lev + 1, \%current);
1767
1768                 # pop stack
1769                 shift @stack;
1770                 die unless @stack == $old_stack_depth;
1771
1772                 # after a block, the command is finished, clear this
1773                 # level
1774                 new_level(%current, $prev);
1775
1776                 next;
1777             }
1778
1779             if ($keyword eq '}') {
1780                 error('Unmatched "}"')
1781                   if $lev <= $base_level;
1782
1783                 # consistency check: check if they havn't forgotten
1784                 # the ';' before the last statement
1785                 error('Missing semicolon before "}"')
1786                   if $current{has_rule};
1787
1788                 # and exit
1789                 return;
1790             }
1791
1792             # include another file
1793             if ($keyword eq '@include' or $keyword eq 'include') {
1794                 my @files = collect_filenames to_array getvalues;
1795                 $keyword = next_token;
1796                 error('Missing ";" - "include FILENAME" must be the last command in a rule')
1797                   unless defined $keyword and $keyword eq ';';
1798
1799                 foreach my $filename (@files) {
1800                     # save old script, open new script
1801                     my $old_script = $script;
1802                     open_script($filename);
1803                     $script->{base_level} = $lev + 1;
1804
1805                     # push stack
1806                     my $old_stack_depth = @stack;
1807
1808                     my $stack = {};
1809
1810                     if (@stack > 0) {
1811                         # include files may set variables for their parent
1812                         $stack->{vars} = ($stack[0]{vars} ||= {});
1813                         $stack->{functions} = ($stack[0]{functions} ||= {});
1814                         $stack->{auto} = { %{ $stack[0]{auto} || {} } };
1815                     }
1816
1817                     unshift @stack, $stack;
1818
1819                     # parse the script
1820                     enter($lev + 1, \%current);
1821
1822                     # pop stack
1823                     shift @stack;
1824                     die unless @stack == $old_stack_depth;
1825
1826                     # restore old script
1827                     $script = $old_script;
1828                 }
1829
1830                 next;
1831             }
1832
1833             # definition of a variable or function
1834             if ($keyword eq '@def' or $keyword eq 'def') {
1835                 error('"def" must be the first token in a command')
1836                   if $current{has_rule};
1837
1838                 my $type = require_next_token();
1839                 if ($type eq '$') {
1840                     my $name = require_next_token();
1841                     error('invalid variable name')
1842                       unless $name =~ /^\w+$/;
1843
1844                     expect_token('=');
1845
1846                     my $value = getvalues(undef, undef, allow_negation => 1);
1847
1848                     expect_token(';');
1849
1850                     $stack[0]{vars}{$name} = $value
1851                       unless exists $stack[-1]{vars}{$name};
1852                 } elsif ($type eq '&') {
1853                     my $name = require_next_token();
1854                     error('invalid function name')
1855                       unless $name =~ /^\w+$/;
1856
1857                     expect_token('(', 'function parameter list or "()" expected');
1858
1859                     my @params;
1860                     while (1) {
1861                         my $token = require_next_token();
1862                         last if $token eq ')';
1863
1864                         if (@params > 0) {
1865                             error('"," expected')
1866                               unless $token eq ',';
1867
1868                             $token = require_next_token();
1869                         }
1870
1871                         error('"$" and parameter name expected')
1872                           unless $token eq '$';
1873
1874                         $token = require_next_token();
1875                         error('invalid function parameter name')
1876                           unless $token =~ /^\w+$/;
1877
1878                         push @params, $token;
1879                     }
1880
1881                     my %function;
1882
1883                     $function{params} = \@params;
1884
1885                     expect_token('=');
1886
1887                     my $tokens = collect_tokens();
1888                     $function{block} = 1 if grep { $_ eq '{' } @$tokens;
1889                     $function{tokens} = $tokens;
1890
1891                     $stack[0]{functions}{$name} = \%function
1892                       unless exists $stack[-1]{functions}{$name};
1893                 } else {
1894                     error('"$" (variable) or "&" (function) expected');
1895                 }
1896
1897                 next;
1898             }
1899
1900             # def references
1901             if ($keyword eq '$') {
1902                 error('variable references are only allowed as keyword parameter');
1903             }
1904
1905             if ($keyword eq '&') {
1906                 my $name = require_next_token;
1907                 error('function name expected')
1908                   unless $name =~ /^\w+$/;
1909
1910                 my $function;
1911                 foreach (@stack) {
1912                     $function = $_->{functions}{$name};
1913                     last if defined $function;
1914                 }
1915                 error("no such function: \&$name")
1916                   unless defined $function;
1917
1918                 my $paramdef = $function->{params};
1919                 die unless defined $paramdef;
1920
1921                 my @params = get_function_params(allow_negation => 1);
1922
1923                 error("Wrong number of parameters for function '\&$name': "
1924                       . @$paramdef . " expected, " . @params . " given")
1925                   unless @params == @$paramdef;
1926
1927                 my %vars;
1928                 for (my $i = 0; $i < @params; $i++) {
1929                     $vars{$paramdef->[$i]} = $params[$i];
1930                 }
1931
1932                 if ($function->{block}) {
1933                     # block {} always ends the current rule, so if the
1934                     # function contains a block, we have to require
1935                     # the calling rule also ends here
1936                     expect_token(';');
1937                 }
1938
1939                 my @tokens = @{$function->{tokens}};
1940                 for (my $i = 0; $i < @tokens; $i++) {
1941                     if ($tokens[$i] eq '$' and $i + 1 < @tokens and
1942                         exists $vars{$tokens[$i + 1]}) {
1943                         my @value = to_array($vars{$tokens[$i + 1]});
1944                         @value = ('(', @value, ')')
1945                           unless @tokens == 1;
1946                         splice(@tokens, $i, 2, @value);
1947                         $i += @value - 2;
1948                     } elsif ($tokens[$i] =~ m,^"(.*)"$,) {
1949                         $tokens[$i] =~ s,\$(\w+),exists $vars{$1} ? $vars{$1} : "\$$1",eg;
1950                     }
1951                 }
1952
1953                 unshift @{$script->{tokens}}, @tokens;
1954
1955                 next;
1956             }
1957
1958             # where to put the rule?
1959             if ($keyword eq 'domain') {
1960                 error('Domain is already specified')
1961                   if exists $current{domain};
1962
1963                 set_domain(%current, getvalues());
1964                 next;
1965             }
1966
1967             if ($keyword eq 'table') {
1968                 error('Table is already specified')
1969                   if exists $current{table};
1970                 $current{table} = $stack[0]{auto}{TABLE} = getvalues();
1971
1972                 set_domain(%current, 'ip')
1973                   unless exists $current{domain};
1974
1975                 next;
1976             }
1977
1978             if ($keyword eq 'chain') {
1979                 error('Chain is already specified')
1980                   if exists $current{chain};
1981                 $current{chain} = $stack[0]{auto}{CHAIN} = getvalues();
1982
1983                 # ferm 1.1 allowed lower case built-in chain names
1984                 foreach (ref $current{chain} ? @{$current{chain}} : $current{chain}) {
1985                     error('Please write built-in chain names in upper case')
1986                       if /^(?:input|forward|output|prerouting|postrouting)$/;
1987                 }
1988
1989                 set_domain(%current, 'ip')
1990                   unless exists $current{domain};
1991
1992                 $current{table} = 'filter'
1993                   unless exists $current{table};
1994
1995                 next;
1996             }
1997
1998             error('Chain must be specified')
1999               unless exists $current{chain};
2000
2001             # policy for built-in chain
2002             if ($keyword eq 'policy') {
2003                 error('Cannot specify matches for policy')
2004                   if $current{has_rule};
2005
2006                 my $policy = getvar();
2007                 error("Invalid policy target: $policy")
2008                   unless $policy =~ /^(?:ACCEPT|DROP)$/;
2009
2010                 expect_token(';');
2011
2012                 foreach my $domain (to_array $current{domain}) {
2013                     foreach my $table (to_array $current{table}) {
2014                         foreach my $chain (to_array $current{chain}) {
2015                             $domains{$domain}{tables}{$table}{chains}{$chain}{policy} = $policy;
2016                         }
2017                     }
2018                 }
2019
2020                 new_level(%current, $prev);
2021                 next;
2022             }
2023
2024             # create a subchain
2025             if ($keyword eq '@subchain' or $keyword eq 'subchain') {
2026                 error('Chain must be specified')
2027                   unless exists $current{chain};
2028
2029                 error('No rule specified before "@subchain"')
2030                   unless $current{has_rule};
2031
2032                 my $subchain;
2033                 $keyword = next_token();
2034
2035                 if ($keyword =~ /^(["'])(.*)\1$/s) {
2036                     $subchain = $2;
2037                     $keyword = next_token();
2038                 } else {
2039                     $subchain = 'ferm_auto_' . ++$auto_chain;
2040                 }
2041
2042                 error('"{" or chain name expected after "@subchain"')
2043                   unless $keyword eq '{';
2044
2045                 # create a deep copy of %current, only containing values
2046                 # which must be in the subchain
2047                 my %inner = ( cow => { keywords => 1, },
2048                               keywords => $current{keywords},
2049                               builtin => {},
2050                               action => {},
2051                             );
2052                 $inner{domain} = $current{domain};
2053                 $inner{domain_family} = $current{domain_family};
2054                 $inner{table} = $current{table};
2055                 $inner{chain} = $inner{auto}{CHAIN} = $subchain;
2056                 $inner{protocol} = $current{protocol}
2057                   if exists $current{protocol};
2058
2059                 # enter the block
2060                 enter(1, \%inner);
2061
2062                 # now handle the parent - it's a jump to the sub chain
2063                 $current{action} = { type => 'jump',
2064                                      chain => $subchain,
2065                                    };
2066
2067                 $current{script} = { filename => $script->{filename},
2068                                      line => $script->{line},
2069                                    };
2070
2071                 mkrules(\%current);
2072
2073                 # and clean up variables set in this level
2074                 new_level(%current, $prev);
2075
2076                 next;
2077             }
2078
2079             # everything else must be part of a "real" rule, not just
2080             # "policy only"
2081             $current{has_rule}++;
2082
2083             # extended parameters:
2084             if ($keyword =~ /^mod(?:ule)?$/) {
2085                 foreach my $module (to_array getvalues) {
2086                     next if grep { $_->{name} eq $module } @{$current{match}};
2087
2088                     my $domain_family = $current{domain_family};
2089                     my $defs = $match_defs{$domain_family}{$module};
2090                     if (not defined $defs and exists $current{protocol}) {
2091                         my $proto = $current{protocol};
2092                         unless (ref $proto) {
2093                             $proto = netfilter_canonical_protocol($current{protocol});
2094                             $defs = $proto_defs{$domain_family}{$proto}
2095                               if netfilter_protocol_module($proto) eq $module;
2096                         }
2097                     }
2098
2099                     push @{$current{match}}, { name => $module,
2100                                                options => {},
2101                                              };
2102
2103                     merge_keywords(%current, 'match', $module, $defs->{keywords})
2104                       if defined $defs;
2105                 }
2106
2107                 next;
2108             }
2109
2110             # keywords from $current{keywords}
2111
2112             if (exists $current{keywords}{$keyword}) {
2113                 my ($type, $module, $def) = @{$current{keywords}{$keyword}};
2114                 my $store;
2115                 if ($type eq 'builtin') {
2116                     $store = $current{builtin};
2117                 } elsif ($type eq 'match') {
2118                     $store = (grep { $_->{name} eq $module } @{$current{match}})[-1]->{options};
2119                 } elsif ($type eq 'target') {
2120                     $store = $current{target_options} ||= {};
2121                 } else {
2122                     die;
2123                 }
2124
2125                 parse_option($def, \%current, $store, $keyword, \$negated);
2126                 next;
2127             }
2128
2129             ###
2130             # actions
2131             #
2132
2133             # jump action
2134             if ($keyword eq 'jump') {
2135                 error('There can only one action per rule')
2136                   if defined $current{action}{type};
2137                 my $chain = getvar();
2138                 if (is_netfilter_core_target($chain)) {
2139                     $current{action} = {
2140                         type => 'target',
2141                         target => $chain,
2142                     };
2143                 } elsif (my $defs = is_netfilter_module_target($current{domain_family}, $chain)) {
2144                     set_module_target(%current, $chain, $defs);
2145                 } else {
2146                     $current{action} = { type => 'jump',
2147                                          chain => $chain,
2148                                        };
2149                 }
2150                 next;
2151             };
2152
2153             # goto action
2154             if ($keyword eq 'realgoto') {
2155                 error('There can only one action per rule')
2156                   if defined $current{action}{type};
2157                 $current{action} = { type => 'goto',
2158                                      chain => getvar(),
2159                                    };
2160                 next;
2161             };
2162
2163             # action keywords
2164             if (is_netfilter_core_target($keyword)) {
2165                 error('There can only one action per rule')
2166                   if defined $current{action}{type};
2167                 $current{action} = { type => 'target',
2168                                      target => $keyword,
2169                                    };
2170                 next;
2171             }
2172
2173             if ($keyword eq 'NOP') {
2174                 error('There can only one action per rule')
2175                   if defined $current{action}{type};
2176                 $current{action} = { type => 'nop',
2177                                    };
2178                 next;
2179             }
2180
2181             if (my $defs = is_netfilter_module_target($current{domain_family}, $keyword)) {
2182                 error('There can only one action per rule')
2183                   if defined $current{action}{type};
2184
2185                 set_module_target(%current, $keyword, $defs);
2186                 next;
2187             }
2188
2189             my $proto = $current{protocol};
2190
2191             ###
2192             # protocol specific options
2193             #
2194
2195             if (defined $proto and not ref $proto) {
2196                 $proto = netfilter_canonical_protocol($proto);
2197
2198                 if ($proto eq 'icmp') {
2199                     my $domains = $current{domain};
2200                     $proto = 'icmpv6' if not ref $domains and $domains eq 'ip6';
2201                 }
2202
2203                 parse_protocol_options(\%current, $proto, $keyword, \$negated)
2204                   and next;
2205             }
2206
2207             if ($keyword eq 'proto') {
2208                 $current{protocol} = parse_keyword(\%current,
2209                                                    { params => 1,
2210                                                      negation => 1 },
2211                                                    'proto', \$negated);
2212                 next;
2213             }
2214
2215             # port switches
2216             if ($keyword =~ /^[sd]port$/) {
2217                 error('To use sport or dport, you have to specify "proto tcp" or "proto udp" first')
2218                   unless defined $proto and grep { /^(?:tcp|udp|udplite|dccp|sctp)$/ } to_array $proto;
2219
2220                 $current{$keyword} = getvalues(undef, undef,
2221                                                allow_negation => 1);
2222                 next;
2223             }
2224
2225             # default
2226             error("Unrecognized keyword: $keyword");
2227         }
2228
2229         # if the rule didn't reset the negated flag, it's not
2230         # supported
2231         error("Doesn't support negation: $keyword")
2232           if $negated;
2233     }
2234
2235     error('Missing "}" at end of file')
2236       if $lev > $base_level;
2237
2238     # consistency check: check if they havn't forgotten
2239     # the ';' before the last statement
2240     error("Missing semicolon before end of file")
2241       if exists $current{domain};
2242 }
2243
2244 sub execute_command {
2245     my ($command, $script) = @_;
2246
2247     print LINES "$command\n"
2248       if $option{lines};
2249     return if $option{noexec};
2250
2251     my $ret = system($command);
2252     unless ($ret == 0) {
2253         if ($? == -1) {
2254             print STDERR "failed to execute: $!\n";
2255             exit 1;
2256         } elsif ($? & 0x7f) {
2257             printf STDERR "child died with signal %d\n", $? & 0x7f;
2258             return 1;
2259         } else {
2260             print STDERR "(rule declared in $script->{filename}:$script->{line})\n"
2261               if defined $script;
2262             return $? >> 8;
2263         }
2264     }
2265
2266     return;
2267 }
2268
2269 sub execute_slow($$) {
2270     my ($domain, $domain_info) = @_;
2271
2272     my $domain_cmd = $domain_info->{tools}{tables};
2273
2274     my $status;
2275     while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2276         my $table_cmd = "$domain_cmd -t $table";
2277
2278         # reset chain policies
2279         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2280             next unless $chain_info->{builtin} or
2281               (not $table_info->{has_builtin} and
2282                is_netfilter_builtin_chain($table, $chain));
2283             $status ||= execute_command("$table_cmd -P $chain ACCEPT");
2284         }
2285
2286         # clear
2287         $status ||= execute_command("$table_cmd -F");
2288         $status ||= execute_command("$table_cmd -X");
2289
2290         next if $option{flush};
2291
2292         # create chains / set policy
2293         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2294             if (exists $chain_info->{policy}) {
2295                 $status ||= execute_command("$table_cmd -P $chain $chain_info->{policy}")
2296                   unless $chain_info->{policy} eq 'ACCEPT';
2297             } elsif (not is_netfilter_builtin_chain($table, $chain)) {
2298                 $status ||= execute_command("$table_cmd -N $chain");
2299             }
2300         }
2301
2302         # dump rules
2303         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2304             my $chain_cmd = "$table_cmd -A $chain";
2305             foreach my $rule (@{$chain_info->{rules}}) {
2306                 $status ||= execute_command($chain_cmd . $rule->{rule});
2307             }
2308         }
2309     }
2310
2311     return $status;
2312 }
2313
2314 sub rules_to_save($$) {
2315     my ($domain, $domain_info) = @_;
2316
2317     # convert this into an iptables-save text
2318     my $result = "# Generated by ferm $VERSION on " . localtime() . "\n";
2319
2320     while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2321         # select table
2322         $result .= '*' . $table . "\n";
2323
2324         # create chains / set policy
2325         foreach my $chain (sort keys %{$table_info->{chains}}) {
2326             my $chain_info = $table_info->{chains}{$chain};
2327             my $policy = $option{flush} ? 'ACCEPT' : $chain_info->{policy};
2328             unless (defined $policy) {
2329                 if (is_netfilter_builtin_chain($table, $chain)) {
2330                     $policy = 'ACCEPT';
2331                 } else {
2332                     $policy = '-';
2333                 }
2334             }
2335             $result .= ":$chain $policy\ [0:0]\n";
2336         }
2337
2338         next if $option{flush};
2339
2340         # dump rules
2341         foreach my $chain (sort keys %{$table_info->{chains}}) {
2342             my $chain_info = $table_info->{chains}{$chain};
2343             foreach my $rule (@{$chain_info->{rules}}) {
2344                 $result .= "-A $chain$rule->{rule}\n";
2345             }
2346         }
2347
2348         # do it
2349         $result .= "COMMIT\n";
2350     }
2351
2352     return $result;
2353 }
2354
2355 sub restore_domain($$) {
2356     my ($domain, $save) = @_;
2357
2358     my $path = $domains{$domain}{tools}{'tables-restore'};
2359
2360     local *RESTORE;
2361     open RESTORE, "|$path"
2362       or die "Failed to run $path: $!\n";
2363
2364     print RESTORE $save;
2365
2366     close RESTORE
2367       or die "Failed to run $path\n";
2368 }
2369
2370 sub execute_fast($$) {
2371     my ($domain, $domain_info) = @_;
2372
2373     my $save = rules_to_save($domain, $domain_info);
2374
2375     if ($option{lines}) {
2376         print LINES "$domain_info->{tools}{'tables-restore'} <<EOT\n"
2377           if $option{shell};
2378         print LINES $save;
2379         print LINES "EOT\n"
2380           if $option{shell};
2381     }
2382
2383     return if $option{noexec};
2384
2385     eval {
2386         restore_domain($domain, $save);
2387     };
2388     if ($@) {
2389         print STDERR $@;
2390         return 1;
2391     }
2392
2393     return;
2394 }
2395
2396 sub rollback() {
2397     my $error;
2398     while (my ($domain, $domain_info) = each %domains) {
2399         next unless $domain_info->{enabled};
2400         unless (defined $domain_info->{tools}{'tables-restore'}) {
2401             print STDERR "Cannot rollback domain '$domain' because there is no ${domain}tables-restore\n";
2402             next;
2403         }
2404
2405         my $reset = '';
2406         while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2407             my $reset_chain = '';
2408             foreach my $chain (keys %{$table_info->{chains}{$table}}) {
2409                 next unless is_netfilter_builtin_chain($table, $chain);
2410                 $reset_chain .= ":${chain} ACCEPT [0:0]\n";
2411             }
2412             $reset .= "*${table}\n${reset_chain}COMMIT\n"
2413               if length $reset_chain;
2414         }
2415
2416         $reset .= $domain_info->{previous}
2417           if defined $domain_info->{previous};
2418
2419         restore_domain($domain, $reset);
2420     }
2421
2422     print STDERR "\nFirewall rules rolled back.\n" unless $error;
2423     exit 1;
2424 }
2425
2426 sub alrm_handler {
2427     # do nothing, just interrupt a system call
2428 }
2429
2430 sub confirm_rules() {
2431     $SIG{ALRM} = \&alrm_handler;
2432
2433     alarm(5);
2434
2435     print STDERR "\n"
2436       . "ferm has applied the new firewall rules.\n"
2437         . "Please type 'yes' to confirm:\n";
2438     STDERR->flush();
2439
2440     alarm(30);
2441
2442     my $line = '';
2443     STDIN->sysread($line, 3);
2444
2445     eval {
2446         require POSIX;
2447         POSIX::tcflush(*STDIN, 2);
2448     };
2449     print STDERR "$@" if $@;
2450
2451     $SIG{ALRM} = 'DEFAULT';
2452
2453     return $line eq 'yes';
2454 }
2455
2456 # end of ferm
2457
2458 __END__
2459
2460 =head1 NAME
2461
2462 ferm - a firewall rule parser for linux
2463
2464 =head1 SYNOPSIS
2465
2466 B<ferm> I<options> I<inputfiles>
2467
2468 =head1 OPTIONS
2469
2470  -n, --noexec      Do not execute the rules, just simulate
2471  -F, --flush       Flush all netfilter tables managed by ferm
2472  -l, --lines       Show all rules that were created
2473  -i, --interactive Interactive mode: revert if user does not confirm
2474  --remote          Remote mode; ignore host specific configuration.
2475                    This implies --noexec and --lines.
2476  -V, --version     Show current version number
2477  -h, --help        Look at this text
2478  --fast            Generate an iptables-save file, used by iptables-restore
2479  --shell           Generate a shell script which calls iptables-restore
2480  --domain {ip|ip6} Handle only the specified domain
2481  --def '$name=v'   Override a variable
2482
2483 =cut