src/ferm

   1 #!/usr/bin/perl
   2
   3 #
   4 # ferm, a firewall setup program that makes firewall rules easy!
   5 #
   6 # Copyright (C) 2001-2007 Auke Kok, Max Kellermann
   7 #
   8 # Comments, questions, greetings and additions to this program
   9 # may be sent to <ferm@foo-projects.org>
  10 #
  11
  12 #
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2 of the License, or
  16 # (at your option) any later version.
  17 #
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  26 #
  27
  28 # $Id$
  29
  30 BEGIN {
  31     eval { require strict; import strict; };
  32     $has_strict = not $@;
  33     if ($@) {
  34         # we need no vars.pm if there is not even strict.pm
  35         $INC{'vars.pm'} = 1;
  36         *vars::import = sub {};
  37     } else {
  38         require IO::Handle;
  39     }
  40
  41     eval { require Getopt::Long; import Getopt::Long; };
  42     $has_getopt = not $@;
  43 }
  44
  45 use vars qw($has_strict $has_getopt);
  46
  47 use vars qw($DATE $VERSION);
  48
  49 # subversion keyword magic
  50 $DATE = '$Date$' =~ m,(\d{4})-(\d\d)-(\d\d), ? $1.$2.$3 : '';
  51
  52 $VERSION = '2.0';
  53 $VERSION .= '~svn' . $DATE;
  54
  55 ## interface variables
  56 # %option = command line and other options
  57 use vars qw(%option);
  58
  59 ## hooks
  60 use vars qw(@pre_hooks @post_hooks);
  61
  62 ## parser variables
  63 # $script: current script file
  64 # @stack = ferm's parser stack containing local variables
  65 # $auto_chain = index for the next auto-generated chain
  66 use vars qw($script @stack $auto_chain);
  67
  68 ## netfilter variables
  69 # %domains = state information about all domains ("ip" and "ip6")
  70 # - initialized: domain initialization is done
  71 # - tools: hash providing the paths of the domain's tools
  72 # - previous: save file of the previous ruleset, for rollback
  73 # - reset: has this domain already been reset?
  74 # - tables{$name}: ferm state information about tables
  75 #   - chains{$chain}: ferm state information about the chains
  76 #     - builtin: whether this is a built-in chain
  77 use vars qw(%domains);
  78
  79 ## constants
  80 use vars qw(%deprecated_keywords);
  81
  82 # keywords from ferm 1.1 which are deprecated, and the new one; these
  83 # are automatically replaced, and a warning is printed
  84 %deprecated_keywords = ( goto => 'jump',
  85                        );
  86
  87 # these hashes provide the Netfilter module definitions
  88 use vars qw(%proto_defs %match_defs %target_defs);
  89
  90 #
  91 # This subsubsystem allows you to support (most) new netfilter modules
  92 # in ferm.  Add a call to one of the "add_XY_def()" functions below.
  93 #
  94 # Ok, now about the cryptic syntax: the function "add_XY_def()"
  95 # registers a new module.  There are three kinds of modules: protocol
  96 # module (e.g. TCP, ICMP), match modules (e.g. state, physdev) and
  97 # target modules (e.g. DNAT, MARK).
  98 #
  99 # The first parameter is always the module name which is passed to
 100 # iptables with "-p", "-m" or "-j" (depending on which kind of module
 101 # this is).
 102 #
 103 # After that, you add an encoded string for each option the module
 104 # supports.  This is where it becomes tricky.
 105 #
 106 # foo           defaults to an option with one argument (which may be a ferm
 107 #               array)
 108 #
 109 # foo*0         option without any arguments
 110 #
 111 # foo=s         one argument which must not be a ferm array ('s' stands for
 112 #               'scalar')
 113 #
 114 # u32=m         an array which renders into multiple iptables options in one
 115 #               rule
 116 #
 117 # ctstate=c     one argument, if it's an array, pass it to iptables as a
 118 #               single comma separated value; example:
 119 #                 ctstate (ESTABLISHED RELATED)  translates to:
 120 #                 --ctstate ESTABLISHED,RELATED
 121 #
 122 # foo=sac       three arguments: scalar, array, comma separated; you may
 123 #               concatenate more than one letter code after the '='
 124 #
 125 # foo&bar       one argument; call the perl function '&bar()' which parses
 126 #               the argument
 127 #
 128 # !foo          negation is allowed and the '!' is written before the keyword
 129 #
 130 # foo!          same as above, but '!' is after the keyword and before the
 131 #               parameters
 132 #
 133 # to:=to-destination    makes "to" an alias for "to-destination"; you have
 134 #                       to add a declaration for option "to-destination"
 135 #
 136
 137 # add a module definition
 138 sub add_def_x {
 139     my $defs = shift;
 140     my $domain_family = shift;
 141     my $params_default = shift;
 142     my $name = shift;
 143     die if exists $defs->{$domain_family}{$name};
 144     my $def = $defs->{$domain_family}{$name} = {};
 145     foreach (@_) {
 146         my $keyword = $_;
 147         my $k = {};
 148
 149         my $params = $params_default;
 150         $params = $1 if $keyword =~ s,\*(\d+)$,,;
 151         $params = $1 if $keyword =~ s,=([acs]+|m)$,,;
 152         if ($keyword =~ s,&(\S+)$,,) {
 153             $params = eval "\\&$1";
 154             die $@ if $@;
 155         }
 156         $k->{params} = $params if $params;
 157
 158         $k->{negation} = $k->{pre_negation} = 1 if $keyword =~ s,^!,,;
 159         $k->{negation} = 1 if $keyword =~ s,!$,,;
 160
 161         $k->{alias} = [$1, $def->{keywords}{$1} || die] if $keyword =~ s,:=(\S+)$,,;
 162
 163         $def->{keywords}{$keyword} = $k;
 164     }
 165
 166     return $def;
 167 }
 168
 169 # add a protocol module definition
 170 sub add_proto_def_x(@) {
 171     my $domain_family = shift;
 172     add_def_x(\%proto_defs, $domain_family, 1, @_);
 173 }
 174
 175 # add a match module definition
 176 sub add_match_def_x(@) {
 177     my $domain_family = shift;
 178     add_def_x(\%match_defs, $domain_family, 1, @_);
 179 }
 180
 181 # add a target module definition
 182 sub add_target_def_x(@) {
 183     my $domain_family = shift;
 184     add_def_x(\%target_defs, $domain_family, 's', @_);
 185 }
 186
 187 sub add_def {
 188     my $defs = shift;
 189     add_def_x($defs, 'ip', @_);
 190 }
 191
 192 # add a protocol module definition
 193 sub add_proto_def(@) {
 194     add_def(\%proto_defs, 1, @_);
 195 }
 196
 197 # add a match module definition
 198 sub add_match_def(@) {
 199     add_def(\%match_defs, 1, @_);
 200 }
 201
 202 # add a target module definition
 203 sub add_target_def(@) {
 204     add_def(\%target_defs, 's', @_);
 205 }
 206
 207 add_proto_def 'dccp', qw(dccp-types!=c dccp-option!);
 208 add_proto_def 'mh', qw(mh-type!);
 209 add_proto_def 'icmp', qw(icmp-type!);
 210 add_proto_def 'icmpv6', qw(icmpv6-type! icmp-type:=icmpv6-type);
 211 add_proto_def 'sctp', qw(chunk-types!=sc);
 212 add_proto_def 'tcp', qw(tcp-flags!=cc !syn*0 tcp-option! mss);
 213 add_proto_def 'udp', qw();
 214
 215 add_match_def '',
 216   # --protocol
 217   qw(protocol! proto:=protocol),
 218   # --source, --destination
 219   qw(source! saddr:=source destination! daddr:=destination),
 220   # --in-interface
 221   qw(in-interface! interface:=in-interface if:=in-interface),
 222   # --out-interface
 223   qw(out-interface! outerface:=out-interface of:=out-interface),
 224   # --fragment
 225   qw(!fragment*0);
 226 add_match_def 'account', qw(aaddr=s aname=s ashort*0);
 227 add_match_def 'addrtype', qw(src-type dst-type);
 228 add_match_def 'ah', qw(ahspi! ahlen! ahres*0);
 229 add_match_def 'comment', qw(comment=s);
 230 add_match_def 'condition', qw(condition!);
 231 add_match_def 'connbytes', qw(!connbytes connbytes-dir connbytes-mode);
 232 add_match_def 'connlimit', qw(!connlimit-above connlimit-mask);
 233 add_match_def 'connmark', qw(mark);
 234 add_match_def 'conntrack', qw(ctstate=c ctproto ctorigsrc! ctorigdst!),
 235   qw(ctreplsrc! ctrepldst! ctstatus ctexpire=s);
 236 add_match_def 'dscp', qw(dscp dscp-class);
 237 add_match_def 'ecn', qw(ecn-tcp-cwr*0 ecn-tcp-ece*0 ecn-ip-ect);
 238 add_match_def 'esp', qw(espspi!);
 239 add_match_def 'eui64';
 240 add_match_def 'fuzzy', qw(lower-limit=s upper-limit=s);
 241 add_match_def 'hbh', qw(hbh-len! hbh-opts=c);
 242 add_match_def 'helper', qw(helper);
 243 add_match_def 'hl', qw(hl-eq! hl-lt=s hl-gt=s);
 244 add_match_def 'hashlimit', qw(hashlimit=s hashlimit-burst=s hashlimit-mode=s hashlimit-name=s),
 245   qw(hashlimit-htable-size=s hashlimit-htable-max=s),
 246   qw(hashlimit-htable-expire=s hashlimit-htable-gcinterval=s);
 247 add_match_def 'iprange', qw(!src-range !dst-range);
 248 add_match_def 'ipv4options', qw(ssrr*0 lsrr*0 no-srr*0 !rr*0 !ts*0 !ra*0 !any-opt*0);
 249 add_match_def 'ipv6header', qw(header!=c soft*0);
 250 add_match_def 'length', qw(length!);
 251 add_match_def 'limit', qw(limit=s limit-burst=s);
 252 add_match_def 'mac', qw(mac-source!);
 253 add_match_def 'mark', qw(mark);
 254 add_match_def 'multiport', qw(source-ports!&multiport_params),
 255   qw(destination-ports!&multiport_params ports!&multiport_params);
 256 add_match_def 'nth', qw(every counter start packet);
 257 add_match_def 'owner', qw(uid-owner gid-owner pid-owner sid-owner cmd-owner);
 258 add_match_def 'physdev', qw(physdev-in! physdev-out!),
 259   qw(!physdev-is-in*0 !physdev-is-out*0 !physdev-is-bridged*0);
 260 add_match_def 'pkttype', qw(pkt-type),
 261 add_match_def 'policy',
 262   qw(dir pol strict*0 reqid spi proto mode tunnel-src tunnel-dst next*0);
 263 add_match_def 'psd', qw(psd-weight-threshold psd-delay-threshold),
 264   qw(psd-lo-ports-weight psd-hi-ports-weight);
 265 add_match_def 'quota', qw(quota=s);
 266 add_match_def 'random', qw(average);
 267 add_match_def 'realm', qw(realm!);
 268 add_match_def 'recent', qw(name=s !set*0 !rcheck*0 !update*0 !seconds !hitcount rttl*0 rsource*0 rdest*0);
 269 add_match_def 'rt', qw(rt-type! rt-segsleft! rt-len! rt-0-res*0 rt-0-addrs=c rt-0-not-strict*0);
 270 add_match_def 'set', qw(set=sc);
 271 add_match_def 'state', qw(state=c);
 272 add_match_def 'statistic', qw(mode=s probability=s every=s packet=s);
 273 add_match_def 'string', qw(algo=s from=s to=s string hex-string);
 274 add_match_def 'tcpmss', qw(!mss);
 275 add_match_def 'time', qw(timestart=s timestop=s days=c datestart=s datestop=s),
 276   qw(!monthday=c !weekdays=c utc*0 localtz*0);
 277 add_match_def 'tos', qw(!tos);
 278 add_match_def 'ttl', qw(ttl-eq ttl-lt=s ttl-gt=s);
 279 add_match_def 'u32', qw(!u32=m);
 280
 281 add_target_def 'BALANCE', qw(to-destination to:=to-destination);
 282 add_target_def 'CLASSIFY', qw(set-class);
 283 add_target_def 'CLUSTERIP', qw(new*0 hashmode clustermac total-nodes local-node hash-init);
 284 add_target_def 'CONNMARK', qw(set-mark save-mark*0 restore-mark*0 mask);
 285 add_target_def 'CONNSECMARK', qw(save*0 restore*0);
 286 add_target_def 'DNAT', qw(to-destination=m to:=to-destination random*0);
 287 add_target_def 'DSCP', qw(set-dscp set-dscp-class);
 288 add_target_def 'ECN', qw(ecn-tcp-remove*0);
 289 add_target_def 'HL', qw(hl-set hl-dec hl-inc);
 290 add_target_def 'IPV4OPTSSTRIP';
 291 add_target_def 'LOG', qw(log-level log-prefix),
 292   qw(log-tcp-sequence*0 log-tcp-options*0 log-ip-options*0 log-uid*0);
 293 add_target_def 'MARK', qw(set-mark set-xmark and-mark or-mark xor-mark);
 294 add_target_def 'MASQUERADE', qw(to-ports random*0);
 295 add_target_def 'MIRROR';
 296 add_target_def 'NETMAP', qw(to);
 297 add_target_def 'NFLOG', qw(nflog-group nflog-prefix nflog-range nflog-threshold);
 298 add_target_def 'NFQUEUE', qw(queue-num);
 299 add_target_def 'NOTRACK';
 300 add_target_def 'REDIRECT', qw(to-ports random*0);
 301 add_target_def 'REJECT', qw(reject-with);
 302 add_target_def 'ROUTE', qw(oif iif gw continue*0 tee*0);
 303 add_target_def 'SAME', qw(to nodst*0 random*0);
 304 add_target_def 'SECMARK', qw(selctx);
 305 add_target_def 'SET', qw(add-set=sc del-set=sc);
 306 add_target_def 'SNAT', qw(to-source=m to:=to-source random*0);
 307 add_target_def 'TARPIT';
 308 add_target_def 'TCPMSS', qw(set-mss clamp-mss-to-pmtu*0);
 309 add_target_def 'TOS', qw(set-tos and-tos or-tos xor-tos);
 310 add_target_def 'TRACE';
 311 add_target_def 'TTL', qw(ttl-set ttl-dec ttl-inc);
 312 add_target_def 'ULOG', qw(ulog-nlgroup ulog-prefix ulog-cprange ulog-qthreshold);
 313
 314 add_match_def_x 'arp', '',
 315   # ip
 316   qw(source-ip! destination-ip! saddr:=source-ip daddr:=destination-ip),
 317   # mac
 318   qw(source-mac! destination-mac!),
 319   # --in-interface
 320   qw(in-interface! interface:=in-interface if:=in-interface),
 321   # --out-interface
 322   qw(out-interface! outerface:=out-interface of:=out-interface),
 323   # misc
 324   qw(h-length=s opcode=s h-type=s proto-type=s),
 325   qw(mangle-ip-s=s mangle-ip-d=s mangle-mac-s=s mangle-mac-d=s mangle-target=s);
 326
 327 add_match_def_x 'eb', '',
 328   # protocol
 329   qw(protocol! proto:=protocol),
 330   # --in-interface
 331   qw(in-interface! interface:=in-interface if:=in-interface),
 332   # --out-interface
 333   qw(out-interface! outerface:=out-interface of:=out-interface),
 334   # logical interface
 335   qw(logical-in! logical-out!),
 336   # --source, --destination
 337   qw(source! saddr:=source destination! daddr:=destination),
 338   # 802.3
 339   qw(802_3-sap! 802_3-type!),
 340   # arp
 341   qw(arp-opcode! arp-htype!=ss arp-ptype!=ss),
 342   qw(arp-ip-src! arp-ip-dst! arp-mac-src! arp-mac-dst!),
 343   # ip
 344   qw(ip-source! ip-destination! ip-tos! ip-protocol! ip-sport! ip-dport!),
 345   # mark_m
 346   qw(mark!),
 347   # pkttype
 348   qw(pkttype-type!),
 349   # stp
 350   qw(stp-type! stp-flags! stp-root-prio! stp-root-addr! stp-root-cost!),
 351   qw(stp-sender-prio! stp-sender-addr! stp-port! stp-msg-age! stp-max-age!),
 352   qw(stp-hello-time! stp-forward-delay!),
 353   # vlan
 354   qw(vlan-id! vlan-prio! vlan-encap!),
 355   # log
 356   qw(log*0 log-level=s log-prefix=s log-ip*0 log-arp*0);
 357
 358 add_target_def_x 'eb', 'arpreply', qw(arpreply-mac arpreply-target);
 359 add_target_def_x 'eb', 'dnat', qw(to-destination dnat-target);
 360 add_target_def_x 'eb', 'mark', qw(set-mark mark-target);
 361 add_target_def_x 'eb', 'redirect', qw(redirect-target);
 362 add_target_def_x 'eb', 'snat', qw(to-source snat-target);
 363
 364 use vars qw(%builtin_keywords);
 365
 366 sub get_builtin_keywords($) {
 367     my $domain_family = shift;
 368     return {} unless defined $domain_family;
 369
 370     return {%{$builtin_keywords{$domain_family}}}
 371       if exists $builtin_keywords{$domain_family};
 372
 373     return {} unless exists $match_defs{$domain_family};
 374     my $defs_kw = $match_defs{$domain_family}{''}{keywords};
 375     my %keywords = map { $_ => ['builtin', '', $defs_kw->{$_} ] } keys %$defs_kw;
 376
 377     $builtin_keywords{$domain_family} = \%keywords;
 378     return {%keywords};
 379 }
 380
 381 # parameter parser for ipt_multiport
 382 sub multiport_params {
 383     my $fw = shift;
 384
 385     # multiport only allows 15 ports at a time. For this
 386     # reason, we do a little magic here: split the ports
 387     # into portions of 15, and handle these portions as
 388     # array elements
 389
 390     my $proto = $fw->{builtin}{protocol};
 391     error('To use multiport, you have to specify "proto tcp" or "proto udp" first')
 392       unless defined $proto and grep { /^(?:tcp|udp|udplite)$/ } to_array($proto);
 393
 394     my $value = getvalues(undef, undef,
 395                           allow_negation => 1,
 396                           allow_array_negation => 1);
 397     if (ref $value and ref $value eq 'ARRAY') {
 398         my @value = @$value;
 399         my @params;
 400
 401         while (@value) {
 402             push @params, join(',', splice(@value, 0, 15));
 403         }
 404
 405         return @params == 1
 406           ? $params[0]
 407             : \@params;
 408     } else {
 409         return join_value(',', $value);
 410     }
 411 }
 412
 413 # initialize stack: command line definitions
 414 unshift @stack, {};
 415
 416 # Get command line stuff
 417 if ($has_getopt) {
 418     my ($opt_noexec, $opt_flush, $opt_lines, $opt_interactive,
 419         $opt_verbose, $opt_debug,
 420         $opt_help,
 421         $opt_version, $opt_test, $opt_fast, $opt_shell,
 422         $opt_domain);
 423
 424     Getopt::Long::Configure('bundling', 'auto_help', 'no_ignore_case',
 425                             'no_auto_abbrev');
 426
 427     sub opt_def {
 428         my ($opt, $value) = @_;
 429         die 'Invalid --def specification'
 430           unless $value =~ /^\$?(\w+)=(.*)$/s;
 431         my ($name, $unparsed_value) = ($1, $2);
 432         my $tokens = tokenize_string($unparsed_value);
 433         my $value = getvalues(\&next_array_token, $tokens);
 434         die 'Extra tokens after --def'
 435           if @$tokens > 0;
 436         $stack[0]{vars}{$name} = $value;
 437     }
 438
 439     local $SIG{__WARN__} = sub { die $_[0]; };
 440     GetOptions('noexec|n' => \$opt_noexec,
 441                'flush|F' => \$opt_flush,
 442                'lines|l' => \$opt_lines,
 443                'interactive|i' => \$opt_interactive,
 444                'verbose|v' => \$opt_verbose,
 445                'debug|d' => \$opt_debug,
 446                'help|h' => \$opt_help,
 447                'version|V' => \$opt_version,
 448                test => \$opt_test,
 449                remote => \$opt_test,
 450                fast => \$opt_fast,
 451                shell => \$opt_shell,
 452                'domain=s' => \$opt_domain,
 453                'def=s' => \&opt_def,
 454               );
 455
 456     if (defined $opt_help) {
 457         require Pod::Usage;
 458         Pod::Usage::pod2usage(-exitstatus => 0);
 459     }
 460
 461     if (defined $opt_version) {
 462         printversion();
 463         exit 0;
 464     };
 465
 466     $option{'noexec'} = (defined $opt_noexec);
 467     $option{flush} = defined $opt_flush;
 468     $option{'lines'} = (defined $opt_lines);
 469     $option{interactive} = (defined $opt_interactive);
 470     $option{test} = (defined $opt_test);
 471
 472     if ($option{test}) {
 473         $option{noexec} = 1;
 474         $option{lines} = 1;
 475     }
 476
 477     delete $option{interactive} if $option{noexec};
 478
 479     mydie('ferm interactive mode not possible: /dev/stdin is not a tty')
 480       if $option{interactive} and not -t STDIN;
 481     mydie('ferm interactive mode not possible: /dev/stderr is not a tty')
 482       if $option{interactive} and not -t STDERR;
 483
 484     $option{fast} = 1 if defined $opt_fast;
 485
 486     if (defined $opt_shell) {
 487         $option{$_} = 1 foreach qw(shell fast lines);
 488     }
 489
 490     $option{domain} = $opt_domain if defined $opt_domain;
 491
 492     print STDERR "Warning: ignoring the obsolete --debug option\n"
 493       if defined $opt_debug;
 494     print STDERR "Warning: ignoring the obsolete --verbose option\n"
 495       if defined $opt_verbose;
 496 } else {
 497     # tiny getopt emulation for microperl
 498     my $filename;
 499     foreach (@ARGV) {
 500         if ($_ eq '--noexec' or $_ eq '-n') {
 501             $option{noexec} = 1;
 502         } elsif ($_ eq '--lines' or $_ eq '-l') {
 503             $option{lines} = 1;
 504         } elsif ($_ eq '--fast') {
 505             $option{fast} = 1;
 506         } elsif ($_ eq '--test') {
 507             $option{test} = 1;
 508             $option{noexec} = 1;
 509             $option{lines} = 1;
 510         } elsif ($_ eq '--shell') {
 511             $option{$_} = 1 foreach qw(shell fast lines);
 512         } elsif (/^-/) {
 513             printf STDERR "Usage: ferm [--noexec] [--lines] [--fast] [--shell] FILENAME\n";
 514             exit 1;
 515         } else {
 516             $filename = $_;
 517         }
 518     }
 519     undef @ARGV;
 520     push @ARGV, $filename;
 521 }
 522
 523 unless (@ARGV == 1) {
 524     require Pod::Usage;
 525     Pod::Usage::pod2usage(-exitstatus => 1);
 526 }
 527
 528 if ($has_strict) {
 529     open LINES, ">&STDOUT" if $option{lines};
 530     open STDOUT, ">&STDERR" if $option{shell};
 531 } else {
 532     # microperl can't redirect file handles
 533     *LINES = *STDOUT;
 534
 535     if ($option{fast} and not $option{noexec}) {
 536         print STDERR "Sorry, ferm on microperl does not allow --fast without --noexec\n";
 537         exit 1
 538     }
 539 }
 540
 541 unshift @stack, {};
 542 open_script($ARGV[0]);
 543
 544 # parse all input recursively
 545 enter(0);
 546 die unless @stack == 2;
 547
 548 # execute all generated rules
 549 my $status;
 550
 551 foreach my $cmd (@pre_hooks) {
 552     print LINES "$cmd\n" if $option{lines};
 553     system($cmd) unless $option{noexec};
 554 }
 555
 556 while (my ($domain, $domain_info) = each %domains) {
 557     next unless $domain_info->{enabled};
 558     my $s = $option{fast} &&
 559       defined $domain_info->{tools}{'tables-restore'}
 560       ? execute_fast($domain, $domain_info)
 561         : execute_slow($domain, $domain_info);
 562     $status = $s if defined $s;
 563 }
 564
 565 foreach my $cmd (@post_hooks) {
 566     print "$cmd\n" if $option{lines};
 567     system($cmd) unless $option{noexec};
 568 }
 569
 570 if (defined $status) {
 571     rollback();
 572     exit $status;
 573 }
 574
 575 # ask user, and rollback if there is no confirmation
 576
 577 confirm_rules() or rollback() if $option{interactive};
 578
 579 exit 0;
 580
 581 # end of program execution!
 582
 583
 584 # funcs
 585
 586 sub printversion {
 587     print "ferm $VERSION\n";
 588     print "Copyright (C) 2001-2007 Auke Kok, Max Kellermann\n";
 589     print "This program is free software released under GPLv2.\n";
 590     print "See the included COPYING file for license details.\n";
 591 }
 592
 593
 594 sub mydie {
 595     print STDERR @_;
 596     print STDERR "\n";
 597     exit 1;
 598 }
 599
 600
 601 sub error {
 602     # returns a nice formatted error message, showing the
 603     # location of the error.
 604     my $tabs = 0;
 605     my @lines;
 606     my $l = 0;
 607     my @words = map { @$_ } @{$script->{past_tokens}};
 608
 609     for my $w ( 0 .. $#words ) {
 610         if ($words[$w] eq "\x29")
 611             { $l++ ; $lines[$l] = "    " x ($tabs-- -1) ;};
 612         if ($words[$w] eq "\x28")
 613             { $l++ ; $lines[$l] = "    " x $tabs++ ;};
 614         if ($words[$w] eq "\x7d")
 615             { $l++ ; $lines[$l] = "    " x ($tabs-- -1) ;};
 616         if ($words[$w] eq "\x7b")
 617             { $l++ ; $lines[$l] = "    " x $tabs++ ;};
 618         if ( $l > $#lines ) { $lines[$l] = "" };
 619         $lines[$l] .= $words[$w] . " ";
 620         if ($words[$w] eq "\x28")
 621             { $l++ ; $lines[$l] = "    " x $tabs ;};
 622         if (($words[$w] eq "\x29") && ($words[$w+1] ne "\x7b"))
 623             { $l++ ; $lines[$l] = "    " x $tabs ;};
 624         if ($words[$w] eq "\x7b")
 625             { $l++ ; $lines[$l] = "    " x $tabs ;};
 626         if (($words[$w] eq "\x7d") && ($words[$w+1] ne "\x7d"))
 627             { $l++ ; $lines[$l] = "    " x $tabs ;};
 628         if (($words[$w] eq "\x3b") && ($words[$w+1] ne "\x7d"))
 629             { $l++ ; $lines[$l] = "    " x $tabs ;}
 630         if ($words[$w-1] eq "option")
 631             { $l++ ; $lines[$l] = "    " x $tabs ;}
 632     }
 633     my $start = $#lines - 4;
 634     if ($start < 0) { $start = 0 } ;
 635     print STDERR "Error in $script->{filename} line $script->{line}:\n";
 636     for $l ( $start .. $#lines)
 637         { print STDERR $lines[$l]; if ($l != $#lines ) {print STDERR "\n"} ; };
 638     print STDERR "<--\n";
 639     mydie(@_);
 640 }
 641
 642 # print a warning message about code from an input file
 643 sub warning {
 644     print STDERR "Warning in $script->{filename} line $script->{line}: "
 645       . (shift) . "\n";
 646 }
 647
 648 sub find_tool($) {
 649     my $name = shift;
 650     return $name if $option{test};
 651     for my $path ('/sbin', split ':', $ENV{PATH}) {
 652         my $ret = "$path/$name";
 653         return $ret if -x $ret;
 654     }
 655     die "$name not found in PATH\n";
 656 }
 657
 658 sub initialize_domain {
 659     my $domain = shift;
 660
 661     return if exists $domains{$domain}{initialized};
 662
 663     die "Invalid domain '$domain'\n" unless $domain =~ /^(?:ip6?|arp|eb)$/;
 664
 665     my @tools = qw(tables);
 666     push @tools, qw(tables-save tables-restore)
 667       if $domain =~ /^ip6?$/;
 668
 669     # determine the location of this domain's tools
 670     foreach my $tool (@tools) {
 671         $domains{$domain}{tools}{$tool} = find_tool("${domain}${tool}");
 672     }
 673
 674     # make tables-save tell us about the state of this domain
 675     # (which tables and chains do exist?), also remember the old
 676     # save data which may be used later by the rollback function
 677     local *SAVE;
 678     if (!$option{test} &&
 679         exists $domains{$domain}{tools}{'tables-save'} &&
 680         open(SAVE, "$domains{$domain}{tools}{'tables-save'}|")) {
 681         my $save = '';
 682
 683         my $table_info;
 684         while (<SAVE>) {
 685             $save .= $_;
 686
 687             if (/^\*(\w+)/) {
 688                 my $table = $1;
 689                 $table_info = $domains{$domain}{tables}{$table} ||= {};
 690             } elsif (defined $table_info and /^:(\w+)\s+(\S+)/
 691                      and $2 ne '-') {
 692                 $table_info->{chains}{$1}{builtin} = 1;
 693                 $table_info->{has_builtin} = 1;
 694             }
 695         }
 696
 697         # for rollback
 698         $domains{$domain}{previous} = $save;
 699     }
 700
 701     $domains{$domain}{initialized} = 1;
 702 }
 703
 704 # split the an input string into words and delete comments
 705 sub tokenize_string($) {
 706     my $string = shift;
 707
 708     my @ret;
 709
 710     foreach my $word ($string =~ m/(".*?"|'.*?'|`.*?`|[!,=&\$\%\(\){};]|[-+\w\/\.:]+|@\w+|#)/g) {
 711         last if $word eq '#';
 712         push @ret, $word;
 713     }
 714
 715     return \@ret;
 716 }
 717
 718 # shift an array; helper function to be passed to &getvar / &getvalues
 719 sub next_array_token {
 720     my $array = shift;
 721     shift @$array;
 722 }
 723
 724 # read some more tokens from the input file into a buffer
 725 sub prepare_tokens() {
 726     my $tokens = $script->{tokens};
 727     while (@$tokens == 0) {
 728         my $handle = $script->{handle};
 729         my $line = <$handle>;
 730         return unless defined $line;
 731
 732         $script->{line} ++;
 733
 734         # the next parser stage eats this
 735         push @$tokens, @{tokenize_string($line)};
 736     }
 737
 738     return 1;
 739 }
 740
 741 # open a ferm sub script
 742 sub open_script($) {
 743     my $filename = shift;
 744
 745     for (my $s = $script; defined $s; $s = $s->{parent}) {
 746         mydie("Circular reference in $script->{filename} line $script->{line}: $filename")
 747           if $s->{filename} eq $filename;
 748     }
 749
 750     local *FILE;
 751     open FILE, "<$filename"
 752       or mydie("Failed to open $filename: $!");
 753     my $handle = *FILE;
 754
 755     $script = { filename => $filename,
 756                 handle => $handle,
 757                 line => 0,
 758                 past_tokens => [],
 759                 tokens => [],
 760                 parent => $script,
 761               };
 762
 763     return $script;
 764 }
 765
 766 # collect script filenames which are being included
 767 sub collect_filenames(@) {
 768     my @ret;
 769
 770     # determine the current script's parent directory for relative
 771     # file names
 772     die unless defined $script;
 773     my $parent_dir = $script->{filename} =~ m,^(.*/),
 774       ? $1 : './';
 775
 776     foreach my $pathname (@_) {
 777         # non-absolute file names are relative to the parent script's
 778         # file name
 779         $pathname = $parent_dir . $pathname
 780           unless $pathname =~ m,^/,;
 781
 782         if ($pathname =~ m,/$,) {
 783             # include all regular files in a directory
 784
 785             error("'$pathname' is not a directory")
 786               unless -d $pathname;
 787
 788             local *DIR;
 789             opendir DIR, $pathname
 790               or error("Failed to open directory '$pathname': $!");
 791             my @names = readdir DIR;
 792             closedir DIR;
 793
 794             # sort those names for a well-defined order
 795             foreach my $name (sort { $a cmp $b } @names) {
 796                 # don't include hidden and backup files
 797                 next if /^\.|~$/;
 798
 799                 my $filename = $pathname . $name;
 800                 push @ret, $filename
 801                   if -f $filename;
 802             }
 803         } elsif ($pathname =~ m,\|$,) {
 804             # run a program and use its output
 805             push @ret, $pathname;
 806         } elsif ($pathname =~ m,^\|,) {
 807             error('This kind of pipe is not allowed');
 808         } else {
 809             # include a regular file
 810
 811             error("'$pathname' is a directory; maybe use trailing '/' to include a directory?")
 812               if -d $pathname;
 813             error("'$pathname' is not a file")
 814               unless -f $pathname;
 815
 816             push @ret, $pathname;
 817         }
 818     }
 819
 820     return @ret;
 821 }
 822
 823 # peek a token from the queue, but don't remove it
 824 sub peek_token() {
 825     return unless prepare_tokens();
 826     return $script->{tokens}[0];
 827 }
 828
 829 # get a token from the queue
 830 sub next_token() {
 831     return unless prepare_tokens();
 832     my $token = shift @{$script->{tokens}};
 833
 834     # update $script->{past_tokens}
 835     my $past_tokens = $script->{past_tokens};
 836
 837     if (@$past_tokens > 0) {
 838         my $prev_token = $past_tokens->[-1][-1];
 839         $past_tokens->[-1] = @$past_tokens > 1 ? ['{'] : []
 840           if $prev_token eq ';';
 841         pop @$past_tokens
 842           if $prev_token eq '}';
 843     }
 844
 845     push @$past_tokens, [] if $token eq '{' or @$past_tokens == 0;
 846     push @{$past_tokens->[-1]}, $token;
 847
 848     # return
 849     return $token;
 850 }
 851
 852 sub expect_token($;$) {
 853     my $expect = shift;
 854     my $msg = shift;
 855     my $token = next_token();
 856     error($msg || "'$expect' expected")
 857       unless defined $token and $token eq $expect;
 858 }
 859
 860 # require that another token exists, and that it's not a "special"
 861 # token, e.g. ";" and "{"
 862 sub require_next_token {
 863     my $code = shift || \&next_token;
 864
 865     my $token = &$code(@_);
 866
 867     error('unexpected end of file')
 868       unless defined $token;
 869
 870     error("'$token' not allowed here")
 871       if $token =~ /^[;{}]$/;
 872
 873     return $token;
 874 }
 875
 876 # return the value of a variable
 877 sub variable_value($) {
 878     my $name = shift;
 879
 880     foreach (@stack) {
 881         return $_->{vars}{$name}
 882           if exists $_->{vars}{$name};
 883     }
 884
 885     return $stack[0]{auto}{$name}
 886       if exists $stack[0]{auto}{$name};
 887
 888     return;
 889 }
 890
 891 # determine the value of a variable, die if the value is an array
 892 sub string_variable_value($) {
 893     my $name = shift;
 894     my $value = variable_value($name);
 895
 896     error("variable '$name' must be a string, is an array")
 897       if ref $value;
 898
 899     return $value;
 900 }
 901
 902 # similar to the built-in "join" function, but also handle negated
 903 # values in a special way
 904 sub join_value($$) {
 905     my ($expr, $value) = @_;
 906
 907     unless (ref $value) {
 908         return $value;
 909     } elsif (ref $value eq 'ARRAY') {
 910         return join($expr, @$value);
 911     } elsif (ref $value eq 'negated') {
 912         # bless'negated' is a special marker for negated values
 913         $value = join_value($expr, $value->[0]);
 914         return bless [ $value ], 'negated';
 915     } else {
 916         die;
 917     }
 918 }
 919
 920 # returns the next parameter, which may either be a scalar or an array
 921 sub getvalues {
 922     my ($code, $param) = (shift, shift);
 923     my %options = @_;
 924
 925     my $token = require_next_token($code, $param);
 926
 927     if ($token eq '(') {
 928         # read an array until ")"
 929         my @wordlist;
 930
 931         for (;;) {
 932             $token = getvalues($code, $param,
 933                                parenthesis_allowed => 1,
 934                                comma_allowed => 1);
 935
 936             unless (ref $token) {
 937                 last if $token eq ')';
 938
 939                 if ($token eq ',') {
 940                     error('Comma is not allowed within arrays, please use only a space');
 941                     next;
 942                 }
 943
 944                 push @wordlist, $token;
 945             } elsif (ref $token eq 'ARRAY') {
 946                 push @wordlist, @$token;
 947             } else {
 948                 error('unknown toke type');
 949             }
 950         }
 951
 952         error('empty array not allowed here')
 953           unless @wordlist or not $options{non_empty};
 954
 955         return @wordlist == 1
 956           ? $wordlist[0]
 957             : \@wordlist;
 958     } elsif ($token =~ /^\`(.*)\`$/s) {
 959         # execute a shell command, insert output
 960         my $command = $1;
 961         my $output = `$command`;
 962         unless ($? == 0) {
 963             if ($? == -1) {
 964                 error("failed to execute: $!");
 965             } elsif ($? & 0x7f) {
 966                 error("child died with signal " . ($? & 0x7f));
 967             } elsif ($? >> 8) {
 968                 error("child exited with status " . ($? >> 8));
 969             }
 970         }
 971
 972         # remove comments
 973         $output =~ s/#.*//mg;
 974
 975         # tokenize
 976         my @tokens = grep { length } split /\s+/s, $output;
 977
 978         my @values;
 979         while (@tokens) {
 980             my $value = getvalues(\&next_array_token, \@tokens);
 981             push @values, to_array($value);
 982         }
 983
 984         # and recurse
 985         return @values == 1
 986           ? $values[0]
 987             : \@values;
 988     } elsif ($token =~ /^\'(.*)\'$/s) {
 989         # single quotes: a string
 990         return $1;
 991     } elsif ($token =~ /^\"(.*)\"$/s) {
 992         # double quotes: a string with escapes
 993         $token = $1;
 994         $token =~ s,\$(\w+),string_variable_value($1),eg;
 995         return $token;
 996     } elsif ($token eq '!') {
 997         error('negation is not allowed here')
 998           unless $options{allow_negation};
 999
1000         $token = getvalues($code, $param);
1001
1002         error('it is not possible to negate an array')
1003           if ref $token and not $options{allow_array_negation};
1004
1005         return bless [ $token ], 'negated';
1006     } elsif ($token eq ',') {
1007         return $token
1008           if $options{comma_allowed};
1009
1010         error('comma is not allowed here');
1011     } elsif ($token eq '=') {
1012         error('equals operator ("=") is not allowed here');
1013     } elsif ($token eq '$') {
1014         my $name = require_next_token($code, $param);
1015         error('variable name expected - if you want to concatenate strings, try using double quotes')
1016           unless $name =~ /^\w+$/;
1017
1018         my $value = variable_value($name);
1019
1020         error("no such variable: \$$name")
1021           unless defined $value;
1022
1023         return $value;
1024     } elsif ($token eq '&') {
1025         error("function calls are not allowed as keyword parameter");
1026     } elsif ($token eq ')' and not $options{parenthesis_allowed}) {
1027         error('Syntax error');
1028     } elsif ($token =~ /^@/) {
1029         if ($token eq '@resolve') {
1030             my @params = get_function_params();
1031             error('Usage: @resolve((hostname ...))')
1032               unless @params == 1;
1033             eval { require Net::DNS; };
1034             error('For the @resolve() function, you need the Perl library Net::DNS')
1035               if $@;
1036             my $type = 'A';
1037             my $resolver = new Net::DNS::Resolver;
1038             my @result;
1039             foreach my $hostname (to_array($params[0])) {
1040                 my $query = $resolver->search($hostname, $type);
1041                 error("DNS query for '$hostname' failed: " . $resolver->errorstring)
1042                   unless $query;
1043                 foreach my $rr ($query->answer) {
1044                     next unless $rr->type eq $type;
1045                     push @result, $rr->address;
1046                 }
1047             }
1048             return \@result;
1049         } else {
1050             error("unknown ferm built-in function");
1051         }
1052     } else {
1053         return $token;
1054     }
1055 }
1056
1057 # returns the next parameter, but only allow a scalar
1058 sub getvar {
1059     my $token = getvalues(@_);
1060
1061     error('array not allowed here')
1062       if ref $token and ref $token eq 'ARRAY';
1063
1064     return $token;
1065 }
1066
1067 sub get_function_params(%) {
1068     expect_token('(', 'function name must be followed by "()"');
1069
1070     my $token = peek_token();
1071     if ($token eq ')') {
1072         require_next_token;
1073         return;
1074     }
1075
1076     my @params;
1077
1078     while (1) {
1079         if (@params > 0) {
1080             $token = require_next_token();
1081             last
1082               if $token eq ')';
1083
1084             error('"," expected')
1085               unless $token eq ',';
1086         }
1087
1088         push @params, getvalues(undef, undef, @_);
1089     }
1090
1091     return @params;
1092 }
1093
1094 # collect all tokens in a flat array reference until the end of the
1095 # command is reached
1096 sub collect_tokens() {
1097     my @level;
1098     my @tokens;
1099
1100     while (1) {
1101         my $keyword = next_token();
1102         error('unexpected end of file within function/variable declaration')
1103           unless defined $keyword;
1104
1105         if ($keyword =~ /^[\{\(]$/) {
1106             push @level, $keyword;
1107         } elsif ($keyword =~ /^[\}\)]$/) {
1108             my $expected = $keyword;
1109             $expected =~ tr/\}\)/\{\(/;
1110             my $opener = pop @level;
1111             error("unmatched '$keyword'")
1112               unless defined $opener and $opener eq $expected;
1113         } elsif ($keyword eq ';' and @level == 0) {
1114             last;
1115         }
1116
1117         push @tokens, $keyword;
1118
1119         last
1120           if $keyword eq '}' and @level == 0;
1121     }
1122
1123     return \@tokens;
1124 }
1125
1126
1127 # returns the specified value as an array. dereference arrayrefs
1128 sub to_array($) {
1129     my $value = shift;
1130     die unless wantarray;
1131     die if @_;
1132     unless (ref $value) {
1133         return $value;
1134     } elsif (ref $value eq 'ARRAY') {
1135         return @$value;
1136     } else {
1137         die;
1138     }
1139 }
1140
1141 # evaluate the specified value as bool
1142 sub eval_bool($) {
1143     my $value = shift;
1144     die if wantarray;
1145     die if @_;
1146     unless (ref $value) {
1147         return $value;
1148     } elsif (ref $value eq 'ARRAY') {
1149         return @$value > 0;
1150     } else {
1151         die;
1152     }
1153 }
1154
1155 sub is_netfilter_core_target($) {
1156     my $target = shift;
1157     die unless defined $target and length $target;
1158
1159     return $target =~ /^(?:ACCEPT|DROP|RETURN|QUEUE)$/;
1160 }
1161
1162 sub is_netfilter_module_target($$) {
1163     my ($domain_family, $target) = @_;
1164     die unless defined $target and length $target;
1165
1166     return defined $domain_family &&
1167       exists $target_defs{$domain_family} &&
1168         exists $target_defs{$domain_family}{$target};
1169 }
1170
1171 sub is_netfilter_builtin_chain($$) {
1172     my ($table, $chain) = @_;
1173
1174     return grep { $_ eq $chain }
1175       qw(PREROUTING INPUT FORWARD OUTPUT POSTROUTING);
1176 }
1177
1178 sub netfilter_canonical_protocol($) {
1179     my $proto = shift;
1180     return 'icmpv6'
1181       if $proto eq 'ipv6-icmp';
1182     return 'mh'
1183       if $proto eq 'ipv6-mh';
1184     return $proto;
1185 }
1186
1187 sub netfilter_protocol_module($) {
1188     my $proto = shift;
1189     return unless defined $proto;
1190     return 'icmp6'
1191       if $proto eq 'icmpv6';
1192     return $proto;
1193 }
1194
1195 # escape the string in a way safe for the shell
1196 sub shell_escape($) {
1197     my $token = shift;
1198
1199     return $token if $token =~ /^[-_a-zA-Z0-9]+$/s;
1200
1201     if ($option{fast}) {
1202         # iptables-save/iptables-restore are quite buggy concerning
1203         # escaping and special characters... we're trying our best
1204         # here
1205
1206         $token =~ s,",',g;
1207         $token = '"' . $token . '"'
1208           if $token =~ /[\s\'\\;&]/s;
1209     } else {
1210         return $token
1211           if $token =~ /^\`.*\`$/;
1212         $token =~ s/'/\\'/g;
1213         $token = '\'' . $token . '\''
1214           if $token =~ /[\s\"\\;<>&|]/s;
1215     }
1216
1217     return $token;
1218 }
1219
1220 # append an option to the shell command line, using information from
1221 # the module definition (see %match_defs etc.)
1222 sub shell_append_option($$$) {
1223     my ($ref, $keyword, $value) = @_;
1224
1225     if (ref $value) {
1226         if (ref $value eq 'negated') {
1227             $value = $value->[0];
1228             $keyword .= ' !';
1229         } elsif (ref $value eq 'pre_negated') {
1230             $value = $value->[0];
1231             $$ref .= ' !';
1232         }
1233     }
1234
1235     unless (defined $value) {
1236         $$ref .= " --$keyword";
1237     } elsif (ref $value) {
1238         if (ref $value eq 'params') {
1239             $$ref .= " --$keyword ";
1240             $$ref .= join(' ', map { shell_escape($_) } @$value);
1241         } elsif (ref $value eq 'multi') {
1242             foreach (@$value) {
1243                 $$ref .= " --$keyword " . shell_escape($_);
1244             }
1245         } else {
1246             die;
1247         }
1248     } else {
1249         $$ref .= " --$keyword " . shell_escape($value);
1250     }
1251 }
1252
1253 # convert an internal rule structure into an iptables call
1254 sub tables($) {
1255     my $rule = shift;
1256
1257     my $domain = $rule->{domain};
1258     my $domain_info = $domains{$domain};
1259     $domain_info->{enabled} = 1;
1260     my $domain_family = $rule->{domain_family};
1261
1262     my $table = $rule->{table};
1263     my $table_info = $domain_info->{tables}{$table} ||= {};
1264
1265     my $chain = $rule->{chain};
1266     my $chain_info = $table_info->{chains}{$chain} ||= {};
1267     my $chain_rules = $chain_info->{rules} ||= [];
1268
1269     return if $option{flush};
1270
1271     # return if this is a declaration-only rule
1272     return
1273       unless $rule->{has_rule};
1274
1275     my $rr = '';
1276
1277     # general iptables options
1278
1279     while (my ($keyword, $value) = each %{$rule->{builtin}}) {
1280         shell_append_option(\$rr, $keyword, $value);
1281     }
1282
1283     #
1284     # match module options
1285     #
1286
1287     my %modules;
1288
1289     if (defined $rule->{builtin}{protocol}) {
1290         my $proto = $rule->{builtin}{protocol};
1291
1292         # special case: --dport and --sport for TCP/UDP
1293         if ($domain_family eq 'ip' and
1294             (exists $rule->{dport} or exists $rule->{sport}) and
1295             $proto =~ /^(?:tcp|udp|udplite|dccp|sctp)$/) {
1296             unless (exists $modules{$proto}) {
1297                 $rr .= " -m $proto";
1298                 $modules{$proto} = 1;
1299             }
1300
1301             shell_append_option(\$rr, 'dport', $rule->{dport})
1302               if exists $rule->{dport};
1303             shell_append_option(\$rr, 'sport', $rule->{sport})
1304               if exists $rule->{sport};
1305         }
1306     }
1307
1308     # modules stored in %match_defs
1309
1310     foreach my $match (@{$rule->{match}}) {
1311         my $module_name = $match->{name};
1312         unless (exists $modules{$module_name}) {
1313             $rr .= " -m $module_name";
1314             $modules{$module_name} = 1;
1315         }
1316
1317         while (my ($keyword, $value) = each %{$match->{options}}) {
1318             shell_append_option(\$rr, $keyword, $value);
1319         }
1320     }
1321
1322     #
1323     # target options
1324     #
1325
1326     my $action = $rule->{action};
1327     if ($action->{type} eq 'jump') {
1328         $table_info->{chains}{$action->{chain}}{rules} ||= [];
1329         $rr .= " -j " . $action->{chain};
1330     } elsif ($action->{type} eq 'goto') {
1331         $table_info->{chains}{$action->{chain}}{rules} ||= [];
1332         $rr .= " -g " . $action->{chain};
1333     } elsif ($action->{type} eq 'target') {
1334         $rr .= " -j " . $action->{target};
1335
1336         # targets stored in %target_defs
1337
1338         while (my ($keyword, $value) = each %{$rule->{target_options}}) {
1339             shell_append_option(\$rr, $keyword, $value);
1340         }
1341     } elsif ($action->{type} ne 'nop') {
1342         die;
1343     }
1344
1345     # this line is done
1346     push @$chain_rules, { rule => $rr,
1347                           script => $rule->{script},
1348                         };
1349 };
1350
1351 sub transform_rule($) {
1352     my $rule = shift;
1353
1354     $rule->{builtin}{protocol} = 'icmpv6'
1355       if $rule->{domain} eq 'ip6' and $rule->{builtin}{protocol} eq 'icmp';
1356 }
1357
1358 sub printrule($) {
1359     my $rule = shift;
1360
1361     transform_rule($rule);
1362
1363     # prints all rules in a hash
1364     tables($rule);
1365 }
1366
1367
1368 sub check_unfold(\@$$) {
1369     my ($unfold, $parent, $key) = @_;
1370
1371     return unless ref $parent->{$key} and
1372       ref $parent->{$key} eq 'ARRAY';
1373
1374     push @$unfold, $parent, $key, $parent->{$key};
1375 }
1376
1377 # convert a bunch of internal rule structures in iptables calls,
1378 # unfold arrays during that
1379 sub mkrules($) {
1380     # compile the list hashes into rules
1381     my $fw = shift;
1382
1383     my @unfold;
1384
1385     foreach my $key (qw(domain table chain)) {
1386         check_unfold(@unfold, $fw, $key);
1387     }
1388
1389     foreach my $key (keys %{$fw->{builtin}}) {
1390         check_unfold(@unfold, $fw->{builtin}, $key);
1391     }
1392
1393     foreach my $match (@{$fw->{match}}) {
1394         while (my ($key, $value) = each %{$match->{options}}) {
1395             check_unfold(@unfold, $match->{options}, $key);
1396         }
1397     }
1398
1399     check_unfold(@unfold, $fw, 'sport');
1400     check_unfold(@unfold, $fw, 'dport');
1401
1402     if (@unfold == 0) {
1403         printrule($fw);
1404         return;
1405     }
1406
1407     sub dofr {
1408         my $fw = shift;
1409         my ($parent, $key, $values) = (shift, shift, shift);
1410
1411         foreach my $value (@$values) {
1412             $parent->{$key} = $value;
1413
1414             if (@_) {
1415                 dofr($fw, @_);
1416             } else {
1417                 printrule($fw);
1418             }
1419         }
1420     }
1421
1422     dofr($fw, @unfold);
1423 }
1424
1425 sub filter_domains($) {
1426     my $domains = shift;
1427     my $result = [];
1428
1429     foreach my $domain (to_array $domains) {
1430         next if exists $option{domain}
1431           and $domain ne $option{domain};
1432
1433         eval {
1434             initialize_domain($domain);
1435         };
1436         error($@) if $@;
1437
1438         push @$result, $domain;
1439     }
1440
1441     return @$result == 1 ? $result->[0] : $result;
1442 }
1443
1444 # parse a keyword from a module definition
1445 sub parse_keyword($$$$) {
1446     my ($current, $def, $keyword, $negated_ref) = @_;
1447
1448     my $params = $def->{params};
1449
1450     my $value;
1451
1452     my $negated;
1453     if ($$negated_ref && exists $def->{pre_negation}) {
1454         $negated = 1;
1455         undef $$negated_ref;
1456     }
1457
1458     unless (defined $params) {
1459         undef $value;
1460     } elsif (ref $params && ref $params eq 'CODE') {
1461         $value = &$params($current);
1462     } elsif ($params eq 'm') {
1463         $value = bless [ to_array getvalues() ], 'multi';
1464     } elsif ($params =~ /^[a-z]/) {
1465         if (exists $def->{negation} and not $negated) {
1466             my $token = peek_token();
1467             if ($token eq '!') {
1468                 require_next_token;
1469                 $negated = 1;
1470             }
1471         }
1472
1473         my @params;
1474         foreach my $p (split(//, $params)) {
1475             if ($p eq 's') {
1476                 push @params, getvar();
1477             } elsif ($p eq 'c') {
1478                 my @v = to_array getvalues(undef, undef,
1479                                            non_empty => 1);
1480                 push @params, join(',', @v);
1481             } else {
1482                 die;
1483             }
1484         }
1485
1486         $value = @params == 1
1487           ? $params[0]
1488             : bless \@params, 'params';
1489     } elsif ($params == 1) {
1490         if (exists $def->{negation} and not $negated) {
1491             my $token = peek_token();
1492             if ($token eq '!') {
1493                 require_next_token;
1494                 $negated = 1;
1495             }
1496         }
1497
1498         $value = getvalues();
1499
1500         warning("log-prefix is too long; truncating to 29 characters: '$1'")
1501           if $keyword eq 'log-prefix' && $value =~ s,^(.{29}).+$,$1,;
1502     } else {
1503         if (exists $def->{negation} and not $negated) {
1504             my $token = peek_token();
1505             if ($token eq '!') {
1506                 require_next_token;
1507                 $negated = 1;
1508             }
1509         }
1510
1511         $value = bless [ map {
1512             getvar()
1513         } (1..$params) ], 'params';
1514     }
1515
1516     $value = bless [ $value ], exists $def->{pre_negation} ? 'pre_negated' : 'negated'
1517       if $negated;
1518
1519     return $value;
1520 }
1521
1522 # parse options of a module
1523 sub parse_option($$$$$) {
1524     my ($def, $current, $store, $keyword, $negated_ref) = @_;
1525
1526     while (exists $def->{alias}) {
1527         ($keyword, $def) = @{$def->{alias}};
1528         die unless defined $def;
1529     }
1530
1531     $store->{$keyword}
1532       = parse_keyword($current, $def,
1533                       $keyword, $negated_ref);
1534     $current->{has_rule} = 1;
1535     return 1;
1536 }
1537
1538 # parse options for a protocol module definition
1539 sub parse_protocol_options($$$$) {
1540     my ($current, $proto, $keyword, $negated_ref) = @_;
1541
1542     my $domain_family = $current->{'domain_family'};
1543     my $proto_defs = $proto_defs{$domain_family};
1544     return unless defined $proto_defs;
1545
1546     my $proto_def = $proto_defs->{$proto};
1547     return unless defined $proto_def and
1548       exists $proto_def->{keywords}{$keyword};
1549
1550     my $module_name = $proto eq 'icmpv6' ? 'icmp6' : $proto;
1551     my $module = { name => $module_name,
1552                    options => {},
1553                    defs => $proto_def,
1554                  };
1555     push @{$current->{match}}, $module;
1556
1557     return parse_option($proto_def->{keywords}{$keyword},
1558                         $current, $module->{options},
1559                         $keyword, $negated_ref);
1560 }
1561
1562 sub copy_on_write($$) {
1563     my ($rule, $key) = @_;
1564     return unless exists $rule->{cow}{$key};
1565     $rule->{$key} = {%{$rule->{$key}}};
1566     delete $rule->{cow}{$key};
1567 }
1568
1569 sub clone_match($) {
1570     my $match = shift;
1571     return { name => $match->{name},
1572              options => { %{$match->{options}} },
1573              defs => $match->{defs},
1574            };
1575 }
1576
1577 sub new_level(\%$) {
1578     my ($current, $prev) = @_;
1579
1580     %$current = ();
1581     if (defined $prev) {
1582         # copy data from previous level
1583         $current->{cow} = { keywords => 1, };
1584         $current->{keywords} = $prev->{keywords};
1585         $current->{builtin} = { %{$prev->{builtin}} };
1586         $current->{match} = [ map { clone_match($_) } @{$prev->{match}} ];
1587         $current->{action} = { %{$prev->{action}} };
1588         foreach my $key (qw(domain domain_family table chain sport dport)) {
1589             $current->{$key} = $prev->{$key}
1590               if exists $prev->{$key};
1591         }
1592     } else {
1593         $current->{cow} = {};
1594         $current->{keywords} = {};
1595         $current->{builtin} = {};
1596         $current->{match} = [];
1597         $current->{action} = {};
1598     }
1599 }
1600
1601 sub rule_defined(\%) {
1602     my $rule = shift;
1603     return defined($rule->{domain}) or
1604       keys(%{$rule->{builtin}}) > 0 or
1605       keys(%{$rule->{match}}) > 0 or
1606       keys(%{$rule->{action}}) > 0;
1607 }
1608
1609 sub set_domain(\%$) {
1610     my ($rule, $domain) = @_;
1611
1612     my $filtered_domain = filter_domains($domain);
1613     my $domain_family;
1614     unless (ref $domain) {
1615         $domain_family = $domain eq 'ip6' ? 'ip' : $domain;
1616     } elsif (@$domain == 0) {
1617         $domain_family = 'none';
1618     } elsif (grep { not /^ip6?$/s } @$domain) {
1619         error('Cannot combine non-IP domains');
1620     } else {
1621         $domain_family = 'ip';
1622     }
1623
1624     $rule->{domain_family} = $domain_family;
1625     $rule->{keywords} = get_builtin_keywords($domain_family);
1626     delete $rule->{cow}{keywords};
1627
1628     $rule->{domain} = $stack[0]{auto}{DOMAIN} = $filtered_domain;
1629 }
1630
1631 # the main parser loop: read tokens, convert them into internal rule
1632 # structures
1633 sub enter($$) {
1634     my $lev = shift;  # current recursion depth
1635     my $prev = shift; # previous rule hash
1636
1637     # enter is the core of the firewall setup, it is a
1638     # simple parser program that recognizes keywords and
1639     # retreives parameters to set up the kernel routing
1640     # chains
1641
1642     my $base_level = $script->{base_level} || 0;
1643     die if $base_level > $lev;
1644
1645     my %current;
1646     new_level(%current, $prev);
1647
1648     # read keywords 1 by 1 and dump into parser
1649     while (defined (my $keyword = next_token())) {
1650         # check if the current rule should be negated
1651         my $negated = $keyword eq '!';
1652         if ($negated) {
1653             # negation. get the next word which contains the 'real'
1654             # rule
1655             $keyword = getvar();
1656
1657             error('unexpected end of file after negation')
1658               unless defined $keyword;
1659         }
1660
1661         # the core: parse all data
1662         for ($keyword)
1663         {
1664             # deprecated keyword?
1665             if (exists $deprecated_keywords{$keyword}) {
1666                 my $new_keyword = $deprecated_keywords{$keyword};
1667                 warning("'$keyword' is deprecated, please use '$new_keyword' instead");
1668                 $keyword = $new_keyword;
1669             }
1670
1671             # effectuation operator
1672             if ($keyword eq ';') {
1673                 if ($current{has_rule} and not $current{action}{type}) {
1674                     # something is wrong when a rule was specifiedd,
1675                     # but no action
1676                     error('No action defined; did you mean "NOP"?');
1677                 }
1678
1679                 error('No chain defined') unless exists $current{chain};
1680
1681                 $current{script} = { filename => $script->{filename},
1682                                      line => $script->{line},
1683                                    };
1684
1685                 mkrules(\%current);
1686
1687                 # and clean up variables set in this level
1688                 new_level(%current, $prev);
1689
1690                 next;
1691             }
1692
1693             # conditional expression
1694             if ($keyword eq '@if') {
1695                 unless (eval_bool(getvalues)) {
1696                     collect_tokens;
1697                     my $token = peek_token();
1698                     require_next_token() if $token and $token eq '@else';
1699                 }
1700
1701                 next;
1702             }
1703
1704             if ($keyword eq '@else') {
1705                 # hack: if this "else" has not been eaten by the "if"
1706                 # handler above, we believe it came from an if clause
1707                 # which evaluated "true" - remove the "else" part now.
1708                 collect_tokens;
1709                 next;
1710             }
1711
1712             # hooks for custom shell commands
1713             if ($keyword eq 'hook') {
1714                 error('"hook" must be the first token in a command')
1715                   if rule_defined(%current);
1716
1717                 my $position = getvar();
1718                 my $hooks;
1719                 if ($position eq 'pre') {
1720                     $hooks = \@pre_hooks;
1721                 } elsif ($position eq 'post') {
1722                     $hooks = \@post_hooks;
1723                 } else {
1724                     error("Invalid hook position: '$position'");
1725                 }
1726
1727                 push @$hooks, getvar();
1728
1729                 expect_token(';');
1730                 next;
1731             }
1732
1733             # recursing operators
1734             if ($keyword eq '{') {
1735                 # push stack
1736                 my $old_stack_depth = @stack;
1737
1738                 unshift @stack, { auto => { %{$stack[0]{auto} || {}} } };
1739
1740                 # recurse
1741                 enter($lev + 1, \%current);
1742
1743                 # pop stack
1744                 shift @stack;
1745                 die unless @stack == $old_stack_depth;
1746
1747                 # after a block, the command is finished, clear this
1748                 # level
1749                 new_level(%current, $prev);
1750
1751                 next;
1752             }
1753
1754             if ($keyword eq '}') {
1755                 error('Unmatched "}"')
1756                   if $lev <= $base_level;
1757
1758                 # consistency check: check if they havn't forgotten
1759                 # the ';' before the last statement
1760                 error('Missing semicolon before "}"')
1761                   if $current{has_rule};
1762
1763                 # and exit
1764                 return;
1765             }
1766
1767             # include another file
1768             if ($keyword eq '@include' or $keyword eq 'include') {
1769                 my @files = collect_filenames to_array getvalues;
1770                 $keyword = next_token;
1771                 error('Missing ";" - "include FILENAME" must be the last command in a rule')
1772                   unless defined $keyword and $keyword eq ';';
1773
1774                 foreach my $filename (@files) {
1775                     # save old script, open new script
1776                     my $old_script = $script;
1777                     open_script($filename);
1778                     $script->{base_level} = $lev + 1;
1779
1780                     # push stack
1781                     my $old_stack_depth = @stack;
1782
1783                     my $stack = {};
1784
1785                     if (@stack > 0) {
1786                         # include files may set variables for their parent
1787                         $stack->{vars} = ($stack[0]{vars} ||= {});
1788                         $stack->{functions} = ($stack[0]{functions} ||= {});
1789                         $stack->{auto} = { %{ $stack[0]{auto} || {} } };
1790                     }
1791
1792                     unshift @stack, $stack;
1793
1794                     # parse the script
1795                     enter($lev + 1, \%current);
1796
1797                     # pop stack
1798                     shift @stack;
1799                     die unless @stack == $old_stack_depth;
1800
1801                     # restore old script
1802                     $script = $old_script;
1803                 }
1804
1805                 next;
1806             }
1807
1808             # definition of a variable or function
1809             if ($keyword eq '@def' or $keyword eq 'def') {
1810                 error('"def" must be the first token in a command')
1811                   if $current{has_rule};
1812
1813                 my $type = require_next_token();
1814                 if ($type eq '$') {
1815                     my $name = require_next_token();
1816                     error('invalid variable name')
1817                       unless $name =~ /^\w+$/;
1818
1819                     expect_token('=');
1820
1821                     my $value = getvalues(undef, undef, allow_negation => 1);
1822
1823                     expect_token(';');
1824
1825                     $stack[0]{vars}{$name} = $value
1826                       unless exists $stack[-1]{vars}{$name};
1827                 } elsif ($type eq '&') {
1828                     my $name = require_next_token();
1829                     error('invalid function name')
1830                       unless $name =~ /^\w+$/;
1831
1832                     expect_token('(', 'function parameter list or "()" expected');
1833
1834                     my @params;
1835                     while (1) {
1836                         my $token = require_next_token();
1837                         last if $token eq ')';
1838
1839                         if (@params > 0) {
1840                             error('"," expected')
1841                               unless $token eq ',';
1842
1843                             $token = require_next_token();
1844                         }
1845
1846                         error('"$" and parameter name expected')
1847                           unless $token eq '$';
1848
1849                         $token = require_next_token();
1850                         error('invalid function parameter name')
1851                           unless $token =~ /^\w+$/;
1852
1853                         push @params, $token;
1854                     }
1855
1856                     my %function;
1857
1858                     $function{params} = \@params;
1859
1860                     expect_token('=');
1861
1862                     my $tokens = collect_tokens();
1863                     $function{block} = 1 if grep { $_ eq '{' } @$tokens;
1864                     $function{tokens} = $tokens;
1865
1866                     $stack[0]{functions}{$name} = \%function
1867                       unless exists $stack[-1]{functions}{$name};
1868                 } else {
1869                     error('"$" (variable) or "&" (function) expected');
1870                 }
1871
1872                 next;
1873             }
1874
1875             # def references
1876             if ($keyword eq '$') {
1877                 error('variable references are only allowed as keyword parameter');
1878             }
1879
1880             if ($keyword eq '&') {
1881                 my $name = require_next_token;
1882                 error('function name expected')
1883                   unless $name =~ /^\w+$/;
1884
1885                 my $function;
1886                 foreach (@stack) {
1887                     $function = $_->{functions}{$name};
1888                     last if defined $function;
1889                 }
1890                 error("no such function: \&$name")
1891                   unless defined $function;
1892
1893                 my $paramdef = $function->{params};
1894                 die unless defined $paramdef;
1895
1896                 my @params = get_function_params(allow_negation => 1);
1897
1898                 error("Wrong number of parameters for function '\&$name': "
1899                       . @$paramdef . " expected, " . @params . " given")
1900                   unless @params == @$paramdef;
1901
1902                 my %vars;
1903                 for (my $i = 0; $i < @params; $i++) {
1904                     $vars{$paramdef->[$i]} = $params[$i];
1905                 }
1906
1907                 if ($function->{block}) {
1908                     # block {} always ends the current rule, so if the
1909                     # function contains a block, we have to require
1910                     # the calling rule also ends here
1911                     expect_token(';');
1912                 }
1913
1914                 my @tokens = @{$function->{tokens}};
1915                 for (my $i = 0; $i < @tokens; $i++) {
1916                     if ($tokens[$i] eq '$' and $i + 1 < @tokens and
1917                         exists $vars{$tokens[$i + 1]}) {
1918                         my @value = to_array($vars{$tokens[$i + 1]});
1919                         @value = ('(', @value, ')')
1920                           unless @tokens == 1;
1921                         splice(@tokens, $i, 2, @value);
1922                         $i += @value - 2;
1923                     } elsif ($tokens[$i] =~ m,^"(.*)"$,) {
1924                         $tokens[$i] =~ s,\$(\w+),exists $vars{$1} ? $vars{$1} : "\$$1",eg;
1925                     }
1926                 }
1927
1928                 unshift @{$script->{tokens}}, @tokens;
1929
1930                 next;
1931             }
1932
1933             # where to put the rule?
1934             if ($keyword eq 'domain') {
1935                 error('Domain is already specified')
1936                   if exists $current{domain};
1937
1938                 set_domain(%current, getvalues());
1939                 next;
1940             }
1941
1942             if ($keyword eq 'table') {
1943                 error('Table is already specified')
1944                   if exists $current{table};
1945                 $current{table} = $stack[0]{auto}{TABLE} = getvalues();
1946
1947                 set_domain(%current, 'ip')
1948                   unless exists $current{domain};
1949
1950                 next;
1951             }
1952
1953             if ($keyword eq 'chain') {
1954                 error('Chain is already specified')
1955                   if exists $current{chain};
1956                 $current{chain} = $stack[0]{auto}{CHAIN} = getvalues();
1957
1958                 # ferm 1.1 allowed lower case built-in chain names
1959                 foreach (ref $current{chain} ? @{$current{chain}} : $current{chain}) {
1960                     error('Please write built-in chain names in upper case')
1961                       if /^(?:input|forward|output|prerouting|postrouting)$/;
1962                 }
1963
1964                 set_domain(%current, 'ip')
1965                   unless exists $current{domain};
1966
1967                 $current{table} = 'filter'
1968                   unless exists $current{table};
1969
1970                 next;
1971             }
1972
1973             error('Chain must be specified')
1974               unless exists $current{chain};
1975
1976             # policy for built-in chain
1977             if ($keyword eq 'policy') {
1978                 error('Cannot specify matches for policy')
1979                   if $current{has_rule};
1980
1981                 my $policy = getvar();
1982                 error("Invalid policy target: $policy")
1983                   unless $policy =~ /^(?:ACCEPT|DROP)$/;
1984
1985                 expect_token(';');
1986
1987                 foreach my $domain (to_array $current{domain}) {
1988                     foreach my $table (to_array $current{table}) {
1989                         foreach my $chain (to_array $current{chain}) {
1990                             $domains{$domain}{tables}{$table}{chains}{$chain}{policy} = $policy;
1991                         }
1992                     }
1993                 }
1994
1995                 new_level(%current, $prev);
1996                 next;
1997             }
1998
1999             # create a subchain
2000             if ($keyword eq '@subchain' or $keyword eq 'subchain') {
2001                 error('Chain must be specified')
2002                   unless exists $current{chain};
2003
2004                 error('No rule specified before "@subchain"')
2005                   unless $current{has_rule};
2006
2007                 my $subchain;
2008                 $keyword = next_token();
2009
2010                 if ($keyword =~ /^(["'])(.*)\1$/s) {
2011                     $subchain = $2;
2012                     $keyword = next_token();
2013                 } else {
2014                     $subchain = 'ferm_auto_' . ++$auto_chain;
2015                 }
2016
2017                 error('"{" or chain name expected after "@subchain"')
2018                   unless $keyword eq '{';
2019
2020                 # create a deep copy of %current, only containing values
2021                 # which must be in the subchain
2022                 my %inner = ( cow => { keywords => 1, },
2023                               keywords => $current{keywords},
2024                               builtin => {},
2025                               action => {},
2026                             );
2027                 $inner{domain} = $current{domain};
2028                 $inner{domain_family} = $current{domain_family};
2029                 $inner{table} = $current{table};
2030                 $inner{chain} = $inner{auto}{CHAIN} = $subchain;
2031                 $inner{builtin}{protocol} = $current{builtin}{protocol}
2032                   if exists $current{builtin}{protocol};
2033
2034                 # enter the block
2035                 enter(1, \%inner);
2036
2037                 # now handle the parent - it's a jump to the sub chain
2038                 $current{action} = { type => 'jump',
2039                                      chain => $subchain,
2040                                    };
2041
2042                 $current{script} = { filename => $script->{filename},
2043                                      line => $script->{line},
2044                                    };
2045
2046                 mkrules(\%current);
2047
2048                 # and clean up variables set in this level
2049                 new_level(%current, $prev);
2050
2051                 next;
2052             }
2053
2054             # everything else must be part of a "real" rule, not just
2055             # "policy only"
2056             $current{has_rule}++;
2057
2058             # extended parameters:
2059             if ($keyword =~ /^mod(?:ule)?$/) {
2060                 foreach my $module (to_array getvalues) {
2061                     next if grep { $_->{name} eq $module } @{$current{match}};
2062
2063                     my $domain_family = $current{domain_family};
2064                     my $defs = $match_defs{$domain_family}{$module};
2065                     if (not defined $defs and exists $current{builtin}{protocol}) {
2066                         my $proto = $current{builtin}{protocol};
2067                         unless (ref $proto) {
2068                             $proto = netfilter_canonical_protocol($current{builtin}{protocol});
2069                             $defs = $proto_defs{$domain_family}{$proto}
2070                               if netfilter_protocol_module($proto) eq $module;
2071                         }
2072                     }
2073
2074                     push @{$current{match}}, { name => $module,
2075                                                options => {},
2076                                                defs => $defs,
2077                                              };
2078
2079                     if (defined $defs) {
2080                         copy_on_write(\%current, 'keywords');
2081                         while (my ($k, $def) = each %{$defs->{keywords}}) {
2082                             $current{keywords}{$k} = [ 'match', $module, $def ];
2083                         }
2084                     }
2085                 }
2086
2087                 next;
2088             }
2089
2090             # keywords from $current{keywords}
2091
2092             if (exists $current{keywords}{$keyword}) {
2093                 my ($type, $module, $def) = @{$current{keywords}{$keyword}};
2094                 my $store;
2095                 if ($type eq 'builtin') {
2096                     $store = $current{builtin};
2097                 } elsif ($type eq 'match') {
2098                     $store = (grep { $_->{name} eq $module } @{$current{match}})[-1]->{options};
2099                 } elsif ($type eq 'target') {
2100                     $store = $current{target_options} ||= {};
2101                 } else {
2102                     die;
2103                 }
2104
2105                 parse_option($def, \%current, $store, $keyword, \$negated);
2106                 next;
2107             }
2108
2109             ###
2110             # actions
2111             #
2112
2113             # jump action
2114             if ($keyword eq 'jump') {
2115                 error('There can only one action per rule')
2116                   if defined $current{action}{type};
2117                 my $chain = getvar();
2118                 if (is_netfilter_core_target($chain) or
2119                     is_netfilter_module_target($current{domain_family}, $chain)) {
2120                     my $defs = $target_defs{$current{domain_family}} &&
2121                       $target_defs{$current{domain_family}}{$chain};
2122                     $current{action} = { type => 'target',
2123                                          target => $chain,
2124                                          defs => $defs,
2125                                        };
2126
2127                     if (defined $defs) {
2128                         copy_on_write(\%current, 'keywords');
2129                         while (my ($k, $def) = each %{$defs->{keywords}}) {
2130                             $current{keywords}{$k} = [ 'target', $keyword, $def ];
2131                         }
2132                     }
2133                 } else {
2134                     $current{action} = { type => 'jump',
2135                                          chain => $chain,
2136                                        };
2137                 }
2138                 next;
2139             };
2140
2141             # goto action
2142             if ($keyword eq 'realgoto') {
2143                 error('There can only one action per rule')
2144                   if defined $current{action}{type};
2145                 $current{action} = { type => 'goto',
2146                                      chain => getvar(),
2147                                    };
2148                 next;
2149             };
2150
2151             # action keywords
2152             if (is_netfilter_core_target($keyword)) {
2153                 error('There can only one action per rule')
2154                   if defined $current{action}{type};
2155                 $current{action} = { type => 'target',
2156                                      target => $keyword,
2157                                    };
2158                 next;
2159             }
2160
2161             if ($keyword eq 'NOP') {
2162                 error('There can only one action per rule')
2163                   if defined $current{action}{type};
2164                 $current{action} = { type => 'nop',
2165                                    };
2166                 next;
2167             }
2168
2169             if (is_netfilter_module_target($current{domain_family}, $keyword)) {
2170                 error('There can only one action per rule')
2171                   if defined $current{action}{type};
2172
2173                 if ($keyword eq 'TCPMSS') {
2174                     my $protos = $current{builtin}{protocol};
2175                     error('No protocol specified before TCPMSS')
2176                       unless defined $protos;
2177                     foreach my $proto (to_array $protos) {
2178                         error('TCPMSS not available for protocol "$proto"')
2179                           unless $proto eq 'tcp';
2180                     }
2181                 }
2182
2183                 my $defs = $target_defs{$current{domain_family}}{$keyword};
2184
2185                 $current{action} = { type => 'target',
2186                                      target => $keyword,
2187                                      defs => $defs,
2188                                    };
2189
2190                 if (defined $defs) {
2191                     copy_on_write(\%current, 'keywords');
2192                     while (my ($k, $def) = each %{$defs->{keywords}}) {
2193                         $current{keywords}{$k} = [ 'target', $keyword, $def ];
2194                     }
2195                 }
2196
2197                 next;
2198             }
2199
2200             my $proto = $current{builtin}{protocol};
2201
2202             ###
2203             # protocol specific options
2204             #
2205
2206             if (defined $proto and not ref $proto) {
2207                 $proto = netfilter_canonical_protocol($proto);
2208
2209                 if ($proto eq 'icmp') {
2210                     my $domains = $current{domain};
2211                     $proto = 'icmpv6' if not ref $domains and $domains eq 'ip6';
2212                 }
2213
2214                 parse_protocol_options(\%current, $proto, $keyword, \$negated)
2215                   and next;
2216             }
2217
2218             # port switches
2219             if ($keyword =~ /^[sd]port$/) {
2220                 error('To use sport or dport, you have to specify "proto tcp" or "proto udp" first')
2221                   unless defined $proto and grep { /^(?:tcp|udp|udplite|dccp|sctp)$/ } to_array $proto;
2222
2223                 $current{$keyword} = getvalues(undef, undef,
2224                                                allow_negation => 1);
2225                 next;
2226             }
2227
2228             # default
2229             error("Unrecognized keyword: $keyword");
2230         }
2231
2232         # if the rule didn't reset the negated flag, it's not
2233         # supported
2234         error("Doesn't support negation: $keyword")
2235           if $negated;
2236     }
2237
2238     error('Missing "}" at end of file')
2239       if $lev > $base_level;
2240
2241     # consistency check: check if they havn't forgotten
2242     # the ';' before the last statement
2243     error("Missing semicolon before end of file")
2244       if $current{has_rule}; # XXX
2245 }
2246
2247 sub execute_command {
2248     my ($command, $script) = @_;
2249
2250     print LINES "$command\n"
2251       if $option{lines};
2252     return if $option{noexec};
2253
2254     my $ret = system($_);
2255     unless ($ret == 0) {
2256         if ($? == -1) {
2257             print STDERR "failed to execute: $!\n";
2258             exit 1;
2259         } elsif ($? & 0x7f) {
2260             printf STDERR "child died with signal %d\n", $? & 0x7f;
2261             return 1;
2262         } else {
2263             print STDERR "(rule declared in $script->{filename}:$script->{line})\n"
2264               if defined $script;
2265             return $? >> 8;
2266         }
2267     }
2268
2269     return;
2270 }
2271
2272 sub execute_slow($$) {
2273     my ($domain, $domain_info) = @_;
2274
2275     my $domain_cmd = $domain_info->{tools}{tables};
2276
2277     while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2278         my $table_cmd = "$domain_cmd -t $table";
2279
2280         # reset chain policies
2281         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2282             next unless $chain_info->{builtin} or
2283               (not $table_info->{has_builtin} and
2284                is_netfilter_builtin_chain($table, $chain));
2285             $status ||= execute_command("$table_cmd -P $chain ACCEPT");
2286         }
2287
2288         # clear
2289         $status ||= execute_command("$table_cmd -F");
2290         $status ||= execute_command("$table_cmd -X");
2291
2292         next if $option{flush};
2293
2294         # create chains / set policy
2295         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2296             if (exists $chain_info->{policy}) {
2297                 $status ||= execute_command("$table_cmd -P $chain $chain_info->{policy}")
2298                   unless $chain_info->{policy} eq 'ACCEPT';
2299             } elsif (not is_netfilter_builtin_chain($table, $chain)) {
2300                 $status ||= execute_command("$table_cmd -N $chain");
2301             }
2302         }
2303
2304         # dump rules
2305         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2306             my $chain_cmd = "$table_cmd -A $chain";
2307             foreach my $rule (@{$chain_info->{rules}}) {
2308                 $status ||= execute_command($chain_cmd . $rule->{rule});
2309             }
2310         }
2311     }
2312
2313     return $status;
2314 }
2315
2316 sub rules_to_save($$) {
2317     my ($domain, $domain_info) = @_;
2318
2319     # convert this into an iptables-save text
2320     my $result = "# Generated by ferm $VERSION on " . localtime() . "\n";
2321
2322     while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2323         # select table
2324         $result .= '*' . $table . "\n";
2325
2326         # create chains / set policy
2327         foreach my $chain (sort keys %{$table_info->{chains}}) {
2328             my $chain_info = $table_info->{chains}{$chain};
2329             my $policy = $option{flush} ? 'ACCEPT' : $chain_info->{policy};
2330             unless (defined $policy) {
2331                 if (is_netfilter_builtin_chain($table, $chain)) {
2332                     $policy = 'ACCEPT';
2333                 } else {
2334                     $policy = '-';
2335                 }
2336             }
2337             $result .= ":$chain $policy\ [0:0]\n";
2338         }
2339
2340         next if $option{flush};
2341
2342         # dump rules
2343         foreach my $chain (sort keys %{$table_info->{chains}}) {
2344             my $chain_info = $table_info->{chains}{$chain};
2345             foreach my $rule (@{$chain_info->{rules}}) {
2346                 $result .= "-A $chain$rule->{rule}\n";
2347             }
2348         }
2349
2350         # do it
2351         $result .= "COMMIT\n";
2352     }
2353
2354     return $result;
2355 }
2356
2357 sub restore_domain($$) {
2358     my ($domain, $save) = @_;
2359
2360     my $path = $domains{$domain}{tools}{'tables-restore'};
2361
2362     local *RESTORE;
2363     open RESTORE, "|$path"
2364       or die "Failed to run $path: $!\n";
2365
2366     print RESTORE $save;
2367
2368     close RESTORE
2369       or die "Failed to run $path\n";
2370 }
2371
2372 sub execute_fast($$) {
2373     my ($domain, $domain_info) = @_;
2374
2375     my $save = rules_to_save($domain, $domain_info);
2376
2377     if ($option{lines}) {
2378         print LINES "$domain_info->{tools}{'tables-restore'} <<EOT\n"
2379           if $option{shell};
2380         print LINES $save;
2381         print LINES "EOT\n"
2382           if $option{shell};
2383     }
2384
2385     return if $option{noexec};
2386
2387     eval {
2388         restore_domain($domain, $save);
2389     };
2390     if ($@) {
2391         print STDERR $@;
2392         return 1;
2393     }
2394
2395     return;
2396 }
2397
2398 sub rollback() {
2399     my $error;
2400     while (my ($domain, $domain_info) = each %domains) {
2401         next unless $domain_info->{enabled};
2402         unless (defined $domain_info->{tools}{'tables-restore'}) {
2403             print STDERR "Cannot rollback domain '$domain' because there is no ${domain}tables-restore\n";
2404             next;
2405         }
2406
2407         my $reset = '';
2408         while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2409             my $reset_chain = '';
2410             foreach my $chain (keys %{$table_info->{chains}{$table}}) {
2411                 next unless is_netfilter_builtin_chain($table, $chain);
2412                 $reset_chain .= ":${chain} ACCEPT [0:0]\n";
2413             }
2414             $reset .= "*${table}\n${reset_chain}COMMIT\n"
2415               if length $reset_chain;
2416         }
2417
2418         $reset .= $domain_info->{previous}
2419           if defined $domain_info->{previous};
2420
2421         restore_domain($domain, $reset);
2422     }
2423
2424     print STDERR "\nFirewall rules rolled back.\n" unless $error;
2425     exit 1;
2426 }
2427
2428 sub alrm_handler {
2429     # do nothing, just interrupt a system call
2430 }
2431
2432 sub confirm_rules() {
2433     $SIG{ALRM} = \&alrm_handler;
2434
2435     alarm(5);
2436
2437     print STDERR "\n"
2438       . "ferm has applied the new firewall rules.\n"
2439         . "Please type 'yes' to confirm:\n";
2440     STDERR->flush();
2441
2442     alarm(30);
2443
2444     my $line = '';
2445     STDIN->sysread($line, 3);
2446
2447     eval {
2448         require POSIX;
2449         POSIX::tcflush(*STDIN, 2);
2450     };
2451     print STDERR "$@" if $@;
2452
2453     $SIG{ALRM} = 'DEFAULT';
2454
2455     return $line eq 'yes';
2456 }
2457
2458 # end of ferm
2459
2460 __END__
2461
2462 =head1 NAME
2463
2464 ferm - a firewall rule parser for linux
2465
2466 =head1 SYNOPSIS
2467
2468 B<ferm> I<options> I<inputfiles>
2469
2470 =head1 OPTIONS
2471
2472  -n, --noexec      Do not execute the rules, just simulate
2473  -F, --flush       Flush all netfilter tables managed by ferm
2474  -l, --lines       Show all rules that were created
2475  -i, --interactive Interactive mode: revert if user does not confirm
2476  --remote          Remote mode; ignore host specific configuration.
2477                    This implies --noexec and --lines.
2478  -V, --version     Show current version number
2479  -h, --help        Look at this text
2480  --fast            Generate an iptables-save file, used by iptables-restore
2481  --shell           Generate a shell script which calls iptables-restore
2482  --domain {ip|ip6} Handle only the specified domain
2483  --def '$name=v'   Override a variable
2484
2485 =cut