src/ferm

   1 #!/usr/bin/perl
   2
   3 #
   4 # ferm, a firewall setup program that makes firewall rules easy!
   5 #
   6 # Copyright (C) 2001-2007 Auke Kok, Max Kellermann
   7 #
   8 # Comments, questions, greetings and additions to this program
   9 # may be sent to <ferm@foo-projects.org>
  10 #
  11
  12 #
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2 of the License, or
  16 # (at your option) any later version.
  17 #
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  26 #
  27
  28 # $Id$
  29
  30 BEGIN {
  31     eval { require strict; import strict; };
  32     $has_strict = not $@;
  33     if ($@) {
  34         # we need no vars.pm if there is not even strict.pm
  35         $INC{'vars.pm'} = 1;
  36         *vars::import = sub {};
  37     } else {
  38         require IO::Handle;
  39     }
  40
  41     eval { require Getopt::Long; import Getopt::Long; };
  42     $has_getopt = not $@;
  43 }
  44
  45 use vars qw($has_strict $has_getopt);
  46
  47 use vars qw($DATE $VERSION);
  48
  49 # subversion keyword magic
  50 $DATE = '$Date$' =~ m,(\d{4})-(\d\d)-(\d\d), ? $1.$2.$3 : '';
  51
  52 $VERSION = '2.0';
  53 $VERSION .= '~svn' . $DATE;
  54
  55 ## interface variables
  56 # %option = command line and other options
  57 use vars qw(%option);
  58
  59 ## hooks
  60 use vars qw(@pre_hooks @post_hooks);
  61
  62 ## parser variables
  63 # $script: current script file
  64 # @stack = ferm's parser stack containing local variables
  65 # $auto_chain = index for the next auto-generated chain
  66 use vars qw($script @stack $auto_chain);
  67
  68 ## netfilter variables
  69 # %domains = state information about all domains ("ip" and "ip6")
  70 # - initialized: domain initialization is done
  71 # - tools: hash providing the paths of the domain's tools
  72 # - previous: save file of the previous ruleset, for rollback
  73 # - tables{$name}: ferm state information about tables
  74 #   - has_builtin: whether built-in chains have been determined in this table
  75 #   - chains{$chain}: ferm state information about the chains
  76 #     - builtin: whether this is a built-in chain
  77 use vars qw(%domains);
  78
  79 ## constants
  80 use vars qw(%deprecated_keywords);
  81
  82 # keywords from ferm 1.1 which are deprecated, and the new one; these
  83 # are automatically replaced, and a warning is printed
  84 %deprecated_keywords = ( goto => 'jump',
  85                        );
  86
  87 # these hashes provide the Netfilter module definitions
  88 use vars qw(%proto_defs %match_defs %target_defs);
  89
  90 #
  91 # This subsubsystem allows you to support (most) new netfilter modules
  92 # in ferm.  Add a call to one of the "add_XY_def()" functions below.
  93 #
  94 # Ok, now about the cryptic syntax: the function "add_XY_def()"
  95 # registers a new module.  There are three kinds of modules: protocol
  96 # module (e.g. TCP, ICMP), match modules (e.g. state, physdev) and
  97 # target modules (e.g. DNAT, MARK).
  98 #
  99 # The first parameter is always the module name which is passed to
 100 # iptables with "-p", "-m" or "-j" (depending on which kind of module
 101 # this is).
 102 #
 103 # After that, you add an encoded string for each option the module
 104 # supports.  This is where it becomes tricky.
 105 #
 106 # foo           defaults to an option with one argument (which may be a ferm
 107 #               array)
 108 #
 109 # foo*0         option without any arguments
 110 #
 111 # foo=s         one argument which must not be a ferm array ('s' stands for
 112 #               'scalar')
 113 #
 114 # u32=m         an array which renders into multiple iptables options in one
 115 #               rule
 116 #
 117 # ctstate=c     one argument, if it's an array, pass it to iptables as a
 118 #               single comma separated value; example:
 119 #                 ctstate (ESTABLISHED RELATED)  translates to:
 120 #                 --ctstate ESTABLISHED,RELATED
 121 #
 122 # foo=sac       three arguments: scalar, array, comma separated; you may
 123 #               concatenate more than one letter code after the '='
 124 #
 125 # foo&bar       one argument; call the perl function '&bar()' which parses
 126 #               the argument
 127 #
 128 # !foo          negation is allowed and the '!' is written before the keyword
 129 #
 130 # foo!          same as above, but '!' is after the keyword and before the
 131 #               parameters
 132 #
 133 # to:=to-destination    makes "to" an alias for "to-destination"; you have
 134 #                       to add a declaration for option "to-destination"
 135 #
 136
 137 # add a module definition
 138 sub add_def_x {
 139     my $defs = shift;
 140     my $domain_family = shift;
 141     my $params_default = shift;
 142     my $name = shift;
 143     die if exists $defs->{$domain_family}{$name};
 144     my $def = $defs->{$domain_family}{$name} = {};
 145     foreach (@_) {
 146         my $keyword = $_;
 147         my $k = {};
 148
 149         my $params = $params_default;
 150         $params = $1 if $keyword =~ s,\*(\d+)$,,;
 151         $params = $1 if $keyword =~ s,=([acs]+|m)$,,;
 152         if ($keyword =~ s,&(\S+)$,,) {
 153             $params = eval "\\&$1";
 154             die $@ if $@;
 155         }
 156         $k->{params} = $params if $params;
 157
 158         $k->{negation} = $k->{pre_negation} = 1 if $keyword =~ s,^!,,;
 159         $k->{negation} = 1 if $keyword =~ s,!$,,;
 160
 161         $k->{alias} = [$1, $def->{keywords}{$1} || die] if $keyword =~ s,:=(\S+)$,,;
 162
 163         $def->{keywords}{$keyword} = $k;
 164     }
 165
 166     return $def;
 167 }
 168
 169 # add a protocol module definition
 170 sub add_proto_def_x(@) {
 171     my $domain_family = shift;
 172     add_def_x(\%proto_defs, $domain_family, 1, @_);
 173 }
 174
 175 # add a match module definition
 176 sub add_match_def_x(@) {
 177     my $domain_family = shift;
 178     add_def_x(\%match_defs, $domain_family, 1, @_);
 179 }
 180
 181 # add a target module definition
 182 sub add_target_def_x(@) {
 183     my $domain_family = shift;
 184     add_def_x(\%target_defs, $domain_family, 's', @_);
 185 }
 186
 187 sub add_def {
 188     my $defs = shift;
 189     add_def_x($defs, 'ip', @_);
 190 }
 191
 192 # add a protocol module definition
 193 sub add_proto_def(@) {
 194     add_def(\%proto_defs, 1, @_);
 195 }
 196
 197 # add a match module definition
 198 sub add_match_def(@) {
 199     add_def(\%match_defs, 1, @_);
 200 }
 201
 202 # add a target module definition
 203 sub add_target_def(@) {
 204     add_def(\%target_defs, 's', @_);
 205 }
 206
 207 add_proto_def 'dccp', qw(dccp-types!=c dccp-option!);
 208 add_proto_def 'mh', qw(mh-type!);
 209 add_proto_def 'icmp', qw(icmp-type!);
 210 add_proto_def 'icmpv6', qw(icmpv6-type! icmp-type:=icmpv6-type);
 211 add_proto_def 'sctp', qw(chunk-types!=sc);
 212 add_proto_def 'tcp', qw(tcp-flags!=cc !syn*0 tcp-option! mss);
 213 add_proto_def 'udp', qw();
 214
 215 add_match_def '',
 216   # --protocol
 217   qw(protocol! proto:=protocol),
 218   # --source, --destination
 219   qw(source! saddr:=source destination! daddr:=destination),
 220   # --in-interface
 221   qw(in-interface! interface:=in-interface if:=in-interface),
 222   # --out-interface
 223   qw(out-interface! outerface:=out-interface of:=out-interface),
 224   # --fragment
 225   qw(!fragment*0);
 226 add_match_def 'account', qw(aaddr=s aname=s ashort*0);
 227 add_match_def 'addrtype', qw(src-type dst-type);
 228 add_match_def 'ah', qw(ahspi! ahlen! ahres*0);
 229 add_match_def 'comment', qw(comment=s);
 230 add_match_def 'condition', qw(condition!);
 231 add_match_def 'connbytes', qw(!connbytes connbytes-dir connbytes-mode);
 232 add_match_def 'connlimit', qw(!connlimit-above connlimit-mask);
 233 add_match_def 'connmark', qw(mark);
 234 add_match_def 'conntrack', qw(ctstate=c ctproto ctorigsrc! ctorigdst!),
 235   qw(ctreplsrc! ctrepldst! ctstatus ctexpire=s);
 236 add_match_def 'dscp', qw(dscp dscp-class);
 237 add_match_def 'ecn', qw(ecn-tcp-cwr*0 ecn-tcp-ece*0 ecn-ip-ect);
 238 add_match_def 'esp', qw(espspi!);
 239 add_match_def 'eui64';
 240 add_match_def 'fuzzy', qw(lower-limit=s upper-limit=s);
 241 add_match_def 'hbh', qw(hbh-len! hbh-opts=c);
 242 add_match_def 'helper', qw(helper);
 243 add_match_def 'hl', qw(hl-eq! hl-lt=s hl-gt=s);
 244 add_match_def 'hashlimit', qw(hashlimit=s hashlimit-burst=s hashlimit-mode=s hashlimit-name=s),
 245   qw(hashlimit-htable-size=s hashlimit-htable-max=s),
 246   qw(hashlimit-htable-expire=s hashlimit-htable-gcinterval=s);
 247 add_match_def 'iprange', qw(!src-range !dst-range);
 248 add_match_def 'ipv4options', qw(ssrr*0 lsrr*0 no-srr*0 !rr*0 !ts*0 !ra*0 !any-opt*0);
 249 add_match_def 'ipv6header', qw(header!=c soft*0);
 250 add_match_def 'length', qw(length!);
 251 add_match_def 'limit', qw(limit=s limit-burst=s);
 252 add_match_def 'mac', qw(mac-source!);
 253 add_match_def 'mark', qw(mark);
 254 add_match_def 'multiport', qw(source-ports!&multiport_params),
 255   qw(destination-ports!&multiport_params ports!&multiport_params);
 256 add_match_def 'nth', qw(every counter start packet);
 257 add_match_def 'owner', qw(uid-owner gid-owner pid-owner sid-owner cmd-owner);
 258 add_match_def 'physdev', qw(physdev-in! physdev-out!),
 259   qw(!physdev-is-in*0 !physdev-is-out*0 !physdev-is-bridged*0);
 260 add_match_def 'pkttype', qw(pkt-type),
 261 add_match_def 'policy',
 262   qw(dir pol strict*0 reqid spi proto mode tunnel-src tunnel-dst next*0);
 263 add_match_def 'psd', qw(psd-weight-threshold psd-delay-threshold),
 264   qw(psd-lo-ports-weight psd-hi-ports-weight);
 265 add_match_def 'quota', qw(quota=s);
 266 add_match_def 'random', qw(average);
 267 add_match_def 'realm', qw(realm!);
 268 add_match_def 'recent', qw(name=s !set*0 !rcheck*0 !update*0 !seconds !hitcount rttl*0 rsource*0 rdest*0);
 269 add_match_def 'rt', qw(rt-type! rt-segsleft! rt-len! rt-0-res*0 rt-0-addrs=c rt-0-not-strict*0);
 270 add_match_def 'set', qw(set=sc);
 271 add_match_def 'state', qw(state=c);
 272 add_match_def 'statistic', qw(mode=s probability=s every=s packet=s);
 273 add_match_def 'string', qw(algo=s from=s to=s string hex-string);
 274 add_match_def 'tcpmss', qw(!mss);
 275 add_match_def 'time', qw(timestart=s timestop=s days=c datestart=s datestop=s),
 276   qw(!monthday=c !weekdays=c utc*0 localtz*0);
 277 add_match_def 'tos', qw(!tos);
 278 add_match_def 'ttl', qw(ttl-eq ttl-lt=s ttl-gt=s);
 279 add_match_def 'u32', qw(!u32=m);
 280
 281 add_target_def 'BALANCE', qw(to-destination to:=to-destination);
 282 add_target_def 'CLASSIFY', qw(set-class);
 283 add_target_def 'CLUSTERIP', qw(new*0 hashmode clustermac total-nodes local-node hash-init);
 284 add_target_def 'CONNMARK', qw(set-mark save-mark*0 restore-mark*0 mask);
 285 add_target_def 'CONNSECMARK', qw(save*0 restore*0);
 286 add_target_def 'DNAT', qw(to-destination=m to:=to-destination random*0);
 287 add_target_def 'DSCP', qw(set-dscp set-dscp-class);
 288 add_target_def 'ECN', qw(ecn-tcp-remove*0);
 289 add_target_def 'HL', qw(hl-set hl-dec hl-inc);
 290 add_target_def 'IPV4OPTSSTRIP';
 291 add_target_def 'LOG', qw(log-level log-prefix),
 292   qw(log-tcp-sequence*0 log-tcp-options*0 log-ip-options*0 log-uid*0);
 293 add_target_def 'MARK', qw(set-mark set-xmark and-mark or-mark xor-mark);
 294 add_target_def 'MASQUERADE', qw(to-ports random*0);
 295 add_target_def 'MIRROR';
 296 add_target_def 'NETMAP', qw(to);
 297 add_target_def 'NFLOG', qw(nflog-group nflog-prefix nflog-range nflog-threshold);
 298 add_target_def 'NFQUEUE', qw(queue-num);
 299 add_target_def 'NOTRACK';
 300 add_target_def 'REDIRECT', qw(to-ports random*0);
 301 add_target_def 'REJECT', qw(reject-with);
 302 add_target_def 'ROUTE', qw(oif iif gw continue*0 tee*0);
 303 add_target_def 'SAME', qw(to nodst*0 random*0);
 304 add_target_def 'SECMARK', qw(selctx);
 305 add_target_def 'SET', qw(add-set=sc del-set=sc);
 306 add_target_def 'SNAT', qw(to-source=m to:=to-source random*0);
 307 add_target_def 'TARPIT';
 308 add_target_def 'TCPMSS', qw(set-mss clamp-mss-to-pmtu*0);
 309 add_target_def 'TOS', qw(set-tos and-tos or-tos xor-tos);
 310 add_target_def 'TRACE';
 311 add_target_def 'TTL', qw(ttl-set ttl-dec ttl-inc);
 312 add_target_def 'ULOG', qw(ulog-nlgroup ulog-prefix ulog-cprange ulog-qthreshold);
 313
 314 add_match_def_x 'arp', '',
 315   # ip
 316   qw(source-ip! destination-ip! saddr:=source-ip daddr:=destination-ip),
 317   # mac
 318   qw(source-mac! destination-mac!),
 319   # --in-interface
 320   qw(in-interface! interface:=in-interface if:=in-interface),
 321   # --out-interface
 322   qw(out-interface! outerface:=out-interface of:=out-interface),
 323   # misc
 324   qw(h-length=s opcode=s h-type=s proto-type=s),
 325   qw(mangle-ip-s=s mangle-ip-d=s mangle-mac-s=s mangle-mac-d=s mangle-target=s);
 326
 327 add_match_def_x 'eb', '',
 328   # protocol
 329   qw(protocol! proto:=protocol),
 330   # --in-interface
 331   qw(in-interface! interface:=in-interface if:=in-interface),
 332   # --out-interface
 333   qw(out-interface! outerface:=out-interface of:=out-interface),
 334   # logical interface
 335   qw(logical-in! logical-out!),
 336   # --source, --destination
 337   qw(source! saddr:=source destination! daddr:=destination),
 338   # 802.3
 339   qw(802_3-sap! 802_3-type!),
 340   # arp
 341   qw(arp-opcode! arp-htype!=ss arp-ptype!=ss),
 342   qw(arp-ip-src! arp-ip-dst! arp-mac-src! arp-mac-dst!),
 343   # ip
 344   qw(ip-source! ip-destination! ip-tos! ip-protocol! ip-sport! ip-dport!),
 345   # mark_m
 346   qw(mark!),
 347   # pkttype
 348   qw(pkttype-type!),
 349   # stp
 350   qw(stp-type! stp-flags! stp-root-prio! stp-root-addr! stp-root-cost!),
 351   qw(stp-sender-prio! stp-sender-addr! stp-port! stp-msg-age! stp-max-age!),
 352   qw(stp-hello-time! stp-forward-delay!),
 353   # vlan
 354   qw(vlan-id! vlan-prio! vlan-encap!),
 355   # log
 356   qw(log*0 log-level=s log-prefix=s log-ip*0 log-arp*0);
 357
 358 add_target_def_x 'eb', 'arpreply', qw(arpreply-mac arpreply-target);
 359 add_target_def_x 'eb', 'dnat', qw(to-destination dnat-target);
 360 add_target_def_x 'eb', 'mark', qw(set-mark mark-target);
 361 add_target_def_x 'eb', 'redirect', qw(redirect-target);
 362 add_target_def_x 'eb', 'snat', qw(to-source snat-target);
 363
 364 use vars qw(%builtin_keywords);
 365
 366 sub get_builtin_keywords($) {
 367     my $domain_family = shift;
 368     return {} unless defined $domain_family;
 369
 370     return {%{$builtin_keywords{$domain_family}}}
 371       if exists $builtin_keywords{$domain_family};
 372
 373     return {} unless exists $match_defs{$domain_family};
 374     my $defs_kw = $match_defs{$domain_family}{''}{keywords};
 375     my %keywords = map { $_ => ['builtin', '', $defs_kw->{$_} ] } keys %$defs_kw;
 376
 377     $builtin_keywords{$domain_family} = \%keywords;
 378     return {%keywords};
 379 }
 380
 381 # parameter parser for ipt_multiport
 382 sub multiport_params {
 383     my $fw = shift;
 384
 385     # multiport only allows 15 ports at a time. For this
 386     # reason, we do a little magic here: split the ports
 387     # into portions of 15, and handle these portions as
 388     # array elements
 389
 390     my $proto = $fw->{builtin}{protocol};
 391     error('To use multiport, you have to specify "proto tcp" or "proto udp" first')
 392       unless defined $proto and grep { /^(?:tcp|udp|udplite)$/ } to_array($proto);
 393
 394     my $value = getvalues(undef, undef,
 395                           allow_negation => 1,
 396                           allow_array_negation => 1);
 397     if (ref $value and ref $value eq 'ARRAY') {
 398         my @value = @$value;
 399         my @params;
 400
 401         while (@value) {
 402             push @params, join(',', splice(@value, 0, 15));
 403         }
 404
 405         return @params == 1
 406           ? $params[0]
 407             : \@params;
 408     } else {
 409         return join_value(',', $value);
 410     }
 411 }
 412
 413 # initialize stack: command line definitions
 414 unshift @stack, {};
 415
 416 # Get command line stuff
 417 if ($has_getopt) {
 418     my ($opt_noexec, $opt_flush, $opt_lines, $opt_interactive,
 419         $opt_verbose, $opt_debug,
 420         $opt_help,
 421         $opt_version, $opt_test, $opt_fast, $opt_shell,
 422         $opt_domain);
 423
 424     Getopt::Long::Configure('bundling', 'auto_help', 'no_ignore_case',
 425                             'no_auto_abbrev');
 426
 427     sub opt_def {
 428         my ($opt, $value) = @_;
 429         die 'Invalid --def specification'
 430           unless $value =~ /^\$?(\w+)=(.*)$/s;
 431         my ($name, $unparsed_value) = ($1, $2);
 432         my $tokens = tokenize_string($unparsed_value);
 433         my $value = getvalues(\&next_array_token, $tokens);
 434         die 'Extra tokens after --def'
 435           if @$tokens > 0;
 436         $stack[0]{vars}{$name} = $value;
 437     }
 438
 439     local $SIG{__WARN__} = sub { die $_[0]; };
 440     GetOptions('noexec|n' => \$opt_noexec,
 441                'flush|F' => \$opt_flush,
 442                'lines|l' => \$opt_lines,
 443                'interactive|i' => \$opt_interactive,
 444                'verbose|v' => \$opt_verbose,
 445                'debug|d' => \$opt_debug,
 446                'help|h' => \$opt_help,
 447                'version|V' => \$opt_version,
 448                test => \$opt_test,
 449                remote => \$opt_test,
 450                fast => \$opt_fast,
 451                shell => \$opt_shell,
 452                'domain=s' => \$opt_domain,
 453                'def=s' => \&opt_def,
 454               );
 455
 456     if (defined $opt_help) {
 457         require Pod::Usage;
 458         Pod::Usage::pod2usage(-exitstatus => 0);
 459     }
 460
 461     if (defined $opt_version) {
 462         printversion();
 463         exit 0;
 464     };
 465
 466     $option{'noexec'} = (defined $opt_noexec);
 467     $option{flush} = defined $opt_flush;
 468     $option{'lines'} = (defined $opt_lines);
 469     $option{interactive} = (defined $opt_interactive);
 470     $option{test} = (defined $opt_test);
 471
 472     if ($option{test}) {
 473         $option{noexec} = 1;
 474         $option{lines} = 1;
 475     }
 476
 477     delete $option{interactive} if $option{noexec};
 478
 479     mydie('ferm interactive mode not possible: /dev/stdin is not a tty')
 480       if $option{interactive} and not -t STDIN;
 481     mydie('ferm interactive mode not possible: /dev/stderr is not a tty')
 482       if $option{interactive} and not -t STDERR;
 483
 484     $option{fast} = 1 if defined $opt_fast;
 485
 486     if (defined $opt_shell) {
 487         $option{$_} = 1 foreach qw(shell fast lines);
 488     }
 489
 490     $option{domain} = $opt_domain if defined $opt_domain;
 491
 492     print STDERR "Warning: ignoring the obsolete --debug option\n"
 493       if defined $opt_debug;
 494     print STDERR "Warning: ignoring the obsolete --verbose option\n"
 495       if defined $opt_verbose;
 496 } else {
 497     # tiny getopt emulation for microperl
 498     my $filename;
 499     foreach (@ARGV) {
 500         if ($_ eq '--noexec' or $_ eq '-n') {
 501             $option{noexec} = 1;
 502         } elsif ($_ eq '--lines' or $_ eq '-l') {
 503             $option{lines} = 1;
 504         } elsif ($_ eq '--fast') {
 505             $option{fast} = 1;
 506         } elsif ($_ eq '--test') {
 507             $option{test} = 1;
 508             $option{noexec} = 1;
 509             $option{lines} = 1;
 510         } elsif ($_ eq '--shell') {
 511             $option{$_} = 1 foreach qw(shell fast lines);
 512         } elsif (/^-/) {
 513             printf STDERR "Usage: ferm [--noexec] [--lines] [--fast] [--shell] FILENAME\n";
 514             exit 1;
 515         } else {
 516             $filename = $_;
 517         }
 518     }
 519     undef @ARGV;
 520     push @ARGV, $filename;
 521 }
 522
 523 unless (@ARGV == 1) {
 524     require Pod::Usage;
 525     Pod::Usage::pod2usage(-exitstatus => 1);
 526 }
 527
 528 if ($has_strict) {
 529     open LINES, ">&STDOUT" if $option{lines};
 530     open STDOUT, ">&STDERR" if $option{shell};
 531 } else {
 532     # microperl can't redirect file handles
 533     *LINES = *STDOUT;
 534
 535     if ($option{fast} and not $option{noexec}) {
 536         print STDERR "Sorry, ferm on microperl does not allow --fast without --noexec\n";
 537         exit 1
 538     }
 539 }
 540
 541 unshift @stack, {};
 542 open_script($ARGV[0]);
 543
 544 # parse all input recursively
 545 enter(0);
 546 die unless @stack == 2;
 547
 548 # execute all generated rules
 549 my $status;
 550
 551 foreach my $cmd (@pre_hooks) {
 552     print LINES "$cmd\n" if $option{lines};
 553     system($cmd) unless $option{noexec};
 554 }
 555
 556 while (my ($domain, $domain_info) = each %domains) {
 557     next unless $domain_info->{enabled};
 558     my $s = $option{fast} &&
 559       defined $domain_info->{tools}{'tables-restore'}
 560       ? execute_fast($domain, $domain_info)
 561         : execute_slow($domain, $domain_info);
 562     $status = $s if defined $s;
 563 }
 564
 565 foreach my $cmd (@post_hooks) {
 566     print "$cmd\n" if $option{lines};
 567     system($cmd) unless $option{noexec};
 568 }
 569
 570 if (defined $status) {
 571     rollback();
 572     exit $status;
 573 }
 574
 575 # ask user, and rollback if there is no confirmation
 576
 577 confirm_rules() or rollback() if $option{interactive};
 578
 579 exit 0;
 580
 581 # end of program execution!
 582
 583
 584 # funcs
 585
 586 sub printversion {
 587     print "ferm $VERSION\n";
 588     print "Copyright (C) 2001-2007 Auke Kok, Max Kellermann\n";
 589     print "This program is free software released under GPLv2.\n";
 590     print "See the included COPYING file for license details.\n";
 591 }
 592
 593
 594 sub mydie {
 595     print STDERR @_;
 596     print STDERR "\n";
 597     exit 1;
 598 }
 599
 600
 601 sub error {
 602     # returns a nice formatted error message, showing the
 603     # location of the error.
 604     my $tabs = 0;
 605     my @lines;
 606     my $l = 0;
 607     my @words = map { @$_ } @{$script->{past_tokens}};
 608
 609     for my $w ( 0 .. $#words ) {
 610         if ($words[$w] eq "\x29")
 611             { $l++ ; $lines[$l] = "    " x ($tabs-- -1) ;};
 612         if ($words[$w] eq "\x28")
 613             { $l++ ; $lines[$l] = "    " x $tabs++ ;};
 614         if ($words[$w] eq "\x7d")
 615             { $l++ ; $lines[$l] = "    " x ($tabs-- -1) ;};
 616         if ($words[$w] eq "\x7b")
 617             { $l++ ; $lines[$l] = "    " x $tabs++ ;};
 618         if ( $l > $#lines ) { $lines[$l] = "" };
 619         $lines[$l] .= $words[$w] . " ";
 620         if ($words[$w] eq "\x28")
 621             { $l++ ; $lines[$l] = "    " x $tabs ;};
 622         if (($words[$w] eq "\x29") && ($words[$w+1] ne "\x7b"))
 623             { $l++ ; $lines[$l] = "    " x $tabs ;};
 624         if ($words[$w] eq "\x7b")
 625             { $l++ ; $lines[$l] = "    " x $tabs ;};
 626         if (($words[$w] eq "\x7d") && ($words[$w+1] ne "\x7d"))
 627             { $l++ ; $lines[$l] = "    " x $tabs ;};
 628         if (($words[$w] eq "\x3b") && ($words[$w+1] ne "\x7d"))
 629             { $l++ ; $lines[$l] = "    " x $tabs ;}
 630         if ($words[$w-1] eq "option")
 631             { $l++ ; $lines[$l] = "    " x $tabs ;}
 632     }
 633     my $start = $#lines - 4;
 634     if ($start < 0) { $start = 0 } ;
 635     print STDERR "Error in $script->{filename} line $script->{line}:\n";
 636     for $l ( $start .. $#lines)
 637         { print STDERR $lines[$l]; if ($l != $#lines ) {print STDERR "\n"} ; };
 638     print STDERR "<--\n";
 639     mydie(@_);
 640 }
 641
 642 # print a warning message about code from an input file
 643 sub warning {
 644     print STDERR "Warning in $script->{filename} line $script->{line}: "
 645       . (shift) . "\n";
 646 }
 647
 648 sub find_tool($) {
 649     my $name = shift;
 650     return $name if $option{test};
 651     for my $path ('/sbin', split ':', $ENV{PATH}) {
 652         my $ret = "$path/$name";
 653         return $ret if -x $ret;
 654     }
 655     die "$name not found in PATH\n";
 656 }
 657
 658 sub initialize_domain {
 659     my $domain = shift;
 660
 661     return if exists $domains{$domain}{initialized};
 662
 663     die "Invalid domain '$domain'\n" unless $domain =~ /^(?:ip6?|arp|eb)$/;
 664
 665     my @tools = qw(tables);
 666     push @tools, qw(tables-save tables-restore)
 667       if $domain =~ /^ip6?$/;
 668
 669     # determine the location of this domain's tools
 670     my %tools = map { $_ => find_tool($domain . $_) } @tools;
 671     $domains{$domain}{tools} = \%tools;
 672
 673     # make tables-save tell us about the state of this domain
 674     # (which tables and chains do exist?), also remember the old
 675     # save data which may be used later by the rollback function
 676     local *SAVE;
 677     if (!$option{test} &&
 678         exists $domains{$domain}{tools}{'tables-save'} &&
 679         open(SAVE, "$domains{$domain}{tools}{'tables-save'}|")) {
 680         my $save = '';
 681
 682         my $table_info;
 683         while (<SAVE>) {
 684             $save .= $_;
 685
 686             if (/^\*(\w+)/) {
 687                 my $table = $1;
 688                 $table_info = $domains{$domain}{tables}{$table} ||= {};
 689             } elsif (defined $table_info and /^:(\w+)\s+(\S+)/
 690                      and $2 ne '-') {
 691                 $table_info->{chains}{$1}{builtin} = 1;
 692                 $table_info->{has_builtin} = 1;
 693             }
 694         }
 695
 696         # for rollback
 697         $domains{$domain}{previous} = $save;
 698     }
 699
 700     $domains{$domain}{initialized} = 1;
 701 }
 702
 703 # split the an input string into words and delete comments
 704 sub tokenize_string($) {
 705     my $string = shift;
 706
 707     my @ret;
 708
 709     foreach my $word ($string =~ m/(".*?"|'.*?'|`.*?`|[!,=&\$\%\(\){};]|[-+\w\/\.:]+|@\w+|#)/g) {
 710         last if $word eq '#';
 711         push @ret, $word;
 712     }
 713
 714     return \@ret;
 715 }
 716
 717 # shift an array; helper function to be passed to &getvar / &getvalues
 718 sub next_array_token {
 719     my $array = shift;
 720     shift @$array;
 721 }
 722
 723 # read some more tokens from the input file into a buffer
 724 sub prepare_tokens() {
 725     my $tokens = $script->{tokens};
 726     while (@$tokens == 0) {
 727         my $handle = $script->{handle};
 728         my $line = <$handle>;
 729         return unless defined $line;
 730
 731         $script->{line} ++;
 732
 733         # the next parser stage eats this
 734         push @$tokens, @{tokenize_string($line)};
 735     }
 736
 737     return 1;
 738 }
 739
 740 # open a ferm sub script
 741 sub open_script($) {
 742     my $filename = shift;
 743
 744     for (my $s = $script; defined $s; $s = $s->{parent}) {
 745         mydie("Circular reference in $script->{filename} line $script->{line}: $filename")
 746           if $s->{filename} eq $filename;
 747     }
 748
 749     local *FILE;
 750     open FILE, "<$filename"
 751       or mydie("Failed to open $filename: $!");
 752     my $handle = *FILE;
 753
 754     $script = { filename => $filename,
 755                 handle => $handle,
 756                 line => 0,
 757                 past_tokens => [],
 758                 tokens => [],
 759                 parent => $script,
 760               };
 761
 762     return $script;
 763 }
 764
 765 # collect script filenames which are being included
 766 sub collect_filenames(@) {
 767     my @ret;
 768
 769     # determine the current script's parent directory for relative
 770     # file names
 771     die unless defined $script;
 772     my $parent_dir = $script->{filename} =~ m,^(.*/),
 773       ? $1 : './';
 774
 775     foreach my $pathname (@_) {
 776         # non-absolute file names are relative to the parent script's
 777         # file name
 778         $pathname = $parent_dir . $pathname
 779           unless $pathname =~ m,^/,;
 780
 781         if ($pathname =~ m,/$,) {
 782             # include all regular files in a directory
 783
 784             error("'$pathname' is not a directory")
 785               unless -d $pathname;
 786
 787             local *DIR;
 788             opendir DIR, $pathname
 789               or error("Failed to open directory '$pathname': $!");
 790             my @names = readdir DIR;
 791             closedir DIR;
 792
 793             # sort those names for a well-defined order
 794             foreach my $name (sort { $a cmp $b } @names) {
 795                 # don't include hidden and backup files
 796                 next if /^\.|~$/;
 797
 798                 my $filename = $pathname . $name;
 799                 push @ret, $filename
 800                   if -f $filename;
 801             }
 802         } elsif ($pathname =~ m,\|$,) {
 803             # run a program and use its output
 804             push @ret, $pathname;
 805         } elsif ($pathname =~ m,^\|,) {
 806             error('This kind of pipe is not allowed');
 807         } else {
 808             # include a regular file
 809
 810             error("'$pathname' is a directory; maybe use trailing '/' to include a directory?")
 811               if -d $pathname;
 812             error("'$pathname' is not a file")
 813               unless -f $pathname;
 814
 815             push @ret, $pathname;
 816         }
 817     }
 818
 819     return @ret;
 820 }
 821
 822 # peek a token from the queue, but don't remove it
 823 sub peek_token() {
 824     return unless prepare_tokens();
 825     return $script->{tokens}[0];
 826 }
 827
 828 # get a token from the queue
 829 sub next_token() {
 830     return unless prepare_tokens();
 831     my $token = shift @{$script->{tokens}};
 832
 833     # update $script->{past_tokens}
 834     my $past_tokens = $script->{past_tokens};
 835
 836     if (@$past_tokens > 0) {
 837         my $prev_token = $past_tokens->[-1][-1];
 838         $past_tokens->[-1] = @$past_tokens > 1 ? ['{'] : []
 839           if $prev_token eq ';';
 840         pop @$past_tokens
 841           if $prev_token eq '}';
 842     }
 843
 844     push @$past_tokens, [] if $token eq '{' or @$past_tokens == 0;
 845     push @{$past_tokens->[-1]}, $token;
 846
 847     # return
 848     return $token;
 849 }
 850
 851 sub expect_token($;$) {
 852     my $expect = shift;
 853     my $msg = shift;
 854     my $token = next_token();
 855     error($msg || "'$expect' expected")
 856       unless defined $token and $token eq $expect;
 857 }
 858
 859 # require that another token exists, and that it's not a "special"
 860 # token, e.g. ";" and "{"
 861 sub require_next_token {
 862     my $code = shift || \&next_token;
 863
 864     my $token = &$code(@_);
 865
 866     error('unexpected end of file')
 867       unless defined $token;
 868
 869     error("'$token' not allowed here")
 870       if $token =~ /^[;{}]$/;
 871
 872     return $token;
 873 }
 874
 875 # return the value of a variable
 876 sub variable_value($) {
 877     my $name = shift;
 878
 879     foreach (@stack) {
 880         return $_->{vars}{$name}
 881           if exists $_->{vars}{$name};
 882     }
 883
 884     return $stack[0]{auto}{$name}
 885       if exists $stack[0]{auto}{$name};
 886
 887     return;
 888 }
 889
 890 # determine the value of a variable, die if the value is an array
 891 sub string_variable_value($) {
 892     my $name = shift;
 893     my $value = variable_value($name);
 894
 895     error("variable '$name' must be a string, is an array")
 896       if ref $value;
 897
 898     return $value;
 899 }
 900
 901 # similar to the built-in "join" function, but also handle negated
 902 # values in a special way
 903 sub join_value($$) {
 904     my ($expr, $value) = @_;
 905
 906     unless (ref $value) {
 907         return $value;
 908     } elsif (ref $value eq 'ARRAY') {
 909         return join($expr, @$value);
 910     } elsif (ref $value eq 'negated') {
 911         # bless'negated' is a special marker for negated values
 912         $value = join_value($expr, $value->[0]);
 913         return bless [ $value ], 'negated';
 914     } else {
 915         die;
 916     }
 917 }
 918
 919 # returns the next parameter, which may either be a scalar or an array
 920 sub getvalues {
 921     my ($code, $param) = (shift, shift);
 922     my %options = @_;
 923
 924     my $token = require_next_token($code, $param);
 925
 926     if ($token eq '(') {
 927         # read an array until ")"
 928         my @wordlist;
 929
 930         for (;;) {
 931             $token = getvalues($code, $param,
 932                                parenthesis_allowed => 1,
 933                                comma_allowed => 1);
 934
 935             unless (ref $token) {
 936                 last if $token eq ')';
 937
 938                 if ($token eq ',') {
 939                     error('Comma is not allowed within arrays, please use only a space');
 940                     next;
 941                 }
 942
 943                 push @wordlist, $token;
 944             } elsif (ref $token eq 'ARRAY') {
 945                 push @wordlist, @$token;
 946             } else {
 947                 error('unknown toke type');
 948             }
 949         }
 950
 951         error('empty array not allowed here')
 952           unless @wordlist or not $options{non_empty};
 953
 954         return @wordlist == 1
 955           ? $wordlist[0]
 956             : \@wordlist;
 957     } elsif ($token =~ /^\`(.*)\`$/s) {
 958         # execute a shell command, insert output
 959         my $command = $1;
 960         my $output = `$command`;
 961         unless ($? == 0) {
 962             if ($? == -1) {
 963                 error("failed to execute: $!");
 964             } elsif ($? & 0x7f) {
 965                 error("child died with signal " . ($? & 0x7f));
 966             } elsif ($? >> 8) {
 967                 error("child exited with status " . ($? >> 8));
 968             }
 969         }
 970
 971         # remove comments
 972         $output =~ s/#.*//mg;
 973
 974         # tokenize
 975         my @tokens = grep { length } split /\s+/s, $output;
 976
 977         my @values;
 978         while (@tokens) {
 979             my $value = getvalues(\&next_array_token, \@tokens);
 980             push @values, to_array($value);
 981         }
 982
 983         # and recurse
 984         return @values == 1
 985           ? $values[0]
 986             : \@values;
 987     } elsif ($token =~ /^\'(.*)\'$/s) {
 988         # single quotes: a string
 989         return $1;
 990     } elsif ($token =~ /^\"(.*)\"$/s) {
 991         # double quotes: a string with escapes
 992         $token = $1;
 993         $token =~ s,\$(\w+),string_variable_value($1),eg;
 994         return $token;
 995     } elsif ($token eq '!') {
 996         error('negation is not allowed here')
 997           unless $options{allow_negation};
 998
 999         $token = getvalues($code, $param);
1000
1001         error('it is not possible to negate an array')
1002           if ref $token and not $options{allow_array_negation};
1003
1004         return bless [ $token ], 'negated';
1005     } elsif ($token eq ',') {
1006         return $token
1007           if $options{comma_allowed};
1008
1009         error('comma is not allowed here');
1010     } elsif ($token eq '=') {
1011         error('equals operator ("=") is not allowed here');
1012     } elsif ($token eq '$') {
1013         my $name = require_next_token($code, $param);
1014         error('variable name expected - if you want to concatenate strings, try using double quotes')
1015           unless $name =~ /^\w+$/;
1016
1017         my $value = variable_value($name);
1018
1019         error("no such variable: \$$name")
1020           unless defined $value;
1021
1022         return $value;
1023     } elsif ($token eq '&') {
1024         error("function calls are not allowed as keyword parameter");
1025     } elsif ($token eq ')' and not $options{parenthesis_allowed}) {
1026         error('Syntax error');
1027     } elsif ($token =~ /^@/) {
1028         if ($token eq '@resolve') {
1029             my @params = get_function_params();
1030             error('Usage: @resolve((hostname ...))')
1031               unless @params == 1;
1032             eval { require Net::DNS; };
1033             error('For the @resolve() function, you need the Perl library Net::DNS')
1034               if $@;
1035             my $type = 'A';
1036             my $resolver = new Net::DNS::Resolver;
1037             my @result;
1038             foreach my $hostname (to_array($params[0])) {
1039                 my $query = $resolver->search($hostname, $type);
1040                 error("DNS query for '$hostname' failed: " . $resolver->errorstring)
1041                   unless $query;
1042                 foreach my $rr ($query->answer) {
1043                     next unless $rr->type eq $type;
1044                     push @result, $rr->address;
1045                 }
1046             }
1047             return \@result;
1048         } else {
1049             error("unknown ferm built-in function");
1050         }
1051     } else {
1052         return $token;
1053     }
1054 }
1055
1056 # returns the next parameter, but only allow a scalar
1057 sub getvar {
1058     my $token = getvalues(@_);
1059
1060     error('array not allowed here')
1061       if ref $token and ref $token eq 'ARRAY';
1062
1063     return $token;
1064 }
1065
1066 sub get_function_params(%) {
1067     expect_token('(', 'function name must be followed by "()"');
1068
1069     my $token = peek_token();
1070     if ($token eq ')') {
1071         require_next_token;
1072         return;
1073     }
1074
1075     my @params;
1076
1077     while (1) {
1078         if (@params > 0) {
1079             $token = require_next_token();
1080             last
1081               if $token eq ')';
1082
1083             error('"," expected')
1084               unless $token eq ',';
1085         }
1086
1087         push @params, getvalues(undef, undef, @_);
1088     }
1089
1090     return @params;
1091 }
1092
1093 # collect all tokens in a flat array reference until the end of the
1094 # command is reached
1095 sub collect_tokens() {
1096     my @level;
1097     my @tokens;
1098
1099     while (1) {
1100         my $keyword = next_token();
1101         error('unexpected end of file within function/variable declaration')
1102           unless defined $keyword;
1103
1104         if ($keyword =~ /^[\{\(]$/) {
1105             push @level, $keyword;
1106         } elsif ($keyword =~ /^[\}\)]$/) {
1107             my $expected = $keyword;
1108             $expected =~ tr/\}\)/\{\(/;
1109             my $opener = pop @level;
1110             error("unmatched '$keyword'")
1111               unless defined $opener and $opener eq $expected;
1112         } elsif ($keyword eq ';' and @level == 0) {
1113             last;
1114         }
1115
1116         push @tokens, $keyword;
1117
1118         last
1119           if $keyword eq '}' and @level == 0;
1120     }
1121
1122     return \@tokens;
1123 }
1124
1125
1126 # returns the specified value as an array. dereference arrayrefs
1127 sub to_array($) {
1128     my $value = shift;
1129     die unless wantarray;
1130     die if @_;
1131     unless (ref $value) {
1132         return $value;
1133     } elsif (ref $value eq 'ARRAY') {
1134         return @$value;
1135     } else {
1136         die;
1137     }
1138 }
1139
1140 # evaluate the specified value as bool
1141 sub eval_bool($) {
1142     my $value = shift;
1143     die if wantarray;
1144     die if @_;
1145     unless (ref $value) {
1146         return $value;
1147     } elsif (ref $value eq 'ARRAY') {
1148         return @$value > 0;
1149     } else {
1150         die;
1151     }
1152 }
1153
1154 sub is_netfilter_core_target($) {
1155     my $target = shift;
1156     die unless defined $target and length $target;
1157
1158     return $target =~ /^(?:ACCEPT|DROP|RETURN|QUEUE)$/;
1159 }
1160
1161 sub is_netfilter_module_target($$) {
1162     my ($domain_family, $target) = @_;
1163     die unless defined $target and length $target;
1164
1165     return defined $domain_family &&
1166       exists $target_defs{$domain_family} &&
1167         exists $target_defs{$domain_family}{$target};
1168 }
1169
1170 sub is_netfilter_builtin_chain($$) {
1171     my ($table, $chain) = @_;
1172
1173     return grep { $_ eq $chain }
1174       qw(PREROUTING INPUT FORWARD OUTPUT POSTROUTING);
1175 }
1176
1177 sub netfilter_canonical_protocol($) {
1178     my $proto = shift;
1179     return 'icmpv6'
1180       if $proto eq 'ipv6-icmp';
1181     return 'mh'
1182       if $proto eq 'ipv6-mh';
1183     return $proto;
1184 }
1185
1186 sub netfilter_protocol_module($) {
1187     my $proto = shift;
1188     return unless defined $proto;
1189     return 'icmp6'
1190       if $proto eq 'icmpv6';
1191     return $proto;
1192 }
1193
1194 # escape the string in a way safe for the shell
1195 sub shell_escape($) {
1196     my $token = shift;
1197
1198     return $token if $token =~ /^[-_a-zA-Z0-9]+$/s;
1199
1200     if ($option{fast}) {
1201         # iptables-save/iptables-restore are quite buggy concerning
1202         # escaping and special characters... we're trying our best
1203         # here
1204
1205         $token =~ s,",',g;
1206         $token = '"' . $token . '"'
1207           if $token =~ /[\s\'\\;&]/s;
1208     } else {
1209         return $token
1210           if $token =~ /^\`.*\`$/;
1211         $token =~ s/'/\\'/g;
1212         $token = '\'' . $token . '\''
1213           if $token =~ /[\s\"\\;<>&|]/s;
1214     }
1215
1216     return $token;
1217 }
1218
1219 # append an option to the shell command line, using information from
1220 # the module definition (see %match_defs etc.)
1221 sub shell_append_option($$$) {
1222     my ($ref, $keyword, $value) = @_;
1223
1224     if (ref $value) {
1225         if (ref $value eq 'negated') {
1226             $value = $value->[0];
1227             $keyword .= ' !';
1228         } elsif (ref $value eq 'pre_negated') {
1229             $value = $value->[0];
1230             $$ref .= ' !';
1231         }
1232     }
1233
1234     unless (defined $value) {
1235         $$ref .= " --$keyword";
1236     } elsif (ref $value) {
1237         if (ref $value eq 'params') {
1238             $$ref .= " --$keyword ";
1239             $$ref .= join(' ', map { shell_escape($_) } @$value);
1240         } elsif (ref $value eq 'multi') {
1241             foreach (@$value) {
1242                 $$ref .= " --$keyword " . shell_escape($_);
1243             }
1244         } else {
1245             die;
1246         }
1247     } else {
1248         $$ref .= " --$keyword " . shell_escape($value);
1249     }
1250 }
1251
1252 # convert an internal rule structure into an iptables call
1253 sub tables($) {
1254     my $rule = shift;
1255
1256     my $domain = $rule->{domain};
1257     my $domain_info = $domains{$domain};
1258     $domain_info->{enabled} = 1;
1259     my $domain_family = $rule->{domain_family};
1260
1261     my $table = $rule->{table};
1262     my $table_info = $domain_info->{tables}{$table} ||= {};
1263
1264     my $chain = $rule->{chain};
1265     my $chain_info = $table_info->{chains}{$chain} ||= {};
1266     my $chain_rules = $chain_info->{rules} ||= [];
1267
1268     return if $option{flush};
1269
1270     # return if this is a declaration-only rule
1271     return
1272       unless $rule->{has_rule};
1273
1274     my $rr = '';
1275
1276     # general iptables options
1277
1278     while (my ($keyword, $value) = each %{$rule->{builtin}}) {
1279         shell_append_option(\$rr, $keyword, $value);
1280     }
1281
1282     #
1283     # match module options
1284     #
1285
1286     my %modules;
1287
1288     if (defined $rule->{builtin}{protocol}) {
1289         my $proto = $rule->{builtin}{protocol};
1290
1291         # special case: --dport and --sport for TCP/UDP
1292         if ($domain_family eq 'ip' and
1293             (exists $rule->{dport} or exists $rule->{sport}) and
1294             $proto =~ /^(?:tcp|udp|udplite|dccp|sctp)$/) {
1295             unless (exists $modules{$proto}) {
1296                 $rr .= " -m $proto";
1297                 $modules{$proto} = 1;
1298             }
1299
1300             shell_append_option(\$rr, 'dport', $rule->{dport})
1301               if exists $rule->{dport};
1302             shell_append_option(\$rr, 'sport', $rule->{sport})
1303               if exists $rule->{sport};
1304         }
1305     }
1306
1307     # modules stored in %match_defs
1308
1309     foreach my $match (@{$rule->{match}}) {
1310         my $module_name = $match->{name};
1311         unless (exists $modules{$module_name}) {
1312             $rr .= " -m $module_name";
1313             $modules{$module_name} = 1;
1314         }
1315
1316         while (my ($keyword, $value) = each %{$match->{options}}) {
1317             shell_append_option(\$rr, $keyword, $value);
1318         }
1319     }
1320
1321     #
1322     # target options
1323     #
1324
1325     my $action = $rule->{action};
1326     if ($action->{type} eq 'jump') {
1327         $table_info->{chains}{$action->{chain}}{rules} ||= [];
1328         $rr .= " -j " . $action->{chain};
1329     } elsif ($action->{type} eq 'goto') {
1330         $table_info->{chains}{$action->{chain}}{rules} ||= [];
1331         $rr .= " -g " . $action->{chain};
1332     } elsif ($action->{type} eq 'target') {
1333         $rr .= " -j " . $action->{target};
1334
1335         # targets stored in %target_defs
1336
1337         while (my ($keyword, $value) = each %{$rule->{target_options}}) {
1338             shell_append_option(\$rr, $keyword, $value);
1339         }
1340     } elsif ($action->{type} ne 'nop') {
1341         die;
1342     }
1343
1344     # this line is done
1345     push @$chain_rules, { rule => $rr,
1346                           script => $rule->{script},
1347                         };
1348 };
1349
1350 sub transform_rule($) {
1351     my $rule = shift;
1352
1353     $rule->{builtin}{protocol} = 'icmpv6'
1354       if $rule->{domain} eq 'ip6' and $rule->{builtin}{protocol} eq 'icmp';
1355 }
1356
1357 sub printrule($) {
1358     my $rule = shift;
1359
1360     transform_rule($rule);
1361
1362     # prints all rules in a hash
1363     tables($rule);
1364 }
1365
1366
1367 sub check_unfold(\@$$) {
1368     my ($unfold, $parent, $key) = @_;
1369
1370     return unless ref $parent->{$key} and
1371       ref $parent->{$key} eq 'ARRAY';
1372
1373     push @$unfold, $parent, $key, $parent->{$key};
1374 }
1375
1376 # convert a bunch of internal rule structures in iptables calls,
1377 # unfold arrays during that
1378 sub mkrules($) {
1379     # compile the list hashes into rules
1380     my $fw = shift;
1381
1382     my @unfold;
1383
1384     foreach my $key (qw(domain table chain)) {
1385         check_unfold(@unfold, $fw, $key);
1386     }
1387
1388     foreach my $key (keys %{$fw->{builtin}}) {
1389         check_unfold(@unfold, $fw->{builtin}, $key);
1390     }
1391
1392     foreach my $match (@{$fw->{match}}) {
1393         while (my ($key, $value) = each %{$match->{options}}) {
1394             check_unfold(@unfold, $match->{options}, $key);
1395         }
1396     }
1397
1398     check_unfold(@unfold, $fw, 'sport');
1399     check_unfold(@unfold, $fw, 'dport');
1400
1401     if (@unfold == 0) {
1402         printrule($fw);
1403         return;
1404     }
1405
1406     sub dofr {
1407         my $fw = shift;
1408         my ($parent, $key, $values) = (shift, shift, shift);
1409
1410         foreach my $value (@$values) {
1411             $parent->{$key} = $value;
1412
1413             if (@_) {
1414                 dofr($fw, @_);
1415             } else {
1416                 printrule($fw);
1417             }
1418         }
1419     }
1420
1421     dofr($fw, @unfold);
1422 }
1423
1424 sub filter_domains($) {
1425     my $domains = shift;
1426     my $result = [];
1427
1428     foreach my $domain (to_array $domains) {
1429         next if exists $option{domain}
1430           and $domain ne $option{domain};
1431
1432         eval {
1433             initialize_domain($domain);
1434         };
1435         error($@) if $@;
1436
1437         push @$result, $domain;
1438     }
1439
1440     return @$result == 1 ? $result->[0] : $result;
1441 }
1442
1443 # parse a keyword from a module definition
1444 sub parse_keyword($$$$) {
1445     my ($current, $def, $keyword, $negated_ref) = @_;
1446
1447     my $params = $def->{params};
1448
1449     my $value;
1450
1451     my $negated;
1452     if ($$negated_ref && exists $def->{pre_negation}) {
1453         $negated = 1;
1454         undef $$negated_ref;
1455     }
1456
1457     unless (defined $params) {
1458         undef $value;
1459     } elsif (ref $params && ref $params eq 'CODE') {
1460         $value = &$params($current);
1461     } elsif ($params eq 'm') {
1462         $value = bless [ to_array getvalues() ], 'multi';
1463     } elsif ($params =~ /^[a-z]/) {
1464         if (exists $def->{negation} and not $negated) {
1465             my $token = peek_token();
1466             if ($token eq '!') {
1467                 require_next_token;
1468                 $negated = 1;
1469             }
1470         }
1471
1472         my @params;
1473         foreach my $p (split(//, $params)) {
1474             if ($p eq 's') {
1475                 push @params, getvar();
1476             } elsif ($p eq 'c') {
1477                 my @v = to_array getvalues(undef, undef,
1478                                            non_empty => 1);
1479                 push @params, join(',', @v);
1480             } else {
1481                 die;
1482             }
1483         }
1484
1485         $value = @params == 1
1486           ? $params[0]
1487             : bless \@params, 'params';
1488     } elsif ($params == 1) {
1489         if (exists $def->{negation} and not $negated) {
1490             my $token = peek_token();
1491             if ($token eq '!') {
1492                 require_next_token;
1493                 $negated = 1;
1494             }
1495         }
1496
1497         $value = getvalues();
1498
1499         warning("log-prefix is too long; truncating to 29 characters: '$1'")
1500           if $keyword eq 'log-prefix' && $value =~ s,^(.{29}).+$,$1,;
1501     } else {
1502         if (exists $def->{negation} and not $negated) {
1503             my $token = peek_token();
1504             if ($token eq '!') {
1505                 require_next_token;
1506                 $negated = 1;
1507             }
1508         }
1509
1510         $value = bless [ map {
1511             getvar()
1512         } (1..$params) ], 'params';
1513     }
1514
1515     $value = bless [ $value ], exists $def->{pre_negation} ? 'pre_negated' : 'negated'
1516       if $negated;
1517
1518     return $value;
1519 }
1520
1521 # parse options of a module
1522 sub parse_option($$$$$) {
1523     my ($def, $current, $store, $keyword, $negated_ref) = @_;
1524
1525     while (exists $def->{alias}) {
1526         ($keyword, $def) = @{$def->{alias}};
1527         die unless defined $def;
1528     }
1529
1530     $store->{$keyword}
1531       = parse_keyword($current, $def,
1532                       $keyword, $negated_ref);
1533     $current->{has_rule} = 1;
1534     return 1;
1535 }
1536
1537 # parse options for a protocol module definition
1538 sub parse_protocol_options($$$$) {
1539     my ($current, $proto, $keyword, $negated_ref) = @_;
1540
1541     my $domain_family = $current->{'domain_family'};
1542     my $proto_defs = $proto_defs{$domain_family};
1543     return unless defined $proto_defs;
1544
1545     my $proto_def = $proto_defs->{$proto};
1546     return unless defined $proto_def and
1547       exists $proto_def->{keywords}{$keyword};
1548
1549     my $module_name = $proto eq 'icmpv6' ? 'icmp6' : $proto;
1550     my $module = { name => $module_name,
1551                    options => {},
1552                    defs => $proto_def,
1553                  };
1554     push @{$current->{match}}, $module;
1555
1556     return parse_option($proto_def->{keywords}{$keyword},
1557                         $current, $module->{options},
1558                         $keyword, $negated_ref);
1559 }
1560
1561 sub copy_on_write($$) {
1562     my ($rule, $key) = @_;
1563     return unless exists $rule->{cow}{$key};
1564     $rule->{$key} = {%{$rule->{$key}}};
1565     delete $rule->{cow}{$key};
1566 }
1567
1568 sub clone_match($) {
1569     my $match = shift;
1570     return { name => $match->{name},
1571              options => { %{$match->{options}} },
1572              defs => $match->{defs},
1573            };
1574 }
1575
1576 sub new_level(\%$) {
1577     my ($current, $prev) = @_;
1578
1579     %$current = ();
1580     if (defined $prev) {
1581         # copy data from previous level
1582         $current->{cow} = { keywords => 1, };
1583         $current->{keywords} = $prev->{keywords};
1584         $current->{builtin} = { %{$prev->{builtin}} };
1585         $current->{match} = [ map { clone_match($_) } @{$prev->{match}} ];
1586         $current->{action} = { %{$prev->{action}} };
1587         foreach my $key (qw(domain domain_family table chain sport dport)) {
1588             $current->{$key} = $prev->{$key}
1589               if exists $prev->{$key};
1590         }
1591     } else {
1592         $current->{cow} = {};
1593         $current->{keywords} = {};
1594         $current->{builtin} = {};
1595         $current->{match} = [];
1596         $current->{action} = {};
1597     }
1598 }
1599
1600 sub rule_defined(\%) {
1601     my $rule = shift;
1602     return defined($rule->{domain}) or
1603       keys(%{$rule->{builtin}}) > 0 or
1604       keys(%{$rule->{match}}) > 0 or
1605       keys(%{$rule->{action}}) > 0;
1606 }
1607
1608 sub set_domain(\%$) {
1609     my ($rule, $domain) = @_;
1610
1611     my $filtered_domain = filter_domains($domain);
1612     my $domain_family;
1613     unless (ref $domain) {
1614         $domain_family = $domain eq 'ip6' ? 'ip' : $domain;
1615     } elsif (@$domain == 0) {
1616         $domain_family = 'none';
1617     } elsif (grep { not /^ip6?$/s } @$domain) {
1618         error('Cannot combine non-IP domains');
1619     } else {
1620         $domain_family = 'ip';
1621     }
1622
1623     $rule->{domain_family} = $domain_family;
1624     $rule->{keywords} = get_builtin_keywords($domain_family);
1625     delete $rule->{cow}{keywords};
1626
1627     $rule->{domain} = $stack[0]{auto}{DOMAIN} = $filtered_domain;
1628 }
1629
1630 # the main parser loop: read tokens, convert them into internal rule
1631 # structures
1632 sub enter($$) {
1633     my $lev = shift;  # current recursion depth
1634     my $prev = shift; # previous rule hash
1635
1636     # enter is the core of the firewall setup, it is a
1637     # simple parser program that recognizes keywords and
1638     # retreives parameters to set up the kernel routing
1639     # chains
1640
1641     my $base_level = $script->{base_level} || 0;
1642     die if $base_level > $lev;
1643
1644     my %current;
1645     new_level(%current, $prev);
1646
1647     # read keywords 1 by 1 and dump into parser
1648     while (defined (my $keyword = next_token())) {
1649         # check if the current rule should be negated
1650         my $negated = $keyword eq '!';
1651         if ($negated) {
1652             # negation. get the next word which contains the 'real'
1653             # rule
1654             $keyword = getvar();
1655
1656             error('unexpected end of file after negation')
1657               unless defined $keyword;
1658         }
1659
1660         # the core: parse all data
1661         for ($keyword)
1662         {
1663             # deprecated keyword?
1664             if (exists $deprecated_keywords{$keyword}) {
1665                 my $new_keyword = $deprecated_keywords{$keyword};
1666                 warning("'$keyword' is deprecated, please use '$new_keyword' instead");
1667                 $keyword = $new_keyword;
1668             }
1669
1670             # effectuation operator
1671             if ($keyword eq ';') {
1672                 if ($current{has_rule} and not $current{action}{type}) {
1673                     # something is wrong when a rule was specifiedd,
1674                     # but no action
1675                     error('No action defined; did you mean "NOP"?');
1676                 }
1677
1678                 error('No chain defined') unless exists $current{chain};
1679
1680                 $current{script} = { filename => $script->{filename},
1681                                      line => $script->{line},
1682                                    };
1683
1684                 mkrules(\%current);
1685
1686                 # and clean up variables set in this level
1687                 new_level(%current, $prev);
1688
1689                 next;
1690             }
1691
1692             # conditional expression
1693             if ($keyword eq '@if') {
1694                 unless (eval_bool(getvalues)) {
1695                     collect_tokens;
1696                     my $token = peek_token();
1697                     require_next_token() if $token and $token eq '@else';
1698                 }
1699
1700                 next;
1701             }
1702
1703             if ($keyword eq '@else') {
1704                 # hack: if this "else" has not been eaten by the "if"
1705                 # handler above, we believe it came from an if clause
1706                 # which evaluated "true" - remove the "else" part now.
1707                 collect_tokens;
1708                 next;
1709             }
1710
1711             # hooks for custom shell commands
1712             if ($keyword eq 'hook') {
1713                 error('"hook" must be the first token in a command')
1714                   if rule_defined(%current);
1715
1716                 my $position = getvar();
1717                 my $hooks;
1718                 if ($position eq 'pre') {
1719                     $hooks = \@pre_hooks;
1720                 } elsif ($position eq 'post') {
1721                     $hooks = \@post_hooks;
1722                 } else {
1723                     error("Invalid hook position: '$position'");
1724                 }
1725
1726                 push @$hooks, getvar();
1727
1728                 expect_token(';');
1729                 next;
1730             }
1731
1732             # recursing operators
1733             if ($keyword eq '{') {
1734                 # push stack
1735                 my $old_stack_depth = @stack;
1736
1737                 unshift @stack, { auto => { %{$stack[0]{auto} || {}} } };
1738
1739                 # recurse
1740                 enter($lev + 1, \%current);
1741
1742                 # pop stack
1743                 shift @stack;
1744                 die unless @stack == $old_stack_depth;
1745
1746                 # after a block, the command is finished, clear this
1747                 # level
1748                 new_level(%current, $prev);
1749
1750                 next;
1751             }
1752
1753             if ($keyword eq '}') {
1754                 error('Unmatched "}"')
1755                   if $lev <= $base_level;
1756
1757                 # consistency check: check if they havn't forgotten
1758                 # the ';' before the last statement
1759                 error('Missing semicolon before "}"')
1760                   if $current{has_rule};
1761
1762                 # and exit
1763                 return;
1764             }
1765
1766             # include another file
1767             if ($keyword eq '@include' or $keyword eq 'include') {
1768                 my @files = collect_filenames to_array getvalues;
1769                 $keyword = next_token;
1770                 error('Missing ";" - "include FILENAME" must be the last command in a rule')
1771                   unless defined $keyword and $keyword eq ';';
1772
1773                 foreach my $filename (@files) {
1774                     # save old script, open new script
1775                     my $old_script = $script;
1776                     open_script($filename);
1777                     $script->{base_level} = $lev + 1;
1778
1779                     # push stack
1780                     my $old_stack_depth = @stack;
1781
1782                     my $stack = {};
1783
1784                     if (@stack > 0) {
1785                         # include files may set variables for their parent
1786                         $stack->{vars} = ($stack[0]{vars} ||= {});
1787                         $stack->{functions} = ($stack[0]{functions} ||= {});
1788                         $stack->{auto} = { %{ $stack[0]{auto} || {} } };
1789                     }
1790
1791                     unshift @stack, $stack;
1792
1793                     # parse the script
1794                     enter($lev + 1, \%current);
1795
1796                     # pop stack
1797                     shift @stack;
1798                     die unless @stack == $old_stack_depth;
1799
1800                     # restore old script
1801                     $script = $old_script;
1802                 }
1803
1804                 next;
1805             }
1806
1807             # definition of a variable or function
1808             if ($keyword eq '@def' or $keyword eq 'def') {
1809                 error('"def" must be the first token in a command')
1810                   if $current{has_rule};
1811
1812                 my $type = require_next_token();
1813                 if ($type eq '$') {
1814                     my $name = require_next_token();
1815                     error('invalid variable name')
1816                       unless $name =~ /^\w+$/;
1817
1818                     expect_token('=');
1819
1820                     my $value = getvalues(undef, undef, allow_negation => 1);
1821
1822                     expect_token(';');
1823
1824                     $stack[0]{vars}{$name} = $value
1825                       unless exists $stack[-1]{vars}{$name};
1826                 } elsif ($type eq '&') {
1827                     my $name = require_next_token();
1828                     error('invalid function name')
1829                       unless $name =~ /^\w+$/;
1830
1831                     expect_token('(', 'function parameter list or "()" expected');
1832
1833                     my @params;
1834                     while (1) {
1835                         my $token = require_next_token();
1836                         last if $token eq ')';
1837
1838                         if (@params > 0) {
1839                             error('"," expected')
1840                               unless $token eq ',';
1841
1842                             $token = require_next_token();
1843                         }
1844
1845                         error('"$" and parameter name expected')
1846                           unless $token eq '$';
1847
1848                         $token = require_next_token();
1849                         error('invalid function parameter name')
1850                           unless $token =~ /^\w+$/;
1851
1852                         push @params, $token;
1853                     }
1854
1855                     my %function;
1856
1857                     $function{params} = \@params;
1858
1859                     expect_token('=');
1860
1861                     my $tokens = collect_tokens();
1862                     $function{block} = 1 if grep { $_ eq '{' } @$tokens;
1863                     $function{tokens} = $tokens;
1864
1865                     $stack[0]{functions}{$name} = \%function
1866                       unless exists $stack[-1]{functions}{$name};
1867                 } else {
1868                     error('"$" (variable) or "&" (function) expected');
1869                 }
1870
1871                 next;
1872             }
1873
1874             # def references
1875             if ($keyword eq '$') {
1876                 error('variable references are only allowed as keyword parameter');
1877             }
1878
1879             if ($keyword eq '&') {
1880                 my $name = require_next_token;
1881                 error('function name expected')
1882                   unless $name =~ /^\w+$/;
1883
1884                 my $function;
1885                 foreach (@stack) {
1886                     $function = $_->{functions}{$name};
1887                     last if defined $function;
1888                 }
1889                 error("no such function: \&$name")
1890                   unless defined $function;
1891
1892                 my $paramdef = $function->{params};
1893                 die unless defined $paramdef;
1894
1895                 my @params = get_function_params(allow_negation => 1);
1896
1897                 error("Wrong number of parameters for function '\&$name': "
1898                       . @$paramdef . " expected, " . @params . " given")
1899                   unless @params == @$paramdef;
1900
1901                 my %vars;
1902                 for (my $i = 0; $i < @params; $i++) {
1903                     $vars{$paramdef->[$i]} = $params[$i];
1904                 }
1905
1906                 if ($function->{block}) {
1907                     # block {} always ends the current rule, so if the
1908                     # function contains a block, we have to require
1909                     # the calling rule also ends here
1910                     expect_token(';');
1911                 }
1912
1913                 my @tokens = @{$function->{tokens}};
1914                 for (my $i = 0; $i < @tokens; $i++) {
1915                     if ($tokens[$i] eq '$' and $i + 1 < @tokens and
1916                         exists $vars{$tokens[$i + 1]}) {
1917                         my @value = to_array($vars{$tokens[$i + 1]});
1918                         @value = ('(', @value, ')')
1919                           unless @tokens == 1;
1920                         splice(@tokens, $i, 2, @value);
1921                         $i += @value - 2;
1922                     } elsif ($tokens[$i] =~ m,^"(.*)"$,) {
1923                         $tokens[$i] =~ s,\$(\w+),exists $vars{$1} ? $vars{$1} : "\$$1",eg;
1924                     }
1925                 }
1926
1927                 unshift @{$script->{tokens}}, @tokens;
1928
1929                 next;
1930             }
1931
1932             # where to put the rule?
1933             if ($keyword eq 'domain') {
1934                 error('Domain is already specified')
1935                   if exists $current{domain};
1936
1937                 set_domain(%current, getvalues());
1938                 next;
1939             }
1940
1941             if ($keyword eq 'table') {
1942                 error('Table is already specified')
1943                   if exists $current{table};
1944                 $current{table} = $stack[0]{auto}{TABLE} = getvalues();
1945
1946                 set_domain(%current, 'ip')
1947                   unless exists $current{domain};
1948
1949                 next;
1950             }
1951
1952             if ($keyword eq 'chain') {
1953                 error('Chain is already specified')
1954                   if exists $current{chain};
1955                 $current{chain} = $stack[0]{auto}{CHAIN} = getvalues();
1956
1957                 # ferm 1.1 allowed lower case built-in chain names
1958                 foreach (ref $current{chain} ? @{$current{chain}} : $current{chain}) {
1959                     error('Please write built-in chain names in upper case')
1960                       if /^(?:input|forward|output|prerouting|postrouting)$/;
1961                 }
1962
1963                 set_domain(%current, 'ip')
1964                   unless exists $current{domain};
1965
1966                 $current{table} = 'filter'
1967                   unless exists $current{table};
1968
1969                 next;
1970             }
1971
1972             error('Chain must be specified')
1973               unless exists $current{chain};
1974
1975             # policy for built-in chain
1976             if ($keyword eq 'policy') {
1977                 error('Cannot specify matches for policy')
1978                   if $current{has_rule};
1979
1980                 my $policy = getvar();
1981                 error("Invalid policy target: $policy")
1982                   unless $policy =~ /^(?:ACCEPT|DROP)$/;
1983
1984                 expect_token(';');
1985
1986                 foreach my $domain (to_array $current{domain}) {
1987                     foreach my $table (to_array $current{table}) {
1988                         foreach my $chain (to_array $current{chain}) {
1989                             $domains{$domain}{tables}{$table}{chains}{$chain}{policy} = $policy;
1990                         }
1991                     }
1992                 }
1993
1994                 new_level(%current, $prev);
1995                 next;
1996             }
1997
1998             # create a subchain
1999             if ($keyword eq '@subchain' or $keyword eq 'subchain') {
2000                 error('Chain must be specified')
2001                   unless exists $current{chain};
2002
2003                 error('No rule specified before "@subchain"')
2004                   unless $current{has_rule};
2005
2006                 my $subchain;
2007                 $keyword = next_token();
2008
2009                 if ($keyword =~ /^(["'])(.*)\1$/s) {
2010                     $subchain = $2;
2011                     $keyword = next_token();
2012                 } else {
2013                     $subchain = 'ferm_auto_' . ++$auto_chain;
2014                 }
2015
2016                 error('"{" or chain name expected after "@subchain"')
2017                   unless $keyword eq '{';
2018
2019                 # create a deep copy of %current, only containing values
2020                 # which must be in the subchain
2021                 my %inner = ( cow => { keywords => 1, },
2022                               keywords => $current{keywords},
2023                               builtin => {},
2024                               action => {},
2025                             );
2026                 $inner{domain} = $current{domain};
2027                 $inner{domain_family} = $current{domain_family};
2028                 $inner{table} = $current{table};
2029                 $inner{chain} = $inner{auto}{CHAIN} = $subchain;
2030                 $inner{builtin}{protocol} = $current{builtin}{protocol}
2031                   if exists $current{builtin}{protocol};
2032
2033                 # enter the block
2034                 enter(1, \%inner);
2035
2036                 # now handle the parent - it's a jump to the sub chain
2037                 $current{action} = { type => 'jump',
2038                                      chain => $subchain,
2039                                    };
2040
2041                 $current{script} = { filename => $script->{filename},
2042                                      line => $script->{line},
2043                                    };
2044
2045                 mkrules(\%current);
2046
2047                 # and clean up variables set in this level
2048                 new_level(%current, $prev);
2049
2050                 next;
2051             }
2052
2053             # everything else must be part of a "real" rule, not just
2054             # "policy only"
2055             $current{has_rule}++;
2056
2057             # extended parameters:
2058             if ($keyword =~ /^mod(?:ule)?$/) {
2059                 foreach my $module (to_array getvalues) {
2060                     next if grep { $_->{name} eq $module } @{$current{match}};
2061
2062                     my $domain_family = $current{domain_family};
2063                     my $defs = $match_defs{$domain_family}{$module};
2064                     if (not defined $defs and exists $current{builtin}{protocol}) {
2065                         my $proto = $current{builtin}{protocol};
2066                         unless (ref $proto) {
2067                             $proto = netfilter_canonical_protocol($current{builtin}{protocol});
2068                             $defs = $proto_defs{$domain_family}{$proto}
2069                               if netfilter_protocol_module($proto) eq $module;
2070                         }
2071                     }
2072
2073                     push @{$current{match}}, { name => $module,
2074                                                options => {},
2075                                                defs => $defs,
2076                                              };
2077
2078                     if (defined $defs) {
2079                         copy_on_write(\%current, 'keywords');
2080                         while (my ($k, $def) = each %{$defs->{keywords}}) {
2081                             $current{keywords}{$k} = [ 'match', $module, $def ];
2082                         }
2083                     }
2084                 }
2085
2086                 next;
2087             }
2088
2089             # keywords from $current{keywords}
2090
2091             if (exists $current{keywords}{$keyword}) {
2092                 my ($type, $module, $def) = @{$current{keywords}{$keyword}};
2093                 my $store;
2094                 if ($type eq 'builtin') {
2095                     $store = $current{builtin};
2096                 } elsif ($type eq 'match') {
2097                     $store = (grep { $_->{name} eq $module } @{$current{match}})[-1]->{options};
2098                 } elsif ($type eq 'target') {
2099                     $store = $current{target_options} ||= {};
2100                 } else {
2101                     die;
2102                 }
2103
2104                 parse_option($def, \%current, $store, $keyword, \$negated);
2105                 next;
2106             }
2107
2108             ###
2109             # actions
2110             #
2111
2112             # jump action
2113             if ($keyword eq 'jump') {
2114                 error('There can only one action per rule')
2115                   if defined $current{action}{type};
2116                 my $chain = getvar();
2117                 if (is_netfilter_core_target($chain) or
2118                     is_netfilter_module_target($current{domain_family}, $chain)) {
2119                     my $defs = $target_defs{$current{domain_family}} &&
2120                       $target_defs{$current{domain_family}}{$chain};
2121                     $current{action} = { type => 'target',
2122                                          target => $chain,
2123                                          defs => $defs,
2124                                        };
2125
2126                     if (defined $defs) {
2127                         copy_on_write(\%current, 'keywords');
2128                         while (my ($k, $def) = each %{$defs->{keywords}}) {
2129                             $current{keywords}{$k} = [ 'target', $keyword, $def ];
2130                         }
2131                     }
2132                 } else {
2133                     $current{action} = { type => 'jump',
2134                                          chain => $chain,
2135                                        };
2136                 }
2137                 next;
2138             };
2139
2140             # goto action
2141             if ($keyword eq 'realgoto') {
2142                 error('There can only one action per rule')
2143                   if defined $current{action}{type};
2144                 $current{action} = { type => 'goto',
2145                                      chain => getvar(),
2146                                    };
2147                 next;
2148             };
2149
2150             # action keywords
2151             if (is_netfilter_core_target($keyword)) {
2152                 error('There can only one action per rule')
2153                   if defined $current{action}{type};
2154                 $current{action} = { type => 'target',
2155                                      target => $keyword,
2156                                    };
2157                 next;
2158             }
2159
2160             if ($keyword eq 'NOP') {
2161                 error('There can only one action per rule')
2162                   if defined $current{action}{type};
2163                 $current{action} = { type => 'nop',
2164                                    };
2165                 next;
2166             }
2167
2168             if (is_netfilter_module_target($current{domain_family}, $keyword)) {
2169                 error('There can only one action per rule')
2170                   if defined $current{action}{type};
2171
2172                 if ($keyword eq 'TCPMSS') {
2173                     my $protos = $current{builtin}{protocol};
2174                     error('No protocol specified before TCPMSS')
2175                       unless defined $protos;
2176                     foreach my $proto (to_array $protos) {
2177                         error('TCPMSS not available for protocol "$proto"')
2178                           unless $proto eq 'tcp';
2179                     }
2180                 }
2181
2182                 my $defs = $target_defs{$current{domain_family}}{$keyword};
2183
2184                 $current{action} = { type => 'target',
2185                                      target => $keyword,
2186                                      defs => $defs,
2187                                    };
2188
2189                 if (defined $defs) {
2190                     copy_on_write(\%current, 'keywords');
2191                     while (my ($k, $def) = each %{$defs->{keywords}}) {
2192                         $current{keywords}{$k} = [ 'target', $keyword, $def ];
2193                     }
2194                 }
2195
2196                 next;
2197             }
2198
2199             my $proto = $current{builtin}{protocol};
2200
2201             ###
2202             # protocol specific options
2203             #
2204
2205             if (defined $proto and not ref $proto) {
2206                 $proto = netfilter_canonical_protocol($proto);
2207
2208                 if ($proto eq 'icmp') {
2209                     my $domains = $current{domain};
2210                     $proto = 'icmpv6' if not ref $domains and $domains eq 'ip6';
2211                 }
2212
2213                 parse_protocol_options(\%current, $proto, $keyword, \$negated)
2214                   and next;
2215             }
2216
2217             # port switches
2218             if ($keyword =~ /^[sd]port$/) {
2219                 error('To use sport or dport, you have to specify "proto tcp" or "proto udp" first')
2220                   unless defined $proto and grep { /^(?:tcp|udp|udplite|dccp|sctp)$/ } to_array $proto;
2221
2222                 $current{$keyword} = getvalues(undef, undef,
2223                                                allow_negation => 1);
2224                 next;
2225             }
2226
2227             # default
2228             error("Unrecognized keyword: $keyword");
2229         }
2230
2231         # if the rule didn't reset the negated flag, it's not
2232         # supported
2233         error("Doesn't support negation: $keyword")
2234           if $negated;
2235     }
2236
2237     error('Missing "}" at end of file')
2238       if $lev > $base_level;
2239
2240     # consistency check: check if they havn't forgotten
2241     # the ';' before the last statement
2242     error("Missing semicolon before end of file")
2243       if $current{has_rule}; # XXX
2244 }
2245
2246 sub execute_command {
2247     my ($command, $script) = @_;
2248
2249     print LINES "$command\n"
2250       if $option{lines};
2251     return if $option{noexec};
2252
2253     my $ret = system($_);
2254     unless ($ret == 0) {
2255         if ($? == -1) {
2256             print STDERR "failed to execute: $!\n";
2257             exit 1;
2258         } elsif ($? & 0x7f) {
2259             printf STDERR "child died with signal %d\n", $? & 0x7f;
2260             return 1;
2261         } else {
2262             print STDERR "(rule declared in $script->{filename}:$script->{line})\n"
2263               if defined $script;
2264             return $? >> 8;
2265         }
2266     }
2267
2268     return;
2269 }
2270
2271 sub execute_slow($$) {
2272     my ($domain, $domain_info) = @_;
2273
2274     my $domain_cmd = $domain_info->{tools}{tables};
2275
2276     while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2277         my $table_cmd = "$domain_cmd -t $table";
2278
2279         # reset chain policies
2280         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2281             next unless $chain_info->{builtin} or
2282               (not $table_info->{has_builtin} and
2283                is_netfilter_builtin_chain($table, $chain));
2284             $status ||= execute_command("$table_cmd -P $chain ACCEPT");
2285         }
2286
2287         # clear
2288         $status ||= execute_command("$table_cmd -F");
2289         $status ||= execute_command("$table_cmd -X");
2290
2291         next if $option{flush};
2292
2293         # create chains / set policy
2294         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2295             if (exists $chain_info->{policy}) {
2296                 $status ||= execute_command("$table_cmd -P $chain $chain_info->{policy}")
2297                   unless $chain_info->{policy} eq 'ACCEPT';
2298             } elsif (not is_netfilter_builtin_chain($table, $chain)) {
2299                 $status ||= execute_command("$table_cmd -N $chain");
2300             }
2301         }
2302
2303         # dump rules
2304         while (my ($chain, $chain_info) = each %{$table_info->{chains}}) {
2305             my $chain_cmd = "$table_cmd -A $chain";
2306             foreach my $rule (@{$chain_info->{rules}}) {
2307                 $status ||= execute_command($chain_cmd . $rule->{rule});
2308             }
2309         }
2310     }
2311
2312     return $status;
2313 }
2314
2315 sub rules_to_save($$) {
2316     my ($domain, $domain_info) = @_;
2317
2318     # convert this into an iptables-save text
2319     my $result = "# Generated by ferm $VERSION on " . localtime() . "\n";
2320
2321     while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2322         # select table
2323         $result .= '*' . $table . "\n";
2324
2325         # create chains / set policy
2326         foreach my $chain (sort keys %{$table_info->{chains}}) {
2327             my $chain_info = $table_info->{chains}{$chain};
2328             my $policy = $option{flush} ? 'ACCEPT' : $chain_info->{policy};
2329             unless (defined $policy) {
2330                 if (is_netfilter_builtin_chain($table, $chain)) {
2331                     $policy = 'ACCEPT';
2332                 } else {
2333                     $policy = '-';
2334                 }
2335             }
2336             $result .= ":$chain $policy\ [0:0]\n";
2337         }
2338
2339         next if $option{flush};
2340
2341         # dump rules
2342         foreach my $chain (sort keys %{$table_info->{chains}}) {
2343             my $chain_info = $table_info->{chains}{$chain};
2344             foreach my $rule (@{$chain_info->{rules}}) {
2345                 $result .= "-A $chain$rule->{rule}\n";
2346             }
2347         }
2348
2349         # do it
2350         $result .= "COMMIT\n";
2351     }
2352
2353     return $result;
2354 }
2355
2356 sub restore_domain($$) {
2357     my ($domain, $save) = @_;
2358
2359     my $path = $domains{$domain}{tools}{'tables-restore'};
2360
2361     local *RESTORE;
2362     open RESTORE, "|$path"
2363       or die "Failed to run $path: $!\n";
2364
2365     print RESTORE $save;
2366
2367     close RESTORE
2368       or die "Failed to run $path\n";
2369 }
2370
2371 sub execute_fast($$) {
2372     my ($domain, $domain_info) = @_;
2373
2374     my $save = rules_to_save($domain, $domain_info);
2375
2376     if ($option{lines}) {
2377         print LINES "$domain_info->{tools}{'tables-restore'} <<EOT\n"
2378           if $option{shell};
2379         print LINES $save;
2380         print LINES "EOT\n"
2381           if $option{shell};
2382     }
2383
2384     return if $option{noexec};
2385
2386     eval {
2387         restore_domain($domain, $save);
2388     };
2389     if ($@) {
2390         print STDERR $@;
2391         return 1;
2392     }
2393
2394     return;
2395 }
2396
2397 sub rollback() {
2398     my $error;
2399     while (my ($domain, $domain_info) = each %domains) {
2400         next unless $domain_info->{enabled};
2401         unless (defined $domain_info->{tools}{'tables-restore'}) {
2402             print STDERR "Cannot rollback domain '$domain' because there is no ${domain}tables-restore\n";
2403             next;
2404         }
2405
2406         my $reset = '';
2407         while (my ($table, $table_info) = each %{$domain_info->{tables}}) {
2408             my $reset_chain = '';
2409             foreach my $chain (keys %{$table_info->{chains}{$table}}) {
2410                 next unless is_netfilter_builtin_chain($table, $chain);
2411                 $reset_chain .= ":${chain} ACCEPT [0:0]\n";
2412             }
2413             $reset .= "*${table}\n${reset_chain}COMMIT\n"
2414               if length $reset_chain;
2415         }
2416
2417         $reset .= $domain_info->{previous}
2418           if defined $domain_info->{previous};
2419
2420         restore_domain($domain, $reset);
2421     }
2422
2423     print STDERR "\nFirewall rules rolled back.\n" unless $error;
2424     exit 1;
2425 }
2426
2427 sub alrm_handler {
2428     # do nothing, just interrupt a system call
2429 }
2430
2431 sub confirm_rules() {
2432     $SIG{ALRM} = \&alrm_handler;
2433
2434     alarm(5);
2435
2436     print STDERR "\n"
2437       . "ferm has applied the new firewall rules.\n"
2438         . "Please type 'yes' to confirm:\n";
2439     STDERR->flush();
2440
2441     alarm(30);
2442
2443     my $line = '';
2444     STDIN->sysread($line, 3);
2445
2446     eval {
2447         require POSIX;
2448         POSIX::tcflush(*STDIN, 2);
2449     };
2450     print STDERR "$@" if $@;
2451
2452     $SIG{ALRM} = 'DEFAULT';
2453
2454     return $line eq 'yes';
2455 }
2456
2457 # end of ferm
2458
2459 __END__
2460
2461 =head1 NAME
2462
2463 ferm - a firewall rule parser for linux
2464
2465 =head1 SYNOPSIS
2466
2467 B<ferm> I<options> I<inputfiles>
2468
2469 =head1 OPTIONS
2470
2471  -n, --noexec      Do not execute the rules, just simulate
2472  -F, --flush       Flush all netfilter tables managed by ferm
2473  -l, --lines       Show all rules that were created
2474  -i, --interactive Interactive mode: revert if user does not confirm
2475  --remote          Remote mode; ignore host specific configuration.
2476                    This implies --noexec and --lines.
2477  -V, --version     Show current version number
2478  -h, --help        Look at this text
2479  --fast            Generate an iptables-save file, used by iptables-restore
2480  --shell           Generate a shell script which calls iptables-restore
2481  --domain {ip|ip6} Handle only the specified domain
2482  --def '$name=v'   Override a variable
2483
2484 =cut