bin/idea.bat

   1 @echo off
   2
   3 ::----------------------------------------------------------------------
   4 :: IntelliJ IDEA Startup Script
   5 ::----------------------------------------------------------------------
   6
   7 :: ---------------------------------------------------------------------
   8 :: Before you run IntelliJ IDEA specify the location of the
   9 :: JDK 1.5 installation directory which will be used for running IDEA
  10 :: ---------------------------------------------------------------------
  11 IF "%IDEA_JDK%" == "" SET IDEA_JDK=%JDK_HOME%
  12 IF "%IDEA_JDK%" == "" goto error
  13
  14 :: ---------------------------------------------------------------------
  15 :: Before you run IntelliJ IDEA specify the location of the
  16 :: directory where IntelliJ IDEA is installed
  17 :: In most cases you do not need to change the settings below.
  18 :: ---------------------------------------------------------------------
  19 SET IDEA_HOME=..
  20
  21 SET JAVA_EXE=%IDEA_JDK%\jre\bin\java.exe
  22 IF NOT EXIST "%JAVA_EXE%" goto error
  23
  24 IF "%IDEA_MAIN_CLASS_NAME%" == "" SET IDEA_MAIN_CLASS_NAME=com.intellij.idea.Main
  25
  26 IF NOT "%IDEA_PROPERTIES%" == "" set IDEA_PROPERTIES_PROPERTY=-Didea.properties.file=%IDEA_PROPERTIES%
  27
  28 :: ---------------------------------------------------------------------
  29 :: You may specify your own JVM arguments in idea.exe.vmoptions file. Put one option per line there.
  30 :: ---------------------------------------------------------------------
  31 SET ACC=
  32 FOR /F "delims=" %%i in (%IDEA_HOME%\bin\idea.exe.vmoptions) DO call %IDEA_HOME%\bin\append.bat "%%i"
  33
  34 set REQUIRED_IDEA_JVM_ARGS=-Xbootclasspath/a:%IDEA_HOME%/lib/boot.jar %IDEA_PROPERTIES_PROPERTY% %REQUIRED_IDEA_JVM_ARGS%
  35 SET JVM_ARGS=%ACC% %REQUIRED_IDEA_JVM_ARGS%
  36
  37 SET OLD_PATH=%PATH%
  38 SET PATH=%IDEA_HOME%\bin;%PATH%
  39
  40 SET CLASS_PATH=%IDEA_HOME%\lib\bootstrap.jar
  41 SET CLASS_PATH=%CLASS_PATH%;%IDEA_HOME%\lib\util.jar
  42 SET CLASS_PATH=%CLASS_PATH%;%IDEA_HOME%\lib\jdom.jar
  43 SET CLASS_PATH=%CLASS_PATH%;%IDEA_HOME%\lib\log4j.jar
  44 SET CLASS_PATH=%CLASS_PATH%;%IDEA_HOME%\lib\extensions.jar
  45 SET CLASS_PATH=%CLASS_PATH%;%IDEA_HOME%\lib\trove4j.jar
  46 SET CLASS_PATH=%CLASS_PATH%;%IDEA_JDK%\lib\tools.jar
  47
  48 :: ---------------------------------------------------------------------
  49 :: You may specify additional class paths in IDEA_CLASS_PATH variable.
  50 :: It is a good idea to specify paths to your plugins in this variable.
  51 :: ---------------------------------------------------------------------
  52 IF NOT "%IDEA_CLASS_PATH%" == "" SET CLASS_PATH=%CLASS_PATH%;%IDEA_CLASS_PATH%
  53
  54 "%JAVA_EXE%" %JVM_ARGS% -cp "%CLASS_PATH%" %IDEA_MAIN_CLASS_NAME% %*
  55
  56 SET PATH=%OLD_PATH%
  57 goto end
  58 :error
  59 echo ---------------------------------------------------------------------
  60 echo ERROR: cannot start IntelliJ IDEA.
  61 echo No JDK found to run IDEA. Please validate either IDEA_JDK or JDK_HOME points to valid JDK installation
  62 echo ---------------------------------------------------------------------
  63 pause
  64 :end