cmake/modules/Findfmt.cmake

   1 find_path(fmt_INCLUDE_DIR NAMES fmt/format.h)
   2
   3 if(fmt_INCLUDE_DIR)
   4   set(_fmt_version_file "${fmt_INCLUDE_DIR}/fmt/core.h")
   5   if(NOT EXISTS "${_fmt_version_file}")
   6     set(_fmt_version_file "${fmt_INCLUDE_DIR}/fmt/format.h")
   7   endif()
   8   if(EXISTS "${_fmt_version_file}")
   9     # parse "#define FMT_VERSION 40100" to 4.1.0
  10     file(STRINGS "${_fmt_version_file}" fmt_VERSION_LINE
  11       REGEX "^#define[ \t]+FMT_VERSION[ \t]+[0-9]+$")
  12     string(REGEX REPLACE "^#define[ \t]+FMT_VERSION[ \t]+([0-9]+)$"
  13       "\\1" fmt_VERSION "${fmt_VERSION_LINE}")
  14     foreach(ver "fmt_VERSION_PATCH" "fmt_VERSION_MINOR" "fmt_VERSION_MAJOR")
  15       math(EXPR ${ver} "${fmt_VERSION} % 100")
  16       math(EXPR fmt_VERSION "(${fmt_VERSION} - ${${ver}}) / 100")
  17     endforeach()
  18     set(fmt_VERSION
  19       "${fmt_VERSION_MAJOR}.${fmt_VERSION_MINOR}.${fmt_VERSION_PATCH}")
  20   endif()
  21 endif()
  22
  23 find_library(fmt_LIBRARY NAMES fmt)
  24
  25 include(FindPackageHandleStandardArgs)
  26 find_package_handle_standard_args(fmt
  27   REQUIRED_VARS fmt_INCLUDE_DIR fmt_LIBRARY
  28   VERSION_VAR fmt_VERSION)
  29 mark_as_advanced(
  30   fmt_INCLUDE_DIR
  31   fmt_LIBRARY
  32   fmt_VERSION_MAJOR
  33   fmt_VERSION_MINOR
  34   fmt_VERSION_PATCH
  35   fmt_VERSION_STRING)
  36
  37 if(fmt_FOUND AND NOT (TARGET fmt::fmt))
  38   add_library(fmt::fmt UNKNOWN IMPORTED)
  39   set_target_properties(fmt::fmt PROPERTIES
  40     INTERFACE_INCLUDE_DIRECTORIES "${fmt_INCLUDE_DIR}"
  41     IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
  42     IMPORTED_LOCATION "${fmt_LIBRARY}")
  43 endif()