src/engrid.pro.app

   1 TEMPLATE = app
   2 LANGUAGE = C++
   3 #TARGET   = engrid
   4
   5 # Enable this if the VTK from the ParaView sources and
   6 # installation want to be used
   7 # Note: Currently only for Windows Compiles with MSVC
   8 Use_VTK_Win_ParaView = yes
   9
  10 CONFIG += qt \
  11           debug_and_release \
  12           thread
  13
  14 QT     += xml \
  15           network \
  16           opengl
  17
  18 win32-msvc* {
  19     QMAKE_CXXFLAGS += -W3
  20 } win32-g++* {
  21     CONFIG += console
  22     QMAKE_CXXFLAGS += -Wall
  23     QMAKE_CXXFLAGS += -Wno-deprecated
  24     QMAKE_CXXFLAGS += -Wl,--no-undefined
  25     QMAKE_CXXFLAGS += -Wl,--enable-runtime-pseudo-reloc
  26 } else {
  27     QMAKE_CXXFLAGS += -Wall
  28     QMAKE_CXXFLAGS += -Wno-deprecated
  29 }
  30
  31 # OpenMP
  32 QMAKE_CXXFLAGS += -fopenmp
  33 LIBS += -lgomp
  34
  35
  36 INCLUDEPATH += ./libengrid
  37 INCLUDEPATH += ./libengrid-build
  38 INCLUDEPATH += ../engrid-build
  39 INCLUDEPATH += ./netgen_svn/netgen-mesher/netgen/nglib
  40 INCLUDEPATH += ./netgen_svn/netgen-mesher/netgen/libsrc/general
  41
  42 win32-msvc* {
  43     DEFINES += _USE_MATH_DEFINES
  44
  45     !isEmpty(Use_VTK_Win_ParaView) {
  46         include(misc/engrid-vtk-win_paraview.pri)
  47     } else {
  48         INCLUDEPATH += $(VTKINCDIR)
  49     }
  50 } win32-g++* {
  51     INCLUDEPATH += $(VTKINCDIR)
  52 } else {
  53     INCLUDEPATH += $(VTKINCDIR)
  54 }
  55
  56 win32-msvc* {
  57     LIBS += -L./libengrid/release -lengrid
  58 } win32-g++* {
  59     LIBS += -L./libengrid/release -lengrid
  60 } else {
  61     LIBS += -lm
  62     LIBS += -ltcl8.5
  63     LIBS += -L./libengrid -lengrid
  64
  65     debian {
  66         LIBS += -lnglib
  67     } else {
  68         LIBS += -L./netgen_svn -lng
  69     }
  70
  71     LIBS        += -L$(VTKLIBDIR)
  72     LIBS        += -lQVTK
  73     LIBS        += -lvtkCommon
  74     LIBS        += -lvtkDICOMParser
  75     LIBS        += -lvtkexoIIc
  76     LIBS        += -lvtkFiltering
  77     LIBS        += -lvtkftgl
  78     LIBS        += -lvtkGenericFiltering
  79     LIBS        += -lvtkGraphics
  80     LIBS        += -lvtkHybrid
  81     LIBS        += -lvtkImaging
  82     LIBS        += -lvtkIO
  83     #LIBS        += -lvtkNetCDF
  84     LIBS        += -lvtkRendering
  85     LIBS        += -lvtksys
  86     LIBS        += -lvtkVolumeRendering
  87     LIBS        += -lvtkWidgets
  88     LIBS        += -L$(BRLCADLIBDIR)
  89     LIBS        += $(BRLCADLIBDIR)/librt.so
  90 }
  91
  92 OTHER_FILES += checkcomments.py todo.txt
  93 RESOURCES   += libengrid/engrid.qrc
  94
  95 SOURCES = main.cpp
  96
  97