configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [21])
   6 m4_define([empathy_micro_version], [1])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.9.5
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.37.6
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_38, [Prevent post 2.38 APIs])
  43
  44 GTK_REQUIRED=3.9.4
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_8, [Ignore post 3.8 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_10, [Prevent post 3.10 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53
  54 TELEPATHY_GLIB_REQUIRED=0.23.2
  55 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  56 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_24, [Prevent post 0.24 APIs])
  57 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  58 AC_DEFINE(TP_DISABLE_SINGLE_INCLUDE, 1, [Disable single include header])
  59
  60 COGL_REQUIRED=1.14
  61 AC_DEFINE(COGL_VERSION_MIN_REQUIRED, COGL_VERSION_1_14, [Ignore post 1.14 deprecations])
  62 AC_DEFINE(COGL_VERSION_MAX_ALLOWED, COGL_VERSION_1_14, [Ignore post 1.14 deprecations])
  63
  64 GSTREAMER_REQUIRED=0.10.32
  65 TP_FS_REQUIRED=0.6.0
  66 LIBSECRET_REQUIRED=0.5
  67 GCR_REQUIRED=2.91.4
  68 LIBCANBERRA_GTK_REQUIRED=0.25
  69 LIBNOTIFY_REQUIRED=0.7.0
  70 LIBSOUP_REQUIRED=2.42.0
  71 TELEPATHY_LOGGER=0.8.0
  72 WEBKIT_REQUIRED=1.9.1
  73 GOA_REQUIRED=3.5.1
  74
  75 # Optional deps
  76 ENCHANT_REQUIRED=1.2.0
  77 GEOCLUE_REQUIRED=2.1.0
  78 GEOCODE_GLIB_REQUIRED=0.99.1
  79 ISO_CODES_REQUIRED=0.35
  80 NAUTILUS_SENDTO_REQUIRED=2.90.0
  81 NETWORK_MANAGER_REQUIRED=0.7.0
  82 CHAMPLAIN_REQUIRED=0.12.1
  83 CHEESE_GTK_REQUIRED=3.4.0
  84 LIBACCOUNTS_REQUIRED=1.4
  85 LIBSIGNON_REQUIRED=1.8
  86 MC_PLUGINS_REQUIRED=5.13.1
  87
  88 # Use --enable-maintainer-mode to disable deprecated symbols,
  89 # disable single include and enable GSEAL. If this is not a released empathy,
  90 # maintainer mode is forced
  91 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  92 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  93 #GNOME_MAINTAINER_MODE_DEFINES
  94
  95 PKG_PROG_PKG_CONFIG([0.25])
  96
  97 # tp-account-widgets
  98 prev_top_build_prefix=$ac_top_build_prefix
  99 prev_ac_configure_args=$ac_configure_args
 100 ac_configure_args="$ac_configure_args --with-pkgdatadir=${datadir}/empathy"
 101 ac_configure_args="$ac_configure_args --with-gettext-package=empathy-tpaw"
 102 ifelse(empathy_released, 1, [],
 103     [
 104         ac_configure_args="$ac_configure_args --enable-unreleased-checks"
 105     ])
 106 AX_CONFIG_DIR([telepathy-account-widgets])
 107 ac_top_build_prefix=$prev_top_build_prefix
 108 ac_configure_args=$prev_ac_configure_args
 109
 110 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-account-widgets/
 111 PKG_CHECK_MODULES(TPAW, telepathy-account-widgets)
 112
 113 EMPATHY_UOA_PROVIDER=`$PKG_CONFIG --variable=uoa_provider telepathy-account-widgets`
 114 AC_DEFINE_UNQUOTED(EMPATHY_UOA_PROVIDER, "$EMPATHY_UOA_PROVIDER",
 115    [Name of provider for accounts imported from libaccounts])
 116
 117 AC_CONFIG_MACRO_DIR([m4])
 118 AC_CONFIG_HEADERS([config.h])
 119 AC_CONFIG_SRCDIR([configure.ac])
 120 AC_CONFIG_AUX_DIR(.)
 121
 122 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 123
 124 # Support silent build rules. Disable
 125 # by either passing --disable-silent-rules to configure or passing V=1
 126 # to make
 127 AM_SILENT_RULES([yes])
 128
 129 # Check for programs
 130 AC_PROG_CC
 131 AC_HEADER_STDC
 132 AC_PROG_MKDIR_P
 133 AM_PATH_GLIB_2_0
 134 AC_PATH_XTRA
 135
 136 # Initialize libtool
 137 LT_PREREQ([2.2])
 138 LT_INIT
 139
 140 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 141 GLIB_GSETTINGS
 142
 143 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG gio-2.0 --variable=glib_compile_resources`
 144 AC_SUBST(GLIB_COMPILE_RESOURCES)
 145 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 146 AC_SUBST(GLIB_GENMARSHAL)
 147
 148 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 149 if test -z "$XSLTPROC"; then
 150   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 151 fi
 152 AM_PATH_PYTHON([2.3])
 153
 154 EMPATHY_ARG_VALGRIND
 155
 156
 157 # -----------------------------------------------------------
 158 # Error flags
 159 # -----------------------------------------------------------
 160 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 161 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 162
 163 AC_ARG_ENABLE(Werror,
 164   AS_HELP_STRING([--disable-Werror],
 165                  [compile without -Werror (normally enabled in development builds)]),
 166     werror=$enableval, :)
 167
 168 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 169 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 170         wno_missing_field_initializers=yes,
 171         wno_missing_field_initializers=no)
 172 AS_COMPILER_FLAG(-Wno-unused-parameter,
 173         wno_unused_parameter=yes,
 174         wno_unused_parameter=no)
 175
 176 ifelse(empathy_released, 1, [],
 177     [
 178         if test x$werror = xyes; then
 179             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 180         fi
 181         if test x$wextra = xyes -a \
 182             x$wno_missing_field_initializers = xyes -a \
 183             x$wno_unused_parameter = xyes; then
 184             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 185         fi
 186     ])
 187
 188 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 189 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 190 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 191 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 192 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 193
 194 AC_SUBST(ERROR_CFLAGS)
 195
 196 AC_ARG_ENABLE(gprof,
 197             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 198             [build with support for gprof]),,
 199             [enable_gprof=no])
 200 if test "x$enable_gprof" != "xno" ; then
 201     CFLAGS="$CFLAGS -pg"
 202     LDFLAGS="$LDFLAGS -pg"
 203 fi
 204
 205 AC_SUBST(LDFLAGS)
 206
 207 # -----------------------------------------------------------
 208 # Pkg-Config dependency checks
 209 # -----------------------------------------------------------
 210
 211 AC_CHECK_LIBM
 212 AC_SUBST(LIBM)
 213
 214 PKG_CHECK_MODULES(EMPATHY,
 215 [
 216    dbus-glib-1
 217    folks >= $FOLKS_REQUIRED
 218    folks-telepathy >= $FOLKS_REQUIRED
 219    glib-2.0 >= $GLIB_REQUIRED
 220    gio-2.0 >= $GLIB_REQUIRED
 221    gio-unix-2.0 >= $GLIB_REQUIRED
 222    libsecret-1 >= $LIBSECRET_REQUIRED
 223    gnutls >= $GNUTLS_REQUIRED
 224    gmodule-export-2.0
 225    gobject-2.0
 226    gsettings-desktop-schemas
 227    libxml-2.0
 228    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 229    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 230    x11
 231    gtk+-3.0 >= $GTK_REQUIRED
 232    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 233    libnotify >= $LIBNOTIFY_REQUIRED
 234    gcr-3 >= $GCR_REQUIRED
 235    libpulse
 236    libpulse-mainloop-glib
 237    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 238    libsoup-2.4 >= $LIBSOUP_REQUIRED
 239    gee-0.8
 240 ])
 241
 242 # -----------------------------------------------------------
 243 # GStreamer
 244 # -----------------------------------------------------------
 245 PKG_CHECK_MODULES(EMPATHY_CALL,
 246 [
 247    farstream-0.2
 248    telepathy-farstream >= $TP_FS_REQUIRED
 249    clutter-1.0 >= $CLUTTER_REQUIRED
 250    clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 251    clutter-gst-3.0
 252    gstreamer-1.0
 253    gstreamer-audio-1.0
 254    gstreamer-video-1.0
 255    cogl-1.0 >= $COGL_REQUIRED
 256 ])
 257
 258 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 259    [Name of provider for accounts imported from GOA])
 260
 261 # -----------------------------------------------------------
 262 # Enable debug
 263 # -----------------------------------------------------------
 264
 265 AC_ARG_ENABLE(debug,
 266   AS_HELP_STRING([--disable-debug],
 267                  [compile without debug code]),
 268     enable_debug=$enableval, enable_debug=yes )
 269
 270 if test x$enable_debug = xyes; then
 271   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 272 fi
 273
 274 # -----------------------------------------------------------
 275 # Language Support
 276 # -----------------------------------------------------------
 277 IT_PROG_INTLTOOL([0.50.0])
 278
 279 GETTEXT_PACKAGE=empathy
 280 AC_SUBST(GETTEXT_PACKAGE)
 281 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 282
 283 # -----------------------------------------------------------
 284 # gudev
 285 # -----------------------------------------------------------
 286 AC_ARG_ENABLE(gudev,
 287               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 288                              [build with gudev support]), ,
 289                              enable_gudev=auto)
 290
 291 if test "x$enable_gudev" != "xno"; then
 292
 293    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 294         have_gudev="yes", have_gudev="no")
 295
 296    if test "x$have_gudev" = "xyes"; then
 297       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 298    fi
 299 else
 300    have_gudev=no
 301 fi
 302
 303 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 304    AC_MSG_ERROR([Could not find gudev dependencies:
 305
 306 $UDEV_PKG_ERRORS])
 307 fi
 308 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 309
 310 # -----------------------------------------------------------
 311 # spellchecking checks: enchant and iso-codes
 312 # -----------------------------------------------------------
 313 AC_ARG_ENABLE(spell,
 314               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 315                              [Enable spell checking]), ,
 316                              enable_spell=auto)
 317
 318 if test "x$enable_spell" != "xno"; then
 319    PKG_CHECK_MODULES(ENCHANT,
 320    [
 321       enchant >= $ENCHANT_REQUIRED,
 322       iso-codes >= $ISO_CODES_REQUIRED
 323    ], have_enchant="yes", have_enchant="no")
 324
 325    if test "x$have_enchant" = "xyes"; then
 326       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 327       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 328          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 329             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 330             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 331             result=yes
 332       else
 333             result=no
 334             have_enchant="no"
 335       fi
 336       AC_MSG_RESULT([$result])
 337    fi
 338 else
 339    have_enchant=no
 340 fi
 341
 342 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 343    AC_MSG_ERROR([Could not find spell-checking dependencies:
 344
 345 $ENCHANT_PKG_ERRORS])
 346 fi
 347
 348 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 349
 350 # -----------------------------------------------------------
 351 # Map view checks: libchamplain
 352 # -----------------------------------------------------------
 353 AC_ARG_ENABLE(map,
 354               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 355                              [Enable map view]), ,
 356                              enable_map=auto)
 357
 358 if test "x$enable_map" != "xno"; then
 359
 360    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 361     [
 362        clutter-gtk-1.0
 363        champlain-gtk-0.12
 364        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 365     ], have_libchamplain="yes", have_libchamplain="no")
 366
 367    if test "x$have_libchamplain" = "xyes"; then
 368       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 369    fi
 370 else
 371    have_libchamplain=no
 372 fi
 373
 374 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 375    AC_MSG_ERROR([Could not find map view dependencies:
 376
 377 $LIBCHAMPLAIN_PKG_ERRORS])
 378 fi
 379
 380 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 381
 382 # -----------------------------------------------------------
 383 # location checks: geoclue
 384 # -----------------------------------------------------------
 385 AC_ARG_ENABLE(location,
 386               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 387                              [Enable location awareness]), ,
 388                              enable_location=auto)
 389
 390 if test "x$enable_location" != "xno"; then
 391    PKG_CHECK_MODULES(GEOCLUE,
 392    [
 393       geoclue-2.0 >= $GEOCLUE_REQUIRED
 394    ], have_geoclue="yes", have_geoclue="no")
 395
 396    if test "x$have_geoclue" = "xyes"; then
 397       GEOCLUE_XML_FILE=`$PKG_CONFIG --variable=dbus_interface geoclue-2.0`
 398       if test "x$GEOCLUE_XML_FILE" = "x"; then
 399         echo "Can't find dbus_interface variable in geoclue-2.0.pc"
 400         have_geoclue="no"
 401       else
 402         AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue-2])
 403         AC_SUBST(GEOCLUE_XML_FILE)
 404       fi
 405    fi
 406 else
 407    have_geoclue="no"
 408 fi
 409
 410 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 411    AC_MSG_ERROR([Could not find location dependencies:
 412
 413 $GEOCLUE_PKG_ERRORS])
 414 fi
 415
 416 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 417 AC_SUBST(GEOCLUE_CFLAGS)
 418 AC_SUBST(GEOCLUE_LIBS)
 419
 420 # -----------------------------------------------------------
 421 # location checks: geocode-glib
 422 # -----------------------------------------------------------
 423 AC_ARG_ENABLE(geocode,
 424               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 425                              [Enable geocode support]), ,
 426                              enable_geocode=auto)
 427
 428 if test "x$enable_geocode" != "xno"; then
 429    PKG_CHECK_MODULES(GEOCODE,
 430    [
 431       geocode-glib-1.0 >= $GEOCODE_GLIB_REQUIRED
 432    ], have_geocode="yes", have_geocode="no")
 433
 434    if test "x$have_geocode" = "xyes"; then
 435       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 436    fi
 437 else
 438    have_geocode="no"
 439 fi
 440
 441 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 442    AC_MSG_ERROR([Could not find geocode dependencies:
 443
 444 $GEOCODE_PKG_ERRORS])
 445 fi
 446
 447 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 448 AC_SUBST(GEOCODE_CFLAGS)
 449 AC_SUBST(GEOCODE_LIBS)
 450
 451 # -----------------------------------------------------------
 452 # goa-mc-plugin
 453 # -----------------------------------------------------------
 454 AC_ARG_ENABLE(goa,
 455               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 456                              [build GOA MC plugin]), ,
 457                              enable_goa=auto)
 458
 459 if test "x$enable_goa" != "xno"; then
 460    PKG_CHECK_MODULES(GOA,
 461     [
 462        mission-control-plugins
 463        goa-1.0 >= $GOA_REQUIRED
 464     ], have_goa="yes", have_goa="no")
 465 else
 466    have_goa=no
 467 fi
 468
 469 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 470    AC_MSG_ERROR([Could not find GOA dependencies:
 471
 472 $GOA_PKG_ERRORS])
 473 fi
 474
 475 if test "x$have_goa" = "xyes"; then
 476    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 477 fi
 478
 479 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 480
 481 # Optional dependency for avatar selection
 482 AC_ARG_WITH([cheese],
 483             AS_HELP_STRING([--with-cheese],
 484                            [enable cheese webcam support]),,
 485             with_cheese=auto)
 486
 487 if test x"$with_cheese" != x"no" ; then
 488    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 489    if test x${have_cheese} = xyes; then
 490      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 491    fi
 492    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 493      AC_MSG_ERROR([Cheese configured but not found:
 494
 495 $CHEESE_PKG_ERRORS])
 496    fi
 497 else
 498    have_cheese=no
 499 fi
 500 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 501
 502 # -----------------------------------------------------------
 503 # ubuntu-online-accounts support
 504 # -----------------------------------------------------------
 505 AC_ARG_ENABLE(ubuntu-online-accounts,
 506               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 507                              [build Ubuntu Online Accounts plugins]), ,
 508                              enable_ubuntu_online_accounts=auto)
 509
 510 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 511    PKG_CHECK_MODULES(UOA,
 512     [
 513        account-plugin
 514        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 515        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 516        libsignon-glib >= $LIBSIGNON_REQUIRED
 517     ], have_uoa="yes", have_uoa="no")
 518
 519    # provider plugin dir
 520    AC_MSG_CHECKING([Accounts provider plugin dir])
 521    ACCOUNTS_PROVIDER_PLUGIN_DIR=`$PKG_CONFIG --variable=provider_plugindir account-plugin`
 522
 523    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 524    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 525
 526    # app plugin dir
 527    AC_MSG_CHECKING([Accounts provider app plugin dir])
 528    ACCOUNTS_APP_PLUGIN_DIR=`$PKG_CONFIG --variable=application_plugindir account-plugin`
 529
 530    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 531    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 532
 533    # provider files dir
 534    AC_MSG_CHECKING([Accounts provider files dir])
 535    ACCOUNTS_PROVIDER_FILES_DIR=`$PKG_CONFIG --variable=providerfilesdir libaccounts-glib`
 536
 537    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 538    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 539
 540    # service files dir
 541    AC_MSG_CHECKING([Accounts service files dir])
 542    ACCOUNTS_SERVICE_FILES_DIR=`$PKG_CONFIG --variable=servicefilesdir libaccounts-glib`
 543
 544    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 545    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 546
 547    # application files dir
 548    AC_MSG_CHECKING([Accounts applications files dir])
 549    ACCOUNTS_APPLICATION_FILES_DIR=`$PKG_CONFIG --variable=applicationfilesdir libaccounts-glib`
 550
 551    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 552    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 553
 554 else
 555    have_uoa=no
 556 fi
 557
 558 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 559    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 560
 561 $UOA_PKG_ERRORS])
 562 fi
 563
 564 if test "x$have_uoa" = "xyes"; then
 565    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 566 fi
 567
 568 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 569
 570 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 571    AC_MSG_CHECKING([Mission Control plugins dir])
 572    MISSION_CONTROL_PLUGINS_DIR=`$PKG_CONFIG --define-variable=libdir='${libdir}' --variable=plugindir mission-control-plugins`
 573
 574    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 575    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 576 fi
 577
 578
 579 # Help documentation
 580 YELP_HELP_INIT
 581
 582 # -----------------------------------------------------------
 583 # Coding style checks
 584 # -----------------------------------------------------------
 585 AC_ARG_ENABLE(coding-style-checks,
 586   AS_HELP_STRING([--disable-coding-style-checks],
 587                  [do not check coding style using grep]),
 588     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 589     [ENABLE_CODING_STYLE_CHECKS=yes])
 590
 591 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 592 # -----------------------------------------------------------
 593
 594 AC_CONFIG_FILES([
 595    Makefile
 596    data/Makefile
 597    data/empathy.desktop.in
 598    data/icons/Makefile
 599    data/themes/Makefile
 600    extensions/Makefile
 601    po/Makefile.in
 602    libempathy/Makefile
 603    libempathy-gtk/Makefile
 604    src/Makefile
 605    goa-mc-plugin/Makefile
 606    ubuntu-online-accounts/Makefile
 607    ubuntu-online-accounts/mc-plugin/Makefile
 608    ubuntu-online-accounts/cc-plugins/Makefile
 609    ubuntu-online-accounts/cc-plugins/account-plugins/Makefile
 610    ubuntu-online-accounts/cc-plugins/providers/Makefile
 611    ubuntu-online-accounts/cc-plugins/services/Makefile
 612    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 613    help/Makefile
 614    tests/Makefile
 615    tests/interactive/Makefile
 616    tests/xml/Makefile
 617    tests/certificates/Makefile
 618    tools/Makefile
 619 ])
 620 AC_OUTPUT
 621
 622 echo "
 623 Configure summary:
 624
 625         Compiler....................:  ${CC}
 626         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 627         Linker Flags................:  ${LDFLAGS}
 628         Prefix......................:  ${prefix}
 629         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 630
 631     Features:
 632         Spell checking (enchant)....:  ${have_enchant}
 633         Display maps (libchamplain).:  ${have_libchamplain}
 634         Location awareness (Geoclue):  ${have_geoclue}
 635         Geocode support (Geocode)...:  ${have_geocode}
 636         Cheese webcam support ......:  ${have_cheese}
 637         Camera monitoring...........:  ${have_gudev}
 638
 639     Extras:
 640         GOA MC plugin...............:  ${have_goa}
 641         Ubuntu Online plugins.......:  ${have_uoa}
 642 "