configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.91)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(ns-self-contained,
 180 [AS_HELP_STRING([--disable-ns-self-contained],
 181                 [disable self contained build under NeXTstep])],
 182    EN_NS_SELF_CONTAINED=$enableval,
 183    EN_NS_SELF_CONTAINED=yes)
 184
 185 AC_ARG_ENABLE(asserts,
 186 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 187       USE_XASSERTS=$enableval,
 188       USE_XASSERTS=no)
 189
 190 AC_ARG_ENABLE(maintainer-mode,
 191 [AS_HELP_STRING([--enable-maintainer-mode],
 192                 [enable make rules and dependencies not useful (and sometimes
 193                  confusing) to the casual installer])],
 194       USE_MAINTAINER_MODE=$enableval,
 195       USE_MAINTAINER_MODE=no)
 196 if test $USE_MAINTAINER_MODE = yes; then
 197   MAINT=
 198 else
 199   MAINT=#
 200 fi
 201 AC_SUBST(MAINT)
 202
 203 AC_ARG_ENABLE(locallisppath,
 204 [AS_HELP_STRING([--enable-locallisppath=PATH],
 205                 [directories Emacs should search for lisp files specific
 206                  to this site])],
 207 if test "${enableval}" = "no"; then
 208   locallisppath=
 209 elif test "${enableval}" != "yes"; then
 210   locallisppath=${enableval}
 211 fi)
 212
 213 #### Make srcdir absolute, if it isn't already.  It's important to
 214 #### avoid running the path through pwd unnecessarily, since pwd can
 215 #### give you automounter prefixes, which can go away.  We do all this
 216 #### so Emacs can find its files when run uninstalled.
 217 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 218 unset CDPATH
 219 case "${srcdir}" in
 220   /* ) ;;
 221   . )
 222     ## We may be able to use the $PWD environment variable to make this
 223     ## absolute.  But sometimes PWD is inaccurate.
 224     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 225     ## but that tested only for a well-formed and valid PWD,
 226     ## it did not object when PWD was well-formed and valid but just wrong.
 227     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 228     then
 229       srcdir="$PWD"
 230     else
 231       srcdir="`(cd ${srcdir}; pwd)`"
 232     fi
 233   ;;
 234   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 235 esac
 236
 237 #### Check if the source directory already has a configured system in it.
 238 if test `pwd` != `(cd ${srcdir} && pwd)` \
 239    && test -f "${srcdir}/src/config.h" ; then
 240   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 241    as a build directory right now; it has been configured in its own
 242    right.  To configure in another directory as well, you MUST
 243    use GNU make.  If you do not have GNU make, then you must
 244    now do `make distclean' in ${srcdir},
 245    and then run $0 again.]])
 246 fi
 247
 248 #### Given the configuration name, set machfile and opsysfile to the
 249 #### names of the m/*.h and s/*.h files we should use.
 250
 251 ### Canonicalize the configuration name.
 252
 253 AC_CANONICAL_HOST
 254 canonical=$host
 255 configuration=${host_alias-${build_alias-$host}}
 256
 257 dnl This used to use changequote, but, apart from `changequote is evil'
 258 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 259 dnl the great gob of text.  Thus it's not processed for possible expansion.
 260 dnl Just make sure the brackets remain balanced.
 261 dnl
 262 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 263 dnl indicated by comments.
 264 dnl quotation begins
 265 [
 266
 267 ### If you add support for a new configuration, add code to this
 268 ### switch statement to recognize your configuration name and select
 269 ### the appropriate operating system and machine description files.
 270
 271 ### You would hope that you could choose an m/*.h file pretty much
 272 ### based on the machine portion of the configuration name, and an s-
 273 ### file based on the operating system portion.  However, it turns out
 274 ### that each m/*.h file is pretty manufacturer-specific - for
 275 ### example mips.h is MIPS
 276 ### So we basically have to have a special case for each
 277 ### configuration name.
 278 ###
 279 ### As far as handling version numbers on operating systems is
 280 ### concerned, make sure things will fail in a fixable way.  If
 281 ### /etc/MACHINES doesn't say anything about version numbers, be
 282 ### prepared to handle anything reasonably.  If version numbers
 283 ### matter, be sure /etc/MACHINES says something about it.
 284 ###
 285 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 286 ### "System V Release 4"; he writes, "The old convention encouraged
 287 ### confusion between `system' and `release' levels'."
 288
 289 machine='' opsys='' unported=no
 290 case "${canonical}" in
 291
 292   ## FreeBSD ports
 293   *-*-freebsd* )
 294     opsys=freebsd
 295     case "${canonical}" in
 296       alpha*-*-freebsd*)        machine=alpha ;;
 297       arm*-*-freebsd*)          machine=arm ;;
 298       ia64-*-freebsd*)          machine=ia64 ;;
 299       sparc-*-freebsd*)         machine=sparc ;;
 300       sparc64-*-freebsd*)       machine=sparc ;;
 301       powerpc-*-freebsd*)       machine=macppc ;;
 302       i[3456]86-*-freebsd*)     machine=intel386 ;;
 303       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 304     esac
 305   ;;
 306
 307   ## FreeBSD kernel + glibc based userland
 308   *-*-kfreebsd*gnu* )
 309     opsys=gnu-kfreebsd
 310     case "${canonical}" in
 311       alpha*-*-kfreebsd*)       machine=alpha ;;
 312       ia64-*-kfreebsd*)         machine=ia64 ;;
 313       sparc-*-kfreebsd*)        machine=sparc ;;
 314       sparc64-*-kfreebsd*)      machine=sparc ;;
 315       powerpc-*-kfreebsd*)      machine=macppc ;;
 316       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 317       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 318     esac
 319   ;;
 320
 321   ## NetBSD ports
 322   *-*-netbsd* )
 323     opsys=netbsd
 324     if test -f /usr/lib/crti.o; then]
 325 dnl The close and open brackets here are because this section is quoted --
 326 dnl see the `changequote' comment above.
 327       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 328 [   fi
 329
 330     case "${canonical}" in
 331       alpha*-*-netbsd*) machine=alpha ;;
 332       i[3456]86-*-netbsd*) machine=intel386 ;;
 333       powerpc-*-netbsd*) machine=macppc ;;
 334       sparc*-*-netbsd*) machine=sparc ;;
 335       vax-*-netbsd*)    machine=vax ;;
 336       arm-*-netbsd*)    machine=arm ;;
 337       x86_64-*-netbsd*) machine=amdx86-64 ;;
 338       hppa-*-netbsd*)   machine=hp800 ;;
 339       m68k-*-netbsd*)   machine=m68k ;;
 340     esac
 341   ;;
 342
 343   ## OpenBSD ports
 344   *-*-openbsd* )
 345     opsys=openbsd
 346     case "${canonical}" in
 347       alpha*-*-openbsd*)        machine=alpha ;;
 348       arm-*-openbsd*)          machine=arm ;;
 349       i386-*-openbsd*)         machine=intel386 ;;
 350       powerpc-*-openbsd*)      machine=macppc ;;
 351       sparc*-*-openbsd*)       machine=sparc ;;
 352       vax-*-openbsd*)          machine=vax ;;
 353       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 354       hppa-*-openbsd*)         machine=hp800 ;;
 355     esac
 356   ;;
 357
 358   ## LynxOS ports
 359   *-*-lynxos* )
 360     opsys=lynxos
 361     case "${canonical}" in
 362       i[3456]86-*-lynxos*) machine=intel386 ;;
 363       powerpc-*-lynxos*) machine=powerpc ;;
 364     esac
 365   ;;
 366
 367   alpha*-*-linux-gnu* )
 368     machine=alpha opsys=gnu-linux
 369   ;;
 370
 371   arm*-*-linux-gnu* )
 372     machine=arm opsys=gnu-linux
 373   ;;
 374
 375   ## Apple Darwin / Mac OS X
 376   *-apple-darwin* )
 377     case "${canonical}" in
 378       i[3456]86-* )  machine=intel386 ;;
 379       powerpc-* )    machine=macppc ;;
 380       * )            unported=yes ;;
 381     esac
 382     opsys=darwin
 383     # Define CPP as follows to make autoconf work correctly.
 384     CPP="${CC-cc} -E -no-cpp-precomp"
 385     # Use fink packages if available.
 386     if test -d /sw/include && test -d /sw/lib; then
 387       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 388       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 389       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 390     fi
 391   ;;
 392
 393   ## HP 9000 series 700 and 800, running HP/UX
 394   hppa*-hp-hpux10.2* )
 395     machine=hp800 opsys=hpux10-20
 396   ;;
 397   hppa*-hp-hpux1[1-9]* )
 398     machine=hp800 opsys=hpux11
 399     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 400   ;;
 401
 402   hppa*-*-linux-gnu* )
 403     machine=hp800 opsys=gnu-linux
 404   ;;
 405
 406   ## IBM machines
 407   s390-*-linux-gnu* )
 408     machine=ibms390 opsys=gnu-linux
 409   ;;
 410   s390x-*-linux-gnu* )
 411     machine=ibms390x opsys=gnu-linux
 412   ;;
 413   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 414     machine=ibmrs6000 opsys=aix4-2
 415   ;;
 416   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 417     machine=ibmrs6000 opsys=aix4-2
 418   ;;
 419   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 420     machine=ibmrs6000 opsys=aix4-2
 421   ;;
 422   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 423     machine=ibmrs6000 opsys=aix4-2
 424   ;;
 425
 426   ## Macintosh PowerPC
 427   powerpc*-*-linux-gnu* )
 428     machine=macppc opsys=gnu-linux
 429   ;;
 430
 431   ## Silicon Graphics machines
 432   ## Iris 4D
 433   mips-sgi-irix6.5 )
 434     machine=iris4d opsys=irix6-5
 435     # Without defining _LANGUAGE_C, things get masked out in the headers
 436     # so that, for instance, grepping for `free' in stdlib.h fails and
 437     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 438     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 439     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 440   ;;
 441
 442   ## Suns
 443   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 444     machine=sparc opsys=gnu-linux
 445   ;;
 446
 447   *-sun-solaris* \
 448     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 449     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 450     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 451     case "${canonical}" in
 452       i[3456]86-*-* )     machine=intel386 ;;
 453       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 454       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 455       sparc* )          machine=sparc ;;
 456       * )               unported=yes ;;
 457     esac
 458     case "${canonical}" in
 459       *-sunos5.3* | *-solaris2.3* )
 460                 opsys=sol2-3
 461                 NON_GNU_CPP=/usr/ccs/lib/cpp
 462                 ;;
 463       *-sunos5.4* | *-solaris2.4* )
 464                 opsys=sol2-4
 465                 NON_GNU_CPP=/usr/ccs/lib/cpp
 466                 RANLIB="ar -ts"
 467                 ;;
 468       *-sunos5.5* | *-solaris2.5* )
 469                 opsys=sol2-5
 470                 NON_GNU_CPP=/usr/ccs/lib/cpp
 471                 RANLIB="ar -ts"
 472                 ;;
 473       *-sunos5.6* | *-solaris2.6* )
 474                 opsys=sol2-6
 475                 NON_GNU_CPP=/usr/ccs/lib/cpp
 476                 RANLIB="ar -ts"
 477                 ;;
 478       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 479                 opsys=sol2-6
 480                 emacs_check_sunpro_c=yes
 481                 NON_GNU_CPP=/usr/ccs/lib/cpp
 482                 ;;
 483       *-sunos5* | *-solaris* )
 484                 opsys=sol2-10
 485                 emacs_check_sunpro_c=yes
 486                 NON_GNU_CPP=/usr/ccs/lib/cpp
 487                 ;;
 488     esac
 489     ## Watch out for a compiler that we know will not work.
 490     case "${canonical}" in
 491      *-solaris* | *-sunos5* )
 492                 if [ "x$CC" = x/usr/ucb/cc ]; then
 493                   ## /usr/ucb/cc doesn't work;
 494                   ## we should find some other compiler that does work.
 495                   unset CC
 496                 fi
 497                 ;;
 498       *) ;;
 499     esac
 500   ;;
 501
 502   ## Vaxen.
 503   vax-dec-* )
 504     machine=vax
 505     case "${canonical}" in
 506       *-vms* )                                          opsys=vms ;;
 507       * )                                               unported=yes
 508     esac
 509   ;;
 510
 511   ## IA-64
 512   ia64*-*-linux* )
 513     machine=ia64 opsys=gnu-linux
 514   ;;
 515
 516   ## Intel 386 machines where we don't care about the manufacturer
 517   i[3456]86-*-* )
 518     machine=intel386
 519     case "${canonical}" in
 520       *-cygwin )                opsys=cygwin ;;
 521       *-darwin* )               opsys=darwin
 522                                 CPP="${CC-cc} -E -no-cpp-precomp"
 523                                 ;;
 524       *-linux-gnu* )            opsys=gnu-linux ;;
 525       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 526       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 527       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 528       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 529     esac
 530   ;;
 531
 532   ## m68k Linux-based GNU system
 533   m68k-*-linux-gnu* )
 534     machine=m68k opsys=gnu-linux
 535   ;;
 536
 537   ## Mips Linux-based GNU system
 538   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 539     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 540     machine=mips opsys=gnu-linux
 541   ;;
 542
 543   ## AMD x86-64 Linux-based GNU system
 544   x86_64-*-linux-gnu* )
 545     machine=amdx86-64 opsys=gnu-linux
 546   ;;
 547
 548   ## Tensilica Xtensa Linux-based GNU system
 549   xtensa*-*-linux-gnu* )
 550     machine=xtensa opsys=gnu-linux
 551     ;;
 552
 553   ## SuperH Linux-based GNU system
 554   sh[34]*-*-linux-gnu* )
 555     machine=sh3 opsys=gnu-linux
 556   ;;
 557
 558   * )
 559     unported=yes
 560   ;;
 561 esac
 562
 563 ### If the code above didn't choose an operating system, just choose
 564 ### an operating system based on the configuration name.  You really
 565 ### only want to use this when you have no idea what the right
 566 ### operating system is; if you know what operating systems a machine
 567 ### runs, it's cleaner to make it explicit in the case statement
 568 ### above.
 569 if test x"${opsys}" = x; then
 570   case "${canonical}" in
 571     *-gnu* )                            opsys=gnu ;;
 572     *-sysv4.2uw* )                      opsys=unixware ;;
 573     *-sysv5uw* )                        opsys=unixware ;;
 574     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 575     *-sysv4.1* | *-sysvr4.1* )
 576         NON_GNU_CPP=/usr/lib/cpp
 577         opsys=usg5-4 ;;
 578     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 579         if [ x$NON_GNU_CPP = x ]; then
 580           if [ -f /usr/ccs/lib/cpp ]; then
 581             NON_GNU_CPP=/usr/ccs/lib/cpp
 582           else
 583             NON_GNU_CPP=/lib/cpp
 584           fi
 585         fi
 586         opsys=usg5-4-2 ;;
 587     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 588     * )
 589       unported=yes
 590     ;;
 591   esac
 592 fi
 593
 594 ]
 595 dnl quotation ends
 596
 597 if test $unported = yes; then
 598   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 599 Check `etc/MACHINES' for recognized configuration names.])
 600 fi
 601
 602 machfile="m/${machine}.h"
 603 opsysfile="s/${opsys}.h"
 604
 605
 606 #### Choose a compiler.
 607 test -n "$CC" && cc_specified=yes
 608
 609 # Save the value of CFLAGS that the user specified.
 610 SPECIFIED_CFLAGS="$CFLAGS"
 611
 612 dnl Sets GCC=yes if using gcc.
 613 AC_PROG_CC
 614
 615 # On Suns, sometimes $CPP names a directory.
 616 if test -n "$CPP" && test -d "$CPP"; then
 617   CPP=
 618 fi
 619
 620 ## If not using gcc, and on Solaris, and no CPP specified, see if
 621 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 622 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 623  test x"$CPP" = x; then
 624   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 625   AC_CACHE_VAL(emacs_cv_sunpro_c,
 626   [AC_TRY_LINK([],
 627 [#ifndef __SUNPRO_C
 628 fail;
 629 #endif
 630 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 631   AC_MSG_RESULT($emacs_cv_sunpro_c)
 632
 633   if test x"$emacs_cv_sunpro_c" = xyes; then
 634     NON_GNU_CPP="$CC -E -Xs"
 635   fi
 636 fi
 637
 638 #### Some systems specify a CPP to use unless we are using GCC.
 639 #### Now that we know whether we are using GCC, we can decide whether
 640 #### to use that one.
 641 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 642 then
 643   CPP="$NON_GNU_CPP"
 644 fi
 645
 646 #### Some systems specify a CC to use unless we are using GCC.
 647 #### Now that we know whether we are using GCC, we can decide whether
 648 #### to use that one.
 649 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 650   test x$cc_specified != xyes
 651 then
 652   CC="$NON_GNU_CC"
 653 fi
 654
 655 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 656 then
 657   CC="$CC $GCC_TEST_OPTIONS"
 658 fi
 659
 660 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 661 then
 662   CC="$CC $NON_GCC_TEST_OPTIONS"
 663 fi
 664
 665 dnl checks for Unix variants
 666 AC_USE_SYSTEM_EXTENSIONS
 667
 668 ### Use -Wno-pointer-sign if the compiler supports it
 669 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 670 SAVE_CFLAGS="$CFLAGS"
 671 CFLAGS="$CFLAGS -Wno-pointer-sign"
 672 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 673 if test $has_option = yes; then
 674    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 675 fi
 676 AC_MSG_RESULT($has_option)
 677 CFLAGS="$SAVE_CFLAGS"
 678 unset has_option
 679 unset SAVE_CFLAGS
 680
 681 #### Some other nice autoconf tests.
 682
 683 dnl checks for programs
 684 AC_PROG_LN_S
 685 AC_PROG_CPP
 686 AC_PROG_INSTALL
 687 if test "x$RANLIB" = x; then
 688   AC_PROG_RANLIB
 689 fi
 690 AC_PATH_PROG(INSTALL_INFO, install-info)
 691 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 692 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 693 dnl Don't use GZIP, which is used by gzip for additional parameters.
 694 AC_PATH_PROG(GZIP_PROG, gzip)
 695
 696
 697 ## Need makeinfo >= 4.6 (?) to build the manuals.
 698 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 699 dnl By this stage, configure has already checked for egrep and set EGREP,
 700 dnl or exited with an error if no egrep was found.
 701 if test "$MAKEINFO" != "no" && \
 702   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 703    MAKEINFO=no
 704 fi
 705
 706 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 707 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 708 ## therefore in the category of "special tools" not normally required, which
 709 ## configure does not have to check for (eg autoconf itself).
 710 ## In a CVS checkout on the other hand, the manuals are not included.
 711 ## So makeinfo is a requirement to build from CVS, and configure
 712 ## should test for it as it does for any other build requirement.
 713 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 714 ## with pre-built manuals, from a CVS checkout.
 715 if test "$MAKEINFO" = "no"; then
 716   if test "x${with_makeinfo}" = "xno"; then
 717     MAKEINFO=off
 718   elif ! test -e $srcdir/info/emacs; then
 719     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 720 source tree does not seem to have pre-built manuals in the `info' directory.
 721 Either install a suitable version of makeinfo, or re-run configure
 722 with the `--without-makeinfo' option to build without the manuals.] )
 723   fi
 724 fi
 725
 726 dnl Add our options to ac_link now, after it is set up.
 727
 728 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 729 then
 730   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 731 fi
 732
 733 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 734 then
 735   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 736 fi
 737
 738 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 739 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 740 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 741 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 742 dnl if not built to support GNU ld.
 743
 744 late_LDFLAGS=$LDFLAGS
 745 if test "$GCC" = yes; then
 746   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 747 else
 748   LDFLAGS="$LDFLAGS -znocombreloc"
 749 fi
 750
 751 AC_MSG_CHECKING([for -znocombreloc])
 752 AC_LINK_IFELSE([main(){return 0;}],
 753   [AC_MSG_RESULT(yes)],
 754   LDFLAGS=$late_LDFLAGS
 755   [AC_MSG_RESULT(no)])
 756
 757 #### Extract some information from the operating system and machine files.
 758
 759 AC_CHECKING([the machine- and system-dependent files to find out
 760  - which libraries the lib-src programs will want, and
 761  - whether the GNU malloc routines are usable])
 762
 763 ### First figure out CFLAGS (which we use for running the compiler here)
 764 ### and REAL_CFLAGS (which we use for real compilation).
 765 ### The two are the same except on a few systems, where they are made
 766 ### different to work around various lossages.  For example,
 767 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 768 ### as implying static linking.
 769
 770 ### If the CFLAGS env var is specified, we use that value
 771 ### instead of the default.
 772
 773 ### It's not important that this name contain the PID; you can't run
 774 ### two configures in the same directory and have anything work
 775 ### anyway.
 776 tempcname="conftest.c"
 777
 778 echo '
 779 #include "'${srcdir}'/src/'${opsysfile}'"
 780 #include "'${srcdir}'/src/'${machfile}'"
 781 #ifndef LIBS_MACHINE
 782 #define LIBS_MACHINE
 783 #endif
 784 #ifndef LIBS_SYSTEM
 785 #define LIBS_SYSTEM
 786 #endif
 787 #ifndef C_SWITCH_SYSTEM
 788 #define C_SWITCH_SYSTEM
 789 #endif
 790 #ifndef C_SWITCH_MACHINE
 791 #define C_SWITCH_MACHINE
 792 #endif
 793 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 794 configure___ c_switch_system=C_SWITCH_SYSTEM
 795 configure___ c_switch_machine=C_SWITCH_MACHINE
 796
 797 #ifndef LIB_X11_LIB
 798 #define LIB_X11_LIB -lX11
 799 #endif
 800
 801 #ifndef LIBX11_SYSTEM
 802 #define LIBX11_SYSTEM
 803 #endif
 804 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 805
 806 #ifdef UNEXEC
 807 configure___ unexec=UNEXEC
 808 #else
 809 configure___ unexec=unexec.o
 810 #endif
 811
 812 #ifdef SYSTEM_MALLOC
 813 configure___ system_malloc=yes
 814 #else
 815 configure___ system_malloc=no
 816 #endif
 817
 818 #ifdef USE_MMAP_FOR_BUFFERS
 819 configure___ use_mmap_for_buffers=yes
 820 #else
 821 configure___ use_mmap_for_buffers=no
 822 #endif
 823
 824 #ifndef C_DEBUG_SWITCH
 825 #define C_DEBUG_SWITCH -g
 826 #endif
 827
 828 #ifndef C_OPTIMIZE_SWITCH
 829 #ifdef __GNUC__
 830 #define C_OPTIMIZE_SWITCH -O2
 831 #else
 832 #define C_OPTIMIZE_SWITCH -O
 833 #endif
 834 #endif
 835
 836 #ifndef C_WARNINGS_SWITCH
 837 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 838 #endif
 839
 840 #ifndef LD_SWITCH_MACHINE
 841 #define LD_SWITCH_MACHINE
 842 #endif
 843
 844 #ifndef LD_SWITCH_SYSTEM
 845 #define LD_SWITCH_SYSTEM
 846 #endif
 847
 848 #ifndef LD_SWITCH_X_SITE_AUX
 849 #define LD_SWITCH_X_SITE_AUX
 850 #endif
 851
 852 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 853 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 854
 855 #ifdef THIS_IS_CONFIGURE
 856
 857 /* Get the CFLAGS for tests in configure.  */
 858 #ifdef __GNUC__
 859 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 860 #else
 861 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 862 #endif
 863
 864 #else /* not THIS_IS_CONFIGURE */
 865
 866 /* Get the CFLAGS for real compilation.  */
 867 #ifdef __GNUC__
 868 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 869 #else
 870 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 871 #endif
 872
 873 #endif /* not THIS_IS_CONFIGURE */
 874 ' > ${tempcname}
 875
 876 # The value of CPP is a quoted variable reference, so we need to do this
 877 # to get its actual value...
 878 CPP=`eval "echo $CPP"`
 879 [eval `${CPP} -Isrc ${tempcname} \
 880        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 881 if test "x$SPECIFIED_CFLAGS" = x; then
 882   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 883          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 884 else
 885   REAL_CFLAGS="$CFLAGS"
 886 fi]
 887 rm ${tempcname}
 888
 889 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 890
 891 ### Make sure subsequent tests use flags consistent with the build flags.
 892
 893 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 894   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 895 else
 896   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 897 fi
 898
 899 dnl For AC_FUNC_GETLOADAVG, at least:
 900 AC_CONFIG_LIBOBJ_DIR(src)
 901
 902 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 903 AC_SYS_LARGEFILE
 904
 905
 906 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 907 ### be located in either /usr/lib64 or /usr/lib.
 908 ### In some rare cases, /usr/lib64 exists but does not contain the
 909 ### relevant files (bug#1287).  Hence test for crtn.o.
 910 case "${canonical}" in
 911   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 912     if test -e /usr/lib64/crtn.o; then
 913       AC_DEFINE(HAVE_LIB64_DIR, 1,
 914         [Define to 1 if the directory /usr/lib64 exists.])
 915 fi
 916 esac
 917
 918 dnl This function defintion taken from Gnome 2.0
 919 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 920 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 921 dnl also defines GSTUFF_PKG_ERRORS on error
 922 AC_DEFUN([PKG_CHECK_MODULES], [
 923   succeeded=no
 924
 925   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 926
 927   if test "$PKG_CONFIG" = "no" ; then
 928      ifelse([$4], , [AC_MSG_ERROR([
 929       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 930   else
 931      PKG_CONFIG_MIN_VERSION=0.9.0
 932      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 933         AC_MSG_CHECKING(for $2)
 934
 935         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 936             AC_MSG_RESULT(yes)
 937             succeeded=yes
 938
 939             AC_MSG_CHECKING($1_CFLAGS)
 940             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 941             AC_MSG_RESULT($$1_CFLAGS)
 942
 943             AC_MSG_CHECKING($1_LIBS)
 944             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 945             AC_MSG_RESULT($$1_LIBS)
 946         else
 947             AC_MSG_RESULT(no)
 948             $1_CFLAGS=""
 949             $1_LIBS=""
 950             ## If we have a custom action on failure, don't print errors, but
 951             ## do set a variable so people can do so.
 952             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 953             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 954         fi
 955
 956         AC_SUBST($1_CFLAGS)
 957         AC_SUBST($1_LIBS)
 958      else
 959         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 960         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 961      fi
 962   fi
 963
 964   if test $succeeded = yes; then
 965      ifelse([$3], , :, [$3])
 966   else
 967      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 968   fi
 969 ])
 970
 971
 972 if test "${with_sound}" != "no"; then
 973   # Sound support for GNU/Linux and the free BSDs.
 974   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 975   # Emulation library used on NetBSD.
 976   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 977   AC_SUBST(LIBSOUND)
 978
 979   ALSA_REQUIRED=1.0.0
 980   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 981   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 982   if test $HAVE_ALSA = yes; then
 983     SAVE_CFLAGS="$CFLAGS"
 984     SAVE_LDFLAGS="$LDFLAGS"
 985     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 986     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 987     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 988                     emacs_alsa_normal=yes,
 989                     emacs_alsa_normal=no)
 990     if test "$emacs_alsa_normal" != yes; then
 991       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 992                      [snd_lib_error_set_handler (0);],
 993                      emacs_alsa_subdir=yes,
 994                      emacs_alsa_subdir=no)
 995       if test "$emacs_alsa_subdir" != yes; then
 996         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 997       fi
 998       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
 999     fi
1000
1001     CFLAGS="$SAVE_CFLAGS"
1002     LDFLAGS="$SAVE_LDFLAGS"
1003     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1004     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1005     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1006   fi
1007   AC_SUBST(CFLAGS_SOUND)
1008 fi
1009
1010 dnl checks for header files
1011 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1012   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1013   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1014   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1015   sys/utsname.h pwd.h)
1016
1017 AC_MSG_CHECKING(if personality LINUX32 can be set)
1018 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1019                emacs_cv_personality_linux32=yes,
1020                emacs_cv_personality_linux32=no)
1021 AC_MSG_RESULT($emacs_cv_personality_linux32)
1022
1023 if test $emacs_cv_personality_linux32 = yes; then
1024   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1025             [Define to 1 if personality LINUX32 can be set.])
1026 fi
1027
1028 dnl On Solaris 8 there's a compilation warning for term.h because
1029 dnl it doesn't define `bool'.
1030 AC_CHECK_HEADERS(term.h, , , -)
1031 AC_HEADER_STDC
1032 AC_HEADER_TIME
1033 AC_CHECK_DECLS([sys_siglist])
1034 if test $ac_cv_have_decl_sys_siglist != yes; then
1035   # For Tru64, at least:
1036   AC_CHECK_DECLS([__sys_siglist])
1037   if test $ac_cv_have_decl___sys_siglist = yes; then
1038     AC_DEFINE(sys_siglist, __sys_siglist,
1039               [Define to any substitute for sys_siglist.])
1040   fi
1041 fi
1042 AC_HEADER_SYS_WAIT
1043
1044 dnl Some systems have utime.h but don't declare the struct anyplace.
1045 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1046 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1047 #include <sys/time.h>
1048 #include <time.h>
1049 #else
1050 #ifdef HAVE_SYS_TIME_H
1051 #include <sys/time.h>
1052 #else
1053 #include <time.h>
1054 #endif
1055 #endif
1056 #ifdef HAVE_UTIME_H
1057 #include <utime.h>
1058 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1059   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1060 if test $emacs_cv_struct_utimbuf = yes; then
1061   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1062 fi
1063
1064 dnl checks for typedefs
1065 AC_TYPE_SIGNAL
1066
1067 dnl Check for speed_t typedef.
1068 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1069   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1070     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1071 if test $emacs_cv_speed_t = yes; then
1072   AC_DEFINE(HAVE_SPEED_T, 1,
1073            [Define to 1 if `speed_t' is declared by <termios.h>.])
1074 fi
1075
1076 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1077 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1078 #include <sys/time.h>
1079 #include <time.h>
1080 #else
1081 #ifdef HAVE_SYS_TIME_H
1082 #include <sys/time.h>
1083 #else
1084 #include <time.h>
1085 #endif
1086 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1087   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1088 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1089 if test $emacs_cv_struct_timeval = yes; then
1090   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1091 fi
1092
1093 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1094 AC_TRY_COMPILE([#include <math.h>],
1095 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1096   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1097 HAVE_EXCEPTION=$emacs_cv_struct_exception
1098 if test $emacs_cv_struct_exception != yes; then
1099   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1100 fi
1101
1102 AC_CHECK_HEADERS(sys/socket.h)
1103 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1104 #if HAVE_SYS_SOCKET_H
1105 #include <sys/socket.h>
1106 #endif])
1107
1108 dnl checks for structure members
1109 AC_STRUCT_TM
1110 AC_STRUCT_TIMEZONE
1111 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1112                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1113                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1114                 [#include <time.h>])
1115 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1116                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1117                   struct ifreq.ifr_addr], , ,
1118                  [AC_INCLUDES_DEFAULT
1119 #if HAVE_SYS_SOCKET_H
1120 #include <sys/socket.h>
1121 #endif
1122 #if HAVE_NET_IF_H
1123 #include <net/if.h>
1124 #endif])
1125
1126 dnl checks for compiler characteristics
1127
1128 dnl Testing __STDC__ to determine prototype support isn't good enough.
1129 dnl DEC C, for instance, doesn't define it with default options, and
1130 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1131 dnl and void *.
1132 AC_C_PROTOTYPES
1133 AC_C_VOLATILE
1134 AC_C_CONST
1135 dnl This isn't useful because we can't turn on use of `inline' unless
1136 dnl the compiler groks `extern inline'.
1137 dnl AC_C_INLINE
1138 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1139   [AC_TRY_COMPILE(, [void * foo;],
1140                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1141 if test $emacs_cv_void_star = yes; then
1142   AC_DEFINE(POINTER_TYPE, void)
1143 else
1144   AC_DEFINE(POINTER_TYPE, char)
1145 fi
1146 AH_TEMPLATE(POINTER_TYPE,
1147             [Define as `void' if your compiler accepts `void *'; otherwise
1148              define as `char'.])dnl
1149
1150
1151
1152 dnl This could be used for targets which can have both byte sexes.
1153 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1154 dnl AC_C_BIGENDIAN
1155
1156 dnl check for Make feature
1157 AC_PROG_MAKE_SET
1158
1159 dnl checks for operating system services
1160 AC_SYS_LONG_FILE_NAMES
1161
1162 #### Choose a window system.
1163
1164 AC_PATH_X
1165 if test "$no_x" = yes; then
1166   window_system=none
1167 else
1168   window_system=x11
1169 fi
1170
1171 ## Workaround for bug in autoconf <= 2.62.
1172 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1173 ## No need to do anything special for these standard directories.
1174 ## This is an experiment, take it out if it causes problems.
1175 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1176
1177    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1178
1179 fi
1180
1181 if test "${x_libraries}" != NONE; then
1182   if test -n "${x_libraries}"; then
1183     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1184     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1185   fi
1186   x_default_search_path=""
1187   x_search_path=${x_libraries}
1188   if test -z "${x_search_path}"; then
1189     x_search_path=/usr/lib
1190   fi
1191   for x_library in `echo ${x_search_path}: | \
1192                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1193     x_search_path="\
1194 ${x_library}/X11/%L/%T/%N%C%S:\
1195 ${x_library}/X11/%l/%T/%N%C%S:\
1196 ${x_library}/X11/%T/%N%C%S:\
1197 ${x_library}/X11/%L/%T/%N%S:\
1198 ${x_library}/X11/%l/%T/%N%S:\
1199 ${x_library}/X11/%T/%N%S"
1200     if test x"${x_default_search_path}" = x; then
1201       x_default_search_path=${x_search_path}
1202     else
1203       x_default_search_path="${x_search_path}:${x_default_search_path}"
1204     fi
1205   done
1206 fi
1207 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1208   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1209 fi
1210
1211 if test x"${x_includes}" = x; then
1212   bitmapdir=/usr/include/X11/bitmaps
1213 else
1214   # accumulate include directories that have X11 bitmap subdirectories
1215   bmd_acc="dummyval"
1216   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1217     if test -d "${bmd}/X11/bitmaps"; then
1218       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1219     fi
1220     if test -d "${bmd}/bitmaps"; then
1221       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1222     fi
1223   done
1224   if test ${bmd_acc} != "dummyval"; then
1225     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1226   fi
1227 fi
1228
1229 HAVE_NS=no
1230 NS_IMPL_COCOA=no
1231 NS_IMPL_GNUSTEP=no
1232 tmp_CPPFLAGS="$CPPFLAGS"
1233 tmp_CFLAGS="$CFLAGS"
1234 CPPFLAGS="$CPPFLAGS -x objective-c"
1235 CFLAGS="$CFLAGS -x objective-c"
1236 if test "${with_ns}" != no; then
1237   if test "${opsys}" = darwin; then
1238      NS_IMPL_COCOA=yes
1239      ns_appdir=`pwd`/nextstep/Emacs.app
1240      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1241      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1242      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1243   elif test -f $GNUSTEP_CONFIG_FILE; then
1244      NS_IMPL_GNUSTEP=yes
1245      ns_appdir=`pwd`/nextstep/Emacs.app
1246      ns_appbindir=`pwd`/nextstep/Emacs.app
1247      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1248      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1249      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1250      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1251      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1252      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1253      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1254      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1255      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1256      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1257   fi
1258   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1259                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1260   files are missing or cannot be compiled.])])
1261   NS_HAVE_NSINTEGER=yes
1262   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1263                                      [NSInteger i;])],
1264                     ns_have_nsinteger=yes,
1265                     ns_have_nsinteger=no)
1266   if test $ns_have_nsinteger = no; then
1267     NS_HAVE_NSINTEGER=no
1268   fi
1269 fi
1270 if test "${HAVE_NS}" = yes; then
1271   window_system=nextstep
1272   with_xft=no
1273   with_freetype=no
1274   # set up packaging dirs
1275   exec_prefix=${ns_appbindir}
1276   libexecdir=${ns_appbindir}/libexec
1277   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1278      prefix=${ns_appresdir}
1279   fi
1280 fi
1281 CFLAGS="$tmp_CFLAGS"
1282 CPPFLAGS="$tmp_CPPFLAGS"
1283
1284 case "${window_system}" in
1285   x11 )
1286     HAVE_X_WINDOWS=yes
1287     HAVE_X11=yes
1288     case "${with_x_toolkit}" in
1289       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1290       motif ) USE_X_TOOLKIT=MOTIF ;;
1291       gtk ) with_gtk=yes
1292 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1293 dnl USE_X_TOOLKIT is set.
1294             USE_X_TOOLKIT=none ;;
1295       no ) USE_X_TOOLKIT=none ;;
1296 dnl If user did not say whether to use a toolkit, make this decision later:
1297 dnl use the toolkit if we have gtk, or X11R5 or newer.
1298       * ) USE_X_TOOLKIT=maybe ;;
1299     esac
1300   ;;
1301   nextstep | none )
1302     HAVE_X_WINDOWS=no
1303     HAVE_X11=no
1304     USE_X_TOOLKIT=none
1305   ;;
1306 esac
1307
1308 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1309    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1310    if test "$HAVE_XSERVER" = true ||
1311       test -n "$DISPLAY" ||
1312       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1313         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1314 were found.  You should install the relevant development files for X
1315 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1316 sure you have development files for image handling, i.e.
1317 tiff, gif, jpeg, png and xpm.
1318 If you are sure you want Emacs compiled without X window support, pass
1319   --without-x
1320 to configure.])
1321    fi
1322 fi
1323
1324 ### If we're using X11, we should use the X menu package.
1325 HAVE_MENUS=no
1326 case ${HAVE_X11} in
1327   yes ) HAVE_MENUS=yes ;;
1328 esac
1329
1330 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1331 # Assume not, until told otherwise.
1332 GNU_MALLOC=yes
1333 doug_lea_malloc=yes
1334 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1335 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1336 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1337                emacs_cv_var___after_morecore_hook,
1338 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1339   emacs_cv_var___after_morecore_hook=yes,
1340   emacs_cv_var___after_morecore_hook=no)])
1341 if test $emacs_cv_var___after_morecore_hook = no; then
1342   doug_lea_malloc=no
1343 fi
1344 if test "${system_malloc}" = "yes"; then
1345   GNU_MALLOC=no
1346   GNU_MALLOC_reason="
1347     (The GNU allocators don't work with this system configuration.)"
1348 fi
1349 if test "$doug_lea_malloc" = "yes" ; then
1350   if test "$GNU_MALLOC" = yes ; then
1351     GNU_MALLOC_reason="
1352       (Using Doug Lea's new malloc from the GNU C Library.)"
1353   fi
1354   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1355             [Define to 1 if you are using the GNU C Library.])
1356 fi
1357
1358 if test x"${REL_ALLOC}" = x; then
1359   REL_ALLOC=${GNU_MALLOC}
1360 fi
1361
1362 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1363 dnl the system configuration file (s/*.h) to turn the use of mmap
1364 dnl in the relocating allocator on.
1365
1366 AC_FUNC_MMAP
1367 if test $use_mmap_for_buffers = yes; then
1368   REL_ALLOC=no
1369 fi
1370
1371 LIBS="$libsrc_libs $LIBS"
1372
1373 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1374 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1375 AC_CHECK_LIB(dnet, dnet_ntoa)
1376 dnl This causes -lresolv to get used in subsequent tests,
1377 dnl which causes failures on some systems such as HPUX 9.
1378 dnl AC_CHECK_LIB(resolv, gethostbyname)
1379
1380 dnl FIXME replace main with a function we actually want from this library.
1381 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1382
1383 AC_CHECK_LIB(pthreads, cma_open)
1384
1385 dnl Check for need for bigtoc support on IBM AIX
1386
1387 case ${host_os} in
1388 aix*)
1389   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1390     case $GCC in
1391     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1392     *) gdb_cv_bigtoc=-bbigtoc ;;
1393     esac
1394
1395     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1396     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1397   ])
1398   ;;
1399 esac
1400
1401 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1402 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1403 # REAL_CPPFLAGS later on.
1404
1405 REAL_CPPFLAGS="$CPPFLAGS"
1406
1407 if test "${HAVE_X11}" = "yes"; then
1408   DEFS="$C_SWITCH_X_SITE $DEFS"
1409   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1410   LIBS="$LIBX $LIBS"
1411   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1412   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1413
1414   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1415   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1416   # but it's more convenient here to set LD_RUN_PATH
1417   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1418   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1419     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1420     export LD_RUN_PATH
1421   fi
1422
1423   if test "${opsys}" = "gnu-linux"; then
1424     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1425     AC_TRY_LINK([],
1426      [XOpenDisplay ("foo");],
1427      [xlinux_first_failure=no],
1428      [xlinux_first_failure=yes])
1429     if test "${xlinux_first_failure}" = "yes"; then
1430       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1431       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1432       OLD_CPPFLAGS="$CPPFLAGS"
1433       OLD_LIBS="$LIBS"
1434       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1435       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1436       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1437       LIBS="$LIBS -b i486-linuxaout"
1438       AC_TRY_LINK([],
1439        [XOpenDisplay ("foo");],
1440        [xlinux_second_failure=no],
1441        [xlinux_second_failure=yes])
1442       if test "${xlinux_second_failure}" = "yes"; then
1443         # If we get the same failure with -b, there is no use adding -b.
1444         # So take it out.  This plays safe.
1445         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1446         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1447         CPPFLAGS="$OLD_CPPFLAGS"
1448         LIBS="$OLD_LIBS"
1449         AC_MSG_RESULT(no)
1450       else
1451         AC_MSG_RESULT(yes)
1452       fi
1453     else
1454       AC_MSG_RESULT(no)
1455     fi
1456   fi
1457
1458   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1459   # header files included from there.
1460   AC_MSG_CHECKING(for Xkb)
1461   AC_TRY_LINK([#include <X11/Xlib.h>
1462 #include <X11/XKBlib.h>],
1463         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1464         emacs_xkb=yes, emacs_xkb=no)
1465   AC_MSG_RESULT($emacs_xkb)
1466   if test $emacs_xkb = yes; then
1467     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1468   fi
1469
1470   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1471 XScreenNumberOfScreen XSetWMProtocols)
1472 fi
1473
1474 if test "${window_system}" = "x11"; then
1475   AC_MSG_CHECKING(X11 version 6)
1476   AC_CACHE_VAL(emacs_cv_x11_version_6,
1477   [AC_TRY_LINK([#include <X11/Xlib.h>],
1478 [#if XlibSpecificationRelease < 6
1479 fail;
1480 #endif
1481 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1482   if test $emacs_cv_x11_version_6 = yes; then
1483     AC_MSG_RESULT(6 or newer)
1484     AC_DEFINE(HAVE_X11R6, 1,
1485               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1486   else
1487     AC_MSG_RESULT(before 6)
1488   fi
1489 fi
1490
1491
1492 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1493 HAVE_RSVG=no
1494 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1495   if test "${with_rsvg}" != "no"; then
1496     RSVG_REQUIRED=2.11.0
1497     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1498
1499     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1500     AC_SUBST(RSVG_CFLAGS)
1501     AC_SUBST(RSVG_LIBS)
1502
1503     if test ".${RSVG_CFLAGS}" != "."; then
1504       HAVE_RSVG=yes
1505       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1506       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1507       LIBS="$RSVG_LIBS $LIBS"
1508     fi
1509   fi
1510 fi
1511
1512
1513 HAVE_GTK=no
1514 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1515   GLIB_REQUIRED=2.6
1516   GTK_REQUIRED=2.6
1517   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1518
1519   dnl Checks for libraries.
1520   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1521   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1522      AC_MSG_ERROR($GTK_PKG_ERRORS)
1523   fi
1524 fi
1525
1526
1527 if test x"$pkg_check_gtk" = xyes; then
1528
1529   AC_SUBST(GTK_CFLAGS)
1530   AC_SUBST(GTK_LIBS)
1531   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1532   CFLAGS="$CFLAGS $GTK_CFLAGS"
1533   LIBS="$GTK_LIBS $LIBS"
1534   dnl Try to compile a simple GTK program.
1535   GTK_COMPILES=no
1536   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1537   if test "${GTK_COMPILES}" != "yes"; then
1538     if test "$USE_X_TOOLKIT" != "maybe"; then
1539       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1540     fi
1541   else
1542     HAVE_GTK=yes
1543     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1544     USE_X_TOOLKIT=none
1545     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1546       :
1547     else
1548       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1549        closing open displays.  This is no problem if you just use
1550        one display, but if you use more than one and close one of them
1551        Emacs may crash.]])
1552       sleep 3
1553     fi
1554   fi
1555
1556 fi
1557
1558
1559 if test "${HAVE_GTK}" = "yes"; then
1560
1561   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1562   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1563   if test "$with_toolkit_scroll_bars" != no; then
1564     with_toolkit_scroll_bars=yes
1565   fi
1566
1567   dnl  Check if we can use multiple displays with this GTK version.
1568   dnl  If gdk_display_open exists, assume all others are there also.
1569   HAVE_GTK_MULTIDISPLAY=no
1570   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1571   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1572     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1573               [Define to 1 if GTK can handle more than one display.])
1574   fi
1575
1576   dnl  Check if we have the old file selection dialog.
1577   dnl  If gdk_display_open exists, assume all others are there also.
1578   HAVE_GTK_FILE_SELECTION=no
1579   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1580
1581   dnl  Check if we have the new file chooser dialog
1582   dnl  If gdk_display_open exists, assume all others are there also.
1583   HAVE_GTK_FILE_CHOOSER=no
1584   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1585
1586   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1587      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1588     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1589               [Define to 1 if GTK has both file selection and chooser dialog.])
1590   fi
1591
1592   dnl Check if pthreads are available.  Emacs only needs this when using
1593   dnl gtk_file_chooser under Gnome.
1594   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1595     HAVE_GTK_AND_PTHREAD=no
1596     AC_CHECK_HEADERS(pthread.h)
1597     if test "$ac_cv_header_pthread_h"; then
1598       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1599     fi
1600     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1601       case "${canonical}" in
1602         *-hpux*) ;;
1603         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1604       esac
1605       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1606                [Define to 1 if you have GTK and pthread (-lpthread).])
1607     fi
1608   fi
1609 fi
1610
1611 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1612 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1613 dnl also not configured.
1614 HAVE_DBUS=no
1615 if test "${with_dbus}" = "yes"; then
1616    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1617    if test "$HAVE_DBUS" = yes; then
1618       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1619    fi
1620 fi
1621
1622 dnl Do not put whitespace before the #include statements below.
1623 dnl Older compilers (eg sunos4 cc) choke on it.
1624 HAVE_XAW3D=no
1625 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1626   if test "$with_xaw3d" != no; then
1627     AC_MSG_CHECKING(for xaw3d)
1628     AC_CACHE_VAL(emacs_cv_xaw3d,
1629     [AC_TRY_LINK([
1630 #include <X11/Intrinsic.h>
1631 #include <X11/Xaw3d/Simple.h>],
1632       [],
1633       emacs_cv_xaw3d=yes,
1634       emacs_cv_xaw3d=no)])
1635   else
1636     emacs_cv_xaw3d=no
1637   fi
1638   if test $emacs_cv_xaw3d = yes; then
1639     AC_MSG_RESULT([yes; using Lucid toolkit])
1640     USE_X_TOOLKIT=LUCID
1641     HAVE_XAW3D=yes
1642     AC_DEFINE(HAVE_XAW3D, 1,
1643               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1644   else
1645     AC_MSG_RESULT(no)
1646     AC_MSG_CHECKING(for libXaw)
1647     AC_CACHE_VAL(emacs_cv_xaw,
1648     [AC_TRY_LINK([
1649 #include <X11/Intrinsic.h>
1650 #include <X11/Xaw/Simple.h>],
1651       [],
1652       emacs_cv_xaw=yes,
1653       emacs_cv_xaw=no)])
1654     if test $emacs_cv_xaw = yes; then
1655       AC_MSG_RESULT([yes; using Lucid toolkit])
1656       USE_X_TOOLKIT=LUCID
1657     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1658       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1659     else
1660       AC_MSG_RESULT([no; do not use toolkit by default])
1661       USE_X_TOOLKIT=none
1662     fi
1663   fi
1664 fi
1665
1666 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1667
1668 if test "${USE_X_TOOLKIT}" != "none"; then
1669   AC_MSG_CHECKING(X11 toolkit version)
1670   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1671   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1672 [#if XtSpecificationRelease < 6
1673 fail;
1674 #endif
1675 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1676   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1677   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1678     AC_MSG_RESULT(6 or newer)
1679     AC_DEFINE(HAVE_X11XTR6, 1,
1680               [Define to 1 if you have the X11R6 or newer version of Xt.])
1681   else
1682     AC_MSG_RESULT(before 6)
1683   fi
1684
1685 dnl If using toolkit, check whether libXmu.a exists.
1686 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1687   OLDLIBS="$LIBS"
1688   if test x$HAVE_X11XTR6 = xyes; then
1689     LIBS="-lXt -lSM -lICE $LIBS"
1690   else
1691     LIBS="-lXt $LIBS"
1692   fi
1693   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1694   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1695 fi
1696
1697 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1698 if test "${HAVE_X11}" = "yes"; then
1699   if test "${USE_X_TOOLKIT}" != "none"; then
1700     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1701   fi
1702 fi
1703
1704 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1705   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1706   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1707     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1708 int x = 5;
1709 #else
1710 Motif version prior to 2.1.
1711 #endif],
1712     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1713   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1714   if test $emacs_cv_motif_version_2_1 = yes; then
1715     HAVE_LIBXP=no
1716     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1717               [Define to 1 if you have Motif 2.1 or newer.])
1718     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1719     if test ${HAVE_LIBXP} = yes; then
1720       AC_DEFINE(HAVE_LIBXP, 1,
1721                 [Define to 1 if you have the Xp library (-lXp).])
1722     fi
1723   else
1724     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1725     # We put this in CFLAGS temporarily to precede other -I options
1726     # that might be in CFLAGS temporarily.
1727     # We put this in CPPFLAGS where it precedes the other -I options.
1728     OLD_CPPFLAGS=$CPPFLAGS
1729     OLD_CFLAGS=$CFLAGS
1730     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1731     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1732     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1733       [int x = 5;],
1734       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1735     if test $emacs_cv_lesstif = yes; then
1736       # Make sure this -I option remains in CPPFLAGS after it is set
1737       # back to REAL_CPPFLAGS.
1738       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1739       # have those other -I options anyway.  Ultimately, having this
1740       # directory ultimately in CPPFLAGS will be enough.
1741       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1742       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1743     else
1744       CFLAGS=$OLD_CFLAGS
1745       CPPFLAGS=$OLD_CPPFLAGS
1746     fi
1747   fi
1748 fi
1749
1750 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1751 dnl using Motif or Xaw3d is available, and unless
1752 dnl --with-toolkit-scroll-bars=no was specified.
1753
1754 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1755             [Define to 1 if we should use toolkit scroll bars.])dnl
1756 USE_TOOLKIT_SCROLL_BARS=no
1757 if test "${with_toolkit_scroll_bars}" != "no"; then
1758   if test "${USE_X_TOOLKIT}" != "none"; then
1759     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1760       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1761       HAVE_XAW3D=no
1762       USE_TOOLKIT_SCROLL_BARS=yes
1763     elif test "${HAVE_XAW3D}" = "yes"; then
1764       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1765       USE_TOOLKIT_SCROLL_BARS=yes
1766     fi
1767   elif test "${HAVE_GTK}" = "yes"; then
1768     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1769     USE_TOOLKIT_SCROLL_BARS=yes
1770   elif test "${HAVE_NS}" = "yes"; then
1771     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1772     USE_TOOLKIT_SCROLL_BARS=yes
1773   fi
1774 fi
1775
1776 dnl See if XIM is available.
1777 AC_TRY_COMPILE([
1778           #include <X11/Xlib.h>
1779           #include <X11/Xresource.h>],
1780          [XIMProc  callback;],
1781          [HAVE_XIM=yes
1782          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1783          HAVE_XIM=no)
1784
1785 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1786
1787 if test "${with_xim}" != "no"; then
1788   AC_DEFINE(USE_XIM, 1,
1789             [Define to 1 if we should use XIM, if it is available.])
1790 fi
1791
1792
1793 if test "${HAVE_XIM}" != "no"; then
1794   late_CFLAGS=$CFLAGS
1795   if test "$GCC" = yes; then
1796     CFLAGS="$CFLAGS --pedantic-errors"
1797   fi
1798   AC_TRY_COMPILE([
1799 #include <X11/Xlib.h>
1800 #include <X11/Xresource.h>],
1801 [Display *display;
1802 XrmDatabase db;
1803 char *res_name;
1804 char *res_class;
1805 XIMProc  callback;
1806 XPointer *client_data;
1807 #ifndef __GNUC__
1808 /* If we're not using GCC, it's probably not XFree86, and this is
1809    probably right, but we can't use something like --pedantic-errors.  */
1810 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1811                                            char*, XIMProc, XPointer*);
1812 #endif
1813 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1814    client_data);],
1815     [emacs_cv_arg6_star=yes])
1816   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1817          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1818 either XPointer or XPointer*.])dnl
1819   if test "$emacs_cv_arg6_star" = yes; then
1820     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1821   else
1822     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1823   fi
1824   CFLAGS=$late_CFLAGS
1825 fi
1826
1827 ### Start of font-backend (under any platform) section.
1828 # (nothing here yet -- this is a placeholder)
1829 ### End of font-backend (under any platform) section.
1830
1831 ### Start of font-backend (under X11) section.
1832 if test "${HAVE_X11}" = "yes"; then
1833    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1834    test "${HAVE_FC}" = "no" && with_freetype=no
1835
1836 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1837    HAVE_XFT=maybe
1838     if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1839       with_xft="no";
1840     fi
1841     if test "x${with_xft}" != "xno"; then
1842
1843       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1844       if test "$HAVE_XFT" != no; then
1845         OLD_CPPFLAGS="$CPPFLAGS"
1846         OLD_CFLAGS="$CFLAGS"
1847         OLD_LIBS="$LIBS"
1848         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1849         CFLAGS="$CFLAGS $XFT_CFLAGS"
1850         LIBS="$XFT_LIBS $LIBS"
1851         AC_CHECK_HEADER(X11/Xft/Xft.h,
1852           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1853
1854         if test "${HAVE_XFT}" = "yes"; then
1855           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1856             AC_SUBST(XFT_LIBS)
1857           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1858         else
1859           CPPFLAGS="$OLD_CPPFLAGS"
1860           CFLAGS="$OLD_CFLAGS"
1861           LIBS="$OLD_LIBS"
1862         fi                        # "${HAVE_XFT}" = "yes"
1863       fi                          # "$HAVE_XFT" != no
1864     fi                            # "x${with_xft}" != "xno"
1865
1866     dnl For the "Does Emacs use" message at the end.
1867     if test "$HAVE_XFT" != "yes"; then
1868        HAVE_XFT=no
1869     fi
1870
1871
1872     HAVE_FREETYPE=no
1873     ### Use -lfreetype if available, unless `--with-freetype=no'.
1874     if test "${HAVE_XFT}" = "yes"; then
1875       dnl As we use Xft, we anyway use freetype.
1876       dnl In this case, there's no need of additional CFLAGS and LIBS.
1877       HAVE_FREETYPE=yes
1878       FONTCONFIG_CFLAGS=
1879       FONTCONFIG_LIBS=
1880     elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1881
1882       PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1883     fi
1884
1885     HAVE_LIBOTF=no
1886     if test "${HAVE_FREETYPE}" = "yes"; then
1887       AC_DEFINE(HAVE_FREETYPE, 1,
1888                 [Define to 1 if using the freetype and fontconfig libraries.])
1889       if test "${with_libotf}" != "no"; then
1890         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1891                           HAVE_LIBOTF=no)
1892         if test "$HAVE_LIBOTF" = "yes"; then
1893           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1894           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1895                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1896                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
1897           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1898             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1899                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
1900           fi
1901         fi
1902       fi
1903     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1904     dnl Does the new font backend require it, or can it work without it?
1905     fi
1906
1907     HAVE_M17N_FLT=no
1908     if test "${HAVE_LIBOTF}" = yes; then
1909       if test "${with_m17n_flt}" != "no"; then
1910         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1911         if test "$HAVE_M17N_FLT" = "yes"; then
1912           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1913         fi
1914       fi
1915     fi
1916 else
1917     HAVE_XFT=no
1918     HAVE_FREETYPE=no
1919     HAVE_LIBOTF=no
1920     HAVE_M17N_FLT=no
1921 fi
1922 ### End of font-backend (under X11) section.
1923
1924 AC_SUBST(FREETYPE_CFLAGS)
1925 AC_SUBST(FREETYPE_LIBS)
1926 AC_SUBST(FONTCONFIG_CFLAGS)
1927 AC_SUBST(FONTCONFIG_LIBS)
1928 AC_SUBST(LIBOTF_CFLAGS)
1929 AC_SUBST(LIBOTF_LIBS)
1930 AC_SUBST(M17N_FLT_CFLAGS)
1931 AC_SUBST(M17N_FLT_LIBS)
1932
1933 ### Use -lXpm if available, unless `--with-xpm=no'.
1934 HAVE_XPM=no
1935 if test "${HAVE_X11}" = "yes"; then
1936   if test "${with_xpm}" != "no"; then
1937     AC_CHECK_HEADER(X11/xpm.h,
1938       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1939     if test "${HAVE_XPM}" = "yes"; then
1940       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1941       AC_EGREP_CPP(no_return_alloc_pixels,
1942       [#include "X11/xpm.h"
1943 #ifndef XpmReturnAllocPixels
1944 no_return_alloc_pixels
1945 #endif
1946       ], HAVE_XPM=no, HAVE_XPM=yes)
1947
1948       if test "${HAVE_XPM}" = "yes"; then
1949         AC_MSG_RESULT(yes)
1950       else
1951         AC_MSG_RESULT(no)
1952       fi
1953     fi
1954   fi
1955
1956   if test "${HAVE_XPM}" = "yes"; then
1957     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1958   fi
1959 fi
1960
1961 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1962 HAVE_JPEG=no
1963 if test "${HAVE_X11}" = "yes"; then
1964   if test "${with_jpeg}" != "no"; then
1965     dnl Checking for jpeglib.h can lose because of a redefinition of
1966     dnl  HAVE_STDLIB_H.
1967     AC_CHECK_HEADER(jerror.h,
1968       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1969   fi
1970
1971   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1972   if test "${HAVE_JPEG}" = "yes"; then
1973     AC_DEFINE(HAVE_JPEG)
1974     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1975         [#include <jpeglib.h>
1976          version=JPEG_LIB_VERSION
1977 ],
1978         [AC_DEFINE(HAVE_JPEG)],
1979         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1980         HAVE_JPEG=no])
1981   fi
1982 fi
1983
1984 ### Use -lpng if available, unless `--with-png=no'.
1985 HAVE_PNG=no
1986 if test "${HAVE_X11}" = "yes"; then
1987   if test "${with_png}" != "no"; then
1988     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1989     # in /usr/include/libpng.
1990     AC_CHECK_HEADERS(png.h libpng/png.h)
1991     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1992       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1993     fi
1994   fi
1995
1996   if test "${HAVE_PNG}" = "yes"; then
1997     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1998   fi
1999 fi
2000
2001 ### Use -ltiff if available, unless `--with-tiff=no'.
2002 HAVE_TIFF=no
2003 if test "${HAVE_X11}" = "yes"; then
2004   if test "${with_tiff}" != "no"; then
2005     AC_CHECK_HEADER(tiffio.h,
2006       [tifflibs="-lz -lm"
2007       # At least one tiff package requires the jpeg library.
2008       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2009       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2010   fi
2011
2012   if test "${HAVE_TIFF}" = "yes"; then
2013     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2014   fi
2015 fi
2016
2017 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2018 HAVE_GIF=no
2019 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2020   AC_CHECK_HEADER(gif_lib.h,
2021 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2022 # Earlier versions can crash Emacs.
2023     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2024
2025   if test "$HAVE_GIF" = yes; then
2026       ac_gif_lib_name="-lgif"
2027   fi
2028
2029 # If gif_lib.h but no libgif, try libungif.
2030   if test x"$try_libungif" = xyes; then
2031     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2032
2033     if test "$HAVE_GIF" = yes; then
2034       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2035       ac_gif_lib_name="-lungif"
2036     fi
2037   fi
2038
2039   if test "${HAVE_GIF}" = "yes"; then
2040     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2041   fi
2042 fi
2043
2044 dnl Check for required libraries.
2045 if test "${HAVE_X11}" = "yes"; then
2046   MISSING=""
2047   WITH_NO=""
2048   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2049     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2050   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2051     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2052   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2053     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2054   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2055     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2056   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2057     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2058
2059   if test "X${MISSING}" != X; then
2060     AC_MSG_ERROR([The following required libraries were not found:
2061     $MISSING
2062 Maybe some development libraries/packages are missing?
2063 If you don't want to link with them give
2064     $WITH_NO
2065 as options to configure])
2066   fi
2067 fi
2068
2069 ### Use -lgpm if available, unless `--with-gpm=no'.
2070 HAVE_GPM=no
2071 if test "${with_gpm}" != "no"; then
2072   AC_CHECK_HEADER(gpm.h,
2073     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2074 fi
2075
2076 if test "${HAVE_GPM}" = "yes"; then
2077   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2078 fi
2079
2080 dnl Check for malloc/malloc.h on darwin
2081 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2082
2083 ### Use NeXTstep API to implement GUI.
2084 if test "${HAVE_NS}" = "yes"; then
2085   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2086   if test "${NS_IMPL_COCOA}" = "yes"; then
2087     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2088     GNU_OBJC_CFLAGS=
2089     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2090   fi
2091   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2092     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2093     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2094   fi
2095   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2096     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2097   fi
2098   # We also have mouse menus.
2099   HAVE_MENUS=yes
2100 fi
2101
2102
2103 ### Use session management (-lSM -lICE) if available
2104 HAVE_X_SM=no
2105 if test "${HAVE_X11}" = "yes"; then
2106   AC_CHECK_HEADER(X11/SM/SMlib.h,
2107     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2108
2109   if test "${HAVE_X_SM}" = "yes"; then
2110     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2111     case "$LIBS" in
2112       *-lSM*) ;;
2113       *)      LIBS="-lSM -lICE $LIBS" ;;
2114     esac
2115   fi
2116 fi
2117
2118 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2119 AC_CACHE_CHECK(whether netdb declares h_errno,
2120                emacs_cv_netdb_declares_h_errno,
2121 [AC_TRY_LINK([#include <netdb.h>],
2122   [return h_errno;],
2123   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2124 if test $emacs_cv_netdb_declares_h_errno = yes; then
2125   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2126 fi
2127
2128 AC_FUNC_ALLOCA
2129
2130 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2131 dnl FIXME is there an autoconf test that does the right thing, without
2132 dnl needing to call A_M_E afterwards?
2133 if test x"$ac_cv_func_alloca_works" != xyes; then
2134    AC_MSG_ERROR( [a system implementation of alloca is required] )
2135 fi
2136
2137 # fmod, logb, and frexp are found in -lm on most systems.
2138 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2139 AC_CHECK_LIB(m, sqrt)
2140
2141 # Check for mail-locking functions in a "mail" library.  Probably this should
2142 # have the same check as for liblockfile below.
2143 AC_CHECK_LIB(mail, maillock)
2144 dnl Debian, at least:
2145 AC_CHECK_LIB(lockfile, maillock)
2146 # If we have the shared liblockfile, assume we must use it for mail
2147 # locking (e.g. Debian).  If we couldn't link against liblockfile
2148 # (no liblockfile.a installed), ensure that we don't need to.
2149 if test "$ac_cv_lib_lockfile_maillock" = no; then
2150   dnl This works for files generally, not just executables.
2151   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2152   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2153                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2154   if test $ac_cv_prog_liblockfile = yes; then
2155     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2156 This probably means that movemail could lose mail.
2157 There may be a `development' package to install containing liblockfile.])
2158   else :
2159   fi
2160 fi
2161 AC_CHECK_FUNCS(touchlock)
2162 AC_CHECK_HEADERS(maillock.h)
2163
2164 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2165 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2166 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2167 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2168 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2169 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2170 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2171 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2172 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2173 cfmakeraw cfsetspeed)
2174
2175 AC_CHECK_HEADERS(sys/un.h)
2176
2177 AC_FUNC_MKTIME
2178 if test "$ac_cv_func_working_mktime" = no; then
2179   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2180 fi
2181
2182 AC_FUNC_GETLOADAVG
2183
2184 AC_FUNC_FSEEKO
2185
2186 # Configure getopt.
2187 m4_include([m4/getopt.m4])
2188 gl_GETOPT_IFELSE([
2189   gl_GETOPT_SUBSTITUTE_HEADER
2190   gl_PREREQ_GETOPT
2191   GETOPTOBJS='getopt.o getopt1.o'
2192 ])
2193 AC_SUBST(GETOPTOBJS)
2194
2195 AC_FUNC_GETPGRP
2196
2197 AC_FUNC_STRFTIME
2198
2199 # UNIX98 PTYs.
2200 AC_CHECK_FUNCS(grantpt)
2201
2202 # PTY-related GNU extensions.
2203 AC_CHECK_FUNCS(getpt)
2204
2205 # Check this now, so that we will NOT find the above functions in ncurses.
2206 # That is because we have not set up to link ncurses in lib-src.
2207 # It's better to believe a function is not available
2208 # than to expect to find it in ncurses.
2209 AC_CHECK_LIB(ncurses, tparm)
2210
2211 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2212
2213 resolv=no
2214 AC_TRY_LINK([#include <netinet/in.h>
2215 #include <arpa/nameser.h>
2216 #include <resolv.h>],
2217     [return res_init();],
2218     have_res_init=yes, have_res_init=no)
2219 if test "$have_res_init" = no; then
2220   OLIBS="$LIBS"
2221   LIBS="$LIBS -lresolv"
2222   AC_MSG_CHECKING(for res_init with -lresolv)
2223   AC_TRY_LINK([#include <netinet/in.h>
2224 #include <arpa/nameser.h>
2225 #include <resolv.h>],
2226     [return res_init();],
2227     have_res_init=yes, have_res_init=no)
2228   AC_MSG_RESULT($have_res_init)
2229   if test "$have_res_init" = yes ; then
2230     resolv=yes
2231   fi
2232   LIBS="$OLIBS"
2233 fi
2234
2235 if test "$have_res_init" = yes; then
2236   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2237 fi
2238
2239 # Do we need the Hesiod library to provide the support routines?
2240 if test "$with_hesiod" != no ; then
2241   # Don't set $LIBS here -- see comments above.
2242   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2243      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2244                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2245   if test "$resolv" = yes ; then
2246     RESOLVLIB=-lresolv
2247   else
2248     RESOLVLIB=
2249   fi
2250   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2251         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2252                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2253         :, $RESOLVLIB)])
2254 fi
2255
2256 # Do we need libresolv (due to res_init or Hesiod)?
2257 if test "$resolv" = yes ; then
2258   AC_DEFINE(HAVE_LIBRESOLV, 1,
2259             [Define to 1 if you have the resolv library (-lresolv).])
2260 fi
2261
2262 # These tell us which Kerberos-related libraries to use.
2263 if test "${with_kerberos}" != no; then
2264   AC_CHECK_LIB(com_err, com_err)
2265   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2266   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2267   AC_CHECK_LIB(krb5, krb5_init_context)
2268   if test "${with_kerberos5}" = no; then
2269     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2270                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2271     AC_CHECK_LIB(krb4, krb_get_cred,,
2272                  [AC_CHECK_LIB(krb, krb_get_cred)])
2273   fi
2274
2275   if test "${with_kerberos5}" != no; then
2276     AC_CHECK_HEADERS(krb5.h,
2277       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2278                         [#include <krb5.h>])])
2279   else
2280     AC_CHECK_HEADERS(des.h,,
2281                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2282                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2283     AC_CHECK_HEADERS(krb.h,,
2284                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2285                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2286   fi
2287   AC_CHECK_HEADERS(com_err.h)
2288 fi
2289
2290 # Solaris requires -lintl if you want strerror (which calls dgettext)
2291 # to return localized messages.
2292 AC_CHECK_LIB(intl, dgettext)
2293
2294 AC_MSG_CHECKING(whether localtime caches TZ)
2295 AC_CACHE_VAL(emacs_cv_localtime_cache,
2296 [if test x$ac_cv_func_tzset = xyes; then
2297 AC_TRY_RUN([#include <time.h>
2298 extern char **environ;
2299 unset_TZ ()
2300 {
2301   char **from, **to;
2302   for (to = from = environ; (*to = *from); from++)
2303     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2304       to++;
2305 }
2306 char TZ_GMT0[] = "TZ=GMT0";
2307 char TZ_PST8[] = "TZ=PST8";
2308 main()
2309 {
2310   time_t now = time ((time_t *) 0);
2311   int hour_GMT0, hour_unset;
2312   if (putenv (TZ_GMT0) != 0)
2313     exit (1);
2314   hour_GMT0 = localtime (&now)->tm_hour;
2315   unset_TZ ();
2316   hour_unset = localtime (&now)->tm_hour;
2317   if (putenv (TZ_PST8) != 0)
2318     exit (1);
2319   if (localtime (&now)->tm_hour == hour_GMT0)
2320     exit (1);
2321   unset_TZ ();
2322   if (localtime (&now)->tm_hour != hour_unset)
2323     exit (1);
2324   exit (0);
2325 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2326 [# If we have tzset, assume the worst when cross-compiling.
2327 emacs_cv_localtime_cache=yes])
2328 else
2329         # If we lack tzset, report that localtime does not cache TZ,
2330         # since we can't invalidate the cache if we don't have tzset.
2331         emacs_cv_localtime_cache=no
2332 fi])dnl
2333 AC_MSG_RESULT($emacs_cv_localtime_cache)
2334 if test $emacs_cv_localtime_cache = yes; then
2335   AC_DEFINE(LOCALTIME_CACHE, 1,
2336             [Define to 1 if localtime caches TZ.])
2337 fi
2338
2339 if test "x$HAVE_TIMEVAL" = xyes; then
2340   AC_CHECK_FUNCS(gettimeofday)
2341   if test $ac_cv_func_gettimeofday = yes; then
2342     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2343                    emacs_cv_gettimeofday_two_arguments,
2344     [AC_TRY_COMPILE([
2345 #ifdef TIME_WITH_SYS_TIME
2346 #include <sys/time.h>
2347 #include <time.h>
2348 #else
2349 #ifdef HAVE_SYS_TIME_H
2350 #include <sys/time.h>
2351 #else
2352 #include <time.h>
2353 #endif
2354 #endif],
2355       [struct timeval time;
2356        gettimeofday (&time, 0);],
2357       emacs_cv_gettimeofday_two_arguments=yes,
2358       emacs_cv_gettimeofday_two_arguments=no)])
2359     if test $emacs_cv_gettimeofday_two_arguments = no; then
2360       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2361                 [Define to 1 if gettimeofday accepts only one argument.])
2362     fi
2363   fi
2364 fi
2365
2366 ok_so_far=yes
2367 AC_CHECK_FUNC(socket, , ok_so_far=no)
2368 if test $ok_so_far = yes; then
2369   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2370 fi
2371 if test $ok_so_far = yes; then
2372   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2373 fi
2374 if test $ok_so_far = yes; then
2375 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2376   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2377             [Define to 1 if you have inet sockets.])
2378 fi
2379
2380 AC_CHECK_HEADERS(sys/ioctl.h)
2381
2382 if test -f /usr/lpp/X11/bin/smt.exp; then
2383   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2384             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2385 fi
2386
2387 AC_MSG_CHECKING(whether system supports dynamic ptys)
2388 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2389   AC_MSG_RESULT(yes)
2390   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2391 else
2392   AC_MSG_RESULT(no)
2393 fi
2394
2395 AC_FUNC_FORK
2396
2397 dnl Adapted from Haible's version.
2398 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2399   [AC_TRY_LINK([#include <langinfo.h>],
2400     [char* cs = nl_langinfo(CODESET);],
2401     emacs_cv_langinfo_codeset=yes,
2402     emacs_cv_langinfo_codeset=no)
2403   ])
2404 if test $emacs_cv_langinfo_codeset = yes; then
2405   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2406     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2407 fi
2408
2409 AC_CHECK_TYPES(size_t)
2410
2411 AC_TYPE_MBSTATE_T
2412
2413 dnl Restrict could probably be used effectively other than in regex.c.
2414 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2415   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2416                   emacs_cv_c_restrict=yes,
2417                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2418                                   emacs_cv_c_restrict=__restrict,
2419                                   emacs_cv_c_restrict=no)])])
2420 case "$emacs_cv_c_restrict" in
2421   yes) emacs_restrict=restrict;;
2422   no) emacs_restrict="";;
2423   *) emacs_restrict="$emacs_cv_c_restrict";;
2424 esac
2425 if test "$emacs_restrict" != __restrict; then
2426   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2427     [Define to compiler's equivalent of C99 restrict keyword.
2428      Don't define if equivalent is `__restrict'.])
2429 fi
2430
2431 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2432   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2433                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2434 if test "$emacs_cv_c_restrict_arr" = yes; then
2435   AC_DEFINE(__restrict_arr, __restrict,
2436     [Define to compiler's equivalent of C99 restrict keyword in array
2437      declarations.  Define as empty for no equivalent.])
2438 fi
2439
2440 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2441 dnl how the tty code is related to POSIX and/or other versions of termios.
2442 dnl The following looks like a useful start.
2443 dnl
2444 dnl AC_SYS_POSIX_TERMIOS
2445 dnl if test $ac_cv_sys_posix_termios = yes; then
2446 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2447 dnl                                and macros for terminal control.])
2448 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2449 dnl fi
2450
2451 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2452
2453 # Set up the CFLAGS for real compilation, so we can substitute it.
2454 CFLAGS="$REAL_CFLAGS"
2455 CPPFLAGS="$REAL_CPPFLAGS"
2456
2457 #### Find out which version of Emacs this is.
2458 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2459          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2460 if test x"${version}" = x; then
2461   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2462 fi
2463
2464 ### Specify what sort of things we'll be editing into Makefile and config.h.
2465 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2466 AC_SUBST(version)
2467 AC_SUBST(configuration)
2468 AC_SUBST(canonical)
2469 AC_SUBST(srcdir)
2470 AC_SUBST(prefix)
2471 AC_SUBST(exec_prefix)
2472 AC_SUBST(bindir)
2473 AC_SUBST(datadir)
2474 AC_SUBST(sharedstatedir)
2475 AC_SUBST(libexecdir)
2476 AC_SUBST(mandir)
2477 AC_SUBST(infodir)
2478 AC_SUBST(lispdir)
2479 AC_SUBST(locallisppath)
2480 AC_SUBST(lisppath)
2481 AC_SUBST(x_default_search_path)
2482 AC_SUBST(etcdir)
2483 AC_SUBST(archlibdir)
2484 AC_SUBST(docdir)
2485 AC_SUBST(bitmapdir)
2486 AC_SUBST(gamedir)
2487 AC_SUBST(gameuser)
2488 AC_SUBST(c_switch_system)
2489 AC_SUBST(c_switch_machine)
2490 AC_SUBST(LD_SWITCH_X_SITE)
2491 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2492 AC_SUBST(C_SWITCH_X_SITE)
2493 AC_SUBST(CFLAGS)
2494 AC_SUBST(X_TOOLKIT_TYPE)
2495 AC_SUBST(machfile)
2496 AC_SUBST(opsysfile)
2497 AC_SUBST(GETLOADAVG_LIBS)
2498 AC_SUBST(ns_appdir)
2499 AC_SUBST(ns_appbindir)
2500 AC_SUBST(ns_appresdir)
2501 AC_SUBST(ns_appsrc)
2502 AC_SUBST(GNUSTEP_MAKEFILES)
2503 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2504 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2505 AC_SUBST(GNU_OBJC_CFLAGS)
2506 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2507
2508 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2509                    [Define to the canonical Emacs configuration name.])
2510 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2511                    [Define to the options passed to configure.])
2512 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2513                    [Define to the used machine dependent file.])
2514 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2515                    [Define to the used os dependent file.])
2516 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2517 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2518  may need to deal with X Windows.  For instance, if you've defined
2519  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2520  your loader can find on its own, you might want to add "-L/..." or
2521  something similar.])
2522 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2523                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2524                     in case it's needed (for Solaris, for example).])
2525 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2526 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2527  may need to deal with X Windows.  For instance, if you've defined
2528  HAVE_X_WINDOWS above and your X include files aren't in a place
2529  that your compiler can find on its own, you might want to add
2530  "-I/..." or something similar.])
2531 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2532                    [Define to the unexec source file name.])
2533
2534 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2535   AC_DEFINE(HAVE_X_WINDOWS, 1,
2536             [Define to 1 if you want to use the X window system.])
2537 fi
2538 if test "${USE_X_TOOLKIT}" != "none" ; then
2539   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2540   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2541     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2542   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2543     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2544   fi
2545 fi
2546 if test "${HAVE_X11}" = "yes" ; then
2547   AC_DEFINE(HAVE_X11, 1,
2548             [Define to 1 if you want to use version 11 of X windows.
2549              Otherwise, Emacs expects to use version 10.])
2550 fi
2551 if test "${HAVE_MENUS}" = "yes" ; then
2552   AC_DEFINE(HAVE_MENUS, 1,
2553             [Define to 1 if you have mouse menus.
2554              (This is automatic if you use X, but the option to specify it remains.)
2555              It is also defined with other window systems that support xmenu.c.])
2556 fi
2557 if test "${GNU_MALLOC}" = "yes" ; then
2558   AC_DEFINE(GNU_MALLOC, 1,
2559             [Define to 1 if you want to use the GNU memory allocator.])
2560 fi
2561 if test "${REL_ALLOC}" = "yes" ; then
2562   AC_DEFINE(REL_ALLOC, 1,
2563             [Define REL_ALLOC if you want to use the relocating allocator for
2564              buffer space.])
2565 fi
2566
2567
2568 AH_TOP([/* GNU Emacs site configuration template file.
2569    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2570      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2571
2572 This file is part of GNU Emacs.
2573
2574 GNU Emacs is free software: you can redistribute it and/or modify
2575 it under the terms of the GNU General Public License as published by
2576 the Free Software Foundation, either version 3 of the License, or
2577 (at your option) any later version.
2578
2579 GNU Emacs is distributed in the hope that it will be useful,
2580 but WITHOUT ANY WARRANTY; without even the implied warranty of
2581 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2582 GNU General Public License for more details.
2583
2584 You should have received a copy of the GNU General Public License
2585 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2586
2587
2588 /* No code in Emacs #includes config.h twice, but some bits of code
2589    intended to work with other packages as well (like gmalloc.c)
2590    think they can include it as many times as they like.  */
2591 #ifndef EMACS_CONFIG_H
2592 #define EMACS_CONFIG_H
2593 ])dnl
2594
2595 AH_BOTTOM([
2596 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2597 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2598 #define HAVE_WINDOW_SYSTEM
2599 #define HAVE_MOUSE
2600 #endif
2601
2602 /* Sadly for now, GNUstep dump does not work.  */
2603 #ifdef NS_IMPL_GNUSTEP
2604 #define CANNOT_DUMP
2605 #endif
2606
2607 /* Define AMPERSAND_FULL_NAME if you use the convention
2608    that & in the full name stands for the login id.  */
2609 /* Turned on June 1996 supposing nobody will mind it.  */
2610 #define AMPERSAND_FULL_NAME
2611
2612 /* Define HAVE_SOUND if we have sound support.  We know it works
2613    and compiles only on the specified platforms.   For others,
2614    it probably doesn't make sense to try.  */
2615
2616 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2617 #ifdef HAVE_MACHINE_SOUNDCARD_H
2618 #define HAVE_SOUND 1
2619 #endif
2620 #ifdef HAVE_SYS_SOUNDCARD_H
2621 #define HAVE_SOUND 1
2622 #endif
2623 #ifdef HAVE_SOUNDCARD_H
2624 #define HAVE_SOUND 1
2625 #endif
2626 #ifdef HAVE_ALSA
2627 #define HAVE_SOUND 1
2628 #endif
2629 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2630
2631 /* If using GNU, then support inline function declarations. */
2632 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2633    generally, because even if non-gcc compilers accept `inline', they
2634    may reject `extern inline'.  */
2635 #if defined (__GNUC__) && defined (OPTIMIZE)
2636 #define INLINE __inline__
2637 #else
2638 #define INLINE
2639 #endif
2640
2641 /* `subprocesses' should be defined if you want to
2642    have code for asynchronous subprocesses
2643    (as used in M-x compile and M-x shell).
2644    Only MSDOS does not support this (it overrides
2645    this in its config_opsysfile below).  */
2646
2647 #define subprocesses
2648
2649 /* Include the os and machine dependent files.  */
2650 #include config_opsysfile
2651 #include config_machfile
2652
2653 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2654   (There is probably a better place to do this, but right now the Cocoa
2655    side does this in s/darwin.h and we cannot
2656    parallel this exactly since GNUstep is multi-OS. */
2657 #ifdef HAVE_NS
2658 #define OTHER_FILES ns-app
2659 # ifdef NS_IMPL_GNUSTEP
2660 /* See also .m.o rule in Makefile.in */
2661 /* FIXME: are all these flags really needed?  Document here why.  */
2662 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2663 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2664 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2665 #  define SYSTEM_PURESIZE_EXTRA 30000
2666 # endif /* NS_IMPL_GNUSTEP */
2667 #endif /* HAVE_NS */
2668
2669 /* SIGTYPE is the macro we actually use.  */
2670 #ifndef SIGTYPE
2671 #define SIGTYPE RETSIGTYPE
2672 #endif
2673
2674 #ifdef emacs /* Don't do this for lib-src.  */
2675 /* Tell regex.c to use a type compatible with Emacs.  */
2676 #define RE_TRANSLATE_TYPE Lisp_Object
2677 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2678 #ifdef make_number
2679 /* If make_number is a macro, use it.  */
2680 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2681 #else
2682 /* If make_number is a function, avoid it.  */
2683 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2684 #endif
2685 #endif
2686
2687 /* Avoid link-time collision with system mktime if we will use our own.  */
2688 #if ! HAVE_MKTIME || BROKEN_MKTIME
2689 #define mktime emacs_mktime
2690 #endif
2691
2692 #define my_strftime nstrftime   /* for strftime.c */
2693
2694 /* The rest of the code currently tests the CPP symbol BSTRING.
2695    Override any claims made by the system-description files.
2696    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2697 #undef BSTRING
2698 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2699 #define BSTRING
2700 #endif
2701
2702 /* Some of the files of Emacs which are intended for use with other
2703    programs assume that if you have a config.h file, you must declare
2704    the type of getenv.
2705
2706    This declaration shouldn't appear when alloca.s or Makefile.in
2707    includes config.h.  */
2708 #ifndef NOT_C_CODE
2709 extern char *getenv ();
2710 #endif
2711
2712 /* These default definitions are good for almost all machines.
2713    The exceptions override them in m/MACHINE.h.  */
2714
2715 #ifndef BITS_PER_CHAR
2716 #define BITS_PER_CHAR 8
2717 #endif
2718
2719 #ifndef BITS_PER_SHORT
2720 #define BITS_PER_SHORT 16
2721 #endif
2722
2723 /* Note that lisp.h uses this in a preprocessor conditional, so it
2724    would not work to use sizeof.  That being so, we do all of them
2725    without sizeof, for uniformity's sake.  */
2726 #ifndef BITS_PER_INT
2727 #define BITS_PER_INT 32
2728 #endif
2729
2730 #ifndef BITS_PER_LONG
2731 #ifdef _LP64
2732 #define BITS_PER_LONG 64
2733 #else
2734 #define BITS_PER_LONG 32
2735 #endif
2736 #endif
2737
2738 /* Define if the compiler supports function prototypes.  It may do so
2739    but not define __STDC__ (e.g. DEC C by default) or may define it as
2740    zero.  */
2741 #undef PROTOTYPES
2742 /* For mktime.c:  */
2743 #ifndef __P
2744 # if defined PROTOTYPES
2745 #  define __P(args) args
2746 # else
2747 #  define __P(args) ()
2748 # endif  /* GCC.  */
2749 #endif /* __P */
2750
2751 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2752 #ifndef NOT_C_CODE
2753 #ifdef HAVE_STRING_H
2754 #include "string.h"
2755 #endif
2756 #ifdef HAVE_STRINGS_H
2757 #include "strings.h"  /* May be needed for bcopy & al. */
2758 #endif
2759 #ifdef HAVE_STDLIB_H
2760 #include <stdlib.h>
2761 #endif
2762 #ifndef __GNUC__
2763 # ifdef HAVE_ALLOCA_H
2764 #  include <alloca.h>
2765 # else /* AIX files deal with #pragma.  */
2766 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2767 char *alloca ();
2768 #  endif
2769 # endif /* HAVE_ALLOCA_H */
2770 #endif /* __GNUC__ */
2771 #ifndef HAVE_SIZE_T
2772 typedef unsigned size_t;
2773 #endif
2774 #endif /* NOT_C_CODE */
2775
2776 /* Define HAVE_X_I18N if we have usable i18n support.  */
2777
2778 #ifdef HAVE_X11R6
2779 #define HAVE_X_I18N
2780 #elif !defined X11R5_INHIBIT_I18N
2781 #define HAVE_X_I18N
2782 #endif
2783
2784 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2785
2786 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2787 #define HAVE_X11R6_XIM
2788 #endif
2789
2790 /* Should we enable expensive run-time checking of data types?  */
2791 #undef ENABLE_CHECKING
2792
2793 #if defined __GNUC__ && (__GNUC__ > 2 \
2794                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2795 #define NO_RETURN       __attribute__ ((__noreturn__))
2796 #else
2797 #define NO_RETURN       /* nothing */
2798 #endif
2799
2800 /* These won't be used automatically yet.  We also need to know, at least,
2801    that the stack is continuous.  */
2802 #ifdef __GNUC__
2803 #  ifndef GC_SETJMP_WORKS
2804   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2805      see NON_SAVING_SETJMP in the target descriptions.  */
2806   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2807      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2808      Fixme: Deal with SVR3.  */
2809 #    define GC_SETJMP_WORKS 1
2810 #  endif
2811 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2812 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2813 #  endif
2814 #endif
2815
2816 #ifndef HAVE_BCOPY
2817 #define bcopy(a,b,s) memcpy (b,a,s)
2818 #endif
2819 #ifndef HAVE_BZERO
2820 #define bzero(a,s) memset (a,0,s)
2821 #endif
2822 #ifndef HAVE_BCMP
2823 #define BCMP memcmp
2824 #endif
2825
2826 #endif /* EMACS_CONFIG_H */
2827
2828 /*
2829 Local Variables:
2830 mode: c
2831 End:
2832 */
2833 ])dnl
2834
2835 #### Report on what we decided to do.
2836 #### Report GTK as a toolkit, even if it doesn't use Xt.
2837 #### It makes printing result more understandable as using GTK sets
2838 #### toolkit_scroll_bars to yes by default.
2839 if test "${HAVE_GTK}" = "yes"; then
2840   USE_X_TOOLKIT=GTK
2841 fi
2842
2843 echo "
2844 Configured for \`${canonical}'.
2845
2846   Where should the build process find the source code?    ${srcdir}
2847   What operating system and machine description files should Emacs use?
2848         \`${opsysfile}' and \`${machfile}'
2849   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2850   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2851   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2852   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2853   What window system should Emacs use?                    ${window_system}
2854   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2855
2856 if test -n "${x_includes}"; then
2857 echo "  Where do we find X Windows header files?                ${x_includes}"
2858 else
2859 echo "  Where do we find X Windows header files?                Standard dirs"
2860 fi
2861 if test -n "${x_libraries}"; then
2862 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2863 else
2864 echo "  Where do we find X Windows libraries?                   Standard dirs"
2865 fi
2866
2867 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2868 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2869 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2870 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2871 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2872 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2873 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2874 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2875 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2876
2877 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2878 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2879 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2880 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2881
2882 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2883 echo
2884
2885 if test $USE_XASSERTS = yes; then
2886    echo "  Compiling with asserts turned on."
2887    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2888 fi
2889
2890 echo
2891
2892 if test "$USE_X_TOOLKIT" = GTK; then
2893   case "$canonical" in
2894   *cygwin*)
2895     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2896   will probably get a crash on startup.  If this happens, please use another
2897   toolkit for Emacs.  See etc/PROBLEMS for more information."
2898   ;;
2899   esac
2900 fi
2901
2902 if test "$HAVE_NS" = "yes"; then
2903    echo
2904    echo "You must run \"make install\" in order to test the built application.
2905 The installed application will go to nextstep/Emacs.app and can be
2906 run or moved from there."
2907    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2908       echo "The application will be fully self-contained."
2909     else
2910       echo "The lisp resources for the application will be installed under ${prefix}.
2911 You may need to run \"make install\" with sudo.  The application will fail
2912 to run if these resources are not installed."
2913    fi
2914    echo
2915 fi
2916
2917 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2918   echo "D-Bus integration has been tested for GNU/Linux only."
2919   echo
2920 fi
2921
2922
2923 # Remove any trailing slashes in these variables.
2924 [test "${prefix}" != NONE &&
2925   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2926 test "${exec_prefix}" != NONE &&
2927   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2928
2929 # Now get this: Some word that is part of the ${srcdir} directory name
2930 # or the ${configuration} value might, just might, happen to be an
2931 # identifier like `sun4' or `i386' or something, and be predefined by
2932 # the C preprocessor to some helpful value like 1, or maybe the empty
2933 # string.  Needless to say consequent macro substitutions are less
2934 # than conducive to the makefile finding the correct directory.
2935 [cpp_undefs="`echo $srcdir $configuration $canonical |
2936   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2937   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2938
2939 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2940 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2941 ## from Makefile.c can correctly provide the arg `-traditional' to the
2942 ## C preprocessor.
2943
2944 AC_EGREP_CPP(yes..yes,
2945         [yes..yes],
2946         CPP_NEED_TRADITIONAL=no,
2947         CPP_NEED_TRADITIONAL=yes)
2948
2949 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2950         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2951         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2952         lwlib/Makefile lisp/Makefile leim/Makefile, [
2953
2954 ### Make the necessary directories, if they don't exist.
2955 for dir in etc lisp ; do
2956   test -d ${dir} || mkdir ${dir}
2957 done
2958
2959 # Build src/Makefile from ${srcdir}/src/Makefile.c
2960 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2961 # This must be done after src/config.h is built, since we rely on that file.
2962
2963 echo creating src/epaths.h
2964 ${MAKE-make} epaths-force
2965
2966 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2967 # `..' to `. .'  unless invoked with -traditional
2968
2969 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2970   CPPFLAGS="$CPPFLAGS -traditional"
2971 fi
2972
2973 echo creating lib-src/Makefile
2974 ( cd lib-src
2975   rm -f junk.c junk1.c junk2.c
2976   sed -e '/start of cpp stuff/q' \
2977       < Makefile.c > junk1.c
2978   sed -e '1,/start of cpp stuff/d'\
2979       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2980       < Makefile.c > junk.c
2981   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2982       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2983   cat junk1.c junk2.c > Makefile.new
2984   rm -f junk.c junk1.c junk2.c
2985   chmod 444 Makefile.new
2986   mv -f Makefile.new Makefile
2987 )
2988
2989 echo creating src/Makefile
2990 ( cd src
2991   rm -f junk.c junk1.c junk2.c
2992   sed -e '/start of cpp stuff/q' \
2993       < Makefile.c > junk1.c
2994   sed -e '1,/start of cpp stuff/d'\
2995       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2996       < Makefile.c > junk.c
2997   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2998       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2999   cat junk1.c junk2.c > Makefile.new
3000   rm -f junk.c junk1.c junk2.c
3001   chmod 444 Makefile.new
3002   mv -f Makefile.new Makefile
3003 )
3004
3005 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3006   echo creating src/.gdbinit
3007   echo source $srcdir/src/.gdbinit > src/.gdbinit
3008 fi
3009
3010 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3011
3012 m4_if(dnl       Do not change this comment
3013    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3014 )dnl