lisp/ediff-merg.el

   1 ;;; ediff-merg.el --- merging utilities
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (provide 'ediff-merg)
  30
  31 ;; compiler pacifier
  32 (defvar ediff-window-A)
  33 (defvar ediff-window-B)
  34 (defvar ediff-window-C)
  35 (defvar ediff-merge-window-share)
  36 (defvar ediff-window-config-saved)
  37
  38 (eval-when-compile
  39   (let ((load-path (cons (expand-file-name ".") load-path)))
  40     (or (featurep 'ediff-init)
  41         (load "ediff-init.el" nil nil 'nosuffix))
  42     (or (featurep 'ediff-util)
  43         (load "ediff-util.el" nil nil 'nosuffix))
  44     ))
  45 ;; end pacifier
  46
  47 (require 'ediff-init)
  48
  49 (defcustom ediff-quit-merge-hook 'ediff-maybe-save-and-delete-merge
  50   "*Hooks to run before quitting a merge job.
  51 The most common use is to save and delete the merge buffer."
  52   :type 'hook
  53   :group 'ediff-merge)
  54
  55
  56 (defcustom ediff-default-variant 'combined
  57   "*The variant to be used as a default for buffer C in merging.
  58 Valid values are the symbols `default-A', `default-B', and `combined'."
  59   :type '(radio (const default-A) (const default-B) (const combined))
  60   :group 'ediff-merge)
  61
  62 (defcustom ediff-combination-pattern
  63   '("<<<<<<< variant A" A ">>>>>>> variant B" B  "####### Ancestor" Ancestor "======= end")
  64   "*Pattern to be used for combining difference regions in buffers A and B.
  65 The value must be a list of the form
  66 (STRING1 bufspec1  STRING2 bufspec2 STRING3 bufspec3 STRING4)
  67 where bufspec is the symbol A, B, or Ancestor. For instance, if the value is
  68 '(STRING1 A  STRING2 Ancestor STRING3 B STRING4) then the
  69 combined text will look like this:
  70
  71 STRING1
  72 diff region from variant A
  73 STRING2
  74 diff region from the ancestor
  75 STRING3
  76 diff region from variant B
  77 STRING4
  78 "
  79   :type '(choice (list string symbol string symbol string)
  80                  (list string symbol string symbol string symbol string))
  81   :group 'ediff-merge)
  82
  83 (defcustom ediff-show-clashes-only nil
  84   "*If t, show only those diff regions where both buffers disagree with the ancestor.
  85 This means that regions that have status prefer-A or prefer-B will be
  86 skipped over.  nil means show all regions."
  87   :type 'boolean
  88   :group 'ediff-merge
  89   )
  90 (make-variable-buffer-local 'ediff-show-clashes-only)
  91
  92 (defcustom ediff-skip-merge-regions-that-differ-from-default nil
  93   "*If t, show only the regions that have not been changed by the user.
  94 A region is considered to have been changed if it is different from the current
  95 default (`default-A', `default-B', `combined') and it hasn't been marked as
  96 `prefer-A' or `prefer-B'.
  97 A region is considered to have been changed also when it is marked as
  98 as `prefer-A', but is different from the corresponding difference region in
  99 Buffer A or if it is marked as `prefer-B' and is different from the region in
 100 Buffer B."
 101   :type 'boolean
 102   :group 'ediff-merge
 103   )
 104 (make-variable-buffer-local 'ediff-skip-merge-regions-that-differ-from-default)
 105
 106 ;; check if there is no clash between the ancestor and one of the variants.
 107 ;; if it is not a merge job then return true
 108 (defsubst ediff-merge-region-is-non-clash (n)
 109   (if (ediff-merge-job)
 110       (string-match "prefer" (or (ediff-get-state-of-merge n) ""))
 111     t))
 112
 113 ;; If ediff-show-clashes-only, check if there is no clash between the ancestor
 114 ;; and one of the variants.
 115 (defsubst ediff-merge-region-is-non-clash-to-skip (n)
 116   (and ediff-show-clashes-only
 117        (ediff-merge-region-is-non-clash n)))
 118
 119 ;; If ediff-skip-changed-regions, check if the merge region differs from
 120 ;; the current default. If a region is different from the default, it means
 121 ;; that the user has made determination as to how to merge for this particular
 122 ;; region.
 123 (defsubst ediff-skip-merge-region-if-changed-from-default-p (n)
 124   (and ediff-skip-merge-regions-that-differ-from-default
 125        (ediff-merge-changed-from-default-p n 'prefers-too)))
 126
 127
 128 (defun ediff-get-combined-region (n)
 129   (let ((pattern-list ediff-combination-pattern)
 130         (combo-region "")
 131         (err-msg
 132          "ediff-combination-pattern: Invalid format. Please consult the documentation")
 133         region-delim region-spec)
 134
 135     (if (< (length pattern-list) 5)
 136         (error err-msg))
 137
 138     (while (> (length pattern-list) 2)
 139       (setq region-delim (nth 0 pattern-list)
 140             region-spec (nth 1 pattern-list))
 141       (or (and (stringp region-delim) (memq region-spec '(A B Ancestor)))
 142           (error err-msg))
 143
 144       (condition-case nil
 145           (setq combo-region
 146                 (concat combo-region
 147                         region-delim "\n"
 148                         (ediff-get-region-contents
 149                          n region-spec ediff-control-buffer)))
 150         (error ""))
 151       (setq pattern-list (cdr (cdr pattern-list)))
 152       )
 153
 154     (setq region-delim (nth 0 pattern-list))
 155     (or (stringp region-delim)
 156         (error err-msg))
 157     (setq combo-region (concat combo-region region-delim "\n"))
 158   ))
 159
 160 ;;(defsubst ediff-make-combined-diff (regA regB)
 161 ;;  (concat (nth 0 ediff-combination-pattern) "\n"
 162 ;;        regA
 163 ;;        (nth 1 ediff-combination-pattern) "\n"
 164 ;;        regB
 165 ;;        (nth 2 ediff-combination-pattern) "\n"))
 166
 167 (defsubst ediff-set-state-of-all-diffs-in-all-buffers (ctl-buf)
 168   (let ((n 0))
 169     (while (< n ediff-number-of-differences)
 170       (ediff-set-state-of-diff-in-all-buffers n ctl-buf)
 171       (setq n (1+ n)))))
 172
 173 (defun ediff-set-state-of-diff-in-all-buffers (n ctl-buf)
 174   (let ((regA (ediff-get-region-contents n 'A ctl-buf))
 175         (regB (ediff-get-region-contents n 'B ctl-buf))
 176         (regC (ediff-get-region-contents n 'C ctl-buf)))
 177     (cond ((and (string= regA regB) (string= regA  regC))
 178            (ediff-set-state-of-diff n 'A "=diff(B)")
 179            (ediff-set-state-of-diff n 'B "=diff(C)")
 180            (ediff-set-state-of-diff n 'C "=diff(A)"))
 181           ((string= regA regB)
 182            (ediff-set-state-of-diff n 'A "=diff(B)")
 183            (ediff-set-state-of-diff n 'B "=diff(A)")
 184            (ediff-set-state-of-diff n 'C nil))
 185           ((string= regA regC)
 186            (ediff-set-state-of-diff n 'A "=diff(C)")
 187            (ediff-set-state-of-diff n 'C "=diff(A)")
 188            (ediff-set-state-of-diff n 'B nil))
 189           ((string= regB regC)
 190            (ediff-set-state-of-diff n 'C "=diff(B)")
 191            (ediff-set-state-of-diff n 'B "=diff(C)")
 192            (ediff-set-state-of-diff n 'A nil))
 193           ((string= regC (ediff-get-combined-region n))
 194            (ediff-set-state-of-diff n 'A nil)
 195              (ediff-set-state-of-diff n 'B nil)
 196              (ediff-set-state-of-diff n 'C "=diff(A+B)"))
 197           (t (ediff-set-state-of-diff n 'A nil)
 198              (ediff-set-state-of-diff n 'B nil)
 199              (ediff-set-state-of-diff n 'C nil)))
 200     ))
 201
 202 (defun ediff-set-merge-mode ()
 203   (normal-mode t)
 204   (remove-hook 'local-write-file-hooks 'ediff-set-merge-mode))
 205
 206
 207 ;; Go over all diffs starting with DIFF-NUM and copy regions into buffer C
 208 ;; according to the state of the difference.
 209 ;; Since ediff-copy-diff refuses to copy identical diff regions, there is
 210 ;; no need to optimize ediff-do-merge any further.
 211 ;;
 212 ;; If re-merging, change state of merge in all diffs starting with
 213 ;; DIFF-NUM, except those where the state is prefer-* or where it is
 214 ;; `default-*' or `combined' but the buf C region appears to be modified
 215 ;; since last set by default.
 216 (defun ediff-do-merge (diff-num &optional remerging)
 217   (if (< diff-num 0) (setq diff-num 0))
 218   (let ((n diff-num)
 219         ;;(default-state-of-merge (format "%S" ediff-default-variant))
 220         do-not-copy state-of-merge)
 221     (while (< n ediff-number-of-differences)
 222       (setq do-not-copy nil) ; reset after each cycle
 223       (if (= (mod n 10) 0)
 224           (message "%s buffers A & B into C ... region %d of %d"
 225                    (if remerging "Re-merging" "Merging")
 226                    n
 227                    ediff-number-of-differences))
 228
 229       (setq state-of-merge (ediff-get-state-of-merge n))
 230
 231       (if remerging
 232           ;;(let ((reg-A (ediff-get-region-contents n 'A ediff-control-buffer))
 233           ;;    (reg-B (ediff-get-region-contents n 'B ediff-control-buffer))
 234           ;;    (reg-C (ediff-get-region-contents n 'C ediff-control-buffer)))
 235           (let ()
 236
 237             ;; if region was edited since it was first set by default
 238             (if (or (ediff-merge-changed-from-default-p n)
 239                     ;; was preferred
 240                     (string-match "prefer" state-of-merge))
 241                 ;; then ignore
 242                 (setq do-not-copy t))
 243
 244             ;; change state of merge for this diff, if necessary
 245             (if (and (string-match "\\(default\\|combined\\)" state-of-merge)
 246                      (not do-not-copy))
 247                 (ediff-set-state-of-merge
 248                  n (format "%S" ediff-default-variant)))
 249             ))
 250
 251       ;; state-of-merge may have changed via ediff-set-state-of-merge, so
 252       ;; check it once again
 253       (setq state-of-merge (ediff-get-state-of-merge n))
 254
 255       (or do-not-copy
 256           (if (string= state-of-merge "combined")
 257               ;; use n+1 because ediff-combine-diffs works via user numbering
 258               ;; of diffs, which is 1+ to what ediff uses internally
 259               (ediff-combine-diffs (1+ n) 'batch)
 260             (ediff-copy-diff
 261              n (if (string-match "-A" state-of-merge) 'A 'B) 'C 'batch)))
 262       (setq n (1+ n)))
 263     (message "Merging buffers A & B into C ... Done")
 264     ))
 265
 266
 267 (defun ediff-re-merge ()
 268   "Remerge unmodified diff regions using a new default.  Start with the current region."
 269   (interactive)
 270   (let* ((default-variant-alist
 271            (list '("default-A") '("default-B") '("combined")))
 272          (actual-alist
 273           (delete (list (symbol-name ediff-default-variant))
 274                   default-variant-alist)))
 275     (setq ediff-default-variant
 276           (intern
 277            (completing-read
 278             (format "Current merge default is `%S'.  New default: "
 279                     ediff-default-variant)
 280             actual-alist nil 'must-match)))
 281     (ediff-do-merge ediff-current-difference 'remerge)
 282     (ediff-recenter)
 283   ))
 284
 285 (defun ediff-shrink-window-C (arg)
 286   "Shrink window C to just one line.
 287 With a prefix argument, returns window C to its normal size.
 288 Used only for merging jobs."
 289   (interactive "P")
 290   (if (not ediff-merge-job)
 291       (error "ediff-shrink-window-C can be used only for merging jobs"))
 292   (cond ((eq arg '-) (setq arg -1))
 293         ((not (numberp arg)) (setq arg nil)))
 294   (cond ((null arg)
 295          (let ((ediff-merge-window-share
 296                 (if (< (window-height ediff-window-C) 3)
 297                     ediff-merge-window-share 0)))
 298            (setq ediff-window-config-saved "") ; force redisplay
 299            (ediff-recenter 'no-rehighlight)))
 300         ((and (< arg 0) (> (window-height ediff-window-C) 2))
 301          (setq ediff-merge-window-share (* ediff-merge-window-share 0.9))
 302          (setq ediff-window-config-saved "") ; force redisplay
 303          (ediff-recenter 'no-rehighlight))
 304         ((and (> arg 0) (> (window-height ediff-window-A) 2))
 305          (setq ediff-merge-window-share (* ediff-merge-window-share 1.1))
 306          (setq ediff-window-config-saved "") ; force redisplay
 307          (ediff-recenter 'no-rehighlight))))
 308
 309
 310 ;; N here is the user's region number.  It is 1+ what Ediff uses internally.
 311 (defun ediff-combine-diffs (n &optional batch-invocation)
 312   "Combine Nth diff regions of buffers A and B and place the combination in C.
 313 N is a prefix argument.  If nil, combine the current difference regions.
 314 Combining is done according to the specifications in variable
 315 `ediff-combination-pattern'."
 316   (interactive "P")
 317   (setq n (if (numberp n) (1- n) ediff-current-difference))
 318
 319   (let (reg-combined)
 320     ;;(setq regA (ediff-get-region-contents n 'A ediff-control-buffer)
 321     ;;    regB (ediff-get-region-contents n 'B ediff-control-buffer))
 322     ;;(setq reg-combined (ediff-make-combined-diff regA regB))
 323     (setq reg-combined (ediff-get-combined-region n))
 324
 325     (ediff-copy-diff n nil 'C batch-invocation reg-combined))
 326     (or batch-invocation (ediff-jump-to-difference (1+ n))))
 327
 328
 329 ;; Checks if the region in buff C looks like a combination of the regions
 330 ;; in buffers A and B.  Return a list (reg-a-beg reg-a-end reg-b-beg reg-b-end)
 331 ;; These refer to where the delimiters for region A, B, Ancestor start and end
 332 ;; in buffer C
 333 (defun ediff-looks-like-combined-merge (region-num)
 334   (if ediff-merge-job
 335       (let ((combined (string-match (regexp-quote "(A+B)")
 336                                     (or (ediff-get-state-of-diff region-num 'C)
 337                                         "")))
 338             (mrgreg-beg (ediff-get-diff-posn 'C 'beg region-num))
 339             (mrgreg-end (ediff-get-diff-posn 'C 'end region-num))
 340             (pattern-list ediff-combination-pattern)
 341             delim reg-beg reg-end delim-regs-list)
 342
 343         (if combined
 344             (ediff-with-current-buffer ediff-buffer-C
 345               (while pattern-list
 346                 (goto-char mrgreg-beg)
 347                 (setq delim (nth 0 pattern-list))
 348                 (search-forward delim mrgreg-end 'noerror)
 349                 (setq reg-beg (match-beginning 0))
 350                 (setq reg-end (match-end 0))
 351                 (if (and reg-beg reg-end)
 352                     (setq delim-regs-list
 353                           ;; in reverse
 354                           (cons reg-end (cons reg-beg delim-regs-list))))
 355                 (if (> (length pattern-list) 1)
 356                     (setq pattern-list (cdr (cdr pattern-list)))
 357                   (setq pattern-list nil))
 358                 )))
 359
 360         (reverse delim-regs-list)
 361         )))
 362
 363 (eval-when-compile (defvar state-of-merge)) ; dynamic var
 364
 365 ;; Check if the non-preferred merge has been modified since originally set.
 366 ;; This affects only the regions that are marked as default-A/B or combined.
 367 ;; If PREFERS-TOO is non-nil, then look at the regions marked as prefers-A/B as
 368 ;; well.
 369 (defun ediff-merge-changed-from-default-p (diff-num &optional prefers-too)
 370   (let ((reg-A (ediff-get-region-contents diff-num 'A ediff-control-buffer))
 371         (reg-B (ediff-get-region-contents diff-num 'B ediff-control-buffer))
 372         (reg-C (ediff-get-region-contents diff-num 'C ediff-control-buffer)))
 373
 374     (setq state-of-merge (ediff-get-state-of-merge diff-num))
 375
 376     ;; if region was edited since it was first set by default
 377     (or (and (string= state-of-merge "default-A")
 378              (not (string= reg-A reg-C)))
 379         (and (string= state-of-merge "default-B")
 380              (not (string= reg-B reg-C)))
 381         (and (string= state-of-merge "combined")
 382              ;;(not (string= (ediff-make-combined-diff reg-A reg-B) reg-C)))
 383              (not (string= (ediff-get-combined-region diff-num) reg-C)))
 384         (and prefers-too
 385              (string= state-of-merge "prefer-A")
 386              (not (string= reg-A reg-C)))
 387         (and prefers-too
 388              (string= state-of-merge "prefer-B")
 389              (not (string= reg-B reg-C)))
 390         )))
 391
 392
 393 ;;; Local Variables:
 394 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
 395 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
 396 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
 397 ;;; End:
 398
 399 ;;; arch-tag: 9b798cf9-02ba-487f-a62e-b63aa823dbfb
 400 ;;; ediff-merg.el ends here