lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 98, 99, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file parses the command line and gets Emacs running.  Options on
  29 ;; the command line are handled in precedence order.  The order is the
  30 ;; one in the list below; first described means first handled.  Options
  31 ;; within each category (delimited by a bar) are handled in the order
  32 ;; encountered on the command line.
  33
  34 ;; -------------------------
  35 ;; -version                  Print Emacs version to stderr, then exit
  36 ;; --version                 successfully right away.
  37 ;;                           This option is handled by emacs.c
  38 ;; -------------------------
  39 ;; -help                     Print a short usage description and exit
  40 ;; --help                    successfully right away.
  41 ;;                           This option is handled by emacs.c
  42 ;; -------------------------
  43 ;; -nl                       Do not use shared memory (for systems that
  44 ;; -no-shared-memory         support this) for the dumped Emacs data.
  45 ;;                           This option is handled by emacs.c
  46 ;;
  47 ;; -map                      For VMS.
  48 ;; --map-data                This option is handled by emacs.c
  49 ;; -------------------------
  50 ;; -t FILE                   Use FILE as the name of the terminal.
  51 ;; --terminal FILE           Using this implies "-nw" also.
  52 ;;                           This option is handled by emacs.c
  53 ;; -------------------------
  54 ;; -d DISPNAME               Use DISPNAME as the name of the X
  55 ;; -display DISPNAME         display for the initial frame.
  56 ;; --display DISPNAME        This option is handled by emacs.c
  57 ;; -------------------------
  58 ;; -nw                       Do not use a windows system (but use the
  59 ;; --no-windows              terminal instead.)
  60 ;;                           This option is handled by emacs.c
  61 ;; -------------------------
  62 ;; -batch                    Execute noninteractively (messages go to stdout,
  63 ;; --batch                   variable noninteractive set to t)
  64 ;;                           This option is handled by emacs.c
  65 ;; -------------------------
  66 ;; -q                        Do not load user's init file and do not load
  67 ;; -no-init-file             "default.el".  Regardless of this switch,
  68 ;; --no-init-file            "site-start" is still loaded.
  69 ;; -------------------------
  70 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  71 ;; --no-site-file            way to prevent loading that file.)
  72 ;; -------------------------
  73 ;; -u USER                   Load USER's init file instead of the init
  74 ;; -user USER                file belonging to the user starting Emacs.
  75 ;; --user USER
  76 ;; -------------------------
  77 ;; -debug-init               Don't catch errors in init files; let the
  78 ;; --debug-init              debugger run.
  79 ;; -------------------------
  80 ;; -i ICONTYPE               Set type of icon using when Emacs is
  81 ;; -itype ICONTYPE           iconified under X.
  82 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  83 ;;
  84 ;; -iconic                   Start Emacs iconified.
  85 ;; --iconic                  This option is passed on to term/x-win.el
  86 ;; -------------------------
  87 ;; Various X options for colors/fonts/geometry/title etc.
  88 ;; These options are passed on to term/x-win.el which see.
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;; -visit FILE
  92 ;; --visit FILE
  93 ;; -file FILE
  94 ;; --file FILE
  95 ;;
  96 ;; -L DIRNAME                Add DIRNAME to load-path
  97 ;; -directory DIRNAME
  98 ;; --directory DIRNAME
  99 ;;
 100 ;; -l FILE                   Load and execute the Emacs lisp code
 101 ;; -load FILE                in FILE.
 102 ;; --load FILE
 103 ;;
 104 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 105 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 106 ;; --funcall FUNC            and should not be used.  (It's a typo
 107 ;; -e FUNC                   promoted to a feature.)
 108 ;;
 109 ;; -eval FORM                Execute Emacs lisp form FORM.
 110 ;; --eval FORM
 111 ;; -execute EXPR
 112 ;; --execute EXPR
 113 ;;
 114 ;; -insert FILE              Insert the contents of FILE into buffer.
 115 ;; --insert FILE
 116 ;; -------------------------
 117 ;; -kill                     Kill (exit) Emacs right away.
 118 ;; --kill
 119 ;; -------------------------
 120
 121 ;;; Code:
 122
 123 (setq top-level '(normal-top-level))
 124
 125 (defvar command-line-processed nil
 126   "Non-nil once command line has been processed")
 127
 128 (defgroup initialization nil
 129   "Emacs start-up procedure"
 130   :group 'internal)
 131
 132 (defcustom inhibit-startup-message nil
 133   "*Non-nil inhibits the initial startup message.
 134 This is for use in your personal init file, once you are familiar
 135 with the contents of the startup message."
 136   :type 'boolean
 137   :group 'initialization)
 138
 139 (defcustom inhibit-startup-echo-area-message nil
 140   "*Non-nil inhibits the initial startup echo area message.
 141 Setting this variable takes effect
 142 only if you do it with the customization buffer
 143 or if your `.emacs' file contains a line of this form:
 144  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 145 If your `.emacs' file is byte-compiled, use the following form instead:
 146  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 147 Thus, someone else using a copy of your `.emacs' file will see
 148 the startup message unless he personally acts to inhibit it."
 149   :type '(choice (const :tag "Don't inhibit")
 150                  (string :tag "Enter your user name, to inhibit"))
 151   :group 'initialization)
 152
 153 (defcustom inhibit-default-init nil
 154   "*Non-nil inhibits loading the `default' library."
 155   :type 'boolean
 156   :group 'initialization)
 157
 158 (defcustom inhibit-startup-buffer-menu nil
 159   "*Non-nil inhibits display of buffer list when more than 2 files are loaded."
 160   :type 'boolean
 161   :group 'initialization)
 162
 163 (defvar command-switch-alist nil
 164   "Alist of command-line switches.
 165 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 166 HANDLER-FUNCTION receives switch name as sole arg;
 167 remaining command-line args are in the variable `command-line-args-left'.")
 168
 169 (defvar command-line-args-left nil
 170   "List of command-line args not yet processed.")
 171
 172 (defvar command-line-functions nil    ;; lrs 7/31/89
 173   "List of functions to process unrecognized command-line arguments.
 174 Each function should access the dynamically bound variables
 175 `argi' (the current argument) and `command-line-args-left' (the remaining
 176 arguments).  The function should return non-nil only if it recognizes and
 177 processes `argi'.  If it does so, it may consume successive arguments by
 178 altering `command-line-args-left' to remove them.")
 179
 180 (defvar command-line-default-directory nil
 181   "Default directory to use for command line arguments.
 182 This is normally copied from `default-directory' when Emacs starts.")
 183
 184 ;;; This is here, rather than in x-win.el, so that we can ignore these
 185 ;;; options when we are not using X.
 186 (defconst command-line-x-option-alist
 187   '(("-bw" 1 x-handle-numeric-switch border-width)
 188     ("-d" 1 x-handle-display)
 189     ("-display" 1 x-handle-display)
 190     ("-name" 1 x-handle-name-switch)
 191     ("-title" 1 x-handle-switch title)
 192     ("-T" 1 x-handle-switch title)
 193     ("-r" 0 x-handle-switch reverse t)
 194     ("-rv" 0 x-handle-switch reverse t)
 195     ("-reverse" 0 x-handle-switch reverse t)
 196     ("-reverse-video" 0 x-handle-switch reverse t)
 197     ("-fn" 1 x-handle-switch font)
 198     ("-font" 1 x-handle-switch font)
 199     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 200     ("-g" 1 x-handle-geometry)
 201     ("-lsp" 1 x-handle-numeric-switch line-spacing)
 202     ("-geometry" 1 x-handle-geometry)
 203     ("-fg" 1 x-handle-switch foreground-color)
 204     ("-foreground" 1 x-handle-switch foreground-color)
 205     ("-bg" 1 x-handle-switch background-color)
 206     ("-background" 1 x-handle-switch background-color)
 207     ("-ms" 1 x-handle-switch mouse-color)
 208     ("-itype" 0 x-handle-switch icon-type t)
 209     ("-i" 0 x-handle-switch icon-type t)
 210     ("-iconic" 0 x-handle-iconic)
 211     ("-xrm" 1 x-handle-xrm-switch)
 212     ("-cr" 1 x-handle-switch cursor-color)
 213     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 214     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 215     ("-bd" 1 x-handle-switch)
 216     ("--border-width" 1 x-handle-numeric-switch border-width)
 217     ("--display" 1 x-handle-display)
 218     ("--name" 1 x-handle-name-switch)
 219     ("--title" 1 x-handle-switch title)
 220     ("--reverse-video" 0 x-handle-switch reverse t)
 221     ("--font" 1 x-handle-switch font)
 222     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 223     ("--geometry" 1 x-handle-geometry)
 224     ("--foreground-color" 1 x-handle-switch foreground-color)
 225     ("--background-color" 1 x-handle-switch background-color)
 226     ("--mouse-color" 1 x-handle-switch mouse-color)
 227     ("--icon-type" 0 x-handle-switch icon-type t)
 228     ("--iconic" 0 x-handle-iconic)
 229     ("--xrm" 1 x-handle-xrm-switch)
 230     ("--cursor-color" 1 x-handle-switch cursor-color)
 231     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 232     ("--line-spacing" 1 x-handle-numeric-switch line-spacing)
 233     ("--border-color" 1 x-handle-switch border-width))
 234   "Alist of X Windows options.
 235 Each element has the form
 236   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 237 where NAME is the option name string, NUMARGS is the number of arguments
 238 that the option accepts, HANDLER is a function to call to handle the option.
 239 FRAME-PARAM (optional) is the frame parameter this option specifies,
 240 and VALUE is the value which is given to that frame parameter
 241 \(most options use the argument for this, so VALUE is not present).")
 242
 243 (defvar before-init-hook nil
 244   "Normal hook run after handling urgent options but before loading init files.")
 245
 246 (defvar after-init-hook nil
 247   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 248 There is no `condition-case' around the running of these functions;
 249 therefore, if you set `debug-on-error' non-nil in `.emacs',
 250 an error in one of these functions will invoke the debugger.")
 251
 252 (defvar emacs-startup-hook nil
 253   "Normal hook run after loading init files and handling the command line.")
 254
 255 (defvar term-setup-hook nil
 256   "Normal hook run after loading terminal-specific Lisp code.
 257 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 258 so as to override the definitions made by the terminal-specific file.
 259 Emacs never sets this variable itself.")
 260
 261 (defvar keyboard-type nil
 262   "The brand of keyboard you are using.
 263 This variable is used to define
 264 the proper function and keypad keys for use under X.  It is used in a
 265 fashion analogous to the environment variable TERM.")
 266
 267 (defvar window-setup-hook nil
 268   "Normal hook run to initialize window system display.
 269 Emacs runs this hook after processing the command line arguments and loading
 270 the user's init file.")
 271
 272 (defcustom initial-major-mode 'lisp-interaction-mode
 273   "Major mode command symbol to use for the initial *scratch* buffer."
 274   :type 'function
 275   :group 'initialization)
 276
 277 (defcustom init-file-user nil
 278   "Identity of user whose `.emacs' file is or was read.
 279 The value is nil if `-q' or `--no-init-file' was specified,
 280 meaning do not load any init file.
 281
 282 Otherwise, the value may be the null string, meaning use the init file
 283 for the user that originally logged in, or it may be a
 284 string containing a user's name meaning use that person's init file.
 285
 286 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 287 evaluates to the name of the directory where the `.emacs' file was
 288 looked for.
 289
 290 Setting `init-file-user' does not prevent Emacs from loading
 291 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 292   :type '(choice (const :tag "none" nil) string)
 293   :group 'initialization)
 294
 295 (defcustom site-run-file "site-start"
 296   "File containing site-wide run-time initializations.
 297 This file is loaded at run-time before `~/.emacs'.  It contains inits
 298 that need to be in place for the entire site, but which, due to their
 299 higher incidence of change, don't make sense to load into emacs'
 300 dumped image.  Thus, the run-time load order is: 1. file described in
 301 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 302
 303 Don't use the `site-start.el' file for things some users may not like.
 304 Put them in `default.el' instead, so that users can more easily
 305 override them.  Users can prevent loading `default.el' with the `-q'
 306 option or by setting `inhibit-default-init' in their own init files,
 307 but inhibiting `site-start.el' requires `--no-site-file', which
 308 is less convenient."
 309   :type '(choice (const :tag "none" nil) string)
 310   :group 'initialization)
 311
 312 (defcustom mail-host-address nil
 313   "*Name of this machine, for purposes of naming users."
 314   :type '(choice (const nil) string)
 315   :group 'mail)
 316
 317 (defcustom user-mail-address nil
 318   "*Full mailing address of this user.
 319 This is initialized based on `mail-host-address',
 320 after your init file is read, in case it sets `mail-host-address'."
 321   :type 'string
 322   :group 'mail)
 323
 324 (defcustom auto-save-list-file-prefix
 325   (cond ((eq system-type 'ms-dos)
 326          ;; MS-DOS cannot have initial dot, and allows only 8.3 names
 327          "~/_emacs.d/auto-save.list/_s")
 328         (t
 329          "~/.emacs.d/auto-save-list/.saves-"))
 330   "Prefix for generating `auto-save-list-file-name'.
 331 This is used after reading your `.emacs' file to initialize
 332 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 333 if you have not already set `auto-save-list-file-name' yourself.
 334 Directories in the prefix will be created if necessary.
 335 Set this to nil if you want to prevent `auto-save-list-file-name'
 336 from being initialized."
 337   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 338                  string)
 339   :group 'auto-save)
 340
 341 (defvar init-file-debug nil)
 342
 343 (defvar init-file-had-error nil)
 344
 345 (defvar normal-top-level-add-subdirs-inode-list nil)
 346
 347 (defun normal-top-level-add-subdirs-to-load-path ()
 348   "Add all subdirectories of current directory to `load-path'.
 349 More precisely, this uses only the subdirectories whose names
 350 start with letters or digits; it excludes any subdirectory named `RCS'
 351 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 352   (let (dirs
 353         attrs
 354         (pending (list default-directory)))
 355     ;; This loop does a breadth-first tree walk on DIR's subtree,
 356     ;; putting each subdir into DIRS as its contents are examined.
 357     (while pending
 358       (setq dirs (cons (car pending) dirs))
 359       (setq pending (cdr pending))
 360       (let* ((this-dir (car dirs))
 361              (contents (directory-files this-dir))
 362              (default-directory this-dir)
 363              (canonicalized (and (eq system-type 'windows-nt)
 364                                  (untranslated-canonical-name this-dir))))
 365         ;; The Windows version doesn't report meaningful inode
 366         ;; numbers, so use the canonicalized absolute file name of the
 367         ;; directory instead.
 368         (setq attrs (or canonicalized
 369                         (nthcdr 10 (file-attributes this-dir))))
 370         (unless (member attrs normal-top-level-add-subdirs-inode-list)
 371           (setq normal-top-level-add-subdirs-inode-list
 372                 (cons attrs normal-top-level-add-subdirs-inode-list))
 373           (while contents
 374             ;; The lower-case variants of RCS and CVS are for DOS/Windows.
 375             (unless (member (car contents) '("." ".." "RCS" "CVS" "rcs" "cvs"))
 376               (when (and (string-match "\\`[[:alnum:]]" (car contents))
 377                          ;; Avoid doing a `stat' when it isn't necessary
 378                          ;; because that can cause trouble when an NFS server
 379                          ;; is down.
 380                          (not (string-match "\\.elc?\\'" (car contents)))
 381                          (file-directory-p (car contents)))
 382                 (let ((expanded (expand-file-name (car contents))))
 383                   (unless (file-exists-p (expand-file-name ".nosearch"
 384                                                            expanded))
 385                     (setq pending (nconc pending (list expanded)))))))
 386             (setq contents (cdr contents))))))
 387     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 388
 389 ;; This function is called from a subdirs.el file.
 390 ;; It assumes that default-directory is the directory
 391 ;; in which the subdirs.el file exists,
 392 ;; and it adds to load-path the subdirs of that directory
 393 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 394 (defun normal-top-level-add-to-load-path (dirs)
 395   (let ((tail load-path)
 396         (thisdir (directory-file-name default-directory)))
 397     (while (and tail
 398                 ;;Don't go all the way to the nil terminator.
 399                 (cdr tail)
 400                 (not (equal thisdir (car tail)))
 401                 (not (and (memq system-type '(ms-dos windows-nt))
 402                           (equal (downcase thisdir) (downcase (car tail))))))
 403       (setq tail (cdr tail)))
 404     ;;Splice the new section in.
 405     (when tail
 406       (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail))))))
 407
 408 (defun normal-top-level ()
 409   (if command-line-processed
 410       (message "Back to top level.")
 411     (setq command-line-processed t)
 412     ;; Give *Messages* the same default-directory as *scratch*,
 413     ;; just to keep things predictable.
 414     (let ((dir default-directory))
 415       (save-excursion
 416         (set-buffer (get-buffer "*Messages*"))
 417         (setq default-directory dir)))
 418     ;; For root, preserve owner and group when editing files.
 419     (if (equal (user-uid) 0)
 420         (setq backup-by-copying-when-mismatch t))
 421     ;; Look in each dir in load-path for a subdirs.el file.
 422     ;; If we find one, load it, which will add the appropriate subdirs
 423     ;; of that dir into load-path,
 424     ;; Look for a leim-list.el file too.  Loading it will register
 425     ;; available input methods.
 426     (let ((tail load-path)
 427           new)
 428       (while tail
 429         (setq new (cons (car tail) new))
 430         (condition-case nil
 431             (let ((default-directory (car tail)))
 432               (load (expand-file-name "subdirs.el" (car tail)) t t t)))
 433         (condition-case nil
 434             (let ((default-directory (car tail)))
 435               (load (expand-file-name "leim-list.el" (car tail)) t t t)))
 436         (setq tail (cdr tail))))
 437     (if (not (eq system-type 'vax-vms))
 438         (progn
 439           ;; If the PWD environment variable isn't accurate, delete it.
 440           (let ((pwd (getenv "PWD")))
 441             (and (stringp pwd)
 442                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 443                  ;; describes the directory linked to, not FOO itself.
 444                  (or (equal (file-attributes
 445                              (concat (file-name-as-directory pwd) "."))
 446                             (file-attributes
 447                              (concat (file-name-as-directory default-directory)
 448                                      ".")))
 449                      (setq process-environment
 450                            (delete (concat "PWD=" pwd)
 451                                    process-environment)))))))
 452     (setq default-directory (abbreviate-file-name default-directory))
 453     (let ((menubar-bindings-done nil))
 454       (unwind-protect
 455           (command-line)
 456         ;; Do this again, in case .emacs defined more abbreviations.
 457         (setq default-directory (abbreviate-file-name default-directory))
 458         ;; Specify the file for recording all the auto save files of this session.
 459         ;; This is used by recover-session.
 460         (or auto-save-list-file-name
 461             (and auto-save-list-file-prefix
 462                  (setq auto-save-list-file-name
 463                        ;; Under MS-DOS our PID is almost always reused between
 464                        ;; Emacs invocations.  We need something more unique.
 465                        (cond ((eq system-type 'ms-dos)
 466                               ;; We are going to access the auto-save
 467                               ;; directory, so make sure it exists.
 468                               (make-directory
 469                                (file-name-directory auto-save-list-file-prefix)
 470                                t)
 471                               (concat
 472                                (make-temp-name
 473                                 (expand-file-name
 474                                  auto-save-list-file-prefix))
 475                                "~"))
 476                              (t
 477                               (expand-file-name
 478                                (format "%s%d-%s~"
 479                                        auto-save-list-file-prefix
 480                                        (emacs-pid)
 481                                        (system-name))))))))
 482         (run-hooks 'emacs-startup-hook)
 483         (and term-setup-hook
 484              (run-hooks 'term-setup-hook))
 485
 486         ;; Don't do this if we failed to create the initial frame,
 487         ;; for instance due to a dense colormap.
 488         (when frame-initial-frame
 489           ;; Modify the initial frame based on what .emacs puts into
 490           ;; ...-frame-alist.
 491           (if (fboundp 'frame-notice-user-settings)
 492               (frame-notice-user-settings))
 493           (if (fboundp 'frame-set-background-mode)
 494               ;; Set the faces for the initial background mode even if
 495               ;; frame-notice-user-settings didn't (such as on a tty).
 496               ;; frame-set-background-mode is idempotent, so it won't
 497               ;; cause any harm if it's already been done.
 498               (let ((frame-background-mode frame-background-mode)
 499                     (frame (selected-frame))
 500                     term)
 501                 (when (and (null window-system)
 502                            ;; Don't override a possibly customized value.
 503                            (null frame-background-mode)
 504                            ;; Don't override user specifications.
 505                            (null (frame-parameter frame 'reverse))
 506                            (let ((bg (frame-parameter frame 'background-color)))
 507                              (or (null bg)
 508                                  (member bg '(unspecified "unspecified-bg")))))
 509                   (setq term (getenv "TERM"))
 510                   (if (string-match "^\\(xterm\\|rxvt\\|dtterm\\|eterm\\)"
 511                                     term)
 512                       (setq frame-background-mode 'light)))
 513                 (frame-set-background-mode (selected-frame)))))
 514
 515         ;; Now we know the user's default font, so add it to the menu.
 516         (if (fboundp 'font-menu-add-default)
 517             (font-menu-add-default))
 518         (and window-setup-hook
 519              (run-hooks 'window-setup-hook))
 520         (or menubar-bindings-done
 521             (if (display-popup-menus-p)
 522                 (precompute-menubar-bindings)))))))
 523
 524 ;; Precompute the keyboard equivalents in the menu bar items.
 525 (defun precompute-menubar-bindings ()
 526   (let ((submap (lookup-key global-map [menu-bar])))
 527     (while submap
 528       (and (consp (car submap))
 529            (symbolp (car (car submap)))
 530            (stringp (car-safe (cdr (car submap))))
 531            (keymapp (cdr (cdr (car submap))))
 532            (progn
 533              (x-popup-menu nil (cdr (cdr (car submap))))
 534              (if purify-flag
 535                  (garbage-collect))))
 536       (setq submap (cdr submap))))
 537     (setq define-key-rebound-commands t))
 538
 539 ;; Command-line options supported by tty's:
 540 (defconst tty-long-option-alist
 541   '(("--name" .         "-name")
 542     ("--title" .        "-T")
 543     ("--reverse-video" . "-reverse")
 544     ("--foreground-color" . "-fg")
 545     ("--background-color" . "-bg")))
 546
 547 (defconst tool-bar-images-pixel-height 24
 548   "Height in pixels of images in the tool bar.")
 549
 550 (defvar tool-bar-originally-present nil
 551   "Non-nil if tool-bars are present before user and site init files are read.")
 552
 553 ;; Handle the X-like command line parameters "-fg", "-bg", "-name", etc.
 554 (defun tty-handle-args (args)
 555   (let ((rest nil))
 556     (message "%s" args)
 557     (while (and args
 558                 (not (equal (car args) "--")))
 559       (let* ((this (car args))
 560              (orig-this this)
 561              completion argval)
 562         (setq args (cdr args))
 563         ;; Check for long options with attached arguments
 564         ;; and separate out the attached option argument into argval.
 565         (if (string-match "^--[^=]*=" this)
 566             (setq argval (substring this (match-end 0))
 567                   this (substring this 0 (1- (match-end 0)))))
 568         (when (string-match "^--" this)
 569           (setq completion (try-completion this tty-long-option-alist))
 570           (if (eq completion t)
 571               ;; Exact match for long option.
 572               (setq this (cdr (assoc this tty-long-option-alist)))
 573             (if (stringp completion)
 574                 (let ((elt (assoc completion tty-long-option-alist)))
 575                   ;; Check for abbreviated long option.
 576                   (or elt
 577                       (error "Option `%s' is ambiguous" this))
 578                   (setq this (cdr elt)))
 579               ;; Check for a short option.
 580               (setq argval nil this orig-this))))
 581         (cond ((or (string= this "-fg") (string= this "-foreground"))
 582                (or argval (setq argval (car args) args (cdr args)))
 583                (setq default-frame-alist
 584                      (cons (cons 'foreground-color argval)
 585                            default-frame-alist)))
 586               ((or (string= this "-bg") (string= this "-background"))
 587                (or argval (setq argval (car args) args (cdr args)))
 588                (setq default-frame-alist
 589                      (cons (cons 'background-color argval)
 590                            default-frame-alist)))
 591               ((or (string= this "-T") (string= this "-name"))
 592                (or argval (setq argval (car args) args (cdr args)))
 593                (setq default-frame-alist
 594                      (cons
 595                       (cons 'title
 596                             (if (stringp argval)
 597                                 argval
 598                               (let ((case-fold-search t)
 599                                     i)
 600                                 (setq argval (invocation-name))
 601
 602                                 ;; Change any . or * characters in name to
 603                                 ;; hyphens, so as to emulate behavior on X.
 604                                 (while
 605                                     (setq i (string-match "[.*]" argval))
 606                                   (aset argval i ?-))
 607                                 argval)))
 608                       default-frame-alist)))
 609               ((or (string= this "-r")
 610                    (string= this "-rv")
 611                    (string= this "-reverse"))
 612                (setq default-frame-alist
 613                      (cons '(reverse . t)
 614                            default-frame-alist)))
 615               (t (setq rest (cons this rest))))))
 616       (nreverse rest)))
 617
 618 (defun command-line ()
 619   (setq command-line-default-directory default-directory)
 620
 621   ;; Choose a reasonable location for temporary files.
 622   (setq temporary-file-directory
 623         (file-name-as-directory
 624          (cond ((memq system-type '(ms-dos windows-nt))
 625                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 626                ((memq system-type '(vax-vms axp-vms))
 627                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 628                (t
 629                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 630   (setq small-temporary-file-directory
 631         (if (eq system-type 'ms-dos)
 632             (getenv "TMPDIR")))
 633
 634   ;; See if we should import version-control from the environment variable.
 635   (let ((vc (getenv "VERSION_CONTROL")))
 636     (cond ((eq vc nil))                 ;don't do anything if not set
 637           ((or (string= vc "t")
 638                (string= vc "numbered"))
 639            (setq version-control t))
 640           ((or (string= vc "nil")
 641                (string= vc "existing"))
 642            (setq version-control nil))
 643           ((or (string= vc "never")
 644                (string= vc "simple"))
 645            (setq version-control 'never))))
 646
 647   ;;! This has been commented out; I currently find the behavior when
 648   ;;! split-window-keep-point is nil disturbing, but if I can get used
 649   ;;! to it, then it would be better to eliminate the option.
 650   ;;! ;; Choose a good default value for split-window-keep-point.
 651   ;;! (setq split-window-keep-point (> baud-rate 2400))
 652
 653   ;; Set the default strings to display in mode line for
 654   ;; end-of-line formats that aren't native to this platform.
 655   (cond
 656    ((memq system-type '(ms-dos windows-nt emx))
 657     (setq eol-mnemonic-unix "(Unix)")
 658     (setq eol-mnemonic-mac  "(Mac)"))
 659    ;; Mac-specific settings should come here, once there's a
 660    ;; system-type symbol specific to MacOS.
 661    (t   ; this is for Unix/GNU/Linux systems
 662     (setq eol-mnemonic-dos  "(DOS)")
 663     (setq eol-mnemonic-mac  "(Mac)")))
 664
 665   ;; Read window system's init file if using a window system.
 666   (condition-case error
 667       (if (and window-system (not noninteractive))
 668           (load (concat term-file-prefix
 669                         (symbol-name window-system)
 670                         "-win")
 671                 ;; Every window system should have a startup file;
 672                 ;; barf if we can't find it.
 673                 nil t))
 674     ;; If we can't read it, print the error message and exit.
 675     (error
 676      (princ
 677       (if (eq (car error) 'error)
 678           (apply 'concat (cdr error))
 679         (if (memq 'file-error (get (car error) 'error-conditions))
 680             (format "%s: %s"
 681                      (nth 1 error)
 682                      (mapconcat (lambda (obj) (prin1-to-string obj t))
 683                                 (cdr (cdr error)) ", "))
 684           (format "%s: %s"
 685                    (get (car error) 'error-message)
 686                    (mapconcat (lambda (obj) (prin1-to-string obj t))
 687                               (cdr error) ", "))))
 688       'external-debugging-output)
 689      (terpri 'external-debugging-output)
 690      (setq window-system nil)
 691      (kill-emacs)))
 692
 693   ;; Windowed displays do this inside their *-win.el.
 694   (when (and (not (display-graphic-p))
 695              (not noninteractive))
 696     (setq command-line-args (tty-handle-args command-line-args)))
 697
 698   (set-locale-environment nil)
 699
 700   (let ((done nil)
 701         (args (cdr command-line-args)))
 702
 703     ;; Figure out which user's init file to load,
 704     ;; either from the environment or from the options.
 705     (setq init-file-user (if noninteractive nil (user-login-name)))
 706     ;; If user has not done su, use current $HOME to find .emacs.
 707     (and init-file-user (string= init-file-user (user-real-login-name))
 708          (setq init-file-user ""))
 709
 710     ;; Process the command-line args, and delete the arguments
 711     ;; processed.  This is consistent with the way main in emacs.c
 712     ;; does things.
 713     (while (and (not done) args)
 714       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 715                         ("--debug-init") ("--iconic") ("--icon-type")))
 716             (argi (car args))
 717             (argval nil))
 718         ;; Handle --OPTION=VALUE format.
 719         (if (and (string-match "\\`--" argi)
 720                  (string-match "=" argi))
 721             (setq argval (substring argi (match-end 0))
 722                   argi (substring argi 0 (match-beginning 0))))
 723         (or (equal argi "--")
 724             (let ((completion (try-completion argi longopts)))
 725               (if (eq completion t)
 726                   (setq argi (substring argi 1))
 727                 (if (stringp completion)
 728                     (let ((elt (assoc completion longopts)))
 729                       (or elt
 730                           (error "Option `%s' is ambiguous" argi))
 731                       (setq argi (substring (car elt) 1)))
 732                   (setq argval nil)))))
 733         (cond
 734          ((or (string-equal argi "-q")
 735               (string-equal argi "-no-init-file"))
 736           (setq init-file-user nil
 737                 args (cdr args)))
 738          ((or (string-equal argi "-u")
 739               (string-equal argi "-user"))
 740           (or argval
 741               (setq args (cdr args)
 742                     argval (car args)))
 743           (setq init-file-user argval
 744                 argval nil
 745                 args (cdr args)))
 746          ((string-equal argi "-no-site-file")
 747           (setq site-run-file nil
 748                 args (cdr args)))
 749          ((string-equal argi "-debug-init")
 750           (setq init-file-debug t
 751                 args (cdr args)))
 752          ((string-equal argi "-iconic")
 753           (setq initial-frame-alist
 754                 (cons '(visibility . icon) initial-frame-alist))
 755           (setq args (cdr args)))
 756          ((or (string-equal argi "-icon-type")
 757               (string-equal argi "-i")
 758               (string-equal argi "-itype"))
 759           (setq default-frame-alist
 760                 (cons '(icon-type . t) default-frame-alist))
 761           (setq args (cdr args)))
 762          (t (setq done t)))
 763         ;; Was argval set but not used?
 764         (and argval
 765              (error "Option `%s' doesn't allow an argument" argi))))
 766
 767     ;; Re-attach the program name to the front of the arg list.
 768     (and command-line-args (setcdr command-line-args args)))
 769
 770   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 771   (when (fboundp 'frame-initialize)
 772     (frame-initialize))
 773
 774   ;; If frame was created with a menu bar, set menu-bar-mode on.
 775   (if (and (not noninteractive)
 776            (or (not (memq window-system '(x w32)))
 777                (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0)))
 778       (menu-bar-mode t))
 779
 780   ;; If frame was created with a tool bar, switch tool-bar-mode on.
 781   (when (and (not noninteractive)
 782              (display-graphic-p)
 783              (> (frame-parameter nil 'tool-bar-lines) 0))
 784     (tool-bar-mode 1))
 785
 786   ;; Can't do this init in defcustom because window-system isn't set.
 787   (when (and (not noninteractive)
 788              (not (eq system-type 'ms-dos))
 789              (memq window-system '(x w32)))
 790     (setq-default blink-cursor t)
 791     (blink-cursor-mode 1))
 792
 793   (unless noninteractive
 794     ;; DOS/Windows systems have a PC-type keyboard which has both
 795     ;; <delete> and <backspace> keys.
 796     (when (or (memq system-type '(ms-dos windows-nt))
 797               (and (memq window-system '(x))
 798                    (fboundp 'x-backspace-delete-keys-p)
 799                    (x-backspace-delete-keys-p)))
 800       (setq-default normal-erase-is-backspace t)
 801       (normal-erase-is-backspace-mode 1)))
 802
 803   (when (and (not noninteractive)
 804              (display-graphic-p)
 805              (fboundp 'x-show-tip))
 806     (setq-default tooltip-mode t)
 807     (tooltip-mode 1))
 808
 809   ;; Register default TTY colors for the case the terminal hasn't a
 810   ;; terminal init file.
 811   (or (memq window-system '(x w32))
 812       (not (tty-display-color-p))
 813       (let* ((colors (cond ((eq window-system 'pc)
 814                             msdos-color-values)
 815                            ((eq system-type 'windows-nt)
 816                             w32-tty-standard-colors)
 817                            (t tty-standard-colors)))
 818              (color (car colors)))
 819         (while colors
 820           (tty-color-define (car color) (cadr color) (cddr color))
 821           (setq colors (cdr colors) color (car colors)))
 822         ;; Modifying color mappings means realized faces don't
 823         ;; use the right colors, so clear them.
 824         (clear-face-cache)))
 825
 826   ;; Record whether the tool-bar is present before the user and site
 827   ;; init files are processed.  frame-notice-user-settings uses this
 828   ;; to determine if the tool-bar has been disabled by the init files,
 829   ;; and the frame needs to be resized.
 830   (when (fboundp 'frame-notice-user-settings)
 831     (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 832                               (assq 'tool-bar-lines default-frame-alist))))
 833       (setq tool-bar-originally-present
 834             (not (or (null tool-bar-lines)
 835                      (null (cdr tool-bar-lines))
 836                      (eq 0 (cdr tool-bar-lines)))))))
 837
 838   (let ((old-scalable-fonts-allowed scalable-fonts-allowed)
 839         (old-font-list-limit font-list-limit)
 840         (old-face-ignored-fonts face-ignored-fonts))
 841
 842     (run-hooks 'before-init-hook)
 843
 844     ;; Run the site-start library if it exists.  The point of this file is
 845     ;; that it is run before .emacs.  There is no point in doing this after
 846     ;; .emacs; that is useless.
 847     (if site-run-file
 848         (load site-run-file t t))
 849
 850     ;; Sites should not disable this.  Only individuals should disable
 851     ;; the startup message.
 852     (setq inhibit-startup-message nil)
 853
 854     ;; Load that user's init file, or the default one, or none.
 855     (let (debug-on-error-from-init-file
 856           debug-on-error-should-be-set
 857           (debug-on-error-initial
 858            (if (eq init-file-debug t) 'startup init-file-debug))
 859           (orig-enable-multibyte default-enable-multibyte-characters))
 860       (let ((debug-on-error debug-on-error-initial)
 861             ;; This function actually reads the init files.
 862             (inner
 863              (function
 864               (lambda ()
 865                 (if init-file-user
 866                     (let ((user-init-file-1
 867                            (cond
 868                             ((eq system-type 'ms-dos)
 869                              (concat "~" init-file-user "/_emacs"))
 870                             ((eq system-type 'windows-nt)
 871                              (if (directory-files "~" nil "^\\.emacs\\(\\.elc?\\)?$")
 872                                  "~/.emacs"
 873                                "~/_emacs"))
 874                             ((eq system-type 'vax-vms)
 875                              "sys$login:.emacs")
 876                             (t
 877                              (concat "~" init-file-user "/.emacs")))))
 878                       ;; This tells `load' to store the file name found
 879                       ;; into user-init-file.
 880                       (setq user-init-file t)
 881                       (load user-init-file-1 t t)
 882
 883                       ;; If we did not find the user's init file,
 884                       ;; set user-init-file conclusively to nil;
 885                       ;; don't let it be set from default.el.
 886                       (if (eq user-init-file t)
 887                           (setq user-init-file nil))
 888
 889                       ;; If we loaded a compiled file, set
 890                       ;; `user-init-file' to the source version if that
 891                       ;; exists.
 892                       (when (and user-init-file
 893                                  (equal (file-name-extension user-init-file)
 894                                         "elc"))
 895                         (let* ((source (file-name-sans-extension user-init-file))
 896                                (alt (concat source ".el")))
 897                           (setq source (cond ((file-exists-p alt) alt)
 898                                              ((file-exists-p source) source)
 899                                              (t nil)))
 900                           (when source
 901                             (when (file-newer-than-file-p source user-init-file)
 902                               (message "Warning: %s is newer than %s"
 903                                        source user-init-file)
 904                               (sit-for 1))
 905                             (setq user-init-file source))))
 906
 907                       (or inhibit-default-init
 908                           (let ((inhibit-startup-message nil))
 909                             ;; Users are supposed to be told their rights.
 910                             ;; (Plus how to get help and how to undo.)
 911                             ;; Don't you dare turn this off for anyone
 912                             ;; except yourself.
 913                             (load "default" t t)))))))))
 914         (if init-file-debug
 915             ;; Do this without a condition-case if the user wants to debug.
 916             (funcall inner)
 917           (condition-case error
 918               (progn
 919                 (funcall inner)
 920                 (setq init-file-had-error nil))
 921             (error
 922              (let ((message-log-max nil))
 923                (save-excursion
 924                  (set-buffer (get-buffer-create "*Messages*"))
 925                  (insert "\n\n"
 926                          (format "An error has occurred while loading `%s':\n\n"
 927                                  user-init-file)
 928                          (format "%s%s%s"
 929                                  (get (car error) 'error-message)
 930                                  (if (cdr error) ": " "")
 931                                  (mapconcat 'prin1-to-string (cdr error) ", "))
 932                          "\n\n"
 933                          "To ensure normal operation, you should investigate the cause\n"
 934                          "of the error in your initialization file and remove it.  Start\n"
 935                          "Emacs with the `--debug-init' option to view a complete error\n"
 936                          "backtrace\n"))
 937                (message "Error in init file: %s%s%s"
 938                         (get (car error) 'error-message)
 939                         (if (cdr error) ": " "")
 940                         (mapconcat 'prin1-to-string (cdr error) ", "))
 941                (pop-to-buffer "*Messages*")
 942                (setq init-file-had-error t)))))
 943         ;; If we can tell that the init file altered debug-on-error,
 944         ;; arrange to preserve the value that it set up.
 945         (or (eq debug-on-error debug-on-error-initial)
 946             (setq debug-on-error-should-be-set t
 947                   debug-on-error-from-init-file debug-on-error)))
 948       (if debug-on-error-should-be-set
 949           (setq debug-on-error debug-on-error-from-init-file))
 950       (unless (or default-enable-multibyte-characters
 951                   (eq orig-enable-multibyte default-enable-multibyte-characters))
 952         ;; Init file changed to unibyte.  Reset existing multibyte
 953         ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 954         ;; Arguably this should only be done if they're free of
 955         ;; multibyte characters.
 956         (mapcar (lambda (buffer)
 957                   (with-current-buffer buffer
 958                     (if enable-multibyte-characters
 959                         (set-buffer-multibyte nil))))
 960                 (buffer-list))
 961         ;; Also re-set the language environment in case it was
 962         ;; originally done before unibyte was set and is sensitive to
 963         ;; unibyte (display table, terminal coding system &c).
 964         (set-language-environment current-language-environment)))
 965
 966     ;; Do this here in case the init file sets mail-host-address.
 967     (or user-mail-address
 968         (setq user-mail-address (concat (user-login-name) "@"
 969                                         (or mail-host-address
 970                                             (system-name)))))
 971
 972     ;; If parameter have been changed in the init file which influence
 973     ;; face realization, clear the face cache so that new faces will
 974     ;; be realized.
 975     (unless (and (eq scalable-fonts-allowed old-scalable-fonts-allowed)
 976                  (eq font-list-limit old-font-list-limit)
 977                  (eq face-ignored-fonts old-face-ignored-fonts))
 978       (clear-face-cache)))
 979
 980   (run-hooks 'after-init-hook)
 981
 982   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 983   (if (get-buffer "*scratch*")
 984       (save-excursion
 985         (set-buffer "*scratch*")
 986         (if (eq major-mode 'fundamental-mode)
 987             (funcall initial-major-mode))))
 988
 989   ;; Load library for our terminal type.
 990   ;; User init file can set term-file-prefix to nil to prevent this.
 991   (and term-file-prefix (not noninteractive) (not window-system)
 992        (let ((term (getenv "TERM"))
 993              hyphend)
 994          (while (and term
 995                      (not (load (concat term-file-prefix term) t t)))
 996            ;; Strip off last hyphen and what follows, then try again
 997            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 998                (setq term (substring term 0 hyphend))
 999              (setq term nil)))))
1000
1001   ;; Process the remaining args.
1002   (command-line-1 (cdr command-line-args))
1003
1004   ;; If -batch, terminate after processing the command options.
1005   (if noninteractive (kill-emacs t)))
1006
1007 (defcustom initial-scratch-message (purecopy "\
1008 ;; This buffer is for notes you don't want to save, and for Lisp evaluation.
1009 ;; If you want to create a file, visit that file with C-x C-f,
1010 ;; then enter the text in that file's own buffer.
1011
1012 ")
1013   "Initial message displayed in *scratch* buffer at startup.
1014 If this is nil, no message will be displayed."
1015   :type 'string)
1016
1017 \f
1018 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1019 ;;; Fancy splash screen
1020 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1021
1022 (defvar fancy-splash-text
1023   '((:face variable-pitch
1024            "You can do basic editing with the menu bar and scroll bar \
1025 using the mouse.\n\n"
1026            :face (variable-pitch :weight bold)
1027            "Important Help menu items:\n"
1028            :face variable-pitch "\
1029 Emacs Tutorial\tLearn-by-doing tutorial for using Emacs efficiently
1030 Emacs FAQ\tFrequently asked questions and answers
1031 \(Non)Warranty\tGNU Emacs comes with "
1032            :face (variable-pitch :slant oblique)
1033            "ABSOLUTELY NO WARRANTY\n"
1034            :face variable-pitch
1035            "\
1036 Copying Conditions\tConditions for redistributing and changing Emacs
1037 Ordering Manuals\tHow to order Emacs manuals from the Free Software Foundation\n")
1038   (:face variable-pitch
1039            "You can do basic editing with the menu bar and scroll bar \
1040 using the mouse.\n\n"
1041            :face (variable-pitch :weight bold)
1042            "Useful File menu items:\n"
1043            :face variable-pitch "\
1044 Exit Emacs\t(Or type Control-x followed by Control-c)
1045 Recover Session\tRecover files you were editing before a crash
1046
1047
1048
1049 "
1050            ))
1051   "A list of texts to show in the middle part of splash screens.
1052 Each element in the list should be a list of strings or pairs
1053 `:face FACE', like `fancy-splash-insert' accepts them.")
1054
1055
1056 (defgroup fancy-splash-screen ()
1057   "Fancy splash screen when Emacs starts."
1058   :version "21.1"
1059   :group 'initialization)
1060
1061
1062 (defcustom fancy-splash-delay 10
1063   "*Delay in seconds between splash screens."
1064   :group 'fancy-splash-screen
1065   :type 'integer)
1066
1067
1068 (defcustom fancy-splash-max-time 60
1069   "*Show splash screens for at most this number of seconds.
1070 Values less than 60 seconds are ignored."
1071   :group 'fancy-splash-screen
1072   :type 'integer)
1073
1074
1075 (defcustom fancy-splash-image nil
1076   "*The image to show in the splash screens, or nil for defaults."
1077   :group 'fancy-splash-screen
1078   :type '(choice (const :tag "Default" nil)
1079                  (file :tag "File")))
1080
1081
1082 ;; These are temporary storage areas for the splash screen display.
1083
1084 (defvar fancy-current-text nil)
1085 (defvar fancy-splash-help-echo nil)
1086 (defvar fancy-splash-stop-time nil)
1087
1088
1089 (defun fancy-splash-insert (&rest args)
1090   "Insert text into the current buffer, with faces.
1091 Arguments from ARGS should be either strings or pairs `:face FACE',
1092 where FACE is a valid face specification, as it can be used with
1093 `put-text-properties'."
1094   (let ((current-face nil))
1095     (while args
1096       (if (eq (car args) :face)
1097           (setq args (cdr args) current-face (car args))
1098         (insert (propertize (car args)
1099                             'face current-face
1100                             'help-echo fancy-splash-help-echo)))
1101       (setq args (cdr args)))))
1102
1103
1104 (defun fancy-splash-head ()
1105   "Insert the head part of the splash screen into the current buffer."
1106   (let* ((image-file (cond ((stringp fancy-splash-image)
1107                             fancy-splash-image)
1108                            ((and (display-color-p)
1109                                  (image-type-available-p 'xpm))
1110                             (if (and (fboundp 'x-display-planes)
1111                                      (= (funcall 'x-display-planes) 8))
1112                                 "splash8.xpm"
1113                               "splash.xpm"))
1114                            (t "splash.pbm")))
1115          (img (create-image image-file))
1116          (image-width (and img (car (image-size img))))
1117          (window-width (window-width (selected-window))))
1118     (when img
1119       (when (> window-width image-width)
1120         ;; Center the image in the window.
1121         (let ((pos (/ (- window-width image-width) 2)))
1122           (insert (propertize " " 'display `(space :align-to ,pos))))
1123
1124         ;; Insert the image with a help-echo and a keymap.
1125         (let ((map (make-sparse-keymap))
1126               (help-echo "mouse-2: browse http://www.gnu.org/"))
1127           (define-key map [mouse-2]
1128             (lambda ()
1129               (interactive)
1130               (browse-url "http://www.gnu.org/")
1131               (throw 'exit nil)))
1132           (define-key map [down-mouse-2] 'ignore)
1133           (define-key map [up-mouse-2] 'ignore)
1134           (insert-image img (propertize "xxx" 'help-echo help-echo
1135                                         'keymap map)))
1136         (insert "\n"))))
1137   (if (eq system-type 'gnu/linux)
1138       (fancy-splash-insert
1139        :face '(variable-pitch :foreground "red")
1140        "GNU Emacs is one component of a Linux-based GNU system.")
1141     (fancy-splash-insert
1142      :face '(variable-pitch :foreground "red")
1143      "GNU Emacs is one component of the GNU operating system."))
1144   (insert "\n"))
1145
1146
1147 (defun fancy-splash-tail ()
1148   "Insert the tail part of the splash screen into the current buffer."
1149   (let ((fg (if (eq (frame-parameter nil 'background-mode) 'dark)
1150                 "cyan" "darkblue")))
1151     (fancy-splash-insert :face `(variable-pitch :foreground ,fg)
1152                          "\nThis is "
1153                          (emacs-version)
1154                          "\n"
1155                          :face '(variable-pitch :height 0.5)
1156                          "Copyright (C) 2001 Free Software Foundation, Inc.")))
1157
1158
1159 (defun fancy-splash-screens-1 (buffer)
1160   "Timer function displaying a splash screen."
1161   (when (> (float-time) fancy-splash-stop-time)
1162     (throw 'stop-splashing nil))
1163   (unless fancy-current-text
1164     (setq fancy-current-text fancy-splash-text))
1165   (let ((text (car fancy-current-text)))
1166     (set-buffer buffer)
1167     (erase-buffer)
1168     (fancy-splash-head)
1169     (apply #'fancy-splash-insert text)
1170     (fancy-splash-tail)
1171     (unless (current-message)
1172       (message fancy-splash-help-echo))
1173     (set-buffer-modified-p nil)
1174     (goto-char (point-min))
1175     (force-mode-line-update)
1176     (setq fancy-current-text (cdr fancy-current-text))))
1177
1178
1179 (defun fancy-splash-default-action ()
1180   "Default action for events in the splash screen buffer."
1181   (interactive)
1182   (push last-command-event unread-command-events)
1183   (throw 'exit nil))
1184
1185
1186 (defun fancy-splash-screens ()
1187   "Display fancy splash screens when Emacs starts."
1188   (setq fancy-splash-help-echo (startup-echo-area-message))
1189   (switch-to-buffer "GNU Emacs")
1190   (setq tab-width 20)
1191   (let ((old-hourglass display-hourglass)
1192         (splash-buffer (current-buffer))
1193         (old-minor-mode-map-alist minor-mode-map-alist)
1194         timer)
1195     (catch 'stop-splashing
1196       (unwind-protect
1197           (let ((map (make-sparse-keymap)))
1198             (use-local-map map)
1199             (define-key map [t] 'fancy-splash-default-action)
1200             (define-key map [mouse-movement] 'ignore)
1201             (define-key map [mode-line t] 'ignore)
1202             (setq cursor-type nil
1203                   display-hourglass nil
1204                   minor-mode-map-alist nil
1205                   buffer-undo-list t
1206                   mode-line-format (propertize "---- %b %-"
1207                                                'face '(:weight bold))
1208                   fancy-splash-stop-time (+ (float-time)
1209                                             (max 60 fancy-splash-max-time))
1210                   timer (run-with-timer 0 fancy-splash-delay
1211                                         #'fancy-splash-screens-1
1212                                         splash-buffer))
1213             (recursive-edit))
1214           (cancel-timer timer)
1215           (setq display-hourglass old-hourglass
1216                 minor-mode-map-alist old-minor-mode-map-alist)
1217           (kill-buffer splash-buffer)))))
1218
1219
1220 (defun use-fancy-splash-screens-p ()
1221   "Return t if fancy splash screens should be used."
1222   (when (or (and (display-color-p)
1223                  (image-type-available-p 'xpm))
1224             (image-type-available-p 'pbm))
1225     (let* ((img (create-image (or fancy-splash-image
1226                                   (if (and (display-color-p)
1227                                            (image-type-available-p 'xpm))
1228                                       "splash.xpm" "splash.pbm"))))
1229            (image-height (and img (cdr (image-size img))))
1230            (window-height (1- (window-height (selected-window)))))
1231       (> window-height (+ image-height 15)))))
1232
1233
1234 (defun startup-echo-area-message ()
1235   (if (eq (key-binding "\C-h\C-p") 'describe-project)
1236       "For information about the GNU Project and its goals, type C-h C-p."
1237     (substitute-command-keys
1238      "For information about the GNU Project and its goals, type \
1239 \\[describe-project].")))
1240
1241
1242 (defun display-startup-echo-area-message ()
1243   (let ((resize-mini-windows t))
1244     (message (startup-echo-area-message))))
1245
1246
1247 (defun command-line-1 (command-line-args-left)
1248   (or noninteractive (input-pending-p) init-file-had-error
1249         (and inhibit-startup-echo-area-message
1250              user-init-file
1251              (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
1252                       (equal inhibit-startup-echo-area-message
1253                              (if (string= init-file-user "")
1254                                  (user-login-name)
1255                                init-file-user)))
1256                  ;; Wasn't set with custom; see if .emacs has a setq.
1257                  (let ((buffer (get-buffer-create " *temp*")))
1258                    (prog1
1259                        (condition-case nil
1260                            (save-excursion
1261                              (set-buffer buffer)
1262                              (insert-file-contents user-init-file)
1263                              (re-search-forward
1264                               (concat
1265                                "([ \t\n]*setq[ \t\n]+"
1266                                "inhibit-startup-echo-area-message[ \t\n]+"
1267                                (regexp-quote
1268                                 (prin1-to-string
1269                                  (if (string= init-file-user "")
1270                                      (user-login-name)
1271                                    init-file-user)))
1272                                "[ \t\n]*)")
1273                               nil t))
1274                          (error nil))
1275                      (kill-buffer buffer)))))
1276         (display-startup-echo-area-message))
1277   (if (null command-line-args-left)
1278       (cond ((and (not inhibit-startup-message) (not noninteractive)
1279                   ;; Don't clobber a non-scratch buffer if init file
1280                   ;; has selected it.
1281                   (string= (buffer-name) "*scratch*"))
1282              ;; If there are no switches to process, we might as well
1283              ;; run this hook now, and there may be some need to do it
1284              ;; before doing any output.
1285              (and term-setup-hook
1286                   (run-hooks 'term-setup-hook))
1287              ;; Don't let the hook be run twice.
1288              (setq term-setup-hook nil)
1289
1290              ;; It's important to notice the user settings before we
1291              ;; display the startup message; otherwise, the settings
1292              ;; won't take effect until the user gives the first
1293              ;; keystroke, and that's distracting.
1294              (when (fboundp 'frame-notice-user-settings)
1295                (frame-notice-user-settings))
1296
1297              (when window-setup-hook
1298                (run-hooks 'window-setup-hook)
1299                (setq window-setup-hook nil))
1300
1301              (when (display-popup-menus-p)
1302                (precompute-menubar-bindings))
1303              (setq menubar-bindings-done t)
1304
1305              ;; Do this now to avoid an annoying delay if the user
1306              ;; clicks the menu bar during the sit-for.
1307              (when (= (buffer-size) 0)
1308                (let ((buffer-undo-list t)
1309                      (wait-for-input t))
1310                  (unwind-protect
1311                      (when (not (input-pending-p))
1312                        (goto-char (point-max))
1313                        ;; The convention for this piece of code is that
1314                        ;; each piece of output starts with one or two newlines
1315                        ;; and does not end with any newlines.
1316                        (insert "Welcome to GNU Emacs")
1317                        (if (eq system-type 'gnu/linux)
1318                            (insert ", one component of a Linux-based GNU system."))
1319                        (insert "\n")
1320
1321                        (if (assq 'display (frame-parameters))
1322
1323                            (if (use-fancy-splash-screens-p)
1324                                (progn
1325                                  (setq wait-for-input nil)
1326                                  (fancy-splash-screens))
1327                              (progn
1328                                (insert "\
1329 You can do basic editing with the menu bar and scroll bar using the mouse.
1330
1331 Useful File menu items:
1332 Exit Emacs              (or type Control-x followed by Control-c)
1333 Recover Session         recover files you were editing before a crash
1334
1335 Important Help menu items:
1336 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
1337 Emacs FAQ               Frequently asked questions and answers
1338 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
1339 Copying Conditions      Conditions for redistributing and changing Emacs.
1340 Getting New Versions    How to obtain the latest version of Emacs.
1341 Ordering Manuals        How to order manuals from the FSF.
1342 ")
1343                                (insert "\n\n" (emacs-version)
1344                                        "
1345 Copyright (C) 2001 Free Software Foundation, Inc.")))
1346
1347                          ;; If keys have their default meanings,
1348                          ;; use precomputed string to save lots of time.
1349                          (if (and (eq (key-binding "\C-h") 'help-command)
1350                                   (eq (key-binding "\C-xu") 'advertised-undo)
1351                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
1352                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
1353                                   (eq (key-binding "\C-hi") 'info)
1354                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
1355                              (insert "
1356 Get help           C-h  (Hold down CTRL and press h)
1357 Undo changes       C-x u       Exit Emacs               C-x C-c
1358 Get a tutorial     C-h t       Use Info to read docs    C-h i
1359 Ordering manuals   C-h RET")
1360                            (insert (substitute-command-keys
1361                                     (format "\n
1362 Get help           %s
1363 Undo changes       \\[advertised-undo]
1364 Exit Emacs         \\[save-buffers-kill-emacs]
1365 Get a tutorial     \\[help-with-tutorial]
1366 Use Info to read docs   \\[info]
1367 Ordering manuals   \\[view-order-manuals]"
1368                                             (let ((where (where-is-internal
1369                                                           'help-command nil t)))
1370                                               (if where
1371                                                   (key-description where)
1372                                                 "M-x help"))))))
1373                          ;; Say how to use the menu bar
1374                          ;; if that is not with the mouse.
1375                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
1376                                   (eq (key-binding [f10]) 'tmm-menubar))
1377                              (insert "
1378 Activate menubar   F10  or  ESC `  or   M-`")
1379                            (insert (substitute-command-keys "
1380 Activate menubar     \\[tmm-menubar]")))
1381
1382                          (if (display-mouse-p)
1383                              (insert "
1384 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
1385                          ;; Many users seem to have problems with these.
1386                          (insert "
1387 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
1388 If you have no Meta key, you may instead type ESC followed by the character.)")
1389                          (and auto-save-list-file-prefix
1390                               ;; Don't signal an error if the
1391                               ;; directory for auto-save-list files
1392                               ;; does not yet exist.
1393                               (file-directory-p (file-name-directory
1394                                                  auto-save-list-file-prefix))
1395                               (directory-files
1396                                (file-name-directory auto-save-list-file-prefix)
1397                                nil
1398                                (concat "\\`"
1399                                        (regexp-quote (file-name-nondirectory
1400                                                       auto-save-list-file-prefix)))
1401                                t)
1402                               (insert "\n\nIf an Emacs session crashed recently, "
1403                                       "type M-x recover-session RET\nto recover"
1404                                       " the files you were editing."))
1405
1406                          (insert "\n\n" (emacs-version)
1407                                  "
1408 Copyright (C) 2001 Free Software Foundation, Inc.")
1409                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
1410                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
1411                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
1412                              (insert
1413                               "\n
1414 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
1415 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1416 of Emacs and modify it; type C-h C-c to see the conditions.
1417 Type C-h C-d for information on getting the latest version.")
1418                            (insert (substitute-command-keys
1419                                     "\n
1420 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
1421 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1422 of Emacs and modify it; type \\[describe-copying] to see the conditions.
1423 Type \\[describe-distribution] for information on getting the latest version."))))
1424                        (goto-char (point-min))
1425
1426                        (set-buffer-modified-p nil)
1427                        (when wait-for-input
1428                          (sit-for 120)))
1429
1430                    (with-current-buffer (get-buffer "*scratch*")
1431                      (erase-buffer)
1432                      (when initial-scratch-message
1433                        (insert initial-scratch-message))
1434                      (set-buffer-modified-p nil)))))))
1435
1436     ;; Delay 2 seconds after the init file error message
1437     ;; was displayed, so user can read it.
1438     (if init-file-had-error
1439         (sit-for 2))
1440     (let ((dir command-line-default-directory)
1441           (file-count 0)
1442           first-file-buffer
1443           tem
1444           just-files;; t if this follows the magic -- option.
1445           ;; This includes our standard options' long versions
1446           ;; and long versions of what's on command-switch-alist.
1447           (longopts
1448            (append '(("--funcall") ("--load") ("--insert") ("--kill")
1449                      ("--directory") ("--eval") ("--execute")
1450                      ("--find-file") ("--visit") ("--file"))
1451                    (mapcar (lambda (elt)
1452                              (list (concat "-" (car elt))))
1453                            command-switch-alist)))
1454           (line 0)
1455           (column 0))
1456
1457       ;; Add the long X options to longopts.
1458       (setq tem command-line-x-option-alist)
1459       (while tem
1460         (if (string-match "^--" (car (car tem)))
1461             (setq longopts (cons (list (car (car tem))) longopts)))
1462         (setq tem (cdr tem)))
1463
1464       ;; Loop, processing options.
1465       (while (and command-line-args-left)
1466         (let* ((argi (car command-line-args-left))
1467                (orig-argi argi)
1468                argval completion
1469                ;; List of directories specified in -L/--directory,
1470                ;; in reverse of the order specified.
1471                extra-load-path
1472                (initial-load-path load-path))
1473           (setq command-line-args-left (cdr command-line-args-left))
1474
1475           ;; Do preliminary decoding of the option.
1476           (if just-files
1477               ;; After --, don't look for options; treat all args as files.
1478               (setq argi "")
1479             ;; Convert long options to ordinary options
1480             ;; and separate out an attached option argument into argval.
1481             (if (string-match "^--[^=]*=" argi)
1482                 (setq argval (substring argi (match-end 0))
1483                       argi (substring argi 0 (1- (match-end 0)))))
1484             (if (equal argi "--")
1485                 (setq completion nil)
1486               (setq completion (try-completion argi longopts)))
1487             (if (eq completion t)
1488                 (setq argi (substring argi 1))
1489               (if (stringp completion)
1490                   (let ((elt (assoc completion longopts)))
1491                     (or elt
1492                         (error "Option `%s' is ambiguous" argi))
1493                     (setq argi (substring (car elt) 1)))
1494                 (setq argval nil argi orig-argi))))
1495
1496           ;; Execute the option.
1497           (cond ((setq tem (assoc argi command-switch-alist))
1498                  (if argval
1499                      (let ((command-line-args-left
1500                             (cons argval command-line-args-left)))
1501                        (funcall (cdr tem) argi))
1502                    (funcall (cdr tem) argi)))
1503
1504                 ((or (string-equal argi "-f") ;what the manual claims
1505                      (string-equal argi "-funcall")
1506                      (string-equal argi "-e")) ; what the source used to say
1507                  (if argval
1508                      (setq tem (intern argval))
1509                    (setq tem (intern (car command-line-args-left)))
1510                    (setq command-line-args-left (cdr command-line-args-left)))
1511                  (if (arrayp (symbol-function tem))
1512                      (command-execute tem)
1513                    (funcall tem)))
1514
1515                 ((or (string-equal argi "-eval")
1516                      (string-equal argi "-execute"))
1517                  (if argval
1518                      (setq tem argval)
1519                    (setq tem (car command-line-args-left))
1520                    (setq command-line-args-left (cdr command-line-args-left)))
1521                  (eval (read tem)))
1522                 ;; Set the default directory as specified in -L.
1523
1524                 ((or (string-equal argi "-L")
1525                      (string-equal argi "-directory"))
1526                  (if argval
1527                      (setq tem argval)
1528                    (setq tem (car command-line-args-left)
1529                          command-line-args-left (cdr command-line-args-left)))
1530                  (setq tem (command-line-normalize-file-name tem))
1531                  (setq extra-load-path
1532                        (cons (expand-file-name tem) extra-load-path))
1533                  (setq load-path (append (nreverse extra-load-path)
1534                                          initial-load-path)))
1535
1536                 ((or (string-equal argi "-l")
1537                      (string-equal argi "-load"))
1538                  (if argval
1539                      (setq tem argval)
1540                    (setq tem (car command-line-args-left)
1541                          command-line-args-left (cdr command-line-args-left)))
1542                  (let ((file (command-line-normalize-file-name tem)))
1543                    ;; Take file from default dir if it exists there;
1544                    ;; otherwise let `load' search for it.
1545                    (if (file-exists-p (expand-file-name file))
1546                        (setq file (expand-file-name file)))
1547                    (load file nil t)))
1548
1549                 ((string-equal argi "-insert")
1550                  (if argval
1551                      (setq tem argval)
1552                    (setq tem (car command-line-args-left)
1553                          command-line-args-left (cdr command-line-args-left)))
1554                  (or (stringp tem)
1555                      (error "File name omitted from `-insert' option"))
1556                  (insert-file-contents (command-line-normalize-file-name tem)))
1557
1558                 ((string-equal argi "-kill")
1559                  (kill-emacs t))
1560
1561                 ((string-match "^\\+[0-9]+\\'" argi)
1562                  (setq line (string-to-int argi)))
1563
1564                 ((string-match "^\\+\\([0-9]+\\):\\([0-9]+\\)\\'" argi)
1565                  (setq line (string-to-int (match-string 1 argi))
1566                        column (string-to-int (match-string 2 argi))))
1567
1568                 ((setq tem (assoc argi command-line-x-option-alist))
1569                  ;; Ignore X-windows options and their args if not using X.
1570                  (setq command-line-args-left
1571                        (nthcdr (nth 1 tem) command-line-args-left)))
1572
1573                 ((or (string-equal argi "-find-file")
1574                      (string-equal argi "-file")
1575                      (string-equal argi "-visit"))
1576                  ;; An explicit option to specify visiting a file.
1577                  (if argval
1578                      (setq tem argval)
1579                    (setq tem (car command-line-args-left)
1580                          command-line-args-left (cdr command-line-args-left)))
1581                  (unless (stringp tem)
1582                    (error "File name omitted from `%s' option" argi))
1583                  (setq file-count (1+ file-count))
1584                  (let ((file (expand-file-name
1585                               (command-line-normalize-file-name tem) dir)))
1586                    (if (= file-count 1)
1587                        (setq first-file-buffer (find-file file))
1588                      (find-file-other-window file)))
1589                  (or (zerop line)
1590                      (goto-line line))
1591                  (setq line 0)
1592                  (unless (< column 1)
1593                    (move-to-column (1- column)))
1594                  (setq column 0))
1595
1596                 ((equal argi "--")
1597                  (setq just-files t))
1598                 (t
1599                  ;; We have almost exhausted our options. See if the
1600                  ;; user has made any other command-line options available
1601                  (let ((hooks command-line-functions);; lrs 7/31/89
1602                        (did-hook nil))
1603                    (while (and hooks
1604                                (not (setq did-hook (funcall (car hooks)))))
1605                      (setq hooks (cdr hooks)))
1606                    (if (not did-hook)
1607                        ;; Ok, presume that the argument is a file name
1608                        (progn
1609                          (if (string-match "\\`-" argi)
1610                              (error "Unknown option `%s'" argi))
1611                          (setq file-count (1+ file-count))
1612                          (let ((file
1613                                 (expand-file-name
1614                                  (command-line-normalize-file-name orig-argi)
1615                                  dir)))
1616                            (if (= file-count 1)
1617                                (setq first-file-buffer (find-file file))
1618                              (find-file-other-window file)))
1619                          (or (zerop line)
1620                              (goto-line line))
1621                          (setq line 0)
1622                          (unless (< column 1)
1623                            (move-to-column (1- column)))
1624                          (setq column 0))))))))
1625       ;; If 3 or more files visited, and not all visible,
1626       ;; show user what they all are.  But leave the last one current.
1627       (and (> file-count 2)
1628            (not noninteractive)
1629            (not inhibit-startup-buffer-menu)
1630            (or (get-buffer-window first-file-buffer)
1631                (list-buffers))))))
1632
1633
1634 (defun command-line-normalize-file-name (file)
1635   "Collapse multiple slashes to one, to handle non-Emacs file names."
1636   (save-match-data
1637     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1638     ;; That is significant on some systems.
1639     ;; However, /// at the beginning is supposed to mean just /, not //.
1640     (if (string-match "^///+" file)
1641         (setq file (replace-match "/" t t file)))
1642     (while (string-match "//+" file 1)
1643       (setq file (replace-match "/" t t file)))
1644     file))
1645
1646 ;;; startup.el ends here