lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a valid Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defun PC-bindings (bind)
 145   (let ((completion-map minibuffer-local-completion-map)
 146         (must-match-map minibuffer-local-must-match-map))
 147     (cond ((not bind)
 148            ;; These bindings are the default bindings.  It would be better to
 149            ;; restore the previous bindings.
 150            (define-key completion-map "\t"      'minibuffer-complete)
 151            (define-key completion-map " "       'minibuffer-complete-word)
 152            (define-key completion-map "?"       'minibuffer-completion-help)
 153
 154            (define-key must-match-map "\t"      'minibuffer-complete)
 155            (define-key must-match-map " "       'minibuffer-complete-word)
 156            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 157            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 158            (define-key must-match-map "?"       'minibuffer-completion-help)
 159
 160            (define-key global-map "\e\t"        'complete-symbol))
 161           (PC-default-bindings
 162            (define-key completion-map "\t"      'PC-complete)
 163            (define-key completion-map " "       'PC-complete-word)
 164            (define-key completion-map "?"       'PC-completion-help)
 165
 166            (define-key completion-map "\e\t"    'PC-complete)
 167            (define-key completion-map "\e "     'PC-complete-word)
 168            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 169            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 170            (define-key completion-map "\e?"     'PC-completion-help)
 171
 172            (define-key must-match-map "\t"      'PC-complete)
 173            (define-key must-match-map " "       'PC-complete-word)
 174            (define-key must-match-map "\r"      'PC-complete-and-exit)
 175            (define-key must-match-map "\n"      'PC-complete-and-exit)
 176            (define-key must-match-map "?"       'PC-completion-help)
 177
 178            (define-key must-match-map "\e\t"    'PC-complete)
 179            (define-key must-match-map "\e "     'PC-complete-word)
 180            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 181            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 182            (define-key must-match-map "\e?"     'PC-completion-help)
 183
 184            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 185
 186 ;;;###autoload
 187 (define-minor-mode partial-completion-mode
 188   "Toggle Partial Completion mode.
 189 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 190
 191 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 192 nil) is enhanced so that if some string is divided into words and each word is
 193 delimited by a character in `PC-word-delimiters', partial words are completed
 194 as much as possible and `*' characters are treated likewise in file names.
 195
 196 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 197 command begins with that sequence of characters, and
 198 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 199 other file in that directory begin with that sequence of characters.
 200
 201 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 202 specially in \\[find-file].  For example,
 203 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 204 See also the variable `PC-include-file-path'.
 205
 206 Partial Completion mode extends the meaning of `completion-auto-help' (which
 207 see), so that if it is neither nil nor t, Emacs shows the `*Completions*'
 208 buffer only on the second attempt to complete.  That is, if TAB finds nothing
 209 to complete, the first TAB just says \"Next char not unique\" and the
 210 second TAB brings up the `*Completions*' buffer."
 211   :global t :group 'partial-completion
 212   ;; Deal with key bindings...
 213   (PC-bindings partial-completion-mode)
 214   ;; Deal with include file feature...
 215   (cond ((not partial-completion-mode)
 216          (remove-hook 'find-file-not-found-functions 'PC-look-for-include-file))
 217         ((not PC-disable-includes)
 218          (add-hook 'find-file-not-found-functions 'PC-look-for-include-file)))
 219   ;; ... with some underhand redefining.
 220   (cond ((not partial-completion-mode)
 221          (ad-disable-advice 'read-file-name-internal 'around 'PC-include-file)
 222          (ad-activate 'read-file-name-internal))
 223         ((not PC-disable-includes)
 224          (ad-enable-advice 'read-file-name-internal 'around 'PC-include-file)
 225          (ad-activate 'read-file-name-internal)))
 226   ;; Adjust the completion selection in *Completion* buffers to the way
 227   ;; we work.  The default minibuffer completion code only completes the
 228   ;; text before point and leaves the text after point alone (new in
 229   ;; Emacs-22).  In contrast we use the whole text and we even sometimes
 230   ;; move point to a place before EOB, to indicate the first position where
 231   ;; there's a difference, so when the user uses choose-completion, we have
 232   ;; to trick choose-completion into replacing the whole minibuffer text
 233   ;; rather than only the text before point.  --Stef
 234   (funcall
 235    (if partial-completion-mode 'add-hook 'remove-hook)
 236    'choose-completion-string-functions
 237    (lambda (&rest x) (goto-char (point-max)) nil))
 238   ;; Build the env-completion and mapping table.
 239   (when (and partial-completion-mode (null PC-env-vars-alist))
 240     (setq PC-env-vars-alist
 241           (mapcar (lambda (string)
 242                     (let ((d (string-match "=" string)))
 243                       (cons (concat "$" (substring string 0 d))
 244                             (and d (substring string (1+ d))))))
 245                   process-environment))))
 246
 247 \f
 248 (defun PC-complete ()
 249   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 250 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 251 name which consists of three or more words, the first beginning with \"b\"
 252 and the third beginning with \"di\".
 253
 254 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 255 `beginning-of-defun', so this would produce a list of completions
 256 just like when normal Emacs completions are ambiguous.
 257
 258 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 259 \".\", and SPC."
 260   (interactive)
 261   (if (PC-was-meta-key)
 262       (minibuffer-complete)
 263     ;; If the previous command was not this one,
 264     ;; never scroll, always retry completion.
 265     (or (eq last-command this-command)
 266         (setq minibuffer-scroll-window nil))
 267     (let ((window minibuffer-scroll-window))
 268       ;; If there's a fresh completion window with a live buffer,
 269       ;; and this command is repeated, scroll that window.
 270       (if (and window (window-buffer window)
 271                (buffer-name (window-buffer window)))
 272           (with-current-buffer (window-buffer window)
 273             (if (pos-visible-in-window-p (point-max) window)
 274                 (set-window-start window (point-min) nil)
 275               (scroll-other-window)))
 276         (PC-do-completion nil)))))
 277
 278
 279 (defun PC-complete-word ()
 280   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 281 See `PC-complete' for details.
 282 This can be bound to other keys, like `-' and `.', if you wish."
 283   (interactive)
 284   (if (eq (PC-was-meta-key) PC-meta-flag)
 285       (if (eq last-command-char ? )
 286           (minibuffer-complete-word)
 287         (self-insert-command 1))
 288     (self-insert-command 1)
 289     (if (eobp)
 290         (PC-do-completion 'word))))
 291
 292
 293 (defun PC-complete-space ()
 294   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 295 See `PC-complete' for details.
 296 This is suitable for binding to other keys which should act just like SPC."
 297   (interactive)
 298   (if (eq (PC-was-meta-key) PC-meta-flag)
 299       (minibuffer-complete-word)
 300     (insert " ")
 301     (if (eobp)
 302         (PC-do-completion 'word))))
 303
 304
 305 (defun PC-complete-and-exit ()
 306   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 307 See `PC-complete' for details."
 308   (interactive)
 309   (if (eq (PC-was-meta-key) PC-meta-flag)
 310       (minibuffer-complete-and-exit)
 311     (PC-do-complete-and-exit)))
 312
 313 (defun PC-force-complete-and-exit ()
 314   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 315 See `PC-complete' for details."
 316   (interactive)
 317   (let ((minibuffer-completion-confirm nil))
 318     (PC-do-complete-and-exit)))
 319
 320 (defun PC-do-complete-and-exit ()
 321   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 322       (exit-minibuffer)
 323     (let ((flag (PC-do-completion 'exit)))
 324       (and flag
 325            (if (or (eq flag 'complete)
 326                    (not minibuffer-completion-confirm))
 327                (exit-minibuffer)
 328              (PC-temp-minibuffer-message " [Confirm]"))))))
 329
 330
 331 (defun PC-completion-help ()
 332   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 333 See `PC-complete' for details."
 334   (interactive)
 335   (if (eq (PC-was-meta-key) PC-meta-flag)
 336       (minibuffer-completion-help)
 337     (PC-do-completion 'help)))
 338
 339 (defun PC-was-meta-key ()
 340   (or (/= (length (this-command-keys)) 1)
 341       (let ((key (aref (this-command-keys) 0)))
 342         (if (integerp key)
 343             (>= key 128)
 344           (not (null (memq 'meta (event-modifiers key))))))))
 345
 346
 347 (defvar PC-ignored-extensions 'empty-cache)
 348 (defvar PC-delims 'empty-cache)
 349 (defvar PC-ignored-regexp nil)
 350 (defvar PC-word-failed-flag nil)
 351 (defvar PC-delim-regex nil)
 352 (defvar PC-ndelims-regex nil)
 353 (defvar PC-delims-list nil)
 354
 355 (defvar PC-completion-as-file-name-predicate
 356   (lambda () minibuffer-completing-file-name)
 357   "A function testing whether a minibuffer completion now will work filename-style.
 358 The function takes no arguments, and typically looks at the value
 359 of `minibuffer-completion-table' and the minibuffer contents.")
 360
 361 (defun PC-do-completion (&optional mode beg end)
 362   (or beg (setq beg (minibuffer-prompt-end)))
 363   (or end (setq end (point-max)))
 364   (let* ((table minibuffer-completion-table)
 365          (pred minibuffer-completion-predicate)
 366          (filename (funcall PC-completion-as-file-name-predicate))
 367          (dirname nil)
 368          (dirlength 0)
 369          (str (buffer-substring beg end))
 370          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 371          (ambig nil)
 372          basestr
 373          env-on
 374          regex
 375          p offset
 376          (poss nil)
 377          helpposs
 378          (case-fold-search completion-ignore-case))
 379
 380     ;; Check if buffer contents can already be considered complete
 381     (if (and (eq mode 'exit)
 382              (test-completion str table pred))
 383         'complete
 384
 385       ;; Do substitutions in directory names
 386       (and filename
 387            (setq basestr (or (file-name-directory str) ""))
 388            (setq dirlength (length basestr))
 389            ;; Do substitutions in directory names
 390            (setq p (substitute-in-file-name basestr))
 391            (not (string-equal basestr p))
 392            (setq str (concat p (file-name-nondirectory str)))
 393            (progn
 394              (delete-region beg end)
 395              (insert str)
 396              (setq end (+ beg (length str)))))
 397
 398       ;; Prepare various delimiter strings
 399       (or (equal PC-word-delimiters PC-delims)
 400           (setq PC-delims PC-word-delimiters
 401                 PC-delim-regex (concat "[" PC-delims "]")
 402                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 403                 PC-delims-list (append PC-delims nil)))
 404
 405       ;; Add wildcards if necessary
 406       (and filename
 407            (let ((dir (file-name-directory str))
 408                  (file (file-name-nondirectory str))
 409                  ;; The base dir for file-completion is passed in `predicate'.
 410                  (default-directory (expand-file-name pred)))
 411              (while (and (stringp dir) (not (file-directory-p dir)))
 412                (setq dir (directory-file-name dir))
 413                (setq file (concat (replace-regexp-in-string
 414                                    PC-delim-regex "*\\&"
 415                                    (file-name-nondirectory dir))
 416                                   "*/" file))
 417                (setq dir (file-name-directory dir)))
 418              (setq str (concat dir file))))
 419
 420       ;; Look for wildcard expansions in directory name
 421       (and filename
 422            (string-match "\\*.*/" str)
 423            (let ((pat str)
 424                  ;; The base dir for file-completion is passed in `predicate'.
 425                  (default-directory (expand-file-name pred))
 426                  files)
 427              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 428              (while (setq p (string-match PC-delim-regex pat p))
 429                (setq pat (concat (substring pat 0 p)
 430                                  "*"
 431                                  (substring pat p))
 432                      p (+ p 2)))
 433              (setq files (PC-expand-many-files (concat pat "*")))
 434              (if files
 435                  (let ((dir (file-name-directory (car files)))
 436                        (p files))
 437                    (while (and (setq p (cdr p))
 438                                (equal dir (file-name-directory (car p)))))
 439                    (if p
 440                        (setq filename nil table nil pred nil
 441                              ambig t)
 442                      (delete-region beg end)
 443                      (setq str (concat dir (file-name-nondirectory str)))
 444                      (insert str)
 445                      (setq end (+ beg (length str)))))
 446                (setq filename nil table nil pred nil))))
 447
 448       ;; Strip directory name if appropriate
 449       (if filename
 450           (if incname
 451               (setq basestr (substring str incname)
 452                     dirname (substring str 0 incname))
 453             (setq basestr (file-name-nondirectory str)
 454                   dirname (file-name-directory str))
 455             ;; Make sure str is consistent with its directory and basename
 456             ;; parts.  This is important on DOZe'NT systems when str only
 457             ;; includes a drive letter, like in "d:".
 458             (setq str (concat dirname basestr)))
 459         (setq basestr str))
 460
 461       ;; Convert search pattern to a standard regular expression
 462       (setq regex (regexp-quote basestr)
 463             offset (if (and (> (length regex) 0)
 464                             (not (eq (aref basestr 0) ?\*))
 465                             (or (eq PC-first-char t)
 466                                 (and PC-first-char filename))) 1 0)
 467             p offset)
 468       (while (setq p (string-match PC-delim-regex regex p))
 469         (if (eq (aref regex p) ? )
 470             (setq regex (concat (substring regex 0 p)
 471                                 PC-ndelims-regex
 472                                 PC-delim-regex
 473                                 (substring regex (1+ p)))
 474                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 475           (let ((bump (if (memq (aref regex p)
 476                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 477                           -1 0)))
 478             (setq regex (concat (substring regex 0 (+ p bump))
 479                                 PC-ndelims-regex
 480                                 (substring regex (+ p bump)))
 481                   p (+ p (length PC-ndelims-regex) 1)))))
 482       (setq p 0)
 483       (if filename
 484           (while (setq p (string-match "\\\\\\*" regex p))
 485             (setq regex (concat (substring regex 0 p)
 486                                 "[^/]*"
 487                                 (substring regex (+ p 2))))))
 488       ;;(setq the-regex regex)
 489       (setq regex (concat "\\`" regex))
 490
 491       (and (> (length basestr) 0)
 492            (= (aref basestr 0) ?$)
 493            (setq env-on t
 494                  table PC-env-vars-alist
 495                  pred nil))
 496
 497       ;; Find an initial list of possible completions
 498       (if (not (setq p (string-match (concat PC-delim-regex
 499                                              (if filename "\\|\\*" ""))
 500                                      str
 501                                      (+ (length dirname) offset))))
 502
 503           ;; Minibuffer contains no hyphens -- simple case!
 504           (setq poss (all-completions (if env-on
 505                                           basestr str)
 506                                       table
 507                                       pred))
 508
 509         ;; Use all-completions to do an initial cull.  This is a big win,
 510         ;; since all-completions is written in C!
 511         (let ((compl (all-completions (if env-on
 512                                           (file-name-nondirectory (substring str 0 p))
 513                                         (substring str 0 p))
 514                                         table
 515                                         pred)))
 516           (setq p compl)
 517           (while p
 518             (and (string-match regex (car p))
 519                  (progn
 520                    (set-text-properties 0 (length (car p)) '() (car p))
 521                    (setq poss (cons (car p) poss))))
 522             (setq p (cdr p)))))
 523
 524       ;; Now we have a list of possible completions
 525       (cond
 526
 527        ;; No valid completions found
 528        ((null poss)
 529         (if (and (eq mode 'word)
 530                  (not PC-word-failed-flag))
 531             (let ((PC-word-failed-flag t))
 532               (delete-backward-char 1)
 533               (PC-do-completion 'word))
 534           (beep)
 535           (PC-temp-minibuffer-message (if ambig
 536                                           " [Ambiguous dir name]"
 537                                         (if (eq mode 'help)
 538                                             " [No completions]"
 539                                           " [No match]")))
 540           nil))
 541
 542        ;; More than one valid completion found
 543        ((or (cdr (setq helpposs poss))
 544             (memq mode '(help word)))
 545
 546         ;; Handle completion-ignored-extensions
 547         (and filename
 548              (not (eq mode 'help))
 549              (let ((p2 poss))
 550
 551                ;; Build a regular expression representing the extensions list
 552                (or (equal completion-ignored-extensions PC-ignored-extensions)
 553                    (setq PC-ignored-regexp
 554                          (concat "\\("
 555                                  (mapconcat
 556                                   'regexp-quote
 557                                   (setq PC-ignored-extensions
 558                                         completion-ignored-extensions)
 559                                   "\\|")
 560                                  "\\)\\'")))
 561
 562                ;; Check if there are any without an ignored extension.
 563                ;; Also ignore `.' and `..'.
 564                (setq p nil)
 565                (while p2
 566                  (or (string-match PC-ignored-regexp (car p2))
 567                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 568                      (setq p (cons (car p2) p)))
 569                  (setq p2 (cdr p2)))
 570
 571                ;; If there are "good" names, use them
 572                (and p (setq poss p))))
 573
 574         ;; Is the actual string one of the possible completions?
 575         (setq p (and (not (eq mode 'help)) poss))
 576         (while (and p
 577                     (not (string-equal (car p) basestr)))
 578           (setq p (cdr p)))
 579         (and p (null mode)
 580              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 581         (if (and p
 582                  (not (and (null mode)
 583                            (eq this-command last-command))))
 584             t
 585
 586           ;; If ambiguous, try for a partial completion
 587           (let ((improved nil)
 588                 prefix
 589                 (pt nil)
 590                 (skip "\\`"))
 591
 592             ;; Check if next few letters are the same in all cases
 593             (if (and (not (eq mode 'help))
 594                      (setq prefix (try-completion "" (mapcar 'list poss))))
 595                 (let ((first t) i)
 596                   (if (eq mode 'word)
 597                       (setq prefix (PC-chop-word prefix basestr)))
 598                   (goto-char (+ beg (length dirname)))
 599                   (while (and (progn
 600                                 (setq i 0)
 601                                 (while (< i (length prefix))
 602                                   (if (and (< (point) end)
 603                                            (eq (aref prefix i)
 604                                                (following-char)))
 605                                       (forward-char 1)
 606                                     (if (and (< (point) end)
 607                                              (or (and (looking-at " ")
 608                                                       (memq (aref prefix i)
 609                                                             PC-delims-list))
 610                                                  (eq (downcase (aref prefix i))
 611                                                      (downcase
 612                                                       (following-char)))))
 613                                         (progn
 614                                           (delete-char 1)
 615                                           (setq end (1- end)))
 616                                       (and filename (looking-at "\\*")
 617                                            (progn
 618                                              (delete-char 1)
 619                                              (setq end (1- end))))
 620                                       (setq improved t))
 621                                     (insert (substring prefix i (1+ i)))
 622                                     (setq end (1+ end)))
 623                                   (setq i (1+ i)))
 624                                 (or pt (setq pt (point)))
 625                                 (looking-at PC-delim-regex))
 626                               (setq skip (concat skip
 627                                                  (regexp-quote prefix)
 628                                                  PC-ndelims-regex)
 629                                     prefix (try-completion
 630                                             ""
 631                                             (mapcar
 632                                              (function
 633                                               (lambda (x)
 634                                                 (list
 635                                                  (and (string-match skip x)
 636                                                       (substring
 637                                                        x
 638                                                        (match-end 0))))))
 639                                              poss)))
 640                               (or (> i 0) (> (length prefix) 0))
 641                               (or (not (eq mode 'word))
 642                                   (and first (> (length prefix) 0)
 643                                        (setq first nil
 644                                              prefix (substring prefix 0 1))))))
 645                   (goto-char (if (eq mode 'word) end
 646                                (or pt beg)))))
 647
 648             (if (and (eq mode 'word)
 649                      (not PC-word-failed-flag))
 650
 651                 (if improved
 652
 653                     ;; We changed it... would it be complete without the space?
 654                     (if (test-completion (buffer-substring 1 (1- end))
 655                                           table pred)
 656                         (delete-region (1- end) end)))
 657
 658               (if improved
 659
 660                   ;; We changed it... enough to be complete?
 661                   (and (eq mode 'exit)
 662                        (test-completion (field-string) table pred))
 663
 664                 ;; If totally ambiguous, display a list of completions
 665                 (if (or (eq completion-auto-help t)
 666                         (and completion-auto-help
 667                              (eq last-command this-command))
 668                         (eq mode 'help))
 669                     (with-output-to-temp-buffer "*Completions*"
 670                       (display-completion-list (sort helpposs 'string-lessp))
 671                       (with-current-buffer standard-output
 672                         ;; Record which part of the buffer we are completing
 673                         ;; so that choosing a completion from the list
 674                         ;; knows how much old text to replace.
 675                         (setq completion-base-size dirlength)))
 676                   (PC-temp-minibuffer-message " [Next char not unique]"))
 677                 nil)))))
 678
 679        ;; Only one possible completion
 680        (t
 681         (if (and (equal basestr (car poss))
 682                  (not (and env-on filename)))
 683             (if (null mode)
 684                 (PC-temp-minibuffer-message " [Sole completion]"))
 685           (delete-region beg end)
 686           (insert (format "%s"
 687                           (if filename
 688                               (substitute-in-file-name (concat dirname (car poss)))
 689                             (car poss)))))
 690         t)))))
 691
 692 (defun PC-chop-word (new old)
 693   (let ((i -1)
 694         (j -1))
 695     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 696                 (setq j (string-match PC-delim-regex new (1+ j)))))
 697     (if (and j
 698              (or (not PC-word-failed-flag)
 699                  (setq j (string-match PC-delim-regex new (1+ j)))))
 700         (substring new 0 (1+ j))
 701       new)))
 702
 703 (defvar PC-not-minibuffer nil)
 704
 705 (defun PC-temp-minibuffer-message (message)
 706   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 707   (cond (PC-not-minibuffer
 708          (message message)
 709          (sit-for 2)
 710          (message ""))
 711         ((fboundp 'temp-minibuffer-message)
 712          (temp-minibuffer-message message))
 713         (t
 714          (let ((point-max (point-max)))
 715            (save-excursion
 716              (goto-char point-max)
 717              (insert message))
 718            (let ((inhibit-quit t))
 719              (sit-for 2)
 720              (delete-region point-max (point-max))
 721              (when quit-flag
 722                (setq quit-flag nil
 723                      unread-command-events '(7))))))))
 724
 725
 726 (defun PC-lisp-complete-symbol ()
 727   "Perform completion on Lisp symbol preceding point.
 728 That symbol is compared against the symbols that exist
 729 and any additional characters determined by what is there
 730 are inserted.
 731 If the symbol starts just after an open-parenthesis,
 732 only symbols with function definitions are considered.
 733 Otherwise, all symbols with function definitions, values
 734 or properties are considered."
 735   (interactive)
 736   (let* ((end (point))
 737          (beg (save-excursion
 738                 (with-syntax-table lisp-mode-syntax-table
 739                   (backward-sexp 1)
 740                   (while (= (char-syntax (following-char)) ?\')
 741                     (forward-char 1))
 742                   (point))))
 743          (minibuffer-completion-table obarray)
 744          (minibuffer-completion-predicate
 745           (if (eq (char-after (1- beg)) ?\()
 746               'fboundp
 747             (function (lambda (sym)
 748                         (or (boundp sym) (fboundp sym)
 749                             (symbol-plist sym))))))
 750          (PC-not-minibuffer t))
 751     (PC-do-completion nil beg end)))
 752
 753 (defun PC-complete-as-file-name ()
 754    "Perform completion on file names preceding point.
 755  Environment vars are converted to their values."
 756    (interactive)
 757    (let* ((end (point))
 758           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 759                                        (point-min) t)
 760                    (+ (point) 2)
 761                    (point-min)))
 762           (minibuffer-completion-table 'read-file-name-internal)
 763           (minibuffer-completion-predicate "")
 764           (PC-not-minibuffer t))
 765      (goto-char end)
 766      (PC-do-completion nil beg end)))
 767
 768 ;; Use the shell to do globbing.
 769 ;; This could now use file-expand-wildcards instead.
 770
 771 (defun PC-expand-many-files (name)
 772   (with-current-buffer (generate-new-buffer " *Glob Output*")
 773     (erase-buffer)
 774     (shell-command (concat "echo " name) t)
 775     (goto-char (point-min))
 776     ;; CSH-style shells were known to output "No match", whereas
 777     ;; SH-style shells tend to simply output `name' when no match is found.
 778     (if (looking-at (concat ".*No match\\|\\(^\\| \\)\\("
 779                             (regexp-quote name)
 780                             "\\|"
 781                             (regexp-quote (expand-file-name name))
 782                             "\\)\\( \\|$\\)"))
 783         nil
 784       (insert "(\"")
 785       (while (search-forward " " nil t)
 786         (delete-backward-char 1)
 787         (insert "\" \""))
 788       (goto-char (point-max))
 789       (delete-backward-char 1)
 790       (insert "\")")
 791       (goto-char (point-min))
 792       (let ((files (read (current-buffer))) (p nil))
 793         (kill-buffer (current-buffer))
 794         (or (equal completion-ignored-extensions PC-ignored-extensions)
 795             (setq PC-ignored-regexp
 796                   (concat "\\("
 797                           (mapconcat
 798                            'regexp-quote
 799                            (setq PC-ignored-extensions
 800                                  completion-ignored-extensions)
 801                            "\\|")
 802                           "\\)\\'")))
 803         (setq p nil)
 804         (while files
 805           ;; This whole process of going through to shell, to echo, and
 806           ;; finally parsing the output is a hack.  It breaks as soon as
 807           ;; there are spaces in the file names or when the no-match
 808           ;; message changes.  To make up for it, we check that what we read
 809           ;; indeed exists, so we may miss some files, but we at least won't
 810           ;; list non-existent ones.
 811           (or (not (file-exists-p (car files)))
 812               (string-match PC-ignored-regexp (car files))
 813               (setq p (cons (car files) p)))
 814           (setq files (cdr files)))
 815         p))))
 816
 817 ;; Facilities for loading C header files.  This is independent from the
 818 ;; main completion code.  See also the variable `PC-include-file-path'
 819 ;; at top of this file.
 820
 821 (defun PC-look-for-include-file ()
 822   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 823       (let ((name (substring (buffer-file-name)
 824                              (match-beginning 1) (match-end 1)))
 825             (punc (aref (buffer-file-name) (match-beginning 0)))
 826             (path nil)
 827             new-buf)
 828         (kill-buffer (current-buffer))
 829         (if (equal name "")
 830             (with-current-buffer (car (buffer-list))
 831               (save-excursion
 832                 (beginning-of-line)
 833                 (if (looking-at
 834                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 835                     (setq name (buffer-substring (match-beginning 1)
 836                                                  (match-end 1))
 837                           punc (char-after (1- (match-beginning 1))))
 838                   ;; Suggested by Frank Siebenlist:
 839                   (if (or (looking-at
 840                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 841                           (looking-at
 842                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 843                           (looking-at
 844                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 845                       (progn
 846                         (setq name (buffer-substring (match-beginning 1)
 847                                                      (match-end 1))
 848                               punc ?\<
 849                               path load-path)
 850                         (if (string-match "\\.elc$" name)
 851                             (setq name (substring name 0 -1))
 852                           (or (string-match "\\.el$" name)
 853                               (setq name (concat name ".el")))))
 854                     (error "Not on an #include line"))))))
 855         (or (string-match "\\.[[:alnum:]]+$" name)
 856             (setq name (concat name ".h")))
 857         (if (eq punc ?\<)
 858             (let ((path (or path (PC-include-file-path))))
 859               (while (and path
 860                           (not (file-exists-p
 861                                 (concat (file-name-as-directory (car path))
 862                                         name))))
 863                 (setq path (cdr path)))
 864               (if path
 865                   (setq name (concat (file-name-as-directory (car path)) name))
 866                 (error "No such include file: <%s>" name)))
 867           (let ((dir (with-current-buffer (car (buffer-list))
 868                        default-directory)))
 869             (if (file-exists-p (concat dir name))
 870                 (setq name (concat dir name))
 871               (error "No such include file: `%s'" name))))
 872         (setq new-buf (get-file-buffer name))
 873         (if new-buf
 874             ;; no need to verify last-modified time for this!
 875             (set-buffer new-buf)
 876           (set-buffer (create-file-buffer name))
 877           (erase-buffer)
 878           (insert-file-contents name t))
 879         ;; Returning non-nil with the new buffer current
 880         ;; is sufficient to tell find-file to use it.
 881         t)
 882     nil))
 883
 884 (defun PC-include-file-path ()
 885   (or PC-include-file-path
 886       (let ((env (getenv "INCPATH"))
 887             (path nil)
 888             pos)
 889         (or env (error "No include file path specified"))
 890         (while (setq pos (string-match ":[^:]+$" env))
 891           (setq path (cons (substring env (1+ pos)) path)
 892                 env (substring env 0 pos)))
 893         path)))
 894
 895 ;; This is adapted from lib-complete.el, by Mike Williams.
 896 (defun PC-include-file-all-completions (file search-path &optional full)
 897   "Return all completions for FILE in any directory on SEARCH-PATH.
 898 If optional third argument FULL is non-nil, returned pathnames should be
 899 absolute rather than relative to some directory on the SEARCH-PATH."
 900   (setq search-path
 901         (mapcar (lambda (dir)
 902                   (if dir (file-name-as-directory dir) default-directory))
 903                 search-path))
 904   (if (file-name-absolute-p file)
 905       ;; It's an absolute file name, so don't need search-path
 906       (progn
 907         (setq file (expand-file-name file))
 908         (file-name-all-completions
 909          (file-name-nondirectory file) (file-name-directory file)))
 910     (let ((subdir (file-name-directory file))
 911           (ndfile (file-name-nondirectory file))
 912           file-lists)
 913       ;; Append subdirectory part to each element of search-path
 914       (if subdir
 915           (setq search-path
 916                 (mapcar (lambda (dir) (concat dir subdir))
 917                         search-path)
 918                 file ))
 919       ;; Make list of completions in each directory on search-path
 920       (while search-path
 921         (let* ((dir (car search-path))
 922                (subdir (if full dir subdir)))
 923           (if (file-directory-p dir)
 924               (progn
 925                 (setq file-lists
 926                       (cons
 927                        (mapcar (lambda (file) (concat subdir file))
 928                                (file-name-all-completions ndfile
 929                                                           (car search-path)))
 930                        file-lists))))
 931           (setq search-path (cdr search-path))))
 932       ;; Compress out duplicates while building complete list (slloooow!)
 933       (let ((sorted (sort (apply 'nconc file-lists)
 934                           (lambda (x y) (not (string-lessp x y)))))
 935             compressed)
 936         (while sorted
 937           (if (equal (car sorted) (car compressed)) nil
 938             (setq compressed (cons (car sorted) compressed)))
 939           (setq sorted (cdr sorted)))
 940         compressed))))
 941
 942 (defadvice read-file-name-internal (around PC-include-file disable)
 943   (if (string-match "<\\([^\"<>]*\\)>?\\'" (ad-get-arg 0))
 944       (let* ((string (ad-get-arg 0))
 945              (action (ad-get-arg 2))
 946              (name (substring string (match-beginning 1) (match-end 1)))
 947              (str2 (substring string (match-beginning 0)))
 948              (completion-table
 949               (mapcar (lambda (x) (format "<%s>" x))
 950                       (PC-include-file-all-completions
 951                        name (PC-include-file-path)))))
 952         (setq ad-return-value
 953               (cond
 954                ((not completion-table) nil)
 955                ((eq action 'lambda) (test-completion str2 completion-table nil))
 956                ((eq action nil) (try-completion str2 completion-table nil))
 957                ((eq action t) (all-completions str2 completion-table nil)))))
 958     ad-do-it))
 959 \f
 960
 961 (provide 'complete)
 962
 963 ;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
 964 ;;; complete.el ends here