lisp/emacs-lisp/timer.el

   1 ;;; timer.el --- run a function with args at some time in future
   2
   3 ;; Copyright (C) 1996, 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Package: emacs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package gives you the capability to run Emacs Lisp commands at
  26 ;; specified times in the future, either as one-shots or periodically.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl-lib))
  31
  32 (cl-defstruct (timer
  33                (:constructor nil)
  34                (:copier nil)
  35                (:constructor timer-create ())
  36                (:type vector)
  37                (:conc-name timer--))
  38   ;; nil if the timer is active (waiting to be triggered),
  39   ;; non-nil if it is inactive ("already triggered", in theory).
  40   (triggered t)
  41   ;; Time of next trigger: for normal timers, absolute time, for idle timers,
  42   ;; time relative to idle-start.
  43   high-seconds low-seconds usecs
  44   ;; For normal timers, time between repetitions, or nil.  For idle timers,
  45   ;; non-nil iff repeated.
  46   repeat-delay
  47   function args                         ;What to do when triggered.
  48   idle-delay                            ;If non-nil, this is an idle-timer.
  49   psecs)
  50
  51 (defun timerp (object)
  52   "Return t if OBJECT is a timer."
  53   (and (vectorp object) (= (length object) 9)))
  54
  55 (defsubst timer--check (timer)
  56   (or (timerp timer) (signal 'wrong-type-argument (list #'timerp timer))))
  57
  58 (defun timer--time-setter (timer time)
  59   (timer--check timer)
  60   (setf (timer--high-seconds timer) (pop time))
  61   (let ((low time) (usecs 0) (psecs 0))
  62     (when (consp time)
  63       (setq low (pop time))
  64       (when time
  65         (setq usecs (pop time))
  66         (when time
  67           (setq psecs (car time)))))
  68     (setf (timer--low-seconds timer) low)
  69     (setf (timer--usecs timer) usecs)
  70     (setf (timer--psecs timer) psecs)
  71     time))
  72
  73 ;; Pseudo field `time'.
  74 (defun timer--time (timer)
  75   (declare (gv-setter timer--time-setter))
  76   (list (timer--high-seconds timer)
  77         (timer--low-seconds timer)
  78         (timer--usecs timer)
  79         (timer--psecs timer)))
  80
  81 (defun timer-set-time (timer time &optional delta)
  82   "Set the trigger time of TIMER to TIME.
  83 TIME must be in the internal format returned by, e.g., `current-time'.
  84 If optional third argument DELTA is a positive number, make the timer
  85 fire repeatedly that many seconds apart."
  86   (setf (timer--time timer) time)
  87   (setf (timer--repeat-delay timer) (and (numberp delta) (> delta 0) delta))
  88   timer)
  89
  90 (defun timer-set-idle-time (timer secs &optional repeat)
  91   ;; FIXME: Merge with timer-set-time.
  92   "Set the trigger idle time of TIMER to SECS.
  93 SECS may be an integer, floating point number, or the internal
  94 time format returned by, e.g., `current-idle-time'.
  95 If optional third argument REPEAT is non-nil, make the timer
  96 fire each time Emacs is idle for that many seconds."
  97   (setf (timer--time timer) (if (consp secs) secs (seconds-to-time secs)))
  98   (setf (timer--repeat-delay timer) repeat)
  99   timer)
 100
 101 (defun timer-next-integral-multiple-of-time (time secs)
 102   "Yield the next value after TIME that is an integral multiple of SECS.
 103 More precisely, the next value, after TIME, that is an integral multiple
 104 of SECS seconds since the epoch.  SECS may be a fraction."
 105   (let* ((trillion 1e12)
 106          (time-sec (+ (nth 1 time)
 107                       (* 65536.0 (nth 0 time))))
 108          (delta-sec (mod (- time-sec) secs))
 109          (next-sec (+ time-sec (ffloor delta-sec)))
 110          (next-sec-psec (ffloor (* trillion (mod delta-sec 1))))
 111          (sub-time-psec (+ (or (nth 3 time) 0)
 112                            (* 1e6 (nth 2 time))))
 113          (psec-diff (- sub-time-psec next-sec-psec)))
 114     (if (and (<= next-sec time-sec) (< 0 psec-diff))
 115         (setq next-sec-psec (+ sub-time-psec
 116                                (mod (- psec-diff) (* trillion secs)))))
 117     (setq next-sec (+ next-sec (floor next-sec-psec trillion)))
 118     (setq next-sec-psec (mod next-sec-psec trillion))
 119     (list (floor next-sec 65536)
 120           (floor (mod next-sec 65536))
 121           (floor next-sec-psec 1000000)
 122           (floor (mod next-sec-psec 1000000)))))
 123
 124 (defun timer-relative-time (time secs &optional usecs psecs)
 125   "Advance TIME by SECS seconds and optionally USECS microseconds
 126 and PSECS picoseconds.  SECS may be either an integer or a
 127 floating point number."
 128   (let ((delta (if (floatp secs)
 129                    (seconds-to-time secs)
 130                  (list (floor secs 65536) (mod secs 65536)))))
 131     (if (or usecs psecs)
 132         (setq delta (time-add delta (list 0 0 (or usecs 0) (or psecs 0)))))
 133     (time-add time delta)))
 134
 135 (defun timer--time-less-p (t1 t2)
 136   "Say whether time value T1 is less than time value T2."
 137   (time-less-p (timer--time t1) (timer--time t2)))
 138
 139 (defun timer-inc-time (timer secs &optional usecs psecs)
 140   "Increment the time set in TIMER by SECS seconds, USECS microseconds,
 141 and PSECS picoseconds.  SECS may be a fraction.  If USECS or PSECS are
 142 omitted, they are treated as zero."
 143   (setf (timer--time timer)
 144         (timer-relative-time (timer--time timer) secs usecs psecs)))
 145
 146 (defun timer-set-time-with-usecs (timer time usecs &optional delta)
 147   "Set the trigger time of TIMER to TIME plus USECS.
 148 TIME must be in the internal format returned by, e.g., `current-time'.
 149 The microsecond count from TIME is ignored, and USECS is used instead.
 150 If optional fourth argument DELTA is a positive number, make the timer
 151 fire repeatedly that many seconds apart."
 152   (declare (obsolete "use `timer-set-time' and `timer-inc-time' instead."
 153                      "22.1"))
 154   (setf (timer--time timer) time)
 155   (setf (timer--usecs timer) usecs)
 156   (setf (timer--psecs timer) 0)
 157   (setf (timer--repeat-delay timer) (and (numberp delta) (> delta 0) delta))
 158   timer)
 159
 160 (defun timer-set-function (timer function &optional args)
 161   "Make TIMER call FUNCTION with optional ARGS when triggering."
 162   (timer--check timer)
 163   (setf (timer--function timer) function)
 164   (setf (timer--args timer) args)
 165   timer)
 166 \f
 167 (defun timer--activate (timer &optional triggered-p reuse-cell idle)
 168   (if (and (timerp timer)
 169            (integerp (timer--high-seconds timer))
 170            (integerp (timer--low-seconds timer))
 171            (integerp (timer--usecs timer))
 172            (integerp (timer--psecs timer))
 173            (timer--function timer))
 174       (let ((timers (if idle timer-idle-list timer-list))
 175             last)
 176         ;; Skip all timers to trigger before the new one.
 177         (while (and timers (timer--time-less-p (car timers) timer))
 178           (setq last timers
 179                 timers (cdr timers)))
 180         (if reuse-cell
 181             (progn
 182               (setcar reuse-cell timer)
 183               (setcdr reuse-cell timers))
 184           (setq reuse-cell (cons timer timers)))
 185         ;; Insert new timer after last which possibly means in front of queue.
 186         (setf (cond (last (cdr last))
 187                     (idle timer-idle-list)
 188                     (t    timer-list))
 189               reuse-cell)
 190         (setf (timer--triggered timer) triggered-p)
 191         (setf (timer--idle-delay timer) idle)
 192         nil)
 193     (error "Invalid or uninitialized timer")))
 194
 195 (defun timer-activate (timer &optional triggered-p reuse-cell)
 196   "Insert TIMER into `timer-list'.
 197 If TRIGGERED-P is t, make TIMER inactive (put it on the list, but
 198 mark it as already triggered).  To remove it, use `cancel-timer'.
 199
 200 REUSE-CELL, if non-nil, is a cons cell to reuse when inserting
 201 TIMER into `timer-list' (usually a cell removed from that list by
 202 `cancel-timer-internal'; using this reduces consing for repeat
 203 timers).  If nil, allocate a new cell."
 204   (timer--activate timer triggered-p reuse-cell nil))
 205
 206 (defun timer-activate-when-idle (timer &optional dont-wait reuse-cell)
 207   "Insert TIMER into `timer-idle-list'.
 208 This arranges to activate TIMER whenever Emacs is next idle.
 209 If optional argument DONT-WAIT is non-nil, set TIMER to activate
 210 immediately \(see below\), or at the right time, if Emacs is
 211 already idle.
 212
 213 REUSE-CELL, if non-nil, is a cons cell to reuse when inserting
 214 TIMER into `timer-idle-list' (usually a cell removed from that
 215 list by `cancel-timer-internal'; using this reduces consing for
 216 repeat timers).  If nil, allocate a new cell.
 217
 218 Using non-nil DONT-WAIT is not recommended when activating an
 219 idle timer from an idle timer handler, if the timer being
 220 activated has an idleness time that is smaller or equal to
 221 the time of the current timer.  That's because the activated
 222 timer will fire right away."
 223   (timer--activate timer (not dont-wait) reuse-cell 'idle))
 224
 225 (defalias 'disable-timeout 'cancel-timer)
 226
 227 (defun cancel-timer (timer)
 228   "Remove TIMER from the list of active timers."
 229   (timer--check timer)
 230   (setq timer-list (delq timer timer-list))
 231   (setq timer-idle-list (delq timer timer-idle-list))
 232   nil)
 233
 234 (defun cancel-timer-internal (timer)
 235   "Remove TIMER from the list of active timers or idle timers.
 236 Only to be used in this file.  It returns the cons cell
 237 that was removed from the timer list."
 238   (let ((cell1 (memq timer timer-list))
 239         (cell2 (memq timer timer-idle-list)))
 240     (if cell1
 241         (setq timer-list (delq timer timer-list)))
 242     (if cell2
 243         (setq timer-idle-list (delq timer timer-idle-list)))
 244     (or cell1 cell2)))
 245
 246 (defun cancel-function-timers (function)
 247   "Cancel all timers which would run FUNCTION.
 248 This affects ordinary timers such as are scheduled by `run-at-time',
 249 and idle timers such as are scheduled by `run-with-idle-timer'."
 250   (interactive "aCancel timers of function: ")
 251   (dolist (timer timer-list)
 252     (if (eq (timer--function timer) function)
 253         (setq timer-list (delq timer timer-list))))
 254   (dolist (timer timer-idle-list)
 255     (if (eq (timer--function timer) function)
 256         (setq timer-idle-list (delq timer timer-idle-list)))))
 257 \f
 258 ;; Record the last few events, for debugging.
 259 (defvar timer-event-last nil
 260   "Last timer that was run.")
 261 (defvar timer-event-last-1 nil
 262   "Next-to-last timer that was run.")
 263 (defvar timer-event-last-2 nil
 264   "Third-to-last timer that was run.")
 265
 266 (defcustom timer-max-repeats 10
 267   "Maximum number of times to repeat a timer, if many repeats are delayed.
 268 Timer invocations can be delayed because Emacs is suspended or busy,
 269 or because the system's time changes.  If such an occurrence makes it
 270 appear that many invocations are overdue, this variable controls
 271 how many will really happen."
 272   :type 'integer
 273   :group 'internal)
 274
 275 (defun timer-until (timer time)
 276   "Calculate number of seconds from when TIMER will run, until TIME.
 277 TIMER is a timer, and stands for the time when its next repeat is scheduled.
 278 TIME is a time-list."
 279   (- (float-time time) (float-time (timer--time timer))))
 280
 281 (defun timer-event-handler (timer)
 282   "Call the handler for the timer TIMER.
 283 This function is called, by name, directly by the C code."
 284   (setq timer-event-last-2 timer-event-last-1)
 285   (setq timer-event-last-1 timer-event-last)
 286   (setq timer-event-last timer)
 287   (let ((inhibit-quit t))
 288     (timer--check timer)
 289     (let ((retrigger nil)
 290           (cell
 291            ;; Delete from queue.  Record the cons cell that was used.
 292            (cancel-timer-internal timer)))
 293       ;; If `cell' is nil, it means the timer was already canceled, so we
 294       ;; shouldn't be running it at all.  This can happen for example with the
 295       ;; following scenario (bug#17392):
 296       ;; - we run timers, starting with A (and remembering the rest as (B C)).
 297       ;; - A runs and a does a sit-for.
 298       ;; - during sit-for we run timer D which cancels timer B.
 299       ;; - timer A finally finishes, so we move on to timers B and C.
 300       (when cell
 301         ;; Re-schedule if requested.
 302         (if (timer--repeat-delay timer)
 303             (if (timer--idle-delay timer)
 304                 (timer-activate-when-idle timer nil cell)
 305               (timer-inc-time timer (timer--repeat-delay timer) 0)
 306               ;; If real time has jumped forward,
 307               ;; perhaps because Emacs was suspended for a long time,
 308               ;; limit how many times things get repeated.
 309               (if (and (numberp timer-max-repeats)
 310                        (< 0 (timer-until timer (current-time))))
 311                   (let ((repeats (/ (timer-until timer (current-time))
 312                                     (timer--repeat-delay timer))))
 313                     (if (> repeats timer-max-repeats)
 314                         (timer-inc-time timer (* (timer--repeat-delay timer)
 315                                                  repeats)))))
 316               ;; Place it back on the timer-list before running
 317               ;; timer--function, so it can cancel-timer itself.
 318               (timer-activate timer t cell)
 319               (setq retrigger t)))
 320         ;; Run handler.
 321         (condition-case-unless-debug err
 322             ;; Timer functions should not change the current buffer.
 323             ;; If they do, all kinds of nasty surprises can happen,
 324             ;; and it can be hellish to track down their source.
 325             (save-current-buffer
 326               (apply (timer--function timer) (timer--args timer)))
 327           (error (message "Error running timer%s: %S"
 328                           (if (symbolp (timer--function timer))
 329                               (format " `%s'" (timer--function timer)) "")
 330                           err)))
 331         (when (and retrigger
 332                    ;; If the timer's been canceled, don't "retrigger" it
 333                    ;; since it might still be in the copy of timer-list kept
 334                    ;; by keyboard.c:timer_check (bug#14156).
 335                    (memq timer timer-list))
 336           (setf (timer--triggered timer) nil))))))
 337
 338 ;; This function is incompatible with the one in levents.el.
 339 (defun timeout-event-p (event)
 340   "Non-nil if EVENT is a timeout event."
 341   (and (listp event) (eq (car event) 'timer-event)))
 342 \f
 343
 344 (declare-function diary-entry-time "diary-lib" (s))
 345
 346 (defun run-at-time (time repeat function &rest args)
 347   "Perform an action at time TIME.
 348 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 349 TIME should be one of: a string giving an absolute time like
 350 \"11:23pm\" (the acceptable formats are those recognized by
 351 `diary-entry-time'; note that such times are interpreted as times
 352 today, even if in the past); a string giving a relative time like
 353 \"2 hours 35 minutes\" (the acceptable formats are those
 354 recognized by `timer-duration'); nil meaning now; a number of
 355 seconds from now; a value from `encode-time'; or t (with non-nil
 356 REPEAT) meaning the next integral multiple of REPEAT.  REPEAT may
 357 be an integer or floating point number.  The action is to call
 358 FUNCTION with arguments ARGS.
 359
 360 This function returns a timer object which you can use in `cancel-timer'."
 361   (interactive "sRun at time: \nNRepeat interval: \naFunction: ")
 362
 363   (or (null repeat)
 364       (and (numberp repeat) (< 0 repeat))
 365       (error "Invalid repetition interval"))
 366
 367   ;; Special case: nil means "now" and is useful when repeating.
 368   (if (null time)
 369       (setq time (current-time)))
 370
 371   ;; Special case: t means the next integral multiple of REPEAT.
 372   (if (and (eq time t) repeat)
 373       (setq time (timer-next-integral-multiple-of-time (current-time) repeat)))
 374
 375   ;; Handle numbers as relative times in seconds.
 376   (if (numberp time)
 377       (setq time (timer-relative-time (current-time) time)))
 378
 379   ;; Handle relative times like "2 hours 35 minutes"
 380   (if (stringp time)
 381       (let ((secs (timer-duration time)))
 382         (if secs
 383             (setq time (timer-relative-time (current-time) secs)))))
 384
 385   ;; Handle "11:23pm" and the like.  Interpret it as meaning today
 386   ;; which admittedly is rather stupid if we have passed that time
 387   ;; already.  (Though only Emacs hackers hack Emacs at that time.)
 388   (if (stringp time)
 389       (progn
 390         (require 'diary-lib)
 391         (let ((hhmm (diary-entry-time time))
 392               (now (decode-time)))
 393           (if (>= hhmm 0)
 394               (setq time
 395                     (encode-time 0 (% hhmm 100) (/ hhmm 100) (nth 3 now)
 396                                  (nth 4 now) (nth 5 now) (nth 8 now)))))))
 397
 398   (or (consp time)
 399       (error "Invalid time format"))
 400
 401   (let ((timer (timer-create)))
 402     (timer-set-time timer time repeat)
 403     (timer-set-function timer function args)
 404     (timer-activate timer)
 405     timer))
 406
 407 (defun run-with-timer (secs repeat function &rest args)
 408   "Perform an action after a delay of SECS seconds.
 409 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 410 SECS and REPEAT may be integers or floating point numbers.
 411 The action is to call FUNCTION with arguments ARGS.
 412
 413 This function returns a timer object which you can use in `cancel-timer'."
 414   (interactive "sRun after delay (seconds): \nNRepeat interval: \naFunction: ")
 415   (apply 'run-at-time secs repeat function args))
 416
 417 (defun add-timeout (secs function object &optional repeat)
 418   "Add a timer to run SECS seconds from now, to call FUNCTION on OBJECT.
 419 If REPEAT is non-nil, repeat the timer every REPEAT seconds.
 420 This function is for compatibility; see also `run-with-timer'."
 421   (run-with-timer secs repeat function object))
 422
 423 (defun run-with-idle-timer (secs repeat function &rest args)
 424   "Perform an action the next time Emacs is idle for SECS seconds.
 425 The action is to call FUNCTION with arguments ARGS.
 426 SECS may be an integer, a floating point number, or the internal
 427 time format returned by, e.g., `current-idle-time'.
 428 If Emacs is currently idle, and has been idle for N seconds (N < SECS),
 429 then it will call FUNCTION in SECS - N seconds from now.  Using
 430 SECS <= N is not recommended if this function is invoked from an idle
 431 timer, because FUNCTION will then be called immediately.
 432
 433 If REPEAT is non-nil, do the action each time Emacs has been idle for
 434 exactly SECS seconds (that is, only once for each time Emacs becomes idle).
 435
 436 This function returns a timer object which you can use in `cancel-timer'."
 437   (interactive
 438    (list (read-from-minibuffer "Run after idle (seconds): " nil nil t)
 439          (y-or-n-p "Repeat each time Emacs is idle? ")
 440          (intern (completing-read "Function: " obarray 'fboundp t))))
 441   (let ((timer (timer-create)))
 442     (timer-set-function timer function args)
 443     (timer-set-idle-time timer secs repeat)
 444     (timer-activate-when-idle timer t)
 445     timer))
 446 \f
 447 (defvar with-timeout-timers nil
 448   "List of all timers used by currently pending `with-timeout' calls.")
 449
 450 (defmacro with-timeout (list &rest body)
 451   "Run BODY, but if it doesn't finish in SECONDS seconds, give up.
 452 If we give up, we run the TIMEOUT-FORMS and return the value of the last one.
 453 The timeout is checked whenever Emacs waits for some kind of external
 454 event (such as keyboard input, input from subprocesses, or a certain time);
 455 if the program loops without waiting in any way, the timeout will not
 456 be detected.
 457 \n(fn (SECONDS TIMEOUT-FORMS...) BODY)"
 458   (declare (indent 1) (debug ((form body) body)))
 459   (let ((seconds (car list))
 460         (timeout-forms (cdr list))
 461         (timeout (make-symbol "timeout")))
 462     `(let ((-with-timeout-value-
 463             (catch ',timeout
 464               (let* ((-with-timeout-timer-
 465                       (run-with-timer ,seconds nil
 466                                       (lambda () (throw ',timeout ',timeout))))
 467                      (with-timeout-timers
 468                          (cons -with-timeout-timer- with-timeout-timers)))
 469                 (unwind-protect
 470                     (progn ,@body)
 471                   (cancel-timer -with-timeout-timer-))))))
 472        ;; It is tempting to avoid the `if' altogether and instead run
 473        ;; timeout-forms in the timer, just before throwing `timeout'.
 474        ;; But that would mean that timeout-forms are run in the deeper
 475        ;; dynamic context of the timer, with inhibit-quit set etc...
 476        (if (eq -with-timeout-value- ',timeout)
 477            (progn ,@timeout-forms)
 478          -with-timeout-value-))))
 479
 480 (defun with-timeout-suspend ()
 481   "Stop the clock for `with-timeout'.  Used by debuggers.
 482 The idea is that the time you spend in the debugger should not
 483 count against these timeouts.
 484
 485 The value is a list that the debugger can pass to `with-timeout-unsuspend'
 486 when it exits, to make these timers start counting again."
 487   (mapcar (lambda (timer)
 488             (cancel-timer timer)
 489             (list timer (time-subtract (timer--time timer) (current-time))))
 490           with-timeout-timers))
 491
 492 (defun with-timeout-unsuspend (timer-spec-list)
 493   "Restart the clock for `with-timeout'.
 494 The argument should be a value previously returned by `with-timeout-suspend'."
 495   (dolist (elt timer-spec-list)
 496     (let ((timer (car elt))
 497           (delay (cadr elt)))
 498       (timer-set-time timer (time-add (current-time) delay))
 499       (timer-activate timer))))
 500
 501 (defun y-or-n-p-with-timeout (prompt seconds default-value)
 502   "Like (y-or-n-p PROMPT), with a timeout.
 503 If the user does not answer after SECONDS seconds, return DEFAULT-VALUE."
 504   (with-timeout (seconds default-value)
 505     (y-or-n-p prompt)))
 506 \f
 507 (defconst timer-duration-words
 508   (list (cons "microsec" 0.000001)
 509         (cons "microsecond" 0.000001)
 510         (cons "millisec" 0.001)
 511         (cons "millisecond" 0.001)
 512         (cons "sec" 1)
 513         (cons "second" 1)
 514         (cons "min" 60)
 515         (cons "minute" 60)
 516         (cons "hour" (* 60 60))
 517         (cons "day" (* 24 60 60))
 518         (cons "week" (* 7 24 60 60))
 519         (cons "fortnight" (* 14 24 60 60))
 520         (cons "month" (* 30 24 60 60))    ; Approximation
 521         (cons "year" (* 365.25 24 60 60)) ; Approximation
 522         )
 523   "Alist mapping temporal words to durations in seconds.")
 524
 525 (defun timer-duration (string)
 526   "Return number of seconds specified by STRING, or nil if parsing fails."
 527   (let ((secs 0)
 528         (start 0)
 529         (case-fold-search t))
 530     (while (string-match
 531             "[ \t]*\\([0-9.]+\\)?[ \t]*\\([a-z]+[a-rt-z]\\)s?[ \t]*"
 532             string start)
 533       (let ((count (if (match-beginning 1)
 534                        (string-to-number (match-string 1 string))
 535                      1))
 536             (itemsize (cdr (assoc (match-string 2 string)
 537                                   timer-duration-words))))
 538         (if itemsize
 539             (setq start (match-end 0)
 540                   secs (+ secs (* count itemsize)))
 541           (setq secs nil
 542                 start (length string)))))
 543     (if (= start (length string))
 544         secs
 545       (if (string-match-p "\\`[0-9.]+\\'" string)
 546           (string-to-number string)))))
 547
 548 (defun internal-timer-start-idle ()
 549   "Mark all idle-time timers as once again candidates for running."
 550   (dolist (timer timer-idle-list)
 551     (if (timerp timer) ;; FIXME: Why test?
 552         (setf (timer--triggered timer) nil))))
 553 \f
 554 (provide 'timer)
 555
 556 ;;; timer.el ends here