lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides the sorting facilities documented in the Emacs
  29 ;; user's manual.
  30
  31 ;;; Code:
  32
  33 (defgroup sort nil
  34   "Commands to sort text in an Emacs buffer."
  35   :group 'data)
  36
  37 (defcustom sort-fold-case nil
  38   "*Non-nil if the buffer sort functions should ignore case."
  39   :group 'sort
  40   :type 'boolean)
  41
  42 ;;;###autoload
  43 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  44   "General text sorting routine to divide buffer into records and sort them.
  45 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  46
  47 We divide the accessible portion of the buffer into disjoint pieces
  48 called sort records.  A portion of each sort record (perhaps all of
  49 it) is designated as the sort key.  The records are rearranged in the
  50 buffer in order by their sort keys.  The records may or may not be
  51 contiguous.
  52
  53 Usually the records are rearranged in order of ascending sort key.
  54 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  55 The variable `sort-fold-case' determines whether alphabetic case affects
  56 the sort order.
  57
  58 The next four arguments are functions to be called to move point
  59 across a sort record.  They will be called many times from within sort-subr.
  60
  61 NEXTRECFUN is called with point at the end of the previous record.
  62 It moves point to the start of the next record.
  63 It should move point to the end of the buffer if there are no more records.
  64 The first record is assumed to start at the position of point when sort-subr
  65 is called.
  66
  67 ENDRECFUN is called with point within the record.
  68 It should move point to the end of the record.
  69
  70 STARTKEYFUN moves from the start of the record to the start of the key.
  71 It may return either a non-nil value to be used as the key, or
  72 else the key is the substring between the values of point after
  73 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  74 starts at the beginning of the record.
  75
  76 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  77 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  78 same as ENDRECFUN."
  79   ;; Heuristically try to avoid messages if sorting a small amt of text.
  80   (let ((messages (> (- (point-max) (point-min)) 50000)))
  81     (save-excursion
  82       (if messages (message "Finding sort keys..."))
  83       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  84                                            startkeyfun endkeyfun))
  85              (old (reverse sort-lists))
  86              (case-fold-search sort-fold-case))
  87         (if (null sort-lists)
  88             ()
  89           (or reverse (setq sort-lists (nreverse sort-lists)))
  90           (if messages (message "Sorting records..."))
  91           (setq sort-lists
  92                 (if (fboundp 'sortcar)
  93                     (sortcar sort-lists
  94                              (cond ((numberp (car (car sort-lists)))
  95                                     ;; This handles both ints and floats.
  96                                     '<)
  97                                    ((consp (car (car sort-lists)))
  98                                     (function
  99                                      (lambda (a b)
 100                                        (> 0 (compare-buffer-substrings
 101                                              nil (car a) (cdr a)
 102                                              nil (car b) (cdr b))))))
 103                                    (t
 104                                     'string<)))
 105                   (sort sort-lists
 106                         (cond ((numberp (car (car sort-lists)))
 107                                'car-less-than-car)
 108                               ((consp (car (car sort-lists)))
 109                                (function
 110                                 (lambda (a b)
 111                                   (> 0 (compare-buffer-substrings
 112                                         nil (car (car a)) (cdr (car a))
 113                                         nil (car (car b)) (cdr (car b)))))))
 114                               (t
 115                                (function
 116                                 (lambda (a b)
 117                                   (string< (car a) (car b)))))))))
 118           (if reverse (setq sort-lists (nreverse sort-lists)))
 119           (if messages (message "Reordering buffer..."))
 120           (sort-reorder-buffer sort-lists old)))
 121       (if messages (message "Reordering buffer... Done"))))
 122   nil)
 123
 124 ;; Parse buffer into records using the arguments as Lisp expressions;
 125 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 126 ;; where KEY is the sort key (a number or string),
 127 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 128
 129 ;; The records appear in the list lastmost first!
 130
 131 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 132   (let ((sort-lists ())
 133         (start-rec nil)
 134         done key)
 135     ;; Loop over sort records.
 136     ;(goto-char (point-min)) -- it is the caller's responsibility to
 137     ;arrange this if necessary
 138     (while (not (eobp))
 139       (setq start-rec (point))          ;save record start
 140       (setq done nil)
 141       ;; Get key value, or move to start of key.
 142       (setq key (catch 'key
 143                   (or (and startkeyfun (funcall startkeyfun))
 144                       ;; If key was not returned as value,
 145                       ;; move to end of key and get key from the buffer.
 146                       (let ((start (point)))
 147                         (funcall (or endkeyfun
 148                                      (prog1 endrecfun (setq done t))))
 149                         (cons start (point))))))
 150       ;; Move to end of this record (start of next one, or end of buffer).
 151       (cond ((prog1 done (setq done nil)))
 152             (endrecfun (funcall endrecfun))
 153             (nextrecfun (funcall nextrecfun) (setq done t)))
 154       (if key (setq sort-lists (cons
 155                                  ;; consing optimization in case in which key
 156                                  ;; is same as record.
 157                                  (if (and (consp key)
 158                                           (equal (car key) start-rec)
 159                                           (equal (cdr key) (point)))
 160                                      (cons key key)
 161                                    (cons key (cons start-rec (point))))
 162                                  sort-lists)))
 163       (and (not done) nextrecfun (funcall nextrecfun)))
 164     sort-lists))
 165
 166 (defun sort-reorder-buffer (sort-lists old)
 167   (let ((last (point-min))
 168         (min (point-min)) (max (point-max))
 169         (old-buffer (current-buffer))
 170         temp-buffer)
 171     (with-temp-buffer
 172       ;; Record the temporary buffer.
 173       (setq temp-buffer (current-buffer))
 174
 175       ;; Copy the sorted text into the temporary buffer.
 176       (while sort-lists
 177         (goto-char (point-max))
 178         (insert-buffer-substring old-buffer
 179                                  last
 180                                  (nth 1 (car old)))
 181         (goto-char (point-max))
 182         (insert-buffer-substring old-buffer
 183                                  (nth 1 (car sort-lists))
 184                                  (cdr (cdr (car sort-lists))))
 185         (setq last (cdr (cdr (car old)))
 186               sort-lists (cdr sort-lists)
 187               old (cdr old)))
 188       (goto-char (point-max))
 189       (insert-buffer-substring old-buffer last max)
 190
 191       ;; Copy the reordered text from the temporary buffer
 192       ;; to the buffer we sorted (OLD-BUFFER).
 193       (set-buffer old-buffer)
 194       (let ((inhibit-quit t))
 195         ;; Make sure insertions done for reordering
 196         ;; do not go after any markers at the end of the sorted region,
 197         ;; by inserting a space to separate them.
 198         (goto-char max)
 199         (insert-before-markers " ")
 200         ;; Delete the original copy of the text.
 201         (delete-region min max)
 202         ;; Now replace the separator " " with the sorted text.
 203         (goto-char (point-max))
 204         (insert-buffer-substring temp-buffer)
 205         (delete-region min (1+ min))))))
 206
 207 ;;;###autoload
 208 (defun sort-lines (reverse beg end)
 209   "Sort lines in region alphabetically; argument means descending order.
 210 Called from a program, there are three arguments:
 211 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 212 The variable `sort-fold-case' determines whether alphabetic case affects
 213 the sort order."
 214   (interactive "P\nr")
 215   (save-excursion
 216     (save-restriction
 217       (narrow-to-region beg end)
 218       (goto-char (point-min))
 219       (sort-subr reverse 'forward-line 'end-of-line))))
 220
 221 ;;;###autoload
 222 (defun sort-paragraphs (reverse beg end)
 223   "Sort paragraphs in region alphabetically; argument means descending order.
 224 Called from a program, there are three arguments:
 225 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 226 The variable `sort-fold-case' determines whether alphabetic case affects
 227 the sort order."
 228   (interactive "P\nr")
 229   (save-excursion
 230     (save-restriction
 231       (narrow-to-region beg end)
 232       (goto-char (point-min))
 233       (sort-subr reverse
 234                  (function
 235                   (lambda ()
 236                     (while (and (not (eobp)) (looking-at paragraph-separate))
 237                       (forward-line 1))))
 238                  'forward-paragraph))))
 239
 240 ;;;###autoload
 241 (defun sort-pages (reverse beg end)
 242   "Sort pages in region alphabetically; argument means descending order.
 243 Called from a program, there are three arguments:
 244 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 245 The variable `sort-fold-case' determines whether alphabetic case affects
 246 the sort order."
 247   (interactive "P\nr")
 248   (save-excursion
 249     (save-restriction
 250       (narrow-to-region beg end)
 251       (goto-char (point-min))
 252       (sort-subr reverse
 253                  (function (lambda () (skip-chars-forward "\n")))
 254                  'forward-page))))
 255 \f
 256 (defvar sort-fields-syntax-table nil)
 257 (if sort-fields-syntax-table nil
 258   (let ((table (make-syntax-table))
 259         (i 0))
 260     (while (< i 256)
 261       (modify-syntax-entry i "w" table)
 262       (setq i (1+ i)))
 263     (modify-syntax-entry ?\  " " table)
 264     (modify-syntax-entry ?\t " " table)
 265     (modify-syntax-entry ?\n " " table)
 266     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 267     (setq sort-fields-syntax-table table)))
 268
 269 (defcustom sort-numeric-base 10
 270   "*The default base used by `sort-numeric-fields'."
 271   :group 'sort
 272   :type 'integer)
 273
 274 ;;;###autoload
 275 (defun sort-numeric-fields (field beg end)
 276   "Sort lines in region numerically by the ARGth field of each line.
 277 Fields are separated by whitespace and numbered from 1 up.
 278 Specified field must contain a number in each line of the region,
 279 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 280 Otherwise, the number is interpreted according to sort-numeric-base.
 281 With a negative arg, sorts by the ARGth field counted from the right.
 282 Called from a program, there are three arguments:
 283 FIELD, BEG and END.  BEG and END specify region to sort."
 284   (interactive "p\nr")
 285   (sort-fields-1 field beg end
 286                  (lambda ()
 287                    (sort-skip-fields field)
 288                    (let* ((case-fold-search t)
 289                           (base
 290                            (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 291                                (cond ((match-beginning 1)
 292                                       (goto-char (match-end 1))
 293                                       16)
 294                                      ((match-beginning 2)
 295                                       (goto-char (match-end 2))
 296                                       8)
 297                                      (t nil)))))
 298                      (string-to-number (buffer-substring (point)
 299                                                          (save-excursion
 300                                                            (forward-sexp 1)
 301                                                            (point)))
 302                                        (or base sort-numeric-base))))
 303                  nil))
 304
 305 ;;;;;###autoload
 306 ;;(defun sort-float-fields (field beg end)
 307 ;;  "Sort lines in region numerically by the ARGth field of each line.
 308 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 309 ;;must contain a floating point number in each line of the region.  With a
 310 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 311 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 312 ;;region to sort."
 313 ;;  (interactive "p\nr")
 314 ;;  (sort-fields-1 field beg end
 315 ;;               (function (lambda ()
 316 ;;                           (sort-skip-fields field)
 317 ;;                           (string-to-number
 318 ;;                            (buffer-substring
 319 ;;                             (point)
 320 ;;                             (save-excursion
 321 ;;                               (re-search-forward
 322 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 323 ;;                               (point))))))
 324 ;;               nil))
 325
 326 ;;;###autoload
 327 (defun sort-fields (field beg end)
 328   "Sort lines in region lexicographically by the ARGth field of each line.
 329 Fields are separated by whitespace and numbered from 1 up.
 330 With a negative arg, sorts by the ARGth field counted from the right.
 331 Called from a program, there are three arguments:
 332 FIELD, BEG and END.  BEG and END specify region to sort.
 333 The variable `sort-fold-case' determines whether alphabetic case affects
 334 the sort order."
 335   (interactive "p\nr")
 336   (sort-fields-1 field beg end
 337                  (function (lambda ()
 338                              (sort-skip-fields field)
 339                              nil))
 340                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 341
 342 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 343   (let ((tbl (syntax-table)))
 344     (if (zerop field) (setq field 1))
 345     (unwind-protect
 346         (save-excursion
 347           (save-restriction
 348             (narrow-to-region beg end)
 349             (goto-char (point-min))
 350             (set-syntax-table sort-fields-syntax-table)
 351             (sort-subr nil
 352                        'forward-line 'end-of-line
 353                        startkeyfun endkeyfun)))
 354       (set-syntax-table tbl))))
 355
 356 ;; Position at the beginning of field N on the current line,
 357 ;; assuming point is initially at the beginning of the line.
 358 (defun sort-skip-fields (n)
 359   (if (> n 0)
 360       ;; Skip across N - 1 fields.
 361       (let ((i (1- n)))
 362         (while (> i 0)
 363           (skip-chars-forward " \t")
 364           (skip-chars-forward "^ \t\n")
 365           (setq i (1- i)))
 366         (skip-chars-forward " \t")
 367         (if (eolp)
 368             (error "Line has too few fields: %s"
 369                    (buffer-substring
 370                     (save-excursion (beginning-of-line) (point))
 371                     (save-excursion (end-of-line) (point))))))
 372     (end-of-line)
 373     ;; Skip back across - N - 1 fields.
 374     (let ((i (1- (- n))))
 375       (while (> i 0)
 376         (skip-chars-backward " \t")
 377         (skip-chars-backward "^ \t\n")
 378         (setq i (1- i)))
 379       (skip-chars-backward " \t"))
 380     (if (bolp)
 381         (error "Line has too few fields: %s"
 382                (buffer-substring
 383                 (save-excursion (beginning-of-line) (point))
 384                 (save-excursion (end-of-line) (point)))))
 385     ;; Position at the front of the field
 386     ;; even if moving backwards.
 387     (skip-chars-backward "^ \t\n")))
 388 \f
 389 (defvar sort-regexp-fields-regexp)
 390 (defvar sort-regexp-record-end)
 391
 392 ;; Move to the beginning of the next match for record-regexp,
 393 ;; and set sort-regexp-record-end to the end of that match.
 394 ;; If the next match is empty and does not advance point,
 395 ;; skip one character and try again.
 396 (defun sort-regexp-fields-next-record ()
 397   (let ((oldpos (point)))
 398     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 399          (setq sort-regexp-record-end (match-end 0))
 400          (if (= sort-regexp-record-end oldpos)
 401              (progn
 402                (forward-char 1)
 403                (re-search-forward sort-regexp-fields-regexp nil 'move)
 404                (setq sort-regexp-record-end (match-end 0)))
 405            t)
 406          (goto-char (match-beginning 0)))))
 407
 408 ;;;###autoload
 409 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 410   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 411 RECORD-REGEXP specifies the textual units which should be sorted.
 412   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 413 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 414   is to be used for sorting.
 415   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 416   RECORD-REGEXP is used.
 417   If it is \"\\\\&\" then the whole record is used.
 418   Otherwise, it is a regular-expression for which to search within the record.
 419 If a match for KEY is not found within a record then that record is ignored.
 420
 421 With a negative prefix arg sorts in reverse order.
 422
 423 The variable `sort-fold-case' determines whether alphabetic case affects
 424 the sort order.
 425
 426 For example: to sort lines in the region by the first word on each line
 427  starting with the letter \"f\",
 428  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 429   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 430   ;; other sort-.*fields functions but then again this was before, since it
 431   ;; didn't use the magnitude of the arg to specify anything.
 432   (interactive "P\nsRegexp specifying records to sort:
 433 sRegexp specifying key within record: \nr")
 434   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 435          (setq key-regexp 0))
 436         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 437          (setq key-regexp (- (aref key-regexp 1) ?0))))
 438   (save-excursion
 439     (save-restriction
 440       (narrow-to-region beg end)
 441       (goto-char (point-min))
 442       (let (sort-regexp-record-end
 443             (sort-regexp-fields-regexp record-regexp))
 444         (re-search-forward sort-regexp-fields-regexp)
 445         (setq sort-regexp-record-end (point))
 446         (goto-char (match-beginning 0))
 447         (sort-subr reverse
 448                    'sort-regexp-fields-next-record
 449                    (function (lambda ()
 450                                (goto-char sort-regexp-record-end)))
 451                    (function (lambda ()
 452                                (let ((n 0))
 453                                  (cond ((numberp key-regexp)
 454                                         (setq n key-regexp))
 455                                        ((re-search-forward
 456                                           key-regexp sort-regexp-record-end t)
 457                                         (setq n 0))
 458                                        (t (throw 'key nil)))
 459                                  (condition-case ()
 460                                      (cons (match-beginning n)
 461                                            (match-end n))
 462                                    ;; if there was no such register
 463                                    (error (throw 'key nil)))))))))))
 464
 465 \f
 466 (defvar sort-columns-subprocess t)
 467
 468 ;;;###autoload
 469 (defun sort-columns (reverse &optional beg end)
 470   "Sort lines in region alphabetically by a certain range of columns.
 471 For the purpose of this command, the region BEG...END includes
 472 the entire line that point is in and the entire line the mark is in.
 473 The column positions of point and mark bound the range of columns to sort on.
 474 A prefix argument means sort into REVERSE order.
 475 The variable `sort-fold-case' determines whether alphabetic case affects
 476 the sort order.
 477
 478 Note that `sort-columns' rejects text that contains tabs,
 479 because tabs could be split across the specified columns
 480 and it doesn't know how to handle that.  Also, when possible,
 481 it uses the `sort' utility program, which doesn't understand tabs.
 482 Use \\[untabify] to convert tabs to spaces before sorting."
 483   (interactive "P\nr")
 484   (save-excursion
 485     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 486       (goto-char (min beg end))
 487       (setq col-beg1 (current-column))
 488       (beginning-of-line)
 489       (setq beg1 (point))
 490       (goto-char (max beg end))
 491       (setq col-end1 (current-column))
 492       (forward-line)
 493       (setq end1 (point))
 494       (setq col-start (min col-beg1 col-end1))
 495       (setq col-end (max col-beg1 col-end1))
 496       (if (search-backward "\t" beg1 t)
 497           (error "sort-columns does not work with tabs -- use M-x untabify"))
 498       (if (not (or (eq system-type 'vax-vms)
 499                    (text-properties-at beg1)
 500                    (< (next-property-change beg1 nil end1) end1)))
 501           ;; Use the sort utility if we can; it is 4 times as fast.
 502           ;; Do not use it if there are any properties in the region,
 503           ;; since the sort utility would lose the properties.
 504           (let ((sort-args (list (if reverse "-rt\n" "-t\n")
 505                                  (concat "+0." (int-to-string col-start))
 506                                  (concat "-0." (int-to-string col-end)))))
 507             (when sort-fold-case
 508               (push "-f" sort-args))
 509             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 510         ;; On VMS, use Emacs's own facilities.
 511         (save-excursion
 512           (save-restriction
 513             (narrow-to-region beg1 end1)
 514             (goto-char beg1)
 515             (sort-subr reverse 'forward-line 'end-of-line
 516                        #'(lambda () (move-to-column col-start) nil)
 517                        #'(lambda () (move-to-column col-end) nil))))))))
 518
 519 ;;;###autoload
 520 (defun reverse-region (beg end)
 521   "Reverse the order of lines in a region.
 522 From a program takes two point or marker arguments, BEG and END."
 523   (interactive "r")
 524   (if (> beg end)
 525       (let (mid) (setq mid end end beg beg mid)))
 526   (save-excursion
 527     ;; put beg at the start of a line and end and the end of one --
 528     ;; the largest possible region which fits this criteria
 529     (goto-char beg)
 530     (or (bolp) (forward-line 1))
 531     (setq beg (point))
 532     (goto-char end)
 533     ;; the test for bolp is for those times when end is on an empty line;
 534     ;; it is probably not the case that the line should be included in the
 535     ;; reversal; it isn't difficult to add it afterward.
 536     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 537     (setq end (point-marker))
 538     ;; the real work.  this thing cranks through memory on large regions.
 539     (let (ll (do t))
 540       (while do
 541         (goto-char beg)
 542         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 543                        ll))
 544         (setq do (/= (point) end))
 545         (delete-region beg (if do (1+ (point)) (point))))
 546       (while (cdr ll)
 547         (insert (car ll) "\n")
 548         (setq ll (cdr ll)))
 549       (insert (car ll)))))
 550
 551 (provide 'sort)
 552
 553 ;;; sort.el ends here