lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman <koppel@ece.lsu.edu>
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;;  With the hi-lock commands text matching interactively entered
  26 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  27 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  28 ;;  using a yellow background face.  New occurrences of `clearly' will
  29 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  30 ;;  will remove the highlighting.  Any existing face can be used for
  31 ;;  highlighting and a set of appropriate faces is provided.  The
  32 ;;  regexps can be written into the current buffer in a form that will
  33 ;;  be recognized the next time the corresponding file is read (when
  34 ;;  file patterns is turned on).
  35 ;;
  36 ;;  Applications:
  37 ;;
  38 ;;    In program source code highlight a variable to quickly see all
  39 ;;    places it is modified or referenced:
  40 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  41 ;;
  42 ;;    In a shell or other buffer that is showing lots of program
  43 ;;    output, highlight the parts of the output you're interested in:
  44 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  45 ;;
  46 ;;    In buffers displaying tables, highlight the lines you're interested in:
  47 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  48 ;;
  49 ;;    When writing text, highlight personal cliches.  This can be
  50 ;;    amusing.
  51 ;;    M-x highlight-phrase as can be seen RET RET
  52 ;;
  53 ;;  Setup:
  54 ;;
  55 ;;    Put the following code in your init file.  This turns on
  56 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  57 ;;    to the edit menu.
  58 ;;
  59 ;;    (global-hi-lock-mode 1)
  60 ;;
  61 ;;    To enable the use of patterns found in files (presumably placed
  62 ;;    there by hi-lock) include the following in your init file:
  63 ;;
  64 ;;    (setq hi-lock-file-patterns-policy 'ask)
  65 ;;
  66 ;;    If you get tired of being asked each time a file is loaded replace
  67 ;;    `ask' with a function that returns t if patterns should be read.
  68 ;;
  69 ;;    You might also want to bind the hi-lock commands to more
  70 ;;    finger-friendly sequences:
  71
  72 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  73 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  74 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  75 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  76 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  77 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  78
  79 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  80 ;;    additional instructions.
  81
  82 ;; Sample file patterns:
  83
  84 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  85 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  86 ; Hi-lock: end
  87
  88 ;;; Code:
  89
  90 (require 'font-lock)
  91
  92 (defgroup hi-lock nil
  93   "Interactively add and remove font-lock patterns for highlighting text."
  94   :link '(custom-manual "(emacs)Highlight Interactively")
  95   :group 'font-lock)
  96
  97 (defcustom hi-lock-file-patterns-range 10000
  98   "Limit of search in a buffer for hi-lock patterns.
  99 When a file is visited and hi-lock mode is on, patterns starting
 100 up to this limit are added to font-lock's patterns.  See documentation
 101 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 102   :type 'integer
 103   :group 'hi-lock)
 104
 105 (defcustom hi-lock-highlight-range 200000
 106   "Size of area highlighted by hi-lock when font-lock not active.
 107 Font-lock is not active in buffers that do their own highlighting,
 108 such as the buffer created by `list-colors-display'.  In those buffers
 109 hi-lock patterns will only be applied over a range of
 110 `hi-lock-highlight-range' characters.  If font-lock is active then
 111 highlighting will be applied throughout the buffer."
 112   :type 'integer
 113   :group 'hi-lock)
 114
 115 (defcustom hi-lock-exclude-modes
 116   '(rmail-mode mime/viewer-mode gnus-article-mode)
 117   "List of major modes in which hi-lock will not run.
 118 For security reasons since font lock patterns can specify function
 119 calls."
 120   :type '(repeat symbol)
 121   :group 'hi-lock)
 122
 123 (defcustom hi-lock-file-patterns-policy 'ask
 124   "Specify when hi-lock should use patterns found in file.
 125 If `ask', prompt when patterns found in buffer; if bound to a function,
 126 use patterns when function returns t (function is called with patterns
 127 as first argument); if nil or `never' or anything else, don't use file
 128 patterns."
 129   :type '(choice (const :tag "Do not use file patterns" never)
 130                  (const :tag "Ask about file patterns" ask)
 131                  (function :tag "Function to check file patterns"))
 132   :group 'hi-lock
 133   :version "22.1")
 134
 135 ;; It can have a function value.
 136 (put 'hi-lock-file-patterns-policy 'risky-local-variable t)
 137
 138 (defcustom hi-lock-auto-select-face nil
 139   "Non-nil if highlighting commands should not prompt for face names.
 140 When non-nil, each hi-lock command will cycle through faces in
 141 `hi-lock-face-defaults' without prompting."
 142   :type 'boolean
 143   :version "24.4")
 144
 145 (defgroup hi-lock-faces nil
 146   "Faces for hi-lock."
 147   :group 'hi-lock
 148   :group 'faces)
 149
 150 (defface hi-yellow
 151   '((((min-colors 88) (background dark))
 152      (:background "yellow1" :foreground "black"))
 153     (((background dark)) (:background "yellow" :foreground "black"))
 154     (((min-colors 88)) (:background "yellow1"))
 155     (t (:background "yellow")))
 156   "Default face for hi-lock mode."
 157   :group 'hi-lock-faces)
 158
 159 (defface hi-pink
 160   '((((background dark)) (:background "pink" :foreground "black"))
 161     (t (:background "pink")))
 162   "Face for hi-lock mode."
 163   :group 'hi-lock-faces)
 164
 165 (defface hi-green
 166   '((((min-colors 88) (background dark))
 167      (:background "green1" :foreground "black"))
 168     (((background dark)) (:background "green" :foreground "black"))
 169     (((min-colors 88)) (:background "green1"))
 170     (t (:background "green")))
 171   "Face for hi-lock mode."
 172   :group 'hi-lock-faces)
 173
 174 (defface hi-blue
 175   '((((background dark)) (:background "light blue" :foreground "black"))
 176     (t (:background "light blue")))
 177   "Face for hi-lock mode."
 178   :group 'hi-lock-faces)
 179
 180 (defface hi-black-b
 181   '((t (:weight bold)))
 182   "Face for hi-lock mode."
 183   :group 'hi-lock-faces)
 184
 185 (defface hi-blue-b
 186   '((((min-colors 88)) (:weight bold :foreground "blue1"))
 187     (t (:weight bold :foreground "blue")))
 188   "Face for hi-lock mode."
 189   :group 'hi-lock-faces)
 190
 191 (defface hi-green-b
 192   '((((min-colors 88)) (:weight bold :foreground "green1"))
 193     (t (:weight bold :foreground "green")))
 194   "Face for hi-lock mode."
 195   :group 'hi-lock-faces)
 196
 197 (defface hi-red-b
 198   '((((min-colors 88)) (:weight bold :foreground "red1"))
 199     (t (:weight bold :foreground "red")))
 200   "Face for hi-lock mode."
 201   :group 'hi-lock-faces)
 202
 203 (defface hi-black-hb
 204   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 205   "Face for hi-lock mode."
 206   :group 'hi-lock-faces)
 207
 208 (defvar-local hi-lock-file-patterns nil
 209   "Patterns found in file for hi-lock.  Should not be changed.")
 210 (put 'hi-lock-file-patterns 'permanent-local t)
 211
 212 (defvar-local hi-lock-interactive-patterns nil
 213   "Patterns provided to hi-lock by user.  Should not be changed.")
 214 (put 'hi-lock-interactive-patterns 'permanent-local t)
 215
 216 (define-obsolete-variable-alias 'hi-lock-face-history
 217                                 'hi-lock-face-defaults "23.1")
 218 (defvar hi-lock-face-defaults
 219   '("hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 220     "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 221   "Default faces for hi-lock interactive functions.")
 222
 223 (define-obsolete-variable-alias 'hi-lock-regexp-history
 224                                 'regexp-history
 225                                 "23.1")
 226
 227 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 228   "Search target for finding hi-lock patterns at top of file.")
 229
 230 (defvar hi-lock-archaic-interface-message-used nil
 231   "True if user alerted that `global-hi-lock-mode' is now the global switch.
 232 Earlier versions of hi-lock used `hi-lock-mode' as the global switch;
 233 the message is issued if it appears that `hi-lock-mode' is used assuming
 234 that older functionality.  This variable avoids multiple reminders.")
 235
 236 (defvar hi-lock-archaic-interface-deduce nil
 237   "If non-nil, sometimes assume that `hi-lock-mode' means `global-hi-lock-mode'.
 238 Assumption is made if `hi-lock-mode' used in the *scratch* buffer while
 239 a library is being loaded.")
 240
 241 (defvar hi-lock-menu
 242   (let ((map (make-sparse-keymap "Hi Lock")))
 243     (define-key-after map [highlight-regexp]
 244       '(menu-item "Highlight Regexp..." highlight-regexp
 245         :help "Highlight text matching PATTERN (a regexp)."))
 246
 247     (define-key-after map [highlight-phrase]
 248       '(menu-item "Highlight Phrase..." highlight-phrase
 249         :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 250
 251     (define-key-after map [highlight-lines-matching-regexp]
 252       '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 253         :help "Highlight lines containing match of PATTERN (a regexp)."))
 254
 255     (define-key-after map [unhighlight-regexp]
 256       '(menu-item "Remove Highlighting..." unhighlight-regexp
 257         :help "Remove previously entered highlighting pattern."
 258         :enable hi-lock-interactive-patterns))
 259
 260     (define-key-after map [hi-lock-write-interactive-patterns]
 261       '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 262         :help "Insert interactively added REGEXPs into buffer at point."
 263         :enable hi-lock-interactive-patterns))
 264
 265     (define-key-after map [hi-lock-find-patterns]
 266       '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 267         :help "Use patterns (if any) near top of buffer."))
 268     map)
 269   "Menu for hi-lock mode.")
 270
 271 (defvar hi-lock-map
 272   (let ((map (make-sparse-keymap "Hi Lock")))
 273     (define-key map "\C-xwi" 'hi-lock-find-patterns)
 274     (define-key map "\C-xwl" 'highlight-lines-matching-regexp)
 275     (define-key map "\C-xwp" 'highlight-phrase)
 276     (define-key map "\C-xwh" 'highlight-regexp)
 277     (define-key map "\C-xwr" 'unhighlight-regexp)
 278     (define-key map "\C-xwb" 'hi-lock-write-interactive-patterns)
 279     map)
 280   "Key map for hi-lock.")
 281
 282 (defvar hi-lock-read-regexp-defaults-function
 283   'hi-lock-read-regexp-defaults
 284   "Function that provides default regexp(s) for highlighting commands.
 285 This function should take no arguments and return one of nil, a
 286 regexp or a list of regexps for use with highlighting commands -
 287 `hi-lock-face-phrase-buffer', `hi-lock-line-face-buffer' and
 288 `hi-lock-face-buffer'.  The return value of this function is used
 289 as DEFAULTS param of `read-regexp' while executing the
 290 highlighting command.  This function is called only during
 291 interactive use.
 292
 293 For example, to highlight at symbol at point use
 294
 295     \(setq hi-lock-read-regexp-defaults-function
 296           'find-tag-default-as-regexp\)
 297
 298 If you need different defaults for different highlighting
 299 operations, use `this-command' to identify the command under
 300 execution.")
 301
 302 ;; Visible Functions
 303
 304 ;;;###autoload
 305 (define-minor-mode hi-lock-mode
 306   "Toggle selective highlighting of patterns (Hi Lock mode).
 307 With a prefix argument ARG, enable Hi Lock mode if ARG is
 308 positive, and disable it otherwise.  If called from Lisp, enable
 309 the mode if ARG is omitted or nil.
 310
 311 Hi Lock mode is automatically enabled when you invoke any of the
 312 highlighting commands listed below, such as \\[highlight-regexp].
 313 To enable Hi Lock mode in all buffers, use `global-hi-lock-mode'
 314 or add (global-hi-lock-mode 1) to your init file.
 315
 316 In buffers where Font Lock mode is enabled, patterns are
 317 highlighted using font lock.  In buffers where Font Lock mode is
 318 disabled, patterns are applied using overlays; in this case, the
 319 highlighting will not be updated as you type.
 320
 321 When Hi Lock mode is enabled, a \"Regexp Highlighting\" submenu
 322 is added to the \"Edit\" menu.  The commands in the submenu,
 323 which can be called interactively, are:
 324
 325 \\[highlight-regexp] REGEXP FACE
 326   Highlight matches of pattern REGEXP in current buffer with FACE.
 327
 328 \\[highlight-phrase] PHRASE FACE
 329   Highlight matches of phrase PHRASE in current buffer with FACE.
 330   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 331   to whitespace and initial lower-case letters will become case insensitive.)
 332
 333 \\[highlight-lines-matching-regexp] REGEXP FACE
 334   Highlight lines containing matches of REGEXP in current buffer with FACE.
 335
 336 \\[unhighlight-regexp] REGEXP
 337   Remove highlighting on matches of REGEXP in current buffer.
 338
 339 \\[hi-lock-write-interactive-patterns]
 340   Write active REGEXPs into buffer as comments (if possible).  They may
 341   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 342   is issued.  The inserted regexps are in the form of font lock keywords.
 343   (See `font-lock-keywords'.)  They may be edited and re-loaded with \\[hi-lock-find-patterns],
 344   any valid `font-lock-keywords' form is acceptable.  When a file is
 345   loaded the patterns are read if `hi-lock-file-patterns-policy' is
 346   'ask and the user responds y to the prompt, or if
 347   `hi-lock-file-patterns-policy' is bound to a function and that
 348   function returns t.
 349
 350 \\[hi-lock-find-patterns]
 351   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 352
 353 When hi-lock is started and if the mode is not excluded or patterns
 354 rejected, the beginning of the buffer is searched for lines of the
 355 form:
 356   Hi-lock: FOO
 357
 358 where FOO is a list of patterns.  The patterns must start before
 359 position \(number of characters into buffer)
 360 `hi-lock-file-patterns-range'.  Patterns will be read until
 361 Hi-lock: end is found.  A mode is excluded if it's in the list
 362 `hi-lock-exclude-modes'."
 363   :group 'hi-lock
 364   :lighter (:eval (if (or hi-lock-interactive-patterns
 365                           hi-lock-file-patterns)
 366                       " Hi" ""))
 367   :global nil
 368   :keymap hi-lock-map
 369   (when (and (equal (buffer-name) "*scratch*")
 370              load-in-progress
 371              (not (called-interactively-p 'interactive))
 372              (not hi-lock-archaic-interface-message-used))
 373     (setq hi-lock-archaic-interface-message-used t)
 374     (if hi-lock-archaic-interface-deduce
 375         (global-hi-lock-mode hi-lock-mode)
 376       (warn
 377        "Possible archaic use of (hi-lock-mode).
 378 Use (global-hi-lock-mode 1) in .emacs to enable hi-lock for all buffers,
 379 use (hi-lock-mode 1) for individual buffers.  For compatibility with Emacs
 380 versions before 22 use the following in your init file:
 381
 382         (if (functionp 'global-hi-lock-mode)
 383             (global-hi-lock-mode 1)
 384           (hi-lock-mode 1))
 385 ")))
 386   (if hi-lock-mode
 387       ;; Turned on.
 388       (progn
 389         (define-key-after menu-bar-edit-menu [hi-lock]
 390           (cons "Regexp Highlighting" hi-lock-menu))
 391         (hi-lock-find-patterns)
 392         (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook nil t))
 393     ;; Turned off.
 394     (when (or hi-lock-interactive-patterns
 395               hi-lock-file-patterns)
 396       (when hi-lock-interactive-patterns
 397         (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 398         (setq hi-lock-interactive-patterns nil))
 399       (when hi-lock-file-patterns
 400         (font-lock-remove-keywords nil hi-lock-file-patterns)
 401         (setq hi-lock-file-patterns nil))
 402       (remove-overlays nil nil 'hi-lock-overlay t)
 403       (when font-lock-fontified (font-lock-fontify-buffer)))
 404     (define-key-after menu-bar-edit-menu [hi-lock] nil)
 405     (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook t)))
 406
 407 ;;;###autoload
 408 (define-globalized-minor-mode global-hi-lock-mode
 409   hi-lock-mode turn-on-hi-lock-if-enabled
 410   :group 'hi-lock)
 411
 412 (defun turn-on-hi-lock-if-enabled ()
 413   (setq hi-lock-archaic-interface-message-used t)
 414   (unless (memq major-mode hi-lock-exclude-modes)
 415     (hi-lock-mode 1)))
 416
 417 ;;;###autoload
 418 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 419 ;;;###autoload
 420 (defun hi-lock-line-face-buffer (regexp &optional face)
 421   "Set face of all lines containing a match of REGEXP to FACE.
 422 Interactively, prompt for REGEXP then FACE.  Use
 423 `hi-lock-read-regexp-defaults-function' to retrieve default
 424 value(s) of REGEXP.  Use the global history list for FACE.
 425
 426 Use Font lock mode, if enabled, to highlight REGEXP.  Otherwise,
 427 use overlays for highlighting.  If overlays are used, the
 428 highlighting will not update as you type."
 429   (interactive
 430    (list
 431     (hi-lock-regexp-okay
 432      (read-regexp "Regexp to highlight line"
 433                   (funcall hi-lock-read-regexp-defaults-function)))
 434     (hi-lock-read-face-name)))
 435   (or (facep face) (setq face 'hi-yellow))
 436   (unless hi-lock-mode (hi-lock-mode 1))
 437   (hi-lock-set-pattern
 438    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 439    ;; or a trailing $ in REGEXP will be interpreted correctly.
 440    (concat "^.*\\(?:" regexp "\\).*$") face))
 441
 442
 443 ;;;###autoload
 444 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 445 ;;;###autoload
 446 (defun hi-lock-face-buffer (regexp &optional face)
 447   "Set face of each match of REGEXP to FACE.
 448 Interactively, prompt for REGEXP then FACE.  Use
 449 `hi-lock-read-regexp-defaults-function' to retrieve default
 450 value(s) REGEXP.  Use the global history list for FACE.
 451
 452 Use Font lock mode, if enabled, to highlight REGEXP.  Otherwise,
 453 use overlays for highlighting.  If overlays are used, the
 454 highlighting will not update as you type."
 455   (interactive
 456    (list
 457     (hi-lock-regexp-okay
 458      (read-regexp "Regexp to highlight"
 459                   (funcall hi-lock-read-regexp-defaults-function)))
 460     (hi-lock-read-face-name)))
 461   (or (facep face) (setq face 'hi-yellow))
 462   (unless hi-lock-mode (hi-lock-mode 1))
 463   (hi-lock-set-pattern regexp face))
 464
 465 ;;;###autoload
 466 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 467 ;;;###autoload
 468 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 469   "Set face of each match of phrase REGEXP to FACE.
 470 Interactively, prompt for REGEXP then FACE.  Use
 471 `hi-lock-read-regexp-defaults-function' to retrieve default
 472 value(s) of REGEXP.  Use the global history list for FACE.  When
 473 called interactively, replace whitespace in user provided regexp
 474 with arbitrary whitespace and make initial lower-case letters
 475 case-insensitive before highlighting with `hi-lock-set-pattern'.
 476
 477 Use Font lock mode, if enabled, to highlight REGEXP.  Otherwise,
 478 use overlays for highlighting.  If overlays are used, the
 479 highlighting will not update as you type."
 480   (interactive
 481    (list
 482     (hi-lock-regexp-okay
 483      (hi-lock-process-phrase
 484       (read-regexp "Phrase to highlight"
 485                    (funcall hi-lock-read-regexp-defaults-function))))
 486     (hi-lock-read-face-name)))
 487   (or (facep face) (setq face 'hi-yellow))
 488   (unless hi-lock-mode (hi-lock-mode 1))
 489   (hi-lock-set-pattern regexp face))
 490
 491 (defun hi-lock-keyword->face (keyword)
 492   (cadr (cadr (cadr keyword))))    ; Keyword looks like (REGEXP (0 'FACE) ...).
 493
 494 (declare-function x-popup-menu "menu.c" (position menu))
 495
 496 (defun hi-lock--regexps-at-point ()
 497   (let ((regexps '()))
 498     ;; When using overlays, there is no ambiguity on the best
 499     ;; choice of regexp.
 500     (let ((regexp (get-char-property (point) 'hi-lock-overlay-regexp)))
 501       (when regexp (push regexp regexps)))
 502     ;; With font-locking on, check if the cursor is on a highlighted text.
 503     (let ((face-after (get-text-property (point) 'face))
 504           (face-before
 505            (unless (bobp) (get-text-property (1- (point)) 'face)))
 506           (faces (mapcar #'hi-lock-keyword->face
 507                          hi-lock-interactive-patterns)))
 508       (unless (memq face-before faces) (setq face-before nil))
 509       (unless (memq face-after faces) (setq face-after nil))
 510       (when (and face-before face-after (not (eq face-before face-after)))
 511         (setq face-before nil))
 512       (when (or face-after face-before)
 513         (let* ((hi-text
 514                 (buffer-substring-no-properties
 515                  (if face-before
 516                      (or (previous-single-property-change (point) 'face)
 517                          (point-min))
 518                    (point))
 519                  (if face-after
 520                      (or (next-single-property-change (point) 'face)
 521                          (point-max))
 522                    (point)))))
 523           ;; Compute hi-lock patterns that match the
 524           ;; highlighted text at point.  Use this later in
 525           ;; during completing-read.
 526           (dolist (hi-lock-pattern hi-lock-interactive-patterns)
 527             (let ((regexp (car hi-lock-pattern)))
 528               (if (string-match regexp hi-text)
 529                   (push regexp regexps)))))))
 530     regexps))
 531
 532 (defvar-local hi-lock--unused-faces nil
 533   "List of faces that is not used and is available for highlighting new text.
 534 Face names from this list come from `hi-lock-face-defaults'.")
 535
 536 ;;;###autoload
 537 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 538 ;;;###autoload
 539 (defun hi-lock-unface-buffer (regexp)
 540   "Remove highlighting of each match to REGEXP set by hi-lock.
 541 Interactively, prompt for REGEXP, accepting only regexps
 542 previously inserted by hi-lock interactive functions.
 543 If REGEXP is t (or if \\[universal-argument] was specified interactively),
 544 then remove all hi-lock highlighting."
 545   (interactive
 546    (cond
 547     (current-prefix-arg (list t))
 548     ((and (display-popup-menus-p)
 549           (listp last-nonmenu-event)
 550           use-dialog-box)
 551      (catch 'snafu
 552        (or
 553         (x-popup-menu
 554          t
 555          (cons
 556           `keymap
 557           (cons "Select Pattern to Unhighlight"
 558                 (mapcar (lambda (pattern)
 559                           (list (car pattern)
 560                                 (format
 561                                  "%s (%s)" (car pattern)
 562                                  (hi-lock-keyword->face pattern))
 563                                 (cons nil nil)
 564                                 (car pattern)))
 565                         hi-lock-interactive-patterns))))
 566         ;; If the user clicks outside the menu, meaning that they
 567         ;; change their mind, x-popup-menu returns nil, and
 568         ;; interactive signals a wrong number of arguments error.
 569         ;; To prevent that, we return an empty string, which will
 570         ;; effectively disable the rest of the function.
 571         (throw 'snafu '("")))))
 572     (t
 573      ;; Un-highlighting triggered via keyboard action.
 574      (unless hi-lock-interactive-patterns
 575        (error "No highlighting to remove"))
 576      ;; Infer the regexp to un-highlight based on cursor position.
 577      (let* ((defaults (or (hi-lock--regexps-at-point)
 578                           (mapcar #'car hi-lock-interactive-patterns))))
 579        (list
 580         (completing-read (if (null defaults)
 581                              "Regexp to unhighlight: "
 582                            (format "Regexp to unhighlight (default %s): "
 583                                    (car defaults)))
 584                          hi-lock-interactive-patterns
 585                          nil t nil nil defaults))))))
 586   (dolist (keyword (if (eq regexp t) hi-lock-interactive-patterns
 587                      (list (assoc regexp hi-lock-interactive-patterns))))
 588     (when keyword
 589       (let ((face (hi-lock-keyword->face keyword)))
 590         ;; Make `face' the next one to use by default.
 591         (when (symbolp face)          ;Don't add it if it's a list (bug#13297).
 592           (add-to-list 'hi-lock--unused-faces (face-name face))))
 593       (font-lock-remove-keywords nil (list keyword))
 594       (setq hi-lock-interactive-patterns
 595             (delq keyword hi-lock-interactive-patterns))
 596       (remove-overlays
 597        nil nil 'hi-lock-overlay-regexp (hi-lock--hashcons (car keyword)))
 598       (when font-lock-fontified (font-lock-fontify-buffer)))))
 599
 600 ;;;###autoload
 601 (defun hi-lock-write-interactive-patterns ()
 602   "Write interactively added patterns, if any, into buffer at point.
 603
 604 Interactively added patterns are those normally specified using
 605 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 606 be found in variable `hi-lock-interactive-patterns'."
 607   (interactive)
 608   (if (null hi-lock-interactive-patterns)
 609       (error "There are no interactive patterns"))
 610   (let ((beg (point)))
 611     (mapc
 612      (lambda (pattern)
 613        (insert (format "%s: (%s)\n"
 614                        hi-lock-file-patterns-prefix
 615                        (prin1-to-string pattern))))
 616      hi-lock-interactive-patterns)
 617     (comment-region beg (point)))
 618   (when (> (point) hi-lock-file-patterns-range)
 619     (warn "Inserted keywords not close enough to top of file")))
 620
 621 ;; Implementation Functions
 622
 623 (defun hi-lock-process-phrase (phrase)
 624   "Convert regexp PHRASE to a regexp that matches phrases.
 625
 626 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 627 and initial lower-case letters made case insensitive."
 628   (let ((mod-phrase nil))
 629     ;; FIXME fragile; better to just bind case-fold-search?  (Bug#7161)
 630     (setq mod-phrase
 631           (replace-regexp-in-string
 632            "\\(^\\|\\s-\\)\\([a-z]\\)"
 633            (lambda (m) (format "%s[%s%s]"
 634                                (match-string 1 m)
 635                                (upcase (match-string 2 m))
 636                                (match-string 2 m))) phrase))
 637     ;; FIXME fragile; better to use search-spaces-regexp?
 638     (setq mod-phrase
 639           (replace-regexp-in-string
 640            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 641
 642 (defun hi-lock-regexp-okay (regexp)
 643   "Return REGEXP if it appears suitable for a font-lock pattern.
 644
 645 Otherwise signal an error.  A pattern that matches the null string is
 646 not suitable."
 647   (if (string-match regexp "")
 648       (error "Regexp cannot match an empty string")
 649     regexp))
 650
 651 (defun hi-lock-read-regexp-defaults ()
 652   "Return the latest regexp from `regexp-history'.
 653 See `hi-lock-read-regexp-defaults-function' for details."
 654   (car regexp-history))
 655
 656 (defun hi-lock-read-face-name ()
 657   "Return face for interactive highlighting.
 658 When `hi-lock-auto-select-face' is non-nil, just return the next face.
 659 Otherwise, read face name from minibuffer with completion and history."
 660   (unless hi-lock-interactive-patterns
 661     (setq hi-lock--unused-faces hi-lock-face-defaults))
 662   (let* ((last-used-face
 663           (when hi-lock-interactive-patterns
 664             (face-name (hi-lock-keyword->face
 665                         (car hi-lock-interactive-patterns)))))
 666          (defaults (append hi-lock--unused-faces
 667                            (cdr (member last-used-face hi-lock-face-defaults))
 668                            hi-lock-face-defaults))
 669          face)
 670           (if (and hi-lock-auto-select-face (not current-prefix-arg))
 671         (setq face (or (pop hi-lock--unused-faces) (car defaults)))
 672       (setq face (completing-read
 673                   (format "Highlight using face (default %s): "
 674                           (car defaults))
 675                   obarray 'facep t nil 'face-name-history defaults))
 676       ;; Update list of un-used faces.
 677       (setq hi-lock--unused-faces (remove face hi-lock--unused-faces))
 678       ;; Grow the list of defaults.
 679       (add-to-list 'hi-lock-face-defaults face t))
 680     (intern face)))
 681
 682 (defun hi-lock-set-pattern (regexp face)
 683   "Highlight REGEXP with face FACE."
 684   ;; Hashcons the regexp, so it can be passed to remove-overlays later.
 685   (setq regexp (hi-lock--hashcons regexp))
 686   (let ((pattern (list regexp (list 0 (list 'quote face) t))))
 687     ;; Refuse to highlight a text that is already highlighted.
 688     (unless (assoc regexp hi-lock-interactive-patterns)
 689       (push pattern hi-lock-interactive-patterns)
 690       (if font-lock-mode
 691           (progn
 692             (font-lock-add-keywords nil (list pattern) t)
 693             (font-lock-fontify-buffer))
 694         (let* ((range-min (- (point) (/ hi-lock-highlight-range 2)))
 695                (range-max (+ (point) (/ hi-lock-highlight-range 2)))
 696                (search-start
 697                 (max (point-min)
 698                      (- range-min (max 0 (- range-max (point-max))))))
 699                (search-end
 700                 (min (point-max)
 701                      (+ range-max (max 0 (- (point-min) range-min))))))
 702           (save-excursion
 703             (goto-char search-start)
 704             (while (re-search-forward regexp search-end t)
 705               (let ((overlay (make-overlay (match-beginning 0) (match-end 0))))
 706                 (overlay-put overlay 'hi-lock-overlay t)
 707                 (overlay-put overlay 'hi-lock-overlay-regexp regexp)
 708                 (overlay-put overlay 'face face))
 709               (goto-char (match-end 0)))))))))
 710
 711 (defun hi-lock-set-file-patterns (patterns)
 712   "Replace file patterns list with PATTERNS and refontify."
 713   (when (or hi-lock-file-patterns patterns)
 714     (font-lock-remove-keywords nil hi-lock-file-patterns)
 715     (setq hi-lock-file-patterns patterns)
 716     (font-lock-add-keywords nil hi-lock-file-patterns t)
 717     (font-lock-fontify-buffer)))
 718
 719 (defun hi-lock-find-patterns ()
 720   "Find patterns in current buffer for hi-lock."
 721   (interactive)
 722   (unless (memq major-mode hi-lock-exclude-modes)
 723     (let ((all-patterns nil)
 724           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 725       (save-excursion
 726         (save-restriction
 727           (widen)
 728           (goto-char (point-min))
 729           (re-search-forward target-regexp
 730                              (+ (point) hi-lock-file-patterns-range) t)
 731           (beginning-of-line)
 732           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 733                       (not (looking-at "\\s-*end")))
 734             (condition-case nil
 735                 (setq all-patterns (append (read (current-buffer)) all-patterns))
 736               (error (message "Invalid pattern list expression at %d"
 737                               (line-number-at-pos)))))))
 738       (when (and all-patterns
 739                  hi-lock-mode
 740                  (cond
 741                   ((eq this-command 'hi-lock-find-patterns) t)
 742                   ((functionp hi-lock-file-patterns-policy)
 743                    (funcall hi-lock-file-patterns-policy all-patterns))
 744                   ((eq hi-lock-file-patterns-policy 'ask)
 745                    (y-or-n-p "Add patterns from this buffer to hi-lock? "))
 746                   (t nil)))
 747         (hi-lock-set-file-patterns all-patterns)
 748         (if (called-interactively-p 'interactive)
 749             (message "Hi-lock added %d patterns." (length all-patterns)))))))
 750
 751 (defun hi-lock-font-lock-hook ()
 752   "Add hi-lock patterns to font-lock's."
 753   (when font-lock-fontified
 754     (font-lock-add-keywords nil hi-lock-file-patterns t)
 755     (font-lock-add-keywords nil hi-lock-interactive-patterns t)))
 756
 757 (defvar hi-lock--hashcons-hash
 758   (make-hash-table :test 'equal :weakness t)
 759   "Hash table used to hash cons regexps.")
 760
 761 (defun hi-lock--hashcons (string)
 762   "Return unique object equal to STRING."
 763   (or (gethash string hi-lock--hashcons-hash)
 764       (puthash string string hi-lock--hashcons-hash)))
 765
 766 (defun hi-lock-unload-function ()
 767   "Unload the Hi-Lock library."
 768   (global-hi-lock-mode -1)
 769   ;; continue standard unloading
 770   nil)
 771
 772 (provide 'hi-lock)
 773
 774 ;;; hi-lock.el ends here