lisp/minibuf-eldef.el

   1 ;;; minibuf-eldef.el --- Only show defaults in prompts when applicable
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Miles Bader <miles@gnu.org>
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; Defines the mode `minibuffer-electric-default-mode'.
  27 ;;
  28 ;; When active, minibuffer prompts that show a default value only show
  29 ;; the default when it's applicable -- that is, when hitting RET would
  30 ;; yield the default value.  If the user modifies the input such that
  31 ;; hitting RET would enter a non-default value, the prompt is modified
  32 ;; to remove the default indication (which is restored if the input is
  33 ;; ever restore to the match the initial input).
  34
  35 ;;; Code:
  36
  37 (defvar minibuffer-default-in-prompt-regexps
  38   '(("\\( (default\\>.*)\\):? \\'" . 1) ("\\( \\[.*\\]\\):? *\\'" . 1))
  39   "*A list of regexps matching the parts of minibuffer prompts showing defaults.
  40 When `minibuffer-electric-default-mode' is active, these regexps are
  41 used to identify the portions of prompts to elide.
  42
  43 Each entry is either a string, which should be a regexp matching the
  44 default portion of the prompt, or a cons cell, who's car is a regexp
  45 matching the default part of the prompt, and who's cdr indicates the
  46 regexp subexpression that matched.")
  47
  48 \f
  49 ;;; Internal variables
  50
  51 ;; A list of minibuffers to which we've added a post-command-hook.
  52 (defvar minibuf-eldef-frobbed-minibufs nil)
  53
  54 ;;; The following are all local variables in the minibuffer
  55
  56 ;; Input pre-inserted into the minibuffer before the user can edit it.
  57 (defvar minibuf-eldef-initial-input)
  58 (make-variable-buffer-local 'minibuf-eldef-initial-input)
  59 ;; and the length of the buffer with it inserted.
  60 (defvar minibuf-eldef-initial-buffer-length)
  61 (make-variable-buffer-local 'minibuf-eldef-initial-buffer-length)
  62
  63 ;; True if the current minibuffer prompt contains the default spec.
  64 (defvar minibuf-eldef-showing-default-in-prompt)
  65 (make-variable-buffer-local 'minibuf-eldef-showing-default-in-prompt)
  66
  67 ;; An overlay covering the default portion of the prompt
  68 (defvar minibuf-eldef-overlay)
  69 (make-variable-buffer-local 'minibuf-eldef-overlay)
  70
  71 \f
  72 ;;; Hook functions
  73
  74 ;; This function goes on minibuffer-setup-hook
  75 (defun minibuf-eldef-setup-minibuffer ()
  76   "Set up a minibuffer for `minibuffer-electric-default-mode'.
  77 The prompt and initial input should already have been inserted."
  78   (let ((regexps minibuffer-default-in-prompt-regexps)
  79         (match nil)
  80         (inhibit-point-motion-hooks t))
  81     (save-excursion
  82       (save-restriction
  83         ;; Narrow to only the prompt
  84         (goto-char (point-min))
  85         (narrow-to-region (point) (minibuffer-prompt-end))
  86         ;; See the prompt contains a default input indicator
  87         (while regexps
  88           (setq match (pop regexps))
  89           (if (re-search-forward (if (stringp match) match (car match)) nil t)
  90               (setq regexps nil)
  91             (setq match nil)))))
  92     (if (not match)
  93         ;; Nope, so just make sure our post-command-hook isn't left around.
  94         (remove-hook 'post-command-hook #'minibuf-eldef-update-minibuffer t)
  95       ;; Yup; set things up so we can frob the prompt as the state of
  96       ;; the input string changes.
  97       (setq match (if (consp match) (cdr match) 0))
  98       (setq minibuf-eldef-overlay
  99             (make-overlay (match-beginning match) (match-end match)))
 100       (setq minibuf-eldef-showing-default-in-prompt t)
 101       (setq minibuf-eldef-initial-input
 102             (minibuffer-contents-no-properties))
 103       (setq minibuf-eldef-initial-buffer-length (point-max))
 104       (add-to-list 'minibuf-eldef-frobbed-minibufs (current-buffer))
 105       (add-hook 'post-command-hook #'minibuf-eldef-update-minibuffer nil t))))
 106
 107 ;; post-command-hook to swap prompts when necessary
 108 (defun minibuf-eldef-update-minibuffer ()
 109   "Update a minibuffer's prompt to include a default only when applicable.
 110 This is intended to be used as a minibuffer post-command-hook for
 111 `minibuffer-electric-default-mode'; the minibuffer should have already
 112 been set up by `minibuf-eldef-setup-minibuffer'."
 113   (unless (eq minibuf-eldef-showing-default-in-prompt
 114               (and (= (point-max) minibuf-eldef-initial-buffer-length)
 115                    (string-equal (minibuffer-contents-no-properties)
 116                                  minibuf-eldef-initial-input)))
 117     ;; swap state
 118     (setq minibuf-eldef-showing-default-in-prompt
 119           (not minibuf-eldef-showing-default-in-prompt))
 120     (cond (minibuf-eldef-showing-default-in-prompt
 121            (overlay-put minibuf-eldef-overlay 'invisible nil)
 122            (overlay-put minibuf-eldef-overlay 'intangible nil))
 123           (t
 124            (overlay-put minibuf-eldef-overlay 'invisible t)
 125            (overlay-put minibuf-eldef-overlay 'intangible t)))))
 126
 127 \f
 128 ;;; Note this definition must be at the end of the file, because
 129 ;;; `define-minor-mode' actually calls the mode-function if the
 130 ;;; associated variable is non-nil, which requires that all needed
 131 ;;; functions be already defined.  [This is arguably a bug in d-m-m]
 132 ;;;###autoload
 133 (define-minor-mode minibuffer-electric-default-mode
 134   "Toggle Minibuffer Electric Default mode.
 135 When active, minibuffer prompts that show a default value only show the
 136 default when it's applicable -- that is, when hitting RET would yield
 137 the default value.  If the user modifies the input such that hitting RET
 138 would enter a non-default value, the prompt is modified to remove the
 139 default indication.
 140
 141 With prefix argument ARG, turn on if positive, otherwise off.
 142 Returns non-nil if the new state is enabled."
 143   :global t
 144   :group 'minibuffer
 145   (if minibuffer-electric-default-mode
 146       ;; Enable the mode
 147       (add-hook 'minibuffer-setup-hook 'minibuf-eldef-setup-minibuffer)
 148     ;; Disable the mode
 149     (remove-hook 'minibuffer-setup-hook 'minibuf-eldef-setup-minibuffer)
 150     ;; Remove our entry from any post-command-hook variable's it's still in
 151     (dolist (minibuf minibuf-eldef-frobbed-minibufs)
 152       (with-current-buffer minibuf
 153         (remove-hook 'post-command-hook #'minibuf-eldef-update-minibuffer t)))
 154     (setq minibuf-eldef-frobbed-minibufs nil)))
 155
 156
 157 (provide 'minibuf-eldef)
 158
 159 ;; arch-tag: 7e421fae-c275-4729-b0da-7836af377d3d
 160 ;;; minibuf-eldef.el ends here