lisp/iimage.el

   1 ;;; iimage.el --- Inline image minor mode.
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: KOSEKI Yoshinori <kose@meadowy.org>
   6 ;; Maintainer: KOSEKI Yoshinori <kose@meadowy.org>
   7 ;; Keywords: multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Iimage is a minor mode that displays images, when image-filename
  27 ;; exists in the buffer.
  28 ;; http://www.netlaputa.ne.jp/~kose/Emacs/iimage.html
  29 ;;
  30 ;; Add to your `~/.emacs':
  31 ;; (autoload 'iimage-mode "iimage" "Support Inline image minor mode." t)
  32 ;; (autoload 'turn-on-iimage-mode "iimage" "Turn on Inline image minor mode." t)
  33 ;;
  34 ;; ** Display images in *Info* buffer.
  35 ;;
  36 ;; (add-hook 'info-mode-hook 'turn-on-iimage-mode)
  37 ;;
  38 ;; .texinfo:   @file{file://foo.png}
  39 ;; .info:      `file://foo.png'
  40 ;;
  41 ;; ** Display images in Wiki buffer.
  42 ;;
  43 ;; (add-hook 'wiki-mode-hook 'turn-on-iimage-mode)
  44 ;;
  45 ;; wiki-file:   [[foo.png]]
  46
  47 ;;; Code:
  48
  49 (eval-when-compile
  50   (require 'image-file))
  51
  52 (defgroup iimage nil
  53   "Support for inline images."
  54   :version "22.1"
  55   :group 'image)
  56
  57 (defconst iimage-version "1.1")
  58 (defvar iimage-mode nil)
  59 (defvar iimage-mode-map nil)
  60
  61 ;; Set up key map.
  62 (unless iimage-mode-map
  63   (setq iimage-mode-map (make-sparse-keymap))
  64   (define-key iimage-mode-map "\C-l" 'iimage-recenter))
  65
  66 (defun iimage-recenter (&optional arg)
  67 "Re-draw images and recenter."
  68   (interactive "P")
  69   (iimage-mode-buffer 0)
  70   (iimage-mode-buffer 1)
  71   (recenter arg))
  72
  73 (defvar iimage-mode-image-filename-regex
  74   (concat "[-+./_0-9a-zA-Z]+\\."
  75           (regexp-opt (nconc (mapcar #'upcase
  76                                      image-file-name-extensions)
  77                              image-file-name-extensions)
  78                       t)))
  79
  80 (defvar iimage-mode-image-regex-alist
  81   `((,(concat "\\(`?file://\\|\\[\\[\\|<\\|`\\)?"
  82               "\\(" iimage-mode-image-filename-regex "\\)"
  83               "\\(\\]\\]\\|>\\|'\\)?") . 2))
  84 "*Alist of filename REGEXP vs NUM.
  85 Each element looks like (REGEXP . NUM).
  86 NUM specifies which parenthesized expression in the regexp.
  87
  88 Examples of image filename regexps:
  89     file://foo.png
  90     `file://foo.png'
  91     \\[\\[foo.gif]]
  92     <foo.png>
  93      foo.JPG
  94 ")
  95
  96 (defvar iimage-mode-image-search-path nil
  97 "*List of directories to search for image files for iimage-mode.")
  98
  99 ;;;###autoload
 100 (defun turn-on-iimage-mode ()
 101 "Unconditionally turn on iimage mode."
 102   (interactive)
 103   (iimage-mode 1))
 104
 105 (defun turn-off-iimage-mode ()
 106 "Unconditionally turn off iimage mode."
 107   (interactive)
 108   (iimage-mode 0))
 109
 110 (defalias 'iimage-locate-file 'locate-file)
 111
 112 (defun iimage-mode-buffer (arg)
 113 "Display/undisplay images.
 114 With numeric ARG, display the images if and only if ARG is positive."
 115   (interactive)
 116   (let ((ing (if (numberp arg)
 117                  (> arg 0)
 118                iimage-mode))
 119         (modp (buffer-modified-p (current-buffer)))
 120         file buffer-read-only)
 121     (save-excursion
 122       (goto-char (point-min))
 123       (dolist (pair iimage-mode-image-regex-alist)
 124         (while (re-search-forward (car pair) nil t)
 125           (if (and (setq file (match-string (cdr pair)))
 126                    (setq file (iimage-locate-file file
 127                                    (cons default-directory
 128                                          iimage-mode-image-search-path))))
 129               (if ing
 130                   (add-text-properties (match-beginning 0) (match-end 0)
 131                                        (list 'display (create-image file)))
 132                 (remove-text-properties (match-beginning 0) (match-end 0)
 133                                         '(display)))))))
 134     (set-buffer-modified-p modp)))
 135
 136 ;;;###autoload
 137 (define-minor-mode iimage-mode
 138   "Toggle inline image minor mode."
 139   :group 'iimage :lighter " iImg" :keymap iimage-mode-map
 140   (run-hooks 'iimage-mode-hook)
 141   (iimage-mode-buffer iimage-mode))
 142
 143 (provide 'iimage)
 144
 145 ;; arch-tag: f6f8e29a-08f6-4a12-9496-51e67441ce65
 146 ;;; iimage.el ends here