lisp/echistory.el

   1 ;;; echistory.el --- Electric Command History Mode
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Author: K. Shane Hartman
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'electric)                     ; command loop
  28 (require 'chistory)                     ; history lister
  29
  30 ;;;###autoload
  31 (defun Electric-command-history-redo-expression (&optional noconfirm)
  32   "Edit current history line in minibuffer and execute result.
  33 With prefix arg NOCONFIRM, execute current line as-is without editing."
  34   (interactive "P")
  35   (let (todo)
  36     (save-excursion
  37       (set-buffer "*Command History*")
  38       (beginning-of-line)
  39       (setq todo (read (current-buffer)))
  40       (if (boundp 'electric-history-in-progress)
  41           (if todo (throw 'electric-history-quit (list noconfirm todo)))))))
  42
  43 (defvar electric-history-map ())
  44 (if electric-history-map
  45     ()
  46   (setq electric-history-map (make-sparse-keymap))
  47   (define-key electric-history-map [t] 'Electric-history-undefined)
  48   (define-key electric-history-map "\e" (make-sparse-keymap))
  49   (define-key electric-history-map [?\e t] 'Electric-history-undefined)
  50   (define-key electric-history-map "\C-u" 'universal-argument)
  51   (define-key electric-history-map " " 'Electric-command-history-redo-expression)
  52   (define-key electric-history-map "!" 'Electric-command-history-redo-expression)
  53   (define-key electric-history-map "\e\C-x" 'eval-sexp)
  54   (define-key electric-history-map "\e\C-d" 'down-list)
  55   (define-key electric-history-map "\e\C-u" 'backward-up-list)
  56   (define-key electric-history-map "\e\C-b" 'backward-sexp)
  57   (define-key electric-history-map "\e\C-f" 'forward-sexp)
  58   (define-key electric-history-map "\e\C-a" 'beginning-of-defun)
  59   (define-key electric-history-map "\e\C-e" 'end-of-defun)
  60   (define-key electric-history-map "\e\C-n" 'forward-list)
  61   (define-key electric-history-map "\e\C-p" 'backward-list)
  62   (define-key electric-history-map "q" 'Electric-history-quit)
  63   (define-key electric-history-map "\C-c" nil)
  64   (define-key electric-history-map "\C-c\C-c" 'Electric-history-quit)
  65   (define-key electric-history-map "\C-]" 'Electric-history-quit)
  66   (define-key electric-history-map "\C-z" 'suspend-emacs)
  67   (define-key electric-history-map (char-to-string help-char) 'Helper-help)
  68   (define-key electric-history-map "?" 'Helper-describe-bindings)
  69   (define-key electric-history-map "\e>" 'end-of-buffer)
  70   (define-key electric-history-map "\e<" 'beginning-of-buffer)
  71   (define-key electric-history-map "\n" 'next-line)
  72   (define-key electric-history-map "\r" 'next-line)
  73   (define-key electric-history-map "\177" 'previous-line)
  74   (define-key electric-history-map "\C-n" 'next-line)
  75   (define-key electric-history-map "\C-p" 'previous-line)
  76   (define-key electric-history-map "\ev" 'scroll-down)
  77   (define-key electric-history-map "\C-v" 'scroll-up)
  78   (define-key electric-history-map [home] 'beginning-of-buffer)
  79   (define-key electric-history-map [down] 'next-line)
  80   (define-key electric-history-map [up] 'previous-line)
  81   (define-key electric-history-map [prior] 'scroll-down)
  82   (define-key electric-history-map [next] 'scroll-up)
  83   (define-key electric-history-map "\C-l" 'recenter)
  84   (define-key electric-history-map "\e\C-v" 'scroll-other-window))
  85
  86 (defvar electric-command-history-hook nil
  87   "If non-nil, its value is called by `electric-command-history'.")
  88
  89 (defun electric-command-history ()
  90   "\\<electric-history-map>Major mode for examining and redoing commands from `command-history'.
  91 This pops up a window with the Command History listing.
  92 The number of command listed is controlled by `list-command-history-max'.
  93 The command history is filtered by `list-command-history-filter' if non-nil.
  94 Combines typeout Command History list window with menu like selection
  95 of an expression from the history for re-evaluation in the *original* buffer.
  96
  97 The history displayed is filtered by `list-command-history-filter' if non-nil.
  98
  99 Like Emacs-Lisp mode except that characters do not insert themselves and
 100 Tab and Linefeed do not indent.  Instead these commands are provided:
 101 \\{electric-history-map}
 102
 103 Calls the value of `electric-command-history-hook' if that is non-nil.
 104 The Command History listing is recomputed each time this mode is invoked."
 105   (interactive)
 106   (let ((electric-history-in-progress t)
 107         (old-buffer (current-buffer))
 108         (todo))
 109     (unwind-protect
 110         (setq todo
 111               (catch 'electric-history-quit
 112                 (save-window-excursion
 113                   (save-window-excursion
 114                     (list-command-history)
 115                     (set-buffer "*Command History*")
 116                     (Command-history-setup)
 117                     (setq major-mode 'electric-command-history)
 118                     (setq mode-name "Electric History")
 119                     (use-local-map electric-history-map))
 120                   (Electric-pop-up-window "*Command History*")
 121                   (run-hooks 'electric-command-history-hook)
 122                   (if (eobp)
 123                       (progn (ding)
 124                              (message "No command history.")
 125                              (throw 'electric-history-quit nil))
 126                     (let ((Helper-return-blurb "return to History"))
 127                       (Electric-command-loop 'electric-history-quit
 128                                              "->" t))))))
 129       (set-buffer "*Command History*")
 130       (command-history-mode)
 131       (bury-buffer (current-buffer)))
 132     (if (consp todo)
 133         (progn (set-buffer old-buffer)
 134                (if (car todo)
 135                    (apply (car (car (cdr todo))) (cdr (car (cdr todo))))
 136                  (edit-and-eval-command "Redo: " (car (cdr todo))))))))
 137
 138 (defun Electric-history-undefined ()
 139   (interactive)
 140   (ding)
 141   (message (substitute-command-keys "Type \\[Helper-help] for help, ? for commands, C-c C-c to quit, Space to execute"))
 142   (sit-for 4))
 143
 144 (defun Electric-history-quit ()
 145   "Quit Electric Command History, restoring previous window configuration."
 146   (interactive)
 147   (if (boundp 'electric-history-in-progress)
 148       (progn (message "")
 149              (throw 'electric-history-quit nil))))
 150
 151 (provide 'echistory)
 152
 153 ;;; echistory.el ends here